home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / hamradio / morsetxt.lbr / MRS-LB10.AZM / MRS-LB10.ASM
Assembly Source File  |  1987-10-31  |  9KB  |  266 lines
  1. .he MRS-LB10.* --CHR$(13)24AUG85                                 -#-
  2. ;MORSETXT system-specific overlay for the Ampro Little Board, and 
  3. ;    master model for other overlays, with hardware notes.
  4. ;
  5. ; AMPRO USERS NOTE: 
  6. ;    The release version of MORSETXT.* v1.0 was written on and
  7. ; for an Ampro Little Board. If that's what you have,  just build
  8. ; the noisemaker, plug it and go.  Read on,  but  be dragging out 
  9. ; your soldering iron, not MLOAD.
  10. ;
  11. ;Required hardware extension:
  12. ;This  program  keys  the  HSO (or equivalent) pin  on  the  DB25 
  13. ;    connector of your computer's serial-B (modem) port.
  14. ;
  15. ;To use it as a Morse code learning aid,  you'll need to  connect 
  16. ;    an  audio noise-maker (something you can stand to listen  to 
  17. ;    for long periods of time) to that pin.
  18. ;
  19. ;The cheapest method of doing this requires the following
  20. ; parts:
  21. ;
  22. ;1. DB25P connector. Radio Shack # 276-1547 or equivalent
  23. ;
  24. ;2. Piezo oscillator.  RS # 273-060 is a little raucous, but good 
  25. ;    for  short periods.  A 2 kilohertz tone would be  ideal  for 
  26. ;    this;  some  Mallory Sonalerts may oscillate there.  Get one 
  27. ;    that outputs a continuous (NOT pulsing) tone.
  28. ;
  29. ;3. Silicon diode.  1N914 (pkg.  RS 276-1620,  276-1122) is  okay 
  30. ;    electrically,  but  somewhat fragile.  1N4001 (RS  276-1101) 
  31. ;    rectifier  is  a lot sturdier.  If you use a  signal  diode, 
  32. ;    consider  mounting the whole circuit either on perfboard  or 
  33. ;    inside a DB25 hood.
  34. ;
  35. ;4. Optional 10k-plus pot, volume control. RS 271-1711 or equiv.
  36. ;
  37. ;(I have  no special love for Radio Shack,  but they do have  the 
  38. ;    advantage  of being virtually everywhere,  hence the use  of 
  39. ;    their catalog numbers.)
  40. ;
  41. ; Schematic:
  42. ;
  43. ; DB25 pin        diode... the UNBANDED end of the diode 
  44. ;                 connects to the DB25 pin. The BANDED end
  45. ;             |\ | goes to the oscillator.
  46. ;  [7]--------| >|-----------------------+
  47. ;  GND        |/ |                       | "plus" lead...
  48. ;                                        | red wire.
  49. ;                +--------+---------+
  50. ;                | PIEZO OSCILLATOR |    
  51. ;                               +--------+---------+
  52. ;         10k - 50k pot                  | "minus" lead...
  53. ;                                        |  black wire.    
  54. ;  [5]----/\/\/\/------+-----------------+    
  55. ; HSO    1   ^2  3     |
  56. ;            |         |
  57. ;            +---------+
  58. ;     (optional volume control)
  59. ;
  60. ;The above  pinout  is valid according to the Ampro  manual.  The 
  61. ;    circuit actually is powered when the HSO line is turned OFF. 
  62. ;    It's done this way because the boot routines on  disk,  when 
  63. ;    loaded, initialize the serial-B port with HSO turned on. The 
  64. ;    machine-specific  routine (and this design) are both adapted 
  65. ;    to this.
  66. ;This means  that the oscillator will be on when you first  power 
  67. ;    up,  and  every time you reset.  That's one way to find  out 
  68. ;    that it's plugged in (experience)...  
  69. ;
  70. ;The diode is needed because the HSO line, when on, swings  above 
  71. ;    ground. The oscillator must be protected from that.
  72. ;The optional pot probably won't silence the oscillator,  but  it 
  73. ;    will  quiet it substantially.  In factory  environments,  my 
  74. ;    experience suggests leaving it out.
  75. ;
  76. ;This circuit  is  unique in that the piezo oscillator can   make 
  77. ;    (more than) enough noise,  powered only by the HSO   output. 
  78. ;    Any  other  circuit  will probably require a  small   power-
  79. ;    supply or a battery, and extra control circuitry.
  80. ;
  81. ;                        --Carroll R. Bryan III WB1HKU/6
  82. ;
  83. ;
  84. ;Assemble with ASM. Any major improvements or new overlays should
  85. ; be uploaded to Ampro1 @ (408)258-8128, unless somone else would
  86. ; rather hub this. 
  87. ;
  88. LF    equ    10
  89. CR    equ    13
  90. FX    equ    0FFh
  91. ;
  92. CLOCK    equ    40    ;CPU clockspeed in hundreds of kilohertz
  93. ;
  94. ;
  95. PORTAS    equ    84h    ;console status and control port
  96. CINMSK    equ    1    ;character-is-input mask
  97. CINMCH    equ    1    ;character-is-input match
  98. PORTBS    equ    8Ch    ;port B status and control port
  99. ;
  100. ;
  101. ;Title block. It's sent to screen by ILPRT, so keep it  
  102. ; the same size. Use the bottom open line for your own
  103. ; overlay credit. If need be, move the text up a line
  104. ; to bring that top open line down.
  105. ;ILPRT returns when it finds a null. The 1Ah which 
  106. ; follows that is an EOF character (a meaningless ldax d
  107. ; instruction as far as the CPU is concerned), so that
  108. ; a console command of TYPE MORSETXT.COM will bring up
  109. ; only the title block (and whatever 'call ILPRT'
  110. ; happens to mean as ASCII).
  111. ; 
  112.  
  113.     org    103h
  114. ;
  115.     db    CR,LF,9,'***----MORSETXT.COM v1.0-----***'
  116.     db    CR,LF,9,'*                              *'
  117.     db    CR,LF,9,'*   International Morse Code   *'
  118.     db    CR,LF,9,'*  transmitter for text files  *'
  119.     db    CR,LF,9,'*  Ampro Little Board version  *'
  120.     db    CR,LF,9,'*    via Port B''s HSO line     *'
  121.     db    CR,LF,9,'*                              *'
  122.     db    CR,LF,9,'***-- --CHR$(13)23AUG85------***'
  123.     db    CR,LF,LF,0,1Ah
  124. ;
  125. ;
  126.     org    235h
  127. ;
  128. DELCON:    db    0,0    ;32-bit value stored in byte-serial
  129.     db    4,0A6h    ;form. Delay constant for 0.1 wpm
  130.             ;when running a Z80 at 0.1 MHz. This
  131.             ;value is adjusted for declared
  132.             ;clockrate in the first routine 
  133.             ;called. DITCNT will be calculated
  134.             ;immediately afterwards. 
  135. ; 
  136. ;
  137. DITCNT:    ds    2    ;the key delay variable.
  138. ;
  139. DAHCNT:    ds    2    ;no longer directly used by program.
  140.             ;(It cut down on the range too much.)
  141.             ;If you're retweaking after an over-
  142.             ;haul, though, you'll want to see
  143.             ;what various values of delay and
  144.             ;DELCNT do to it and DITCNT. That's
  145.             ;why I left it in the COMfile.
  146. ;
  147. CLKBYT:    db    CLOCK    ;clock frequency in 100 KHz increments
  148. ;
  149. ;WSPACE, XTNFLG and PRETTY are copied into WSPBYT, XTNBYT and PRYBYT
  150. ; just before every filename line's arguments are brought down and 
  151. ; plugged in. However you set them will be the default condition. If
  152. ; the just-loaded command line has switch-commands in it, they will
  153. ; toggle running conditions away from your default.
  154. ;The advantage is in rearranging the sending commands in wildcard
  155. ; expansions, where no command switches are possible.
  156. ;
  157. ;
  158. WSPACE:    db    0    ;if non-zero, space out the characters.
  159. XTNFLG:    db    0    ;if non-zero, only ARRL characters. 
  160. PRETTY:    db    0    ;if zero,an excess period becomes <bt>,
  161.             ;only one space in a row is sent.
  162. ;
  163. KEY:    jmp    KEYR
  164. UNKEY:    jmp    UNKEYR     ;Hooks for the three hardware-dependent
  165. CONSEN:    jmp    CSEN    ;routines, allowing for overlays.
  166. SEIKON:    ds    3    ;jmp CONSAY...and one for calling out again. 
  167. ;
  168. ;@ 024Dh:
  169. ;
  170. ;These are the hardware-specific sending routines.
  171. ;As written, KEYSTB works with the Ampro's DART. The callers,
  172. ; KEY and UNKEY,  differ in that KEY calls with A=0FFh, while
  173. ; UNKEY calls with A=0. The Ampro initialization routines set
  174. ; the HSO line  on serial-B,  so this routine-set resets that 
  175. ; line in order to key the oscillator.
  176. ;Don't trash anything but A, and be as quick as you can.  The 
  177. ; massive delays in KEY and UNKEY  will mask  a  lot of fixed 
  178. ; delay,  but you want to be able to  really hear  an  honest 
  179. ; 45 wpm, don't you?  
  180. ;
  181. ;If you have to rewrite KEY and UNKEY, pay attention to
  182. ; the CPU's T-states. Those delays were tweaked to yield
  183. ; true clear-text codespeed with the extrapolated constant
  184. ; in DELCON. 
  185. ;DELCON should be left at its present value if possible.
  186. ; Too big, and slow-speed delay increments get defaulted
  187. ; to FFFF. Too small, and the upper speed increments get
  188. ; grossly off.
  189. ;
  190. KEYR:    mvi    a,FX    ;delay-count is in hl
  191.     call    KEYSTB
  192. KELP:    nop! nop! nop! nop! nop    ;If you mess with these
  193.     nop! nop! nop! nop! nop    ;delays, you'll have to
  194.     nop! nop! nop! nop! nop    ;retune the master delay
  195.     nop! nop! nop! nop! nop    ;count. Try to put it in
  196.     nop! nop! nop! nop! nop    ;the same general range.
  197.     nop! nop         ;Otherwise, you'll run
  198.     mov    a,a        ;out of arithmetic range
  199.     dcx    h        ;one way or the other.
  200.     mov    a,l
  201.     ora    h
  202.     jnz    KELP
  203.     ret
  204. ;
  205. UNKEYR:    xra    a    ;ditto
  206.     call    KEYSTB
  207. UKELP:    nop! nop! nop! nop! nop
  208.     nop! nop! nop! nop! nop
  209.     nop! nop! nop! nop! nop
  210.     nop! nop! nop! nop! nop
  211.     nop! nop! nop! nop! nop
  212.     nop! nop
  213.     mov    a,a
  214.     dcx    h
  215.     mov    a,l
  216.     ora    h
  217.     jnz    UKELP
  218.     ret
  219. ;
  220. ;Hopefully, this is the only routine in the code-timing
  221. ; nest that you'll have to tweak. 
  222. ;
  223. ;
  224. KEYSTB:    cma        ;Reverse the sense to deal with preset. 
  225.             ;Now it's 00 to sound the note, 0FFh to
  226.             ;silence it.
  227.     push    psw    ;Hide it. 
  228.     mvi    a,5    ;Vector the DART to register 5...
  229.     out    PORTBS    ;where we find the RTS assertion bit.
  230.     pop    psw    ;Now we're ready to put together a 
  231.             ;control word.
  232.     push    b    ;Copy bc out before we clobber it...
  233.     mvi    b,68h    ;Default condition in the register,
  234.             ;which we must preserve...
  235.             ;(8-bit transmission, transmit enabled)
  236.             ;
  237.     ani    2    ;Expose just the bit we want to change.
  238.     add    b    ;Slam 'em together, and shove the pair
  239.     out    PORTBS    ;out the airlock.
  240.     pop    b    ;Get back whatever's in b
  241.     ret        ;and go home.
  242. ;
  243. ;This is the direct port status call. It is called by
  244. ; ILMORS and GOCHAR on their way back from sending a
  245. ; character. If CON: has a freshly typed character,
  246. ; go play with it. Otherwise, as you were.   
  247. ;
  248. CSEN:    in    PORTAS    ;console port
  249.     ani    CINMSK
  250.     cpi    CINMCH    ;Here's where we break off if
  251.     cz    SEIKON    ;CON: is sending.
  252.     ret
  253. ;
  254. ;@ 02B7h as written:
  255. ;
  256. ;I trust this is enough room for whatever you have to do.
  257. ; 
  258.     org    400h
  259. ;
  260. ;
  261.     end
  262. ;
  263.  
  264. eof MRS-LB10.ASM/Ampro[stuff.933]--CHR$(13)30JUN85
  265.  
  266.