home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxc-kc10.asm < prev    next >
Assembly Source File  |  1994-07-13  |  6KB  |  234 lines
  1. ;-----------------------------------------------------------------
  2. ; MXC-KC10.ASM
  3. ; clock overlay for mex and the Kenmore Computer Technologies (KCT)
  4. ; Ztime-I real-time clock.
  5.  
  6. rev    equ    12    ;V 1.2
  7.  
  8. ; V1.2  30 Aug 86 - Fixed Year storage to chip          - Rea Williams
  9. ; V1.1  26 Apr 85 - Added CSET routine            - Joe Griffith
  10. ; V1.0  24 Apr 85 - Original, TM-KCT11.ASM        - Joe Griffith
  11.  
  12. ;--------------------------------------------------------------------
  13. ;     This overlay provides the current date and time to MEX+ or higher
  14. ; versions of MEX.  It is configured for the Kenmore Computer
  15. ; Technologies (KCT) Ztime-I real-time calendar/clock although it
  16. ; will probably work with any clock using the MM58167A clock chip.
  17.  
  18. no    equ    0    
  19. yes    equ    0ffh
  20. i8080    equ    yes        ;for xlat- do not change
  21. i8086    equ    no
  22. cpm    equ    yes
  23. pcdos    equ    no
  24. cr    equ    13
  25. lf    equ    10
  26.  
  27. mex    equ    0D00h        ;address of the service processor
  28. ilp    equ    240        ;inline print
  29. sblank    equ    244        ;scan input stream to next non-blank (cy=end)
  30. evala    equ    243        ;evaluate number from input to HL
  31. gnc    equ    241        ;get next character
  32. decout    equ    239        ;decimal output from HL
  33.  
  34. bport    equ    0E0h        ;base port address for KCT clock
  35.                 ;this address should be changed to
  36.                 ;reflect wherever your MM58167A is.
  37. centry    equ    1900        ;hard code since it is not available
  38.                 ;from the clock chip
  39.  
  40. ;--------------------------------------------------------------------
  41.     
  42.     org    100h        ;processor type flag is here
  43.  
  44. if i8080
  45.     db    0c3h        ;show which processor we are for
  46. endif
  47. if i8086
  48.     db    0E9h
  49. endif
  50.  
  51. ;-----------------------------------------------------------------
  52. ;   JMP table for clock overlay
  53.  
  54.     org    0e00h        ;start of clock overlay 
  55.  
  56.     jmp    gettim        ;get time
  57.     jmp    getdat        ;get date
  58.     jmp    setclk        ;cset processor
  59.     ret            ;clock overlay init
  60.     nop
  61.     nop
  62.     ret            ;clock overlay de-init
  63. thisyr:    db    0        ;this is actually the space reserved
  64.                 ;for the address portion of the jmp
  65.                 ;but no de-init is needed so the year
  66.                 ;is stored here.  Note that the system
  67.                 ;must be cloned after the clock is set
  68.                 ;to permanently store the year here.
  69. hlpflg:    db    0        ;likewise the help flag is stored here
  70.  
  71. ;--------------------------------------------------------------------
  72. ; subroutine GETTIM returns the time as follows:
  73. ;
  74. ; B - Hours (0-23)
  75. ; C - Minutes (0-59)
  76. ; D - Seconds (0-59)
  77. ; E - Hundreths of seconds (0-99) 
  78.  
  79. gettim:    in    bport+2        ;get seconds
  80.     push    psw        ;save for future reference
  81.     
  82.     call    makbin        ;make it a binary number
  83.     mov    d,a        ;store it
  84.     in    bport+3        ;get minutes
  85.     call    makbin
  86.     mov    c,a
  87.     in    bport+4        ;get hours
  88.     call    makbin
  89.     mov    b,a
  90.  
  91.     in    bport+2
  92.     mov    l,a        ;store it
  93.     pop    psw        ;get original seconds back
  94.     cmp    l        ;compare the two
  95.     jnz    gettim        ;not the same so do it over else
  96.     mvi    e,0        ;clear hundreds of seconds
  97.     ret
  98.  
  99. ;------------------------------------------------------------------------
  100. ; subroutine GETDAT returns the date as follows:
  101. ; 
  102. ; BC - Year (1985-2099)
  103. ; D - Month (1=January, 2=February, etc.)
  104. ; E - Day of month (1-31)
  105.  
  106. getdat:    in    bport+2        ;get seconds
  107.     push    psw        ;save it for future reference
  108.  
  109.     in    bport+7        ;get month
  110.     call    makbin
  111.     mov    d,a
  112.     in    bport+6        ;get day of month
  113.     call    makbin
  114.     mov    e,a
  115.  
  116.     in    bport+2        ;get seconds again
  117.     mov    l,a        ;store temporarily
  118.     pop    psw        ;get original seconds
  119.     cmp    l        ;compare the two
  120.     jnz    getdat        ;if not the same do it over
  121.     in      bport+9         ;get year 
  122.     call    makbin
  123.     mov    c,a        ;put in it's proper place
  124.     mvi    b,0
  125.     lxi    h,centry    ;load the century
  126.     dad    b        ;add it to the stored value
  127.     mov    c,l        ;move hl to bc
  128.     mov    b,h
  129.     ret
  130.  
  131. ;-----------------------------------------------------------------
  132. ;  This routine takes the two BCD values in each nibble of the
  133. ; accumulator and converts it to a single binary value.
  134.  
  135. makbin:    push    d        ;save the current value
  136.     push    psw        ;save the original value
  137.     rrc            ;put the 10s value in the lower bits
  138.     rrc
  139.     rrc
  140.     rrc
  141.     ani    0Fh        ;mask off whatever is in the high nibble
  142.     add    a        ;multiply this register by 10
  143.     mov    e,a
  144.     add    a
  145.     add    a
  146.     add    e
  147.     mov     e,a        ;save in e
  148.     pop    psw        ;get the original value
  149.     ani    0Fh        ;allow only low bits
  150.     add    e        ;get total to a
  151.     pop    d        ;restore de
  152.     ret            ;all done
  153.  
  154. ;----------------------------------------------------------------------
  155. ;   CSET processor.  This routine allows the user to set the clock from
  156. ; command level by typing CSET yy/mm/dd hh:mm:ss.
  157.  
  158. setclk:    call    ilprt
  159.     db    'KCT Clock OVR V'
  160.     db    rev/10+'0','.'
  161.     db    rev mod 10+'0'
  162.     db    cr,lf,lf,0
  163.  
  164.     xra    a        ;get a zero
  165.     sta    hlpflg        ;store it as a flag
  166.     call    twobcd        ;get the first two numbers
  167.     rc
  168.     out    bport+9        ;put in the year
  169.     call    twobcd        ;get the month
  170.     rc
  171.     out    bport+7        ;put in the months counter
  172.     call    twobcd        ;get the day of the month
  173.     rc
  174.     out    bport+6        ;put in the day counter
  175.     call    twobcd        ;get the hour
  176.     rc
  177.     out    bport+4        ;put in the hour counter
  178.     call    twobcd        ;get the minutes
  179.     rc
  180.     out    bport+3        ;put in the minutes counter
  181.     call    twobcd        ;get the seconds
  182.     rc
  183.     out    bport+2        ;put in the seconds counter
  184.     ret
  185.  
  186. ;------------------------------------------------------------------
  187. ;   this routine looks at the CSET parameter and returns with a BCD
  188. ; pair in the two nibbles of the accumulator.  Blanks and separators
  189. ; are skiped.  The carry flag is set when the end of the line is
  190. ; reached.
  191.  
  192. twobcd:    call    getnum        ;get the 10's digit
  193.     jc    chlp        ;no numbers there
  194.     rrc            ;put it in the high nibble
  195.     rrc
  196.     rrc
  197.     rrc
  198.     push    psw        ;save it
  199.     call    getnum        ;get the 1's
  200.     mov    b,a        ;temporary storage
  201.     pop    psw        ;get the 10s back
  202.     ora    b        ;merge the two
  203.     ret
  204.  
  205. getnum:    mvi    c,gnc        ;get the next character
  206.     call    mex
  207.     rc            ;carry means there is no more input
  208.     cpi    '0'
  209.     jc    getnum        ;char is smaller than ascii zero
  210.     cpi    ':'
  211.     jnc    getnum        ;char is not an ascii digit
  212.     cmc            ;reset carry flag
  213.     sta    hlpflg
  214.     sbi    '0'        ;make it a binary value
  215.     ret
  216.  
  217. chlp:    lda    hlpflg        ;get the help flag
  218.     cpi    0        ;is it null
  219.     stc            ;flag the end
  220.     rnz            ;if not then don't print
  221.     call     ilprt
  222.     db    'CSET YY/MM/DD HH:MM:SS'
  223.     db    cr,lf,lf,0
  224.     stc            ;flag the system
  225.     ret
  226.  
  227. ;----------------------------------------------------------------------
  228. ; inline print routine
  229.  
  230. ilprt:    mvi    c,ilp
  231.     jmp    mex
  232.  
  233.     end    
  234.