home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / bye3 / b3c-ss1.ins < prev    next >
Text File  |  1994-07-13  |  3KB  |  131 lines
  1. ;
  2. ; B3C-SS1.INS - Clock routine for the System Support 1    07/24/85
  3. ;                        -- by pst
  4. ; 
  5. ;    This clock routine needs:
  6. ;        BCD2BIN    - no
  7. ;        BIN2BCD - no
  8. ;
  9. ; 6/28/85 - Added hold support and also pokes RTCBUF with time.
  10. ;                        -- pst
  11. ;
  12. ;----------------------------------------------------------------
  13. ;
  14. ;    Note- This is an insert--not an overlay
  15. ;
  16.      IF    RTC
  17. SS1BASE    EQU    050H        ; Base port for SS1
  18. CLKCMD    EQU    SS1BASE+10    ; Clock command port
  19. CLKDATA    EQU    SS1BASE+11    ; Clock data port
  20. CLKREAD    EQU    16        ; Read command bit
  21. CLKHOLD    EQU    64        ; Hold command bit
  22. ;
  23. TIME:    LXI    H,RTCBUF    ; Point to RTC buffer
  24.     MVI    C,5        ; Set counter for hour tens
  25.     CALL    RDIGIT        ; Get hour tens
  26.     CALL    SHFT4        ; Save in buffer
  27.     CALL    MULT10        ; Multiply by 10
  28.     MOV    B,A        ; Save in B reg
  29.     CALL    RDIGIT        ; Get hour units in A reg
  30.     CALL    ADDLOW        ; Set BCD digit
  31.     ADD    B        ; Add tens digit from B
  32.     STA    CCHOUR        ; Store for later use
  33. ;
  34. ;    Minutes
  35. ;
  36.     CALL    RDIGIT        ; Get minute tens in A reg
  37.     CALL    SHFT4        ; Save in buffer
  38.     CALL    MULT10        ; Multiply by 10
  39.     MOV    B,A        ; Save in B reg
  40.     CALL    RDIGIT        ; Get minute units in A reg
  41.     CALL    ADDLOW        ; Set BCD digit
  42.     ADD    B        ; Add in minutes tens from B
  43.     STA    CCMIN        ; Store for later use
  44. ;
  45. ;    Seconds
  46. ;
  47.     CALL    RDIGIT        ; Second tens
  48.     CALL    SHFT4
  49.     CALL    RDIGIT        ; Second units
  50.     CALL    ADDLOW
  51. ;
  52. ;    Year
  53. ;
  54.     INX    H        ; Skip over "19"
  55.     MVI    C,12        ; Start with years tens
  56.     CALL    RDIGIT
  57.     CALL    SHFT4
  58.     CALL    RDIGIT        ; Years units
  59.     CALL    ADDLOW
  60. ;
  61.     CALL    RDIGIT        ; Month tens
  62.     CALL    SHFT4
  63.     CALL    RDIGIT        ; Month units
  64.     CALL    ADDLOW
  65. ;
  66.     CALL    RDIGIT        ; Day tens
  67.     CALL    SHFT4
  68.     CALL    RDIGIT        ; Day units
  69.     CALL    ADDLOW
  70. ;
  71.     XRA    A
  72.     OUT    CLKCMD        ; Turn off hold bit
  73.     RET
  74. ;
  75. ;    Read a digit
  76. ;        Command in C
  77. ;        Digit returned in A
  78. ;        C is decremented
  79. ;        Hold bit is set
  80. ;
  81. RDIGIT:    MOV    A,C        ; Get command byte
  82.     DCR    C        ; Bump it for next operation
  83.     ORI    CLKREAD+CLKHOLD    ; Add in read & hold bits
  84.     OUT    CLKCMD        ; Output it
  85.     ANI    15        ; Strip off any commands
  86.     CPI    5        ; Was it hour tens digit?
  87.     IN    CLKDATA        ; Get data
  88.     RNZ            ; No, return
  89.     ANI    3        ; Yes, so kill 24 hour bit
  90.     RET
  91. ;
  92. ;    Multiply register A by 10
  93. ;    Destroys 'D'
  94. ;
  95. MULT10:    ADD    A        ; 2x
  96.     MOV    D,A
  97.     ADD    A        ; 4x
  98.     ADD    A        ; 8x
  99.     ADD    D        ; 10x
  100.     RET
  101. ;
  102. ;    Shift A to high nibble
  103. ;        Stores shifted value in 'M'
  104. ;        Destroys 'E'
  105. ;        A is left unchanged
  106. ;
  107. SHFT4:    MOV    E,A
  108.     ANI    15        ; Only handle lower 4 bits
  109.     RLC            ; Shift A over 4 bits
  110.     RLC
  111.     RLC
  112.     RLC            
  113.     MOV    M,A        ; Save it while we're at it
  114.     MOV    A,E
  115.     RET
  116. ;
  117. ;    Add in low BCD nibble
  118. ;        Gets high nibble from M
  119. ;        Stores new BCD byte in M
  120. ;        Increments HL
  121. ;        Destroyes 'E'
  122. ;
  123. ADDLOW:    MOV    E,A
  124.     ANI    15        ; Deal with low nibble only
  125.     ORA    M        ; Add in high nibble from tens digit
  126.     MOV    M,A        ; Save new BCD byte in buffer
  127.     INX    H        ; Move on to next location
  128.     MOV    A,E
  129.     RET
  130.      ENDIF            ; RTC
  131.