home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mx-sm13a.asm < prev    next >
Assembly Source File  |  1994-07-13  |  9KB  |  297 lines
  1. $TITLE    'MEX SMARTMODEM OVERLAY V1.3a'
  2. ;
  3. ; (DELETE ABOVE TITLE LINE IF ASSEMBLING WITH ASM)
  4. ;
  5. ; Smartmodem overlay for MEX: revision 1.3A (for Anchor)    
  6. ; Written 04/16/84 by Ronald G. Fowler (V1.0)
  7. ;
  8. ;
  9. ; 09/07/84: Added three additional calls to DISCON to prevent Anchor
  10. ;           Mark XII hangup for abort, timeout and no connect codes.
  11. ;           All additional code is lower case.  Retitled the overlay
  12. ;           MX-SM13A.ASM  The suffix "A" for Anchor (Bob Sandel)
  13. ;      
  14. ; 07/16/84: Added equate NUMRES to enable/disable numeric result code 
  15. ;        interpretation.  Under TurboDos, the first digit of the 
  16. ;        phone number was being interpreted as a result code as it 
  17. ;        was echoed by the Anchor modem as it dialed.  Set NUMRES false
  18. ;        to disable numeric results. (Bob Puckett)
  19. ;
  20. ; 06/06/84: Fixed problem for Anchor users, where, when the modem returned
  21. ;        "DIAL TONE", the "N" in "TONE" was being regarded as a NO-CONNECT
  22. ;        code.  Now we flush the entire result line before reading another.
  23. ;        Also added code for numeric version of "CONNECT 1200".  --RGF
  24. ;
  25. ; Small bug repaired: (V1.1) 05/14/84 (Steve Grandi): Smartmodem was not being 
  26. ;    flushed after a dial string so that last digit of the phone number 
  27. ;    was being interpreted as a numeric result code causing the program, 
  28. ;    for certain numbers, to give up even as the modem merrily dialed away.
  29. ;
  30. ; This modules adapts MEX for the DC Hayes Smartmodem (as well
  31. ; as many others -- including US Robotics -- that use a similar
  32. ; command language). The main function of this module is to pro-
  33. ; vide dialing capability; the disconnect vector is ancillary.
  34. ; You may use this module as a model to develop dialing routines
  35. ; for non-standard modems (e.g., the Racal-Vadic).  The only
  36. ; pertinent entry point is the DIAL routine; you'll find entry
  37. ; specs for that below.
  38. ;
  39. ; The only conditional you might want to change in this
  40. ; module is the DISC equate below -- if left on, MEX will
  41. ; use the Smartmodem's disconnect code.  If you prefer to
  42. ; provide your own in your overlay's DISCV vector (e.g.,
  43. ; by dropping DTR), then set DISC to FALSE and re-assemble.
  44. ; (If you don't understand this, then play it safe, and
  45. ; leave the equate set as it is).
  46. ;
  47. ; This overlay will work with any modem overlay that terminates
  48. ; prior to 0B00H
  49. ;
  50. FALSE    EQU    0
  51. TRUE    EQU    NOT FALSE
  52. ;
  53. ;
  54. NUMRES    EQU    FALSE        ; TRUE = INTERPRET NUMERIC RESULT CODES
  55.                 ; FALSE = IGNORE NUMERIC RESULT CODES
  56. ;
  57. DISC    EQU    TRUE        ;<<== CHANGE TO FALSE IF YOU DISC. WITH DTR
  58. ;
  59. ; SYSTEM CONSTANTS
  60. ;
  61. TPULSE    EQU    0105H        ;TONE/PULSE FLAG IN MODEM OVERLAY
  62. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  63. DISCV    EQU    0165H        ;LOCATION OF DISCONNECT VECTOR IN OVERLAY
  64. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  65. MEX    EQU    0D00H        ;"CALL MEX"
  66. ;
  67. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  68. ;
  69. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  70. TIMER    EQU    254
  71. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  72. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  73. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  74. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  75. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  76. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  77. ;
  78. CR    EQU    13
  79. LF    EQU    10
  80. ;
  81. ;
  82. ;
  83.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  84.     JMP    DIAL
  85. ;    
  86.     IF    DISC        ;IF PROVIDING DISCONNECT CODE
  87.     ORG    DISCV        ;OVERLAY THE VECTOR
  88.     JMP    DISCON
  89.     ENDIF
  90. ;
  91. ; This is the DIAL routine called by MEX to dial a digit. The digit
  92. ; to be dialed is passed in the A register.  Note that two special
  93. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  94. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  95. ; in the accumulator prior to dialing a number.  Mex will also call
  96. ; dial with 255 in A as an indication that dialing is complete. Thus,
  97. ; the overlay may use these values to "block" the number, holding it
  98. ; in a buffer until it is completely assembled (in fact, that's the
  99. ; scheme employed here for the Smartmodem).
  100. ;
  101. ; After the 254-start-dial sequence, MEX will call the overlay with
  102. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  103. ; its, and will send each to the DIAL routine un-inspected (some modems,
  104. ; like the Smartmodem, allow special non-numeric characters in the
  105. ; phone number, and MEX may make no assumptions about these).
  106. ;
  107. ; After receiving the end-dial sequence (255) the overlay must take
  108. ; whatever end-of-dial actions are necessary *including* waiting for
  109. ; carrier at the distant end.  The overlay should monitor the keyboard
  110. ; during this wait (using the MEX keystat service call), and return
  111. ; an exit code to MEX in the A register, as follows:
  112. ;
  113. ;    0 - Carrier detected, connection established
  114. ;    1 - Far end busy (only for modems that can detect this condition)
  115. ;    2 - No answer (or timed out waiting for modem response)
  116. ;    3 - Keyboard abort (^C only: all others should be ignored)
  117. ;    4 - Error reported by modem
  118. ;
  119. ; <No other codes should be returned after an end-dial sequence>
  120. ;
  121. ; The overlay should not loop forever in the carrier-wait routine, but
  122. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  123. ; ms character wait) service call routine.
  124. ;
  125. ; The DIAL routine is free to use any of the registers, but must return
  126. ; the above code after an end-dial sequence
  127. ;
  128.     ORG    DIALOC
  129. ;
  130. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  131.     CPI    254        ;START DIAL?
  132.     JZ    STDIAL        ;JUMP IF SO
  133.     CPI    255        ;END DIAL?
  134.     JZ    ENDIAL        ;JUMP IF SO
  135. ;
  136. ; Not start or end sequence, must be a digit to be sent to the modem
  137. ;
  138.     MOV    M,A        ;PUT CHAR IN BUFFER
  139.     INX    H        ;ADVANCE POINTER
  140.     SHLD    DIALPT        ;STUFF PNTR
  141.     RET            ;ALL DONE
  142. ;
  143. ; Here on a start-dial sequence
  144. ;
  145. STDIAL:    LXI    H,DIALBF    ;SET UP BUFFER POINTER
  146.     SHLD    DIALPT
  147.     RET
  148. ;
  149. ; Here on an end-dial sequence
  150. ;
  151. ENDIAL:    MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  152.     INX    H        ;FOLLOWED BY TERMINATOR
  153.     MVI    M,0
  154.     LDA    TPULSE        ;GET OVERLAY'S TOUCH-TONE FLAG
  155.     STA    SMDIAL+3    ;PUT INTO STRING
  156.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  157.     CALL    SMSEND        ;SEND IT
  158. WAITSM:    MVI    C,INMDM
  159.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  160.     JNC    WAITSM        ;LOOP UNTIL NO MORE CHARACTERS
  161. ;
  162. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  163. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  164. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  165. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  166. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  167. ; WAIT TO 20 SECONDS).
  168. ;
  169. RESULT:    MVI    C,35        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  170. SMWLP:    PUSH    B
  171.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  172.     MVI    C,TMDINP    ;DO TIMED INPUT
  173.     CALL    MEX
  174.     POP    B
  175.     JNC    SMTEST        ;JUMP IF MODEM HAD A CHAR
  176.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  177.     MVI    C,CHEKCC
  178.     CALL    MEX
  179.     POP    B
  180.     JNZ    SMNEXT        ;IF NOT, JUMP
  181.         push b
  182.         call discon             ;added to prevent Anchor hangup
  183.         pop b
  184.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  185.     MVI    C,SNDCHR
  186.     CALL    MEX
  187.     MVI    A,3        ;RETURN ABORT CODE
  188.     RET
  189. SMNEXT:    DCR    C        ;NO
  190.     JNZ    SMWLP        ;CONTINUE
  191. ;
  192. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  193. ;
  194. SMTIMO:    call discon             ;added to prevent anchor hangup
  195.         MVI    A,2        ;RETURN TIMEOUT CODE
  196.     RET
  197. ;
  198. ; MODEM GAVE US A RESULT, CHECK IT
  199. ;
  200. SMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  201.     CALL    SMANAL        ;TEST THE RESULT
  202.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  203.     PUSH    PSW        ;SAVE IT
  204. SMTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  205.     CALL    MEX
  206.     JC    SMCHEK        ;JUMP IF NO INPUT
  207.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  208.     JNZ    SMTLP        ;EAT ANY IN-BETWEEN
  209. SMCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  210.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  211.         rz
  212.         call discon             ;added to prevent anchor hangup
  213.     RET
  214. ;
  215. SMANAL:    MVI    B,0        ;PREP CONNECT CODE
  216.     CPI    'C'        ;"CONNECT"?
  217.     RZ
  218.  
  219.     IF     NUMRES
  220.     CPI    '1'        ;NUMERIC VERSION OF "CONNECT"
  221.     RZ
  222.     CPI    '5'        ;NUMERIC VERSION OF "CONNECT 1200"
  223.     RZ
  224.     ENDIF
  225.  
  226.     INR    B        ;PREP BUSY CODE B=1
  227.     CPI    'B'
  228.     RZ
  229.     INR    B        ;PREP NO CONNECT MSG B=2
  230.     CPI    'N'        ;N=NO CONNECT
  231.     RZ
  232.  
  233.     IF     NUMRES
  234.     CPI    '3'        ;NUMERIC VERSION OF "NO CONNECT"
  235.     RZ
  236.     ENDIF
  237.  
  238.     MVI    B,4        ;PREP MODEM ERROR
  239.     CPI    'E'        ;E=ERROR
  240.     RZ
  241.  
  242.     IF    NUMRES
  243.     CPI    '4'        ;NUMERIC VERSION OF "ERROR"
  244.     RZ
  245.     ENDIF
  246.  
  247.     STC            ;UNKNOWN...
  248.     RET
  249. ;
  250. ; FOLLOWING ROUTINE DISCONNECTS THE MODEM USING SMARTMODEM
  251. ; CODES. ALL REGISTERS ARE AVAILABLE FOR THIS FUNCTION.
  252. ; NOTHING RETURNED TO CALLER.
  253. ;
  254.     IF    DISC
  255. ;
  256. DISCON:    MVI    B,12
  257.     MVI    C,TIMER        ;WAIT 1.2 SECONDS
  258.     CALL    MEX
  259.     LXI    H,SMATN        ;SEND '+++'
  260.     CALL    SMSEND
  261.     MVI    B,12        ;WAIT 1.2 MORE SECONDS
  262.     MVI    C,TIMER
  263.     CALL    MEX
  264.     LXI    H,SMDISC    ;SEND 'ATH'
  265.     CALL    SMSEND
  266.     MVI    B,10            ;WAIT 1 SECOND
  267.     MVI    C,TIMER
  268.     CALL    MEX
  269.     RET
  270. ;
  271. SMATN:    DB    '+++',0
  272. SMDISC:    DB    'ATH',CR,0
  273. ;
  274.     ENDIF
  275. ;
  276. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  277. ;
  278. SMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  279.     CALL    MEX
  280.     JNZ    SMSEND
  281.     MOV    A,M        ;FETCH NEXT CHARACTER
  282.     INX    H
  283.     ORA    A        ;END?
  284.     RZ            ;DONE IF SO
  285.     MOV    B,A        ;NO, POSITION FOR SENDING
  286.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  287.     CALL    MEX
  288.     JMP    SMSEND
  289. ;
  290. ; DATA AREA
  291. ;
  292. SMDIAL:    DB    'ATDT '
  293. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  294. DIALPT:    DS    2        ;DIAL POSITION POINTER
  295. ;
  296.     END
  297.