home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mtimer12.bqs / MTIMER12.BAS
BASIC Source File  |  1985-02-09  |  2KB  |  42 lines
  1. 0  ' Revision 1.2 10/23/84
  2. 10 ' MTIMER10.BAS by Lawrence Davis 9/25/84
  3. 12 ' Insert your own clock routine at line 190
  4. 13 ' Clear screen string currently CHR$(26) - ^Z
  5. 15 ' This program must be compiled using BASCOM
  6. 16 ' Compile as follows: BASCOM in A drive   MTIMER.BAS in B drive
  7. 17 ' A>BASCOM =B:MTIMER12 /O
  8. 18 ' A>L80 B:MTIMER12,B:MTIMER/N/E
  9. 19 DIM L$(128)
  10. 20 PRINT CHR$(26);TAB(20)"Mex Timer Program - Version 1.2
  11. 25 PRINT TAB(27);"For Epson QX-10
  12. 30 PRINT:PRINT:PRINT
  13. 40 INPUT "Set the STARTUP TIME:  (Enter as HH:MM) ",A$
  14. 45 PRINT:PRINT"Enter the Mex COMMAND LINE (eg. LOAD PHONE.PHN;READ BBS) "
  15. 47 INPUT "MEX>",M$
  16. 50 PRINT CHR$(26);"The STARTUP TIME is set for ";A$
  17. 55 PRINT:PRINT;"The Mex COMMAND LINE is <"+M$+">"
  18. 60 PRINT:PRINT;"You must leave the computer and modem ON"
  19. 80 GOSUB 190        'read clock
  20. 90 IF TM$=A$ THEN 164     'Is it time?  Yes, then run MEX
  21. 100 OLDTM$=TM$        'If not, then try again
  22. 110 GOSUB 190        'Read clock
  23. 120 IF TM$>OLDTM$ THEN 80 
  24. 130 GOTO 110
  25. 164 L=LEN(M$)+1        'Length of command line + space (20h)
  26. 165 POKE &H80,L        'Poke length into default buffer
  27. 166 POKE &H81,&H20    'poke space (20h)
  28. 168 J=130        'Decimal equivalent of 82h
  29. 169 FOR I%=1 TO LEN(M$)    'Loop times number of chars in command line
  30. 170   L$(I%)=MID$(M$,I%,1)'Assign a string variable to each char in comm. line
  31. 171   POKE J,ASC(L$(I%)) 'Poke command line into default buffer addresses
  32. 172   J=J+1        'Increment address counter
  33. 175 NEXT I%        'Do it again
  34. 180 PRINT CHR$(26):RUN "MEX"
  35. 190 OUT &H3D,4:TH=INP(&H3C):GOSUB 220:DH$=TH$    'Clock routine for
  36. 200 OUT &H3D,2:TH=INP(&H3C):GOSUB 220:DI$=TH$    'Epson QX-10
  37. 210 TM$=DH$+":"+DI$:RETURN
  38. 220 TH$=""
  39. 230 IF TH<10 THEN TH$="0"
  40. 240 TH$=TH$+HEX$(TH)                'End clock routine
  41. 250 RETURN
  42.