home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / heath / money.lbr / MONEY.BZS / MONEY.BAS
BASIC Source File  |  1987-03-22  |  14KB  |  340 lines
  1. 10 ' FINANCE PROGRAM           MONEY.BAS           by: Gary Olander DESERT DATA
  2. 20 ' Ver 2-1                   P.O.Box 1268, Sparks, Nevada 89431 (702)358-2690
  3. 30 ' Ver 2-2 2/87 CP/M-80  
  4. 32 ' NOTE: PRINT CHR$(27);CHR$(69) is the screen clear routine for an H/Z 19 TERM.
  5. 40 D$="$######.##":D1$="$#####.##":D2$="$####.##"
  6. 50 PRINT CHR$(27);CHR$(69)
  7. 51 PRINT TAB(30)"$ $ MONEY $ $"
  8. 52 PRINT TAB(27)"Version 2-2   2/87"
  9. 53 PRINT:PRINT
  10. 60 PRINT TAB(28)"1 - Investments"
  11. 61 PRINT
  12. 70 PRINT TAB(28)"2 - Depreciation"
  13. 71 PRINT
  14. 80 PRINT TAB(28)"3 - Loans"
  15. 81 PRINT
  16. 90 PRINT TAB(28)"4 - Rule of ``78''"
  17. 91 PRINT
  18. 100 PRINT TAB(28)"5 - Payment schedule "
  19. 101 PRINT
  20. 110 PRINT TAB(28)"0 - End of Program"
  21. 120 GOSUB 1630:ON VAL(A$) GOSUB 150,220,280,360,1650
  22. 130 IF A$="0" THEN PRINT CHR$(27);CHR$(69):SYSTEM
  23. 140 GOTO 50
  24. 150 PRINT CHR$(27);CHR$(69)
  25. 151 PRINT TAB(28)"  Investments"
  26. 152 PRINT:PRINT
  27. 160 PRINT TAB(22)"1 - One-time investment"
  28. 161 PRINT
  29. 170 PRINT TAB(22)"2 - Regular Deposits"
  30. 171 PRINT
  31. 180 PRINT TAB(22)"3 - Deposits required for savings goal"
  32. 181 PRINT
  33. 190 PRINT TAB(22)"4 - End this group"
  34. 191 PRINT
  35. 200 GOSUB 1630:ON VAL(A$) GOSUB 520,590,670
  36. 210 GOTO 50
  37. 220 PRINT CHR$(27);CHR$(69)
  38. 221 PRINT TAB(28)"  Depreciation"
  39. 222 PRINT:PRINT
  40. 230 PRINT TAB(24)"1 - Double Declining"
  41. 231 PRINT
  42. 240 PRINT TAB(24)"2 - Straight Line"
  43. 241 PRINT
  44. 250 PRINT TAB(24)"3 - End this group"
  45. 251 PRINT
  46. 260 GOSUB 1630:ON VAL(A$) GOSUB 800,1040
  47. 270 GOTO 50
  48. 280 PRINT CHR$(27);CHR$(69)
  49. 281 PRINT TAB(28)"  Loans"
  50. 282 PRINT:PRINT
  51. 290 PRINT TAB(22)"1 - Regular Payment"
  52. 291 PRINT
  53. 300 PRINT TAB(22)"2 - Last Payment"
  54. 301 PRINT
  55. 310 PRINT TAB(22)"3 - Remaining Balance"
  56. 311 PRINT
  57. 320 PRINT TAB(22)"4 - Cost of Borrowing"
  58. 321 PRINT
  59. 330 PRINT TAB(22)"5 - End this group"
  60. 331 PRINT
  61. 340 GOSUB 1630:ON VAL(A$) GOSUB 1220,1300,1400,1490
  62. 350 GOTO 50
  63. 360 PRINT CHR$(27);CHR$(69)
  64. 361 PRINT TAB(28)"  Rule of ``78''"
  65. 362 PRINT
  66. 370 PRINT "Also known as the Sum of the Digits or The Direct Method."
  67. 380 PRINT "from the UCCC (Uniform Consumer Credit Code) Regulation, Referance"
  68. 390 PRINT "Office of Consumer Affairs, 112 E. 14th Ave.,Denver Col.80203"
  69. 400 PRINT "Enter the contract  FINANCE CHARGE (total)  ";:INPUT A
  70. 410 PRINT "Enter the number of MONTHS of contract term ";:INPUT N
  71. 420 PRINT "Enter the MONTHS LEFT on contract term"
  72. 430 PRINT "( a partial month counts as a whole )       ";:INPUT S
  73. 440 C=(S+1)*S:K=(N+1)*N:P=C/K:R=A*P:M=(N-S)*(N+S+1):B=(N+1)*N:E=M/B:F=A*E
  74. 450 PRINT "The refund factor of the finance charge    = ";USING".##";P;:PRINT " %"    
  75. 460 PRINT "The cost of borrowing factor               = ";USING".##";E;:PRINT " %"
  76. 470 PRINT "The amount of PRE-PAYMENT  REFUND  is        ";USING D$;R
  77. 480 PRINT "Cost of Borrowing using the Rule of ``78''   ";USING D$;F
  78. 490 GOSUB 1610
  79. 500 IF A$="Y" GOTO 360
  80. 510 GOTO 50
  81. 520 PRINT CHR$(27);CHR$(69)
  82. 521 PRINT TAB(26)"One time Investment"
  83. 522 PRINT
  84. 530 PRINT "Enter the initial investment      ";:INPUT I1
  85. 540 PRINT "Enter the interest rate   (A.P.R.)";:INPUT R
  86. 550 PRINT "Enter the Term (Years,Months)     ";:INPUT Y,M
  87. 560 PRINT "Enter Number of Compounding Periods per year ";:INPUT N
  88. 570 R=R/N/100:Y=(12*Y+M)/12:T2=I1*(1+R)^(N*Y):T2=INT(T2*100+.5)/100:I2=T2-I1
  89. 580 GOSUB 760:GOSUB 1610:IF A$="Y" OR A$="y"THEN 520 ELSE 150
  90. 590 PRINT CHR$(27);CHR$(69)
  91. 591 PRINT TAB(26)"Regular Deposits"
  92. 592 PRINT
  93. 600 PRINT "Enter amount of each deposit      ";:INPUT D
  94. 610 PRINT "Enter the interest rate   (A.P.R.)";:INPUT R
  95. 620 PRINT "Enter the Term (Years,Months)     ";:INPUT Y,M
  96. 630 PRINT "Enter Number of deposits a Year   ";:INPUT N
  97. 640 R=R/N/100:Y=(Y*12+M)/12:T2=D*((1+R)^(N*Y)-1)/R:T2=INT(T2*100+.5)/100
  98. 650 I1=D*Y*N:I2=T2-I1
  99. 660 GOSUB 760:GOSUB 1610:IF A$="Y" OR A$="y" THEN 590 ELSE 150
  100. 670 PRINT CHR$(27);CHR$(69)
  101. 671 PRINT TAB(26)"Savings Goal Deposits"
  102. 672 PRINT
  103. 680 PRINT "Enter desired goal                ";:INPUT T2
  104. 690 PRINT "Enter the interest rate   (A.P.R.)";:INPUT R
  105. 700 PRINT "Enter the Term (Years,Months)     ";:INPUT Y,M
  106. 710 PRINT "Enter Number of deposits a Year   ";:INPUT N
  107. 720 R=R/N/100:Y=(Y*12+M)/12:D=T2*R/((1+R)^(N*Y)-1):D=INT(D*100+.5)/100
  108. 730 I1=D*Y*N:I2=T2-I1
  109. 740 PRINT CHR$(27);CHR$(69)
  110. 741 PRINT TAB(26)"Savings Goal Deposits"
  111. 742 PRINT
  112. 743 PRINT "Regular Deposits reguired     ";USING D$;D
  113. 750 GOSUB 760:GOSUB 1610:IF A$="Y" OR A$="y" THEN 670 ELSE 150
  114. 760 PRINT "Net investment                ";USING D$;I1
  115. 770 PRINT "Accumulative interest         ";USING D$;I2
  116. 780 PRINT "Total investment Value        ";USING D$;T2
  117. 790 RETURN
  118. 800 PRINT CHR$(27);CHR$(69)
  119. 801 PRINT TAB(28)"Double Declining Depreciation
  120. 802 PRINT
  121. 860 PRINT "Maximize annual double declining depreciation will change to"" straight line"
  122. 870 PRINT "once then double declining method is less than the straight"" line method
  123. 880 PRINT "Enter the original value             ";:INPUT X
  124. 890 PRINT "Enter Depreciation term (Years)      ";:INPUT Y
  125. 900 PRINT "Enter salvage Value at end of term   ";:INPUT R
  126. 902 PRINT "Is this for 1 - SCREEN:, or 2 - PRINTER: ?":A$=INPUT$(1)
  127. 903 IF A$="1" THEN 906
  128. 904 IF A$="2" THEN GOSUB 2121
  129. 905 GOTO 902
  130. 906 PRINT
  131. 910 PRINT "          YEARS                AMOUNT            CURRENT VALUE"
  132. 920 PRINT "           0";TAB(52);USING D$;X
  133. 930 K=0:Z=X-R
  134. 940 E=(2/Y)*Z
  135. 950 Z=Z-E:K=K+1:V=Z+R:PRINT TAB(10);K;TAB(30);USING D$;E;
  136. 960 PRINT TAB(52);USING D$;V
  137. 970 IF K=Y THEN 1000
  138. 980 IF E>(Z+1)/(Y-K) THEN 940
  139. 990 E=Z/(Y-K):IF K<=(Y-1) THEN 950
  140. 1000 PRINT :PRINT
  141. 1010 PRINT "THIS COMPUTATION IS A MAXIMIZE DOUBLE DECLINING DEPRECIATION"
  142. 1020 PRINT "for an asset worth $ ";X;" at purchase with $ ";R;" salvage value"
  143. 1030 CLOSE:GOSUB 1610:IF A$="Y" OR A$="y" THEN 800 ELSE 220
  144. 1040 PRINT CHR$(27);CHR$(69)
  145. 1041 PRINT TAB(28)"Straight Line Depreciation"
  146. 1042 PRINT
  147. 1100 PRINT "Enter the original value             ";:INPUT X
  148. 1110 PRINT "Enter Depreciation term (Years)      ";:INPUT Y
  149. 1120 PRINT "Enter salvage Value at end of term   ";:INPUT R
  150. 1130 Z=X-R:J=0:D=Z/Y:V=X-D
  151. 1132 PRINT "Is this for 1 - SCREEN:, or 2 - PRINTER: ?":A$=INPUT$(1)
  152. 1133 IF A$="1" THEN 1136
  153. 1134 IF A$="2" THEN GOSUB 2301
  154. 1135 GOTO 1132
  155. 1136 PRINT
  156. 1140 PRINT "          YEARS                AMOUNT            CURRENT VALUE"
  157. 1150 PRINT "           0";TAB(52);USING D$;X
  158. 1160 FOR J=1 TO Y:PRINT TAB(10);J;TAB(30);USING D$;D;
  159. 1170 PRINT TAB(52);USING D$;V:V=V-D:NEXT J
  160. 1180 PRINT :PRINT
  161. 1190 PRINT "This Computation is STRAIGHT LINE DEPRECIATION
  162. 1200 PRINT "for an asset worth $ ";X;" at purchase with $ ";R;" salvage value"
  163. 1210 CLOSE:GOSUB 1610:IF A$="Y" OR A$="y" THEN 1040 ELSE 220
  164. 1220 PRINT CHR$(27);CHR$(69)
  165. 1221 PRINT TAB(26)"Regular Loan Payment"
  166. 1222 PRINT
  167. 1230 PRINT "Enter the Principal amount      ";:INPUT P1
  168. 1240 PRINT "Enter the Term (Years,Months)   ";:INPUT Y,M
  169. 1250 PRINT "Enter the interest rate (A.P.R.)";:INPUT R
  170. 1260 PRINT "Enter number of Pmts per Year   ";:INPUT N
  171. 1270 R=R/N/100:Y=(Y*12+M)/12:P3=1/(1+R)^(N*Y):P2=P1*R/(1-P3)
  172. 1280 PRINT "The Regular payment is          ";USING D$;P2
  173. 1290 GOSUB 1610:IF A$="Y" OR A$="y" THEN 1220 ELSE 280
  174. 1300 PRINT CHR$(27);CHR$(69)
  175. 1301 PRINT TAB(26)"Last Loan Payment"
  176. 1302 PRINT
  177. 1310 PRINT "Enter the Principal amount      ";:INPUT P1
  178. 1320 PRINT "Enter the Term (Years, Months)  ";:INPUT Y,M
  179. 1330 PRINT "Enter the interest rate (A.P.R.)";:INPUT R
  180. 1340 PRINT "Enter number of Pmts per Year   ";:INPUT N
  181. 1350 PRINT "Enter amount of Regular Payment";:INPUT P4
  182. 1360 R=R/N/100:Y=(Y*12+M)/12:I1=N*Y:FOR I=1 TO I1:R1=INT(P1*R*100+.5)/100
  183. 1370 R2=P4-R1:P1=P1-R2:NEXT I:P2=P4+P1
  184. 1380 PRINT "The Last Payment will be        ";USING D$;P2
  185. 1390 GOSUB 1610:IF A$="Y" OR A$="y" THEN 1300 ELSE 280
  186. 1400 PRINT CHR$(27);CHR$(69)
  187. 1401 PRINT TAB(26)"Remaining Balance"
  188. 1402 PRINT
  189. 1410 PRINT "Enter the Principal amount      ";:INPUT P1
  190. 1420 PRINT "Enter the Regular Payment       ";:INPUT P4
  191. 1430 PRINT "Enter the interest rate (A.P.R.)";:INPUT R
  192. 1440 PRINT "Enter number of Pmts per Year   ";:INPUT N
  193. 1450 PRINT "Enter number of Pmts made       ";:INPUT I1
  194. 1460 R=R/N/100:FOR I=1 TO I1:R1=INT(P1*R*100+.5)/100:R2=P4-R1:P1=P1-R2:NEXT I
  195. 1470 PRINT "The Remaining Balance is        ";USING D$;P1
  196. 1480 GOSUB 1610:IF A$="Y" OR A$="y" THEN 1400 ELSE 280
  197. 1490 PRINT CHR$(27);CHR$(69)
  198. 1491 PRINT TAB(26)"Cost of Borrowing"
  199. 1492 PRINT
  200. 1500 PRINT "Enter the Principal amount      ";:INPUT P1
  201. 1510 PRINT "Enter the term (Years,Months)   ";:INPUT Y,M
  202. 1520 PRINT "Enter the interest rate (A.P.R.)";:INPUT R
  203. 1530 PRINT "Enter number of Pmts per Year   ";:INPUT N
  204. 1540 R=R/N/100:Y=(Y*12+M)/12:P3=1/(1+R)^(N*Y):P4=P1*R/(1-P3):P4=INT(P4*100+.5)/100:P5=P1:C=0:I1=N*Y
  205. 1550 FOR I=1 TO I1:R1=INT(P5*R*100+.5)/100:R2=P4-R1:P5=P5-R2:C=C+P4:NEXT I
  206. 1560 C=C+P5:C1=C-P1
  207. 1570 PRINT "Regular Payment                 ";USING D$;P4
  208. 1580 PRINT "Total of Payments               ";USING D$;C
  209. 1590 PRINT "Cost of Borrowing               ";USING D$;C1
  210. 1600 GOSUB 1610:IF A$="Y" OR A$="y" THEN 1490 ELSE 280
  211. 1610 PRINT "Another Calculation (Y or N)  ";:A$=INPUT$(1)
  212. 1611 PRINT CHR$(27);CHR$(69)
  213. 1620 RETURN
  214. 1630 PRINT:PRINT
  215. 1631 PRINT TAB(20)"Enter one of the above option numbers  ";:A$=INPUT$(1)
  216. 1632 PRINT
  217. 1640 RETURN
  218. 1650 PRINT CHR$(27);CHR$(69)
  219. 1660 PRINT
  220. 1670 PRINT TAB(28)"Payment Schedule "
  221. 1671 PRINT
  222. 1680 PRINT "Enter the Amount of the Loan         ";:INPUT A#
  223. 1690 PRINT "Enter the interest rate    (A.P.R.)  ";:INPUT R
  224. 1700 R1=R
  225. 1710 PRINT "Enter the length of the loan (Months)";:INPUT M
  226. 1720 IF M<>INT(M) THEN 1710
  227. 1730 PRINT "Want the monthly payment calculated (Y/N) ?";:B$=INPUT$(1)
  228. 1740 R=R/1200
  229. 1750 IF B$="Y" OR B$="y" THEN 1790
  230. 1751 PRINT
  231. 1760 PRINT "What is the Monthly Payment   ";:INPUT P 
  232. 1770 GOTO 1811
  233. 1780 REM  CALCULATE MONTHLY PAYMENT AND ROUND UP TO CENTS.
  234. 1790 C=(R+1)^M
  235. 1800 P=A#*((R*C)/(C-1))
  236. 1810 P=(P*100)+1: P=INT(P):P=P/100
  237. 1811 PRINT "Is this for 1 - SCREEN:, or 2 - PRINTER: ?":A$=INPUT$(1)
  238. 1812 IF A$="1" THEN 1815 
  239. 1813 IF A$="2" THEN GOSUB 2431
  240. 1814 GOTO 1811
  241. 1815 PRINT CHR$(27);CHR$(69)
  242. 1820 PRINT TAB(15)"The Monthly Payment is   ";USING D$;P;
  243. 1830 PRINT TAB(15)"Amount of Loan ";USING D$;A#;:PRINT " at ";R1;" % Interest"
  244. 1840 PRINT TAB(15)"The payments are ";USING D2$;P;
  245. 1850 PRINT " for ";M;"  Months.":PRINT
  246. 1860 Z=0:I2=0:N2#=0:P2=0:F=0
  247. 1870 B#=A#:GOSUB 2100
  248. 1880 FOR K=1 TO M
  249. 1890 I=B#*R
  250. 1900 I=(I*100)+1:I=INT(I):I=I/100
  251. 1910 IF K=M THEN P=B#+1
  252. 1920 P2=P2+P
  253. 1930 N=P-I:B#=B#-N:I2#=I2#+I:N2#=N2#+N
  254. 1940 PRINT TAB(1);K;TAB(8) USING D$;B#;:PRINT TAB(21);I;TAB(33) USING D$;I2#;:PRINT TAB(47);N;TAB(62);:PRINT USING D$;N2#
  255. 2000 V=V+1:IF V=12 THEN GOSUB 2091
  256. 2010 NEXT K
  257. 2011 PRINT
  258. 2020 PRINT TAB(8)"FINAL PAYMENT =";P
  259. 2040 PRINT TAB(8)"The Final Payment is ";TAB(32);
  260. 2050 PRINT USING D2$;P;:PRINT TAB(46);"Total of Payments $ ";P2
  261. 2060 PRINT TAB(8)"TOTAL PAYMENTS=";P2
  262. 2070 PRINT
  263. 2080 PRINT TAB(18)"WOULD YOU LIKE TO CALCULATE ANOTHER (Y/N) ?";:A$=INPUT$(1)
  264. 2090 IF A$="Y" OR A$="y" THEN 1650 ELSE 50
  265. 2091 PRINT
  266. 2092 PRINT TAB(16)"Press 1:, Key for next page or 0: Key to abort":A$=INPUT$(1)
  267. 2093 IF A$="1" THEN 2096
  268. 2094 IF A$="0" THEN 2080
  269. 2095 GOTO 2092
  270. 2096 PRINT CHR$(27);CHR$(69)
  271. 2100 PRINT TAB(22)"Amount of Loan ";USING D$;A#
  272. 2101 PRINT TAB(1)"Month    Balance    Interest    Int.to Date   Principle"    "    Princ.to Date"
  273. 2102 PRINT
  274. 2110 V=0:RETURN
  275. 2120 REM SUBROUTINE FOR PRINTER DDD
  276. 2121 PRINT "Please align paper and make printer ready, then press <RETURN>";:LINE INPUT X$
  277. 2130 LPRINT TAB(15)"Double Declining Depreciation Printout"
  278. 2140 LPRINT
  279. 2150 LPRINT "          YEARS                AMOUNT            CURRENT VALUE"
  280. 2160 LPRINT "           0";TAB(52);USING D$;X
  281. 2170 K=0:Z=X-R
  282. 2180 E=(2/Y)*Z
  283. 2190 Z=Z-E:K=K+1:V=Z+R:LPRINT TAB(10);K;TAB(30);USING D$;E;
  284. 2200 LPRINT TAB(52);USING D$;V
  285. 2210 IF K=Y THEN 2240
  286. 2220 IF E>(Z+1)/(Y-K) THEN 2180
  287. 2230 E=Z/(Y-K):IF K<=(Y-1) THEN 2190
  288. 2240 LPRINT :LPRINT
  289. 2250 LPRINT "THIS COMPUTATION IS A MAXIMIZE DOUBLE DECLINING DEPRECIATION"
  290. 2260 LPRINT "for an asset worth $ ";X;" at purchase with $ ";R;" salvage value"
  291. 2270 LPRINT CHR$(12)
  292. 2280 CLOSE:GOSUB 1610:IF A$="Y" OR A$="y" THEN 800 ELSE 220
  293. 2290 RETURN
  294. 2300 REM SLD PRINTER SUBROUTINE
  295. 2301 PRINT "Please align paper and make printer ready, then press <RETURN>";:LINE INPUT X$
  296. 2310 LPRINT TAB(15) "Straight Line Depreciation Printout"
  297. 2320 LPRINT
  298. 2330 LPRINT "          YEARS                AMOUNT            CURRENT VALUE"
  299. 2340 LPRINT "           0";TAB(52);USING D$;X
  300. 2350 FOR J=1 TO Y:LPRINT TAB(10);J;TAB(30);USING D$;D;
  301. 2360 LPRINT TAB(52);USING D$;V:V=V-D:NEXT J
  302. 2370 LPRINT :LPRINT
  303. 2380 LPRINT "This Computation is STRAIGHT LINE DEPRECIATION
  304. 2390 LPRINT "for an asset worth $ ";X;" at purchase with $ ";R;" salvage value"
  305. 2400 LPRINT CHR$(12)
  306. 2410 CLOSE:GOSUB 1610:IF A$="Y" OR A$="y" THEN 1040 ELSE 220
  307. 2420 RETURN
  308. 2430 REM PRINTER SUBROUTINE FOR PAYMENT SCHEDULE           
  309. 2431 PRINT "Please align paper and make printer ready, then press <RETURN>";:LINE INPUT X$
  310. 2432 LPRINT TAB(22)"Payment Schedule Printout"
  311. 2440 LPRINT TAB(15)"The Monthly Payment is   ";USING D$;P;
  312. 2450 LPRINT TAB(15)"Amount of Loan ";USING D$;A#;:LPRINT " at ";R1;" % Interest"
  313. 2460 LPRINT TAB(15)"The payments are ";USING D2$;P;
  314. 2470 LPRINT " for ";M;"  Months.":LPRINT
  315. 2480 Z=0:I2=0:N2#=0:P2=0:F=0
  316. 2490 B#=A#:GOSUB 2680
  317. 2500 FOR K=1 TO M
  318. 2510 I=B#*R
  319. 2520 I=(I*100)+1:I=INT(I):I=I/100
  320. 2530 IF K=M THEN P=B#+1
  321. 2540 P2=P2+P
  322. 2550 N=P-I:B#=B#-N:I2#=I2#+I:N2#=N2#+N 
  323. 2560 LPRINT TAB(1);K;TAB(8) USING D$;B#;:LPRINT TAB(21);I;TAB(33) USING D$;I2#;:LPRINT TAB(47);N;TAB(62);:LPRINT USING D$;N2#
  324. 2570 V=V+1:IF V=12 THEN GOSUB 2680
  325. 2580 NEXT K
  326. 2590 LPRINT TAB(8)"FINAL PAYMENT =";P
  327. 2610 LPRINT TAB(8)"The Final Payment is ";TAB(32);
  328. 2620 LPRINT USING D2$;P;:LPRINT TAB(46);"Total of Payments $ ";P2
  329. 2630 LPRINT TAB(8)"TOTAL PAYMENTS=";P2
  330. 2640 LPRINT CHR$(12)
  331. 2650 PRINT "WOULD YOU LIKE TO CALCULATE ANOTHER (Y/N) ?";:A$=INPUT$(1)
  332. 2660 IF A$="Y" OR A$="y" THEN 1650 ELSE 50
  333. 2670 LPRINT
  334. 2680 LPRINT TAB(1)"Month    Balance    Interest    Int.to Date   Principle"    "    Princ.to Date"
  335. 2690 LPRINT
  336. 2700 V=0:RETURN
  337. 580 NEXT K
  338. 2590 LPRINT TAB(8)"FINAL PAYMENT =";P
  339. 2610 LPRINT TAB(8)"The Final Payment is ";TAB(32);
  340. 2620 LPRINT USING D2$;P;: