home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / basic / windchil.bqs / WINDCHIL.BAS
BASIC Source File  |  1986-12-04  |  2KB  |  35 lines

  1. 10    REM ************** WINDCHIL.BAS **************
  2. 20    REM WRITTEN IN MICROSOFT BASIC BY MIKE LOZANO
  3. 30    REM CHIEF METEOROLOGIST, WHO TELEVISION, DES MOINES, IOWA
  4. 40    REM 1801 GRAND AVE. DES MOINES, IOWA 50308 (515)-242-3635
  5. 50    REM RELEASED TO THE PUBLIC DOMAIN FOR PERSONAL & NON-PROFIT USE.
  6. 60    REM DON'T CHANGE MATHEMATICAL RELATIONSHIP OF LINES
  7. 70    REM 180 & 210 OR YOU'LL GET FALSE RESULTS!
  8. 80    REM LINES 190 & 200 ARE THE FORMULA FOR WIND CHILL FACTOR.
  9. 90    PRINT CHR$(12):PRINT:PRINT: REM CHR$(12) CLEARS THE SCREEN
  10. 100    PRINT" WIND CHILL CALCULATOR ":PRINT:
  11. 110    INPUT" ENTER TEMPERATURE ",T: PRINT:
  12. 120    PRINT" (F) or (C)?":PRINT
  13. 130    T$=INKEY$: IF LEN(T$)=0 THEN GOTO 130
  14. 140    IF T$="F" THEN GOTO 170 
  15. 150    IF T$="C" THEN GOSUB 280:GOTO 170
  16. 160    PRINT CHR$(7);:GOTO 130
  17. 170    INPUT" ENTER WIND SPEED ",V:PRINT:
  18. 180    IF V>60 THEN V=60
  19. 190    A=6.686*SQR(V)-.447*V+10.45
  20. 200    WCI=91.4+A*(.04538*T-4.148)
  21. 210    IF V<5 THEN WCI=T ELSE IF WCI>T THEN GOTO 300
  22. 220    IF T$="C" THEN WCI=((5/9)*(WCI-32)) ELSE WCI=WCI:
  23. 230    PRINT " WIND CHILL = ";:PRINT USING "####.#";WCI;:PRINT" ";T$;: PRINT " DEGREES": PRINT:PRINT:
  24. 240    PRINT" ANOTHER RUN? Y/N ":
  25. 250    C$=INKEY$: IF LEN(C$)=0 THEN GOTO 250
  26. 260    IF C$="Y" THEN GOTO 20 ELSE IF C$="N" THEN END
  27. 270    PRINT CHR$(7);:GOTO 250
  28. 280    T=((9/5)*(T))+32
  29. 290    RETURN
  30. 300    PRINT" SORRY - BEYOND FORMULA LIMITS! ":PRINT:GOTO 240
  31. 310    REM ** FOR FREE WINDCHILL BROCHURE WHICH EXPLAINS WHAT WIND CHILL
  32. 320    REM ** ACTUALLY IS - HOW IT CAME TO BE - AND WHEN IT'S DANGEROUS
  33. 330    REM ** SEND S.A.S.E (BUSINESS SIZE ENVELOPE) TO ADDRESS ABOVE.
  34. 340    REM ** ENJOY!!!
  35.