home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxh-kp53.asm < prev    next >
Assembly Source File  |  1994-07-13  |  26KB  |  948 lines
  1.     Title  'MexPlus Overlay for Kaypros Version 5.3'
  2. ;
  3. REV    EQU    53        ;OVERLAY REVISION LEVEL
  4. ;
  5. ;
  6. ;  MexPlus Hardware (MXH) Overlay for Kaypro Computers
  7. ;  using an external smartmodem.
  8. ;
  9. ;  NOTE: To fully implement MEXPLUS you need also get:
  10. ;
  11. ;    MXT-KP*.OVR     Kaypro termcap (video) overlay
  12. ;    MXM-SM*.OVR     Smartmodem dialing overlay
  13. ;    MXC-K484.OVR    For Kaypro Internal factory clock, or
  14. ;    MXC-LG10.OVR    Legacy KP10 clock overlay
  15. ;
  16. ;  MEXPLUS uses the following conventions:
  17. ;
  18. ;  MXH-*.OVR    Hardware overlay for computer
  19. ;  MXT-*.OVR    Terminal capability overlay
  20. ;  MXC-*.OVR    Real-time clock overlay for 8080/Z80 vers
  21. ;  MXM-*.OVR    Modem overlay
  22. ;
  23. ;  These overlays are available from The NightOwl Connection
  24. ;  if you are subscriber or thru The DatCOM Super System
  25. ;  (813) 937-3608  300/1200 bps (annual fee also req'd).
  26. ;
  27. ;  //////////////////////////////////////////////////////////
  28. ;
  29. ;  A full-featured SET command processor is implemented.
  30. ;  The following table outlines the SET command options:
  31. ;
  32. ;        
  33. ;    SET Command
  34. ;
  35. ;    BAUD <RATE>            Set modem to Baud rate specified.
  36. ;                    Baud rates supported are 110, 300,
  37. ;                    600, 1200, 2400, 4800, 9600, 19200
  38. ;
  39. ;    ORIG                            Set modem to Originate mode
  40. ;    ANSWER                          Set modem to Auto-answer mode
  41. ;    TONE                            Set modem to Tone dialing
  42. ;    PULSE                           Set modem to Pulse dialing
  43. ;    MONITOR                Turn Hayes monitor ON
  44. ;    QUIET                Turn Hayes monitor OFF
  45. ;    PARITY                          Set Parity to Odd, Even, or Off
  46. ;    STOPBITS                        Set number of Stop Bits to 1, 1.5, 2
  47. ;    LENGTH                 Set word length to 5, 6, 7, 8
  48. ;
  49. ;    MANUAL ORIG <or> ANSWER        Place modem in active state and
  50. ;                    generate Answer or Originate
  51. ;                    carrier tone
  52. ;
  53. ;
  54. ;  History:
  55. ;  08/12/85   v5.3  Trimmed down the code, it was 7 bytes too long.
  56. ;            Remember, this thing HAS to end by 0AFF!;  Also,
  57. ;            all the Smartmodem code that's still here (I
  58. ;            thought somebody removed all that???) induced me
  59. ;            to do a new Kaypro overlay, MXH-KG10 (Kaypro Gen-
  60. ;            eric), with no Smartmodem code.  I've been able
  61. ;            to test it only on a couple of Kaypro models -- I
  62. ;            think it should work for all -- I'd appreciate any
  63. ;            feedback from people using the KG10 overlay.
  64. ;                        --Ron Fowler
  65. ;
  66. ;  07/12/85   v5.2  Removed and rewote code for 'eye wash' as it made a
  67. ;            nice generic kp overlay kp-video dependent. Changed
  68. ;            code to enter mex's video attribute routines the way
  69. ;            its supposed to be done. Also changed modem init to
  70. ;            wait 30 sec before timout. Was hanging up prematurely
  71. ;            on many long distance calls. 
  72. ;                            -- Mike Woodward
  73. ;
  74. ;  05/28/85   v5.1   Added some video 'eye-wash' to the console
  75. ;                    displays to make em look nicer.
  76. ;                                                    -- Steve Sanders
  77. ; 
  78. ;  05/26/84   v5.0   Modified MXO-KPS4 for MexPlus compatibility.
  79. ;                                 -- Terry Carroll
  80. ;
  81. ;------------------------------------------------------------
  82. ;
  83. ; Kaypro port definitions
  84. ;
  85. EXPORT    EQU    04H        ;base external port
  86. EXTCT1    EQU    EXPORT+2    ;external modem status port
  87. EXTDAT    EQU    EXPORT        ;external modem data port
  88. BAUDRP    EQU    00H        ;external modem baud rate port
  89. ;
  90. ; Kaypro bit definitions
  91. ;
  92. MDRCVB    EQU    01H        ;modem receive bit (DAV)
  93. MDRCVR    EQU    01H        ;modem receive ready
  94. MDSNDB    EQU    04H        ;modem send bit
  95. MDSNDR    EQU    04H        ;modem send ready bit
  96. ;
  97. ;
  98. ; MEX service processor equates
  99. ;
  100. MEX    EQU    0D00H        ;address of the service processor
  101. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  102. TIMER    EQU    254        ;delay 100ms * reg B
  103. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  104. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  105. SNDRDY    EQU    251        ;test for modem-send ready
  106. RCVRDY    EQU    250        ;test for modem-receive ready
  107. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  108. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  109. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  110. PARSFN    EQU    246        ;parse filename from input stream
  111. BDPARS    EQU    245        ;parse baud-rate from input stream
  112. SBLANK    EQU    244        ;scan input stream to next non-blank
  113. EVALA    EQU    243        ;evaluate numeric from input stream
  114. LKAHED    EQU    242        ;get nxt char w/o removing from input
  115. GNC    EQU    241        ;get char from input, cy=1 if none
  116. ILP    EQU    240        ;inline print
  117. DECOUT    EQU    239        ;decimal output
  118. PRBAUD    EQU    238        ;print baud rate
  119. ;
  120. ; MEX TERMINAL OVERLAY VECTORS
  121. CLS    EQU    140FH        ;clear screen
  122. ENTREV    EQU    1415H        ;enter rev video
  123. EXREV    EQU    1418H        ;exit rev video
  124. ENTBRT    EQU    141BH        ;enter bright (exit dim?)
  125. EXBRT    EQU    141EH        ;exit bright (enter dim?)
  126. ;
  127. PRINT    EQU    9        ;BDOS/MEX print-string function call
  128. ;
  129. BELL    EQU    7        ;bell
  130. TAB    EQU    9
  131. CR    EQU    13        ;carriage return
  132. LF    EQU    10        ;linefeed
  133. ESC    EQU    1BH        ;escape
  134. YES    EQU    0FFH
  135. NO    EQU    0
  136. ;
  137. I8080    EQU    YES        ;FOR TRANSLATOR - DO NOT CHANGE
  138. I8086    EQU    NO
  139. CPM    EQU    YES
  140. PCDOS    EQU    NO
  141. ;
  142. ;
  143. ; ## The following JUMP instruction is necessary for MEXPLUS loadable overlays
  144. ;
  145.     ORG    100H
  146.     DB    0C3H        ;##JMP INSTRUCTION (MEX 1.2)
  147. ;
  148. ; Change the clock speed to suit your system
  149. ;
  150.     DS    2        ;(for  "JMP   START" instruction)
  151.  
  152.     DB    NO        ;yes=PMMI S-100 Modem            103H
  153.     DB    YES        ;yes=HAYES Smartmodem, no=non-PMMI    104H
  154. TPULSE:    DB    'T'        ;T=touch, P=pulse (Smartmodem-only)    105H
  155. CLOCK:    DB    50        ;clock speed in MHz x10, 25.5 MHz max.    106H
  156.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  157. MSPEED:    DB    5        ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  158.                 ;6=2400 7=4800 8=9600 9=19200 default
  159. BYTDLY:    DB    5        ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  160.                 ;default time to send character in ter-
  161.                 ;minal mode file transfer for slow BBS.
  162. CRDLY:    DB    5        ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  163.                 ;default time for extra wait after CRLF
  164.                 ;in terminal mode file transfer
  165. COLUMS:    DB    5        ;number of DIR columns shown        10AH
  166. SETFLG:    DB    YES        ;yes=user-added Setup routine        10BH
  167. SCRTST:    DB    YES        ;Cursor control routine         10CH
  168.     DB    YES        ;yes=resend a record after any non-ACK    10DH
  169.                 ;no=resend a record after a valid-NAK
  170. BAKFLG:    DB    YES        ;yes=change any file same name to .BAK    10EH
  171. CRCDFL:    DB    YES        ;yes=default to CRC checking        10FH
  172. TOGCRC:    DB    YES        ;yes=allow toggling of CRC to Checksum    110H
  173. CVTBS:    DB    NO        ;yes=convert backspace to rub        111H
  174. TOGLBK:    DB    YES        ;yes=allow toggling of bksp to rub    112H
  175. ADDLF:    DB    NO        ;no=no LF after CR to send file in    113H
  176.                 ;terminal mode (added by remote echo)
  177. TOGLF:    DB    YES        ;yes=allow toggling of LF after CR    114H
  178.     DB    YES        ;yes=allow transmission of logon    115H
  179.                 ;write logon sequence at location LOGON
  180. SAVCCP:    DB    YES        ;yes=do not overwrite CCP        116H
  181.     DB    NO        ;yes=local command if EXTCHR precedes    117H
  182.                 ;no=external command if EXTCHR precedes
  183.     DB    YES        ;yes=allow toggling of LOCONEXTCHR    118H
  184. LSTTST:    DB    YES        ;yes=printer available on printer port    119H
  185. XOFTST:    DB    NO        ;yes=checks for XOFF from remote while    11AH
  186.                 ;sending a file in terminal mode
  187. XONWT:    DB    NO        ;yes=wait for XON after CR while    11BH
  188.                 ;sending a file in terminal mode
  189. TOGXOF:    DB    YES        ;yes=allow toggling of XOFF checking    11CH
  190. IGNCTL:    DB    NO        ;yes=CTL-chars above ^M not displayed    11DH
  191. EXTRA1:    DB    0        ;for future expansion            11EH
  192. EXITCHR    DB    'E'-40H        ;^E = Exit to main menu            11FH
  193. BRKCHR:    DB    '@'-40H        ;^@ = Send 300 ms. break tone        120H
  194. NOCONN:    DB    'N'-40H        ;^N = Disconnect from the phone line    121H
  195. LOGCHR:    DB    'L'-40H        ;^L = Send logon            122H
  196. LSTCHR:    DB    'P'-40H        ;^P = Toggle printer            123H
  197. UNSAVE:    DB    'R'-40H        ;^R = Close input text buffer        124H
  198. TRNCHR:    DB    'T'-40H        ;^T = Transmit file to remote        125H
  199. SAVCHR:    DB    'Y'-40H        ;^Y = Open input text buffer        126H
  200. EXTCHR:    DB    '^'-40H        ;^^ = Send next character        127H
  201.     DS    2        ;unused by MEX                128H
  202. ;
  203. ;
  204. ; Low-level modem I/O routines.
  205. ;
  206. INCTL1:    JMP    INCTRL        ;in modem control port
  207.     DB    0,0,0,0,0,0,0    ;spares if needed for non-PMMI
  208. ;
  209. OTDATA:    JMP    OUTDTA        ;out modem data port
  210.     DB    0,0,0,0,0,0,0    ;spares if needed for non=PMMI
  211. ;
  212. INPORT: JMP    INDATA        ;in modem data port
  213.     DB    0,0,0,0,0,0,0    ;spares if needed for non-PMMI
  214. ;
  215. ; Bit-test routines. 
  216. ;
  217. MASKR:    ANI MDRCVB          ;bit to test for receive ready
  218.     RET
  219. TESTR:    CPI MDRCVR          ;value of receive bit when ready
  220.     RET
  221. MASKS:    ANI MDSNDB          ;bit to test for send ready
  222.     RET
  223. TESTS:    CPI MDSNDR          ;value of send bit when ready
  224.     RET
  225. ;
  226. ;
  227. ; ## Following are two new entrie points for MEXPLUS
  228. ; DCDTST returns data-carrier detect in A: 0 if no carrier
  229. ;  present, 0FFH if carrier is present, and 0FEH if overlay
  230. ;  doesn't know (i.e., doesn't support carrier detect)
  231. ; RNGDET works similarly for ring-detect.
  232. ;
  233. DCDTST:    JMP    DCDVEC        ;data carrier detect            154H
  234. RNGDET:    JMP    RNGVEC        ;ring-detect                157H
  235. ;
  236. ; End of MEXPLUS added vectors
  237. ;
  238.     DB    0,0,0,0,0    ;reserved space, assumed 0
  239. ;                                    15FH
  240. SMDISC:    DS    3        ;software disconnect (in smartmodem overlay)
  241. ;
  242.     DS    3        ;DIALV: not done here (maybe MXO-SM)    162H
  243. DISCV:    JMP    DISCON        ;disconnect (if not used, should be JMP SMDISC)
  244. GOODBV:    JMP    GOODBYE        ;                    168H
  245. INMODV:    JMP    NITMOD        ;go to user written routine        16BH
  246.     JMP    PBAUD        ;NEWBDV                    16EH
  247.     RET             ;NOPARV                    171H
  248.     NOP
  249.     NOP
  250.     RET             ;PARITV                    174H
  251.     NOP
  252.     NOP
  253. SETUPV:    JMP    SETCMD        ;                    177H
  254.     DS    3        ;not used by MEX            17AH
  255. VERSNV:    JMP    SYSVER        ;                    17DH
  256. BREAKV:    JMP    SBREAK        ;                    180H
  257. ;
  258. ; Do not change the following six lines (they provide access to routines
  259. ; in MEX that are present to support MDM7 overlays -- they will likely
  260. ; be gone by MEX v2.0).
  261. ;
  262. ILPRTV:    DS    3        ;                    183H
  263. INBUFV    DS    3        ;                    186H
  264. ILCMPV:    DS    3        ;                    189H
  265. INMDMV:    DS    3        ;                    18CH
  266.     DS    3        ;                    18FH
  267. TIMERV    DS    3        ;                    192H
  268. ;
  269. ;
  270.     ORG    200H        ;## NEW BOUNDARY FOR MEX1.2
  271. ;------------------------------------------------------------
  272. ;
  273. ; end of fixed area
  274. ;
  275. ;------------------------------------------------------------
  276. ;
  277. ; Low level modem routine area
  278. ;
  279. INCTRL:    MVI    A,10H
  280.     OUT    EXTCT1
  281.     IN    EXTCT1
  282.     RET
  283. ;
  284. INDATA:    IN    EXTDAT
  285.     RET
  286. ;
  287. OUTDTA:    OUT    EXTDAT
  288.     RET
  289. ;
  290. ; Print out the overlay version
  291. ;
  292. SYSVER:      CALL  MILP
  293.       DB    CR,LF
  294.       DB    'KAYPRO MexPlus Overlay --- Version '
  295.       DB    REV/10+'0'
  296.       DB    '.'
  297.       DB    REV MOD 10+'0'
  298.       DB    CR,LF,CR,LF
  299.       DB    0
  300.       RET
  301. ;
  302. ; Break, disconnect and goodbye routines
  303. ;
  304. SBREAK:   MVI    A,5
  305.       OUT    EXTCT1
  306.       LDA    REG5
  307.       ORI    9AH        ;Send a break
  308.        OUT    EXTCT1
  309.       MVI    B,3        ;DELAY 300 MS.
  310.       CALL  MTIME
  311.       MVI    A,5
  312.       OUT    EXTCT1
  313.       LDA    REG5
  314.       OUT    EXTCT1        ;stop break
  315.       RET
  316. ;
  317. ; ## return data carrier detect status
  318. ;      0    = no carrier
  319. ;      255  = carrier present
  320. ;      254  = we don't know (DCD not supported)
  321. ;
  322. DCDVEC:    MVI    A,0FEH        ;get status port
  323.     RET            ;return "we don't know" detect
  324. ;
  325. ; ## return ring-detect status:
  326. ;
  327. ;     0   =  not ringing
  328. ;     255 =  ring detected
  329. ;     254 =  we don't kno
  330. ;
  331. RNGVEC:    MVI    A,0FEH        ;return "we don't know"
  332.     RET
  333. ;
  334. ; Disconnect Hayes, etc.
  335. ;
  336. DISCON:   MVI    A,5
  337.       OUT    EXTCT1        ;SEND TO THE STATUS PORT
  338.       MVI    A,68H        ;TURN OFF DTR/RTS
  339.       OUT    EXTCT1
  340.       MVI    B,10        ;DELAY 1 SEC.
  341.       CALL  MTIME
  342.       MVI    A,5
  343.       OUT    EXTCT1
  344.       MVI    A,0EAH        ;TURN 'EM BACK ON AGAIN
  345.       OUT    EXTCT1
  346.       RET
  347. ;
  348. ; GOODBYE routines are called by MEX prior to exit to CP/M
  349. ;
  350. GOODBYE:  RET            ;NOTE: EXIT TO CP/M WITH NO CHANGE TO
  351.                 ;CONNECT STATUS OR SETTINGS (PARITY, ETC)
  352. ;
  353. ; Initialize RS-232 port, Smartmodem, and default modes.
  354. ;
  355. NITMOD:   CALL    INCTRL        ;SEE IF MODEM IS CONNECTED, I.E., RETURNING
  356.       ANI    08H        ;   TO ACTIVE MODEM FROM CPM
  357.       RNZ            ;SKIP IF CONNECTED
  358.           CALL  NITSIO
  359.       LDA    MSPEED        ;GET DEFAULT BAUD RATE
  360.       CALL    PBAUD        ;SET IT
  361.       LDA    MONFLG        ;GET MONITOR DEFAULT
  362.       ORA    A
  363.       MVI    A,'0'        ;SPEAKER OFF
  364.       JZ    NITMOD4
  365.       MVI    A,'1'        ;SPEAKER ON
  366. NITMOD4:  STA    SMINIT+3    ;PUT IT IN SMINIT STRING
  367.       LDA    ANSFLG        ;GET MODE DEFAULT
  368.       ORA    A
  369.       MVI    A,'0'        ;ORIGINATE
  370.       JZ    NITMOD5
  371.       MVI    A,'1'        ;ANSWER
  372. NITMOD5:  STA    SMINIT+8    ;PUT IT IN SMINIT STRING
  373.       LXI    H,SMINIT
  374. SINIT:      CALL    SMSEND        ;SEND THE INIT STRING
  375. SMTLP1:      MVI    C,INMDM        ;WAIT FOR MODEM RESPONSE
  376.       CALL    MEX
  377.       JNC    SMTLP1        ;EAT EVERYTHING UNTIL SILENCE FOR
  378.       RET            ; 100 MSEC
  379. ;
  380. ;    Initialize the Zilog SIO chip
  381. ;
  382. NITSIO:      MVI   A,00H        ;Select reg. 0
  383.       OUT   EXTCT1
  384.       LDA    REG0        ;Command byte
  385.       OUT   EXTCT1
  386.       MVI    A,04H        ;Select reg. 4
  387.       OUT   EXTCT1
  388.       LDA    REG4        ;Receive/transmit control byte
  389.       OUT   EXTCT1
  390.       MVI    A,03H        ;Select reg. 3
  391.       OUT   EXTCT1
  392.       LDA    REG3        ;Receiver logic byte
  393.       OUT   EXTCT1
  394.       MVI    A,05H        ;Select reg. 5
  395.       OUT   EXTCT1
  396.       LDA    REG5        ;Transmitter logic byte
  397.       OUT   EXTCT1
  398.       RET
  399. ;
  400. ; Set command processor
  401. ;
  402. SETCMD:      MVI    C,SBLANK    ;ANY ARGUMENTS?
  403.       CALL  MEX
  404.       JC    SETSHO        ;IF NOT, DISPLAY DEFAULT(S)
  405.       LXI    D,CMDTBL
  406.           MVI    C,LOOKUP
  407.       CALL  MEX        ;PARSE THE ARGUMENT
  408.       PUSH    H        ;SAVE ANY PARSED ARGUMENTS ON STACK
  409.       RNC            ;IF WE HAVE ONE, RETURN TO IT
  410.       POP    H        ;OOPS, INPUT NOT FOUND IN TABLE
  411. SETERR:      CALL    ENTREV        ;TERMINAL OVERLAY ENTER REV VIDEO
  412.       LXI    D,SETEMS
  413.       MVI    C,PRINT
  414.       CALL    MEX
  415.       CALL  EXREV        ;TERMINAL OVERLAY EXIT REV VIDEO
  416.       CALL  CRLF
  417.       RET
  418. SETEMS:      DB    CR,LF,'=> SET command error <='
  419.       db    CR,LF,'$'
  420. ;
  421. ; Argument table
  422. ;
  423. CMDTBL:   DB    '?'+80H            ; HELP
  424.       DW    SETHELP
  425.       DB    'ORI','G'+80H        ; ORIGINATE MODE
  426.       DW    ORIG
  427.       DB    'ANSWE','R'+80H        ; ANSWER MODE
  428.       DW    ANS
  429.       DB    'TON','E'+80H        ; TONE DIALING
  430.       DW    STTONE
  431.       DB    'PULS','E'+80H        ; PULSE DIALING
  432.       DW    STPULSE
  433.       DB    'MONITO','R'+80H    ; MONITOR ON
  434.       DW    MONIT
  435.       DB    'QUIE','T'+80H        ; MONITOR OFF
  436.       DW    QUIET
  437.       DB    'BAU','D'+80H        ; SET BAUD
  438.       DW    STBAUD
  439.       DB    'PARIT','Y'+80H        ; SET PARITY
  440.       DW    STPRTY
  441.       DB    'STOPBIT','S'+80H    ; SET STOPBITS
  442.       DW    STSTOP
  443.       DB    'LENGT','H'+80H        ; SET LENGTH
  444.       DW    STBITS
  445.       DB    'MANUA','L'+80H        ; SET TO MANUAL MODE
  446.       DW    MANUAL
  447.       DB    0            ;TABLE TERMINATOR
  448. ;
  449. ;
  450. ;  "SET (no args): PRINT CURRENT STATISTICS
  451. ;
  452. SETSHO:      CALL  ENTREV            ;TERMINAL OVERLAY ENTER REV VIDEO
  453.       CALL  MILP
  454.       DB    ' Current SET values: '
  455.       db    CR,LF,0
  456.       CALL    EXREV            ;TERMINAL OVERLAY EXIT REV VIDEO
  457.       CALL    CRLF
  458.       CALL    MDSHOW
  459.       CALL    TPSHOW
  460.       CALL    BDSHOW
  461.       CALL    MONSHO
  462.       CALL    CRLF
  463.       CALL  SHPRTY
  464.       CALL    SHSTOP
  465.       CALL  SHBITS
  466.       CALL  CRLF
  467.       CALL  CRLF
  468.       RET
  469. ;
  470. ; "SET ?" processor
  471. ;
  472. SETHELP:  CALL  CLS
  473.       CALL    ENTREV
  474.       CALL    MILP
  475.       db    ' Available SET Commands: '
  476.       db    CR,LF,0
  477.       CALL  EXREV
  478.       CALL  MILP
  479.       DB    CR,LF,'SET ORIG      - Set modem to Originate mode'
  480.       DB    CR,LF,'                (Disable auto-answer mode)'
  481.       DB    CR,LF,'SET ANSWER    - Set modem to auto-answer mode'
  482.       DB    CR,LF,'SET TONE      - Set modem for Touchtone dialing'
  483.       DB    CR,LF,'SET PULSE     - Set modem for Pulse dialing'
  484.       DB    CR,LF,'SET PARITY    - OFF, EVEN or ODD'
  485.       DB    CR,LF,'SET STOPBITS  - 1, 1.5 or 2'
  486.       DB    CR,LF,'SET LENGTH    - 5, 6, 7 or 8'
  487.       DB    CR,LF,'SET QUIET     - Turn Modem monitor OFF'
  488.       DB    CR,LF,'SET MONITOR   - Turn Modem monitor ON'
  489.       DB    CR,LF,'SET BAUD      - 300, 1200, 2400, 4800, 9600, 19200'
  490.       DB    CR,LF,'SET MANUAL    - ORIG or ANSWER'
  491.       DB    CR,LF,'                Manually generate Answer or Originate '
  492.       DB    'carrier tone'
  493.       DB    CR,LF,CR,LF,0
  494.       RET
  495. ;
  496. ; Set manual processor
  497. ; Note: manual mode does not change the auto-answer status of the modem
  498. ;
  499. MANUAL:      MVI    C,SBLANK    ;check for ORIG <or> ANSWER
  500.       CALL    MEX        ;
  501.       JC    SETERR        ;if none, print error
  502.       LXI    D,MANTBL    ;check for proper syntax
  503.       MVI    C,LOOKUP
  504.       CALL    MEX
  505.       PUSH    H        ;match found, go do it!
  506.       RNC            ;
  507.       POP    H        ;no match: fix stack and
  508.       JMP    SETERR        ;  print error
  509. ;
  510. MANORIG:  MVI   B,30        ;FORCE 3 SECOND DELAY ON ORIGINATE END
  511.       CALL  MTIME
  512.       LXI    H,SMATD        ;SEND OUT 'ATD'
  513.       CALL    SINIT
  514.       CALL  MILP
  515.       DB    CR,LF,'Manual originate mode......',CR,LF
  516.       DB    'Modem now awaiting detection of an answer tone......'
  517.       DB    CR,LF,CR,LF,CR,LF,0
  518.       JMP    GOMAN
  519. MANANS:      LXI    H,SMATA        ;SEND OUT 'ATA'
  520.       CALL    SINIT
  521.       CALL  MILP
  522.       DB    CR,LF,CR,LF,'Manual answer mode -- carrier tone sent',CR,LF
  523.       DB    CR,LF,0
  524.       JMP   GOMAN
  525. ;
  526. SMATD:      DB    'ATD',CR,0
  527. SMATA:      DB    'ATA',CR,0
  528. ;
  529. GOMAN:      MVI   B,20
  530.       CALL  MTIME
  531.       CALL  MILP
  532.       DB    'Enter Terminal Mode at next command prompt',CR,LF
  533.       DB    'to check status of connection',CR,LF,CR,LF
  534.       DB    'To return to voice mode,',CR,LF
  535.       DB    'disconnect from within terminal mode <ESC N>,',CR,LF
  536.       DB    'or from command line <DSC>',CR,LF,CR,LF,CR,LF,0
  537.       RET
  538. ;
  539. ; Manual originate / answer command table
  540. ;
  541. MANTBL:   DB    'ORI','G'+80H        ;MANUAL ORIGINATE MODE
  542.       DW    MANORIG
  543.       DB    'ANSWE','R'+80H        ;MANUAL ANSWER MODE
  544.       DW    MANANS
  545.       DB    0
  546. ;
  547. ; "SET BAUD" processor
  548. ;
  549. STBAUD:      MVI    C,BDPARS    ;FUNCTION CODE: PARSE A BAUDRATE
  550.       CALL    MEX        ;LET MEX LOOK UP CODE
  551.       JC    SETERR        ;JUMP IF INVALID CODE
  552.       CALL    PBAUD        ;NO, TRY TO SET IT
  553.       JC    SETERR        ;IF NOT ONE OF OURS, BOMB OUT
  554. BDSHOW:      LDA    MSPEED        ;GET CURRENT BAUD RATE
  555.       MVI    C,PRBAUD    ;LET MEX PRINT IT
  556.       CALL    MEX
  557.       CALL  CRLF
  558.       RET 
  559. ;
  560. ; This routine sets baud rate passed as MSPEED code in A.
  561. ; Returns CY=1 if baud rate not supported.
  562. ;
  563. PBAUD:      PUSH    H        ;DON'T ALTER ANYBODY
  564.       PUSH    D
  565.       PUSH     B
  566.       MOV    E,A        ;MSPEED CODE TO DE
  567.       MVI    D,0
  568.       LXI    H,BAUDTB    ;OFFSET INTO TABLE
  569.       DAD    D
  570.       MOV    A,M        ;FETCH CODE
  571.       ORA    A        ;0 MEANS UNSUPPORTED CODE
  572.       STC            ;PREP CARRY IN CASE UNSUPPORTED
  573.       JZ    PBEXIT        ;EXIT IF BAD
  574.       OUT    BAUDRP        ;IF OK, SET IT
  575.       MOV    A,E        ;GET MSPEED CODE BACK
  576.       STA    MSPEED        ;SET IT
  577.       ORA    A        ;RETURN NO ERRORS
  578. PBEXIT:      POP    B
  579.       POP    D
  580.       POP    H
  581.       RET
  582. ;
  583. BAUDTB:      DB    02H        ;110
  584.       DB    05H        ;300
  585.       DB    0        ;450 (not supported)
  586.       DB    06H        ;600
  587.       DB    0        ;710 (not supported)
  588.       DB    07H        ;1200
  589.       DB    0AH        ;2400
  590.       DB    0CH        ;4800
  591.       DB    0EH        ;9600
  592.       DB    0FH        ;19200 
  593. ;
  594. ; SET MODEM STATUS TO ENABLE OR DISABLE AUTO-ANSWER
  595. ;
  596. ORIG:      XRA    A
  597.       STA    ANSFLG        ;SET ORIG FLAG
  598.       LXI    H,SMO        ;SEND OUT ATS0=0
  599.       CALL    SINIT
  600.       JMP    MDSHOW
  601. ;
  602. SMO:      DB    'ATS0=0',CR,0
  603. SMA:      DB    'ATS0=1',CR,0
  604. ;
  605. ANS:      MVI    A,0FFH
  606.       STA    ANSFLG        ;SET ANS FLAG
  607.       LXI    H,SMA        ;SEND OUT ATS0=1
  608.       CALL    SINIT
  609. ;
  610. MDSHOW:      LDA    ANSFLG
  611.       ORA    A
  612.       JZ    MDORIG        
  613.       CALL    MILP
  614.       DB    'Auto-answer mode',CR,LF,0
  615.       RET
  616. MDORIG:      CALL    MILP
  617.       DB    'Originate mode',CR,LF,0
  618.       RET
  619. ;
  620. ;
  621. ; Monitor control processor
  622. ;
  623. QUIET:       XRA    A
  624.       STA    MONFLG
  625.       LXI    H,SMQT
  626.       CALL    SINIT
  627.       JMP    MONSHO
  628. ;
  629. MONIT:       MVI    A,0FFH
  630.       STA    MONFLG
  631.       LXI    H,SMMON
  632.       CALL    SINIT
  633. ;
  634. MONSHO:      LDA    MONFLG
  635.       ORA    A
  636.       JZ    MONOFF
  637.       CALL    MILP
  638.       DB    'Monitor Speaker ON',CR,LF,0
  639.       RET
  640. ;
  641. MONOFF:      CALL    MILP
  642.       DB    'Monitor Speaker OFF',CR,LF,0
  643.       RET
  644. ;
  645. SMQT:      DB    'ATM0',CR,0
  646. SMMON:      DB    'ATM1',CR,0
  647. ;
  648. ; Set dial processor
  649. ;
  650. STTONE:      MVI    A,'T'
  651.       STA   TPULSE
  652.       JMP    TPSHOW
  653. ;
  654. STPULSE:  MVI    A,'P'
  655.           STA    TPULSE
  656. ;
  657. TPSHOW:      LDA    TPULSE
  658.       CPI    54H
  659.       JZ    TPTONE
  660.       CALL    MILP
  661.           DB    'Pulse Dialing',CR,LF,0
  662.       RET
  663. TPTONE:      CALL    MILP
  664.       DB    'Touchtone Dialing',CR,LF,0      
  665.       RET
  666. ;
  667. ;    SET PARITY command: reset transmit/receive parity
  668. ;
  669. ;        Parity is controlled by bits 0 and 1 of
  670. ;        the byte sent to the SIO write-register
  671. ;        4 as follows:
  672. ;
  673. ;           Parity    Bit 1       Bit 0
  674. ;                 Off          -          0
  675. ;              Odd      0         1
  676. ;             Even      1         1
  677. ;
  678. STPRTY:      MVI    C,SBLANK    ;check for parity code
  679.       CALL    MEX        ;
  680.       JC    SETERR        ;if none, print error
  681.       LXI    D,PARTBL    ;check for proper syntax
  682.       MVI    C,LOOKUP
  683.       CALL    MEX
  684.       PUSH    H        ;match found, go do it!
  685.       RNC            ;
  686.       POP    H        ;no match: fix stack and
  687.       JMP    SETERR        ;  print error
  688. ;
  689. PROFF:      LDA    REG4        ;get register 4 byte
  690.       ANI    0FEH        ;reset bit 0
  691.       JMP    PARTB1        ;
  692. PREVEN:      LDA    REG4        ;
  693.       ORI    003H        ;set bits 0 & 1
  694.       JMP    PARTB1        ;
  695. PRODD:      LDA    REG4        ;
  696.       ORI    001H        ;set bit 0
  697.       ANI    0FDH        ;reset bit 1
  698. PARTB1:      STA    REG4        ;
  699.       CALL    NITSIO        ;re-initialize the USART
  700.       CALL    SHPRTY        ;print the result
  701.       RET             ;
  702. SHPRTY:      CALL    MILP        ;display parity
  703.       DB    'Parity:  ',TAB,' ',0
  704.       LDA    REG4        ;
  705.       ANI    001H        ;test bit 0
  706.       CPI    0        ;if bit0=0 then parity off
  707.       JNZ    SHPRT1        ;
  708.       CALL    MILP        ;
  709.       DB    'Off',CR,LF,0    ;
  710.       RET
  711. SHPRT1:      LDA    REG4        ;
  712.       ANI    002H        ;test bit 1
  713.       CPI    0        ;if bit1=0 then parity odd
  714.       JNZ    SHPRT2        ;
  715.       CALL    MILP        ;
  716.       DB    'Odd',CR,LF,0    ;
  717.       RET            ;
  718. SHPRT2:      CALL    MILP        ;
  719.       DB    'Even',CR,LF,0    ;
  720.       RET
  721. ;
  722. ;    SET PARITY command table
  723. ;
  724. PARTBL:      DB    'OF','F'+80H    ;"set parity off"
  725.       DW    PROFF
  726.       DB    'EVE','N'+80H    ;"set parity even"
  727.       DW    PREVEN
  728.       DB    'OD','D'+80H    ;"set parity odd"
  729.       DW    PRODD
  730.       DB    0        ;<<== end of parity table
  731. ;
  732. ;    SET STOPBITS command: reset number of stop bits
  733. ;
  734. ;        The number of stop bits is controlled by bits
  735. ;        2 and 3 of the byte sent to the SIO write-
  736. ;        register 4, as follows:
  737. ;
  738. ;            Stop bits       Bit 3    Bit 2
  739. ;            1         0            1
  740. ;               1.5         1          0
  741. ;            2         1          1
  742. ;
  743. ;
  744. STSTOP:      MVI    C,SBLANK    ;check for stop bits
  745.       CALL    MEX        ;
  746.       JC    SETERR        ;if none, print error
  747.       LXI    D,STPTBL    ;check for proper syntax
  748.       MVI   C,LOOKUP
  749.       CALL    MEX        ;
  750.       PUSH    H        ;match found, go do it!
  751.       RNC            ;
  752.       POP    H        ;no match: fix stack and
  753.       JMP    SETERR        ;  print error
  754. ;
  755. STOP01:      LDA    REG4        ;get register 4 byte
  756.       ANI    0F7H        ;reset bit 3
  757.       ORI    004H        ;set bit 2
  758.       JMP    STSTP1        ;
  759. STOP02:      LDA    REG4        ;
  760.       ORI    00CH        ;set bits 2 and 3
  761.       JMP    STSTP1        ;
  762. STOP15:      LDA    REG4        ;
  763.       ORI    008H        ;set bit 3
  764.       ANI    0FBH        ;reset bit 2
  765. STSTP1:      STA    REG4        ;
  766.       CALL    NITSIO        ;
  767.       CALL    SHSTOP        ;print the result
  768.       RET
  769. SHSTOP:      CALL    MILP        ;display stop-bits
  770.       DB    'Stop bits:',TAB,' ',0
  771.       LDA    REG4        ;
  772.       ANI    004H        ;test bit 2
  773.       CPI    0        ;if bit2=0 then 1.5
  774.       JNZ    SHSTP1        ;
  775.       CALL    MILP        ;
  776.       DB    '1.5',CR,LF,0    ;
  777.       RET
  778. SHSTP1:      LDA    REG4        ;
  779.       ANI    008H        ;test bit 3
  780.       CPI    0        ;if bit3=0 then 1
  781.       JNZ    SHSTP2        ;
  782.       CALL    MILP        ;
  783.       DB    '1',CR,LF,0    ;
  784.       RET
  785. SHSTP2:      CALL    MILP        ;
  786.       DB    '2',CR,LF,0    ;
  787.       RET
  788. ;
  789. ;    SET STOPBITS command table
  790. ;
  791. STPTBL:      DB    '1'+80H        ;"set stop 1"
  792.       DW    STOP01
  793.       DB    '2'+80H        ;"set stop 2"
  794.       DW    STOP02
  795.       DB    '1.','5'+80H    ;"set stop 1.5"
  796.       DW    STOP15
  797.       DB    0        ;<<== End of stop-bits table
  798. ;
  799. ;    SET LENGTH command: set bits per character
  800. ;
  801. ;        The number of bits per character is controlled for
  802. ;        the receiver circuit by bits 6 and 7 of the byte
  803. ;        sent to the SIO write-register 3 and for the trans-
  804. ;        mitter circuit by bits 5 and 6 of the byte sent to
  805. ;        the SIO write-register 5.  The assumption has been
  806. ;        made here that both transmission and reception will
  807. ;        be carried on at the same number of bits per charac-
  808. ;        ter.  The bit configurations are shown for register
  809. ;        3 only, but are the same for register 5:
  810. ;
  811. ;            BPC        Bit 7        Bit 6
  812. ;             5          0          0
  813. ;             6          1             0
  814. ;             7          0          1
  815. ;             8          1          1
  816. ;
  817. STBITS:      MVI    C,SBLANK    ;check for bits/char
  818.       CALL    MEX        ;
  819.       JC    SETERR        ;if none, print error
  820.       LXI    D,BITTBL    ;check for proper syntax
  821.       MVI    C,LOOKUP
  822.       CALL    MEX
  823.       PUSH    H        ;match found, go do it!
  824.       RNC            ;
  825.       POP    H        ;no match: fix stack and
  826.       JMP    SETERR        ;  print error
  827. ;
  828. BIT5:      LDA    REG3        ;
  829.       ANI    0BFH        ;reset bit 6
  830.       ANI    07FH        ;reset bit 7
  831.       STA    REG3        ;
  832.       LDA    REG5        ;
  833.       ANI    0DFH        ;reset bit 5
  834.       ANI    0BFH        ;reset bit 6
  835.       JMP    STBTS1        ;
  836. BIT6:      LDA    REG3        ;
  837.       ANI    0BFH        ;reset bit 6
  838.       ORI    080H        ;set bit 7
  839.       STA    REG3        ;
  840.       LDA    REG5        ;
  841.       ANI    0DFH        ;reset bit 5
  842.       ORI    040H        ;set bit 6
  843.       JMP    STBTS1        ;
  844. BIT7:      LDA    REG3        ;
  845.       ORI    040H        ;set bit 6
  846.       ANI    07FH        ;reset bit 7
  847.       STA    REG3        ;
  848.       LDA    REG5        ;
  849.       ORI    020H        ;set bit 5
  850.       ANI    0BFH        ;reset bit 6
  851.       JMP    STBTS1        ;
  852. BIT8:      LDA    REG3        ;
  853.       ORI    040H        ;set bit 6
  854.       ORI    080H        ;set bit 7
  855.       STA    REG3        ;
  856.       LDA    REG5        ;
  857.       ORI    020H        ;set bit 5
  858.       ORI    040H        ;set bit 6
  859. STBTS1:      STA    REG5        ;
  860.       CALL    NITSIO        ;
  861.       CALL    SHBITS        ;print the result
  862.       RET
  863. SHBITS:      CALL    MILP        ;display bits/char
  864.       DB    'Bits/char:',TAB,' ',0
  865.       LDA    REG5        ;
  866.       ANI    040H        ;test bit 6
  867.       CPI    0        ;if bit6=0 then 6 bpc
  868.       JNZ    SHBTS2        ;
  869.       LDA    REG5        ;
  870.       ANI    020H        ;test bit 5
  871.       CPI    0        ;if bit5=0 then 5 bpc
  872.       JNZ    SHBTS1        ;
  873.       CALL    MILP        ;
  874.       DB    '5',CR,LF,0    ;
  875.       RET            ;
  876. SHBTS1:      CALL    MILP        ;
  877.       DB    '7',CR,LF,0    ;
  878.       RET            ;
  879. SHBTS2:      LDA    REG5        ;
  880.       ANI    020H        ;test bit 5
  881.       CPI    0        ;if bit5=0 then 6 bpc
  882.       JNZ    SHBTS3        ;
  883.       CALL    MILP        ;
  884.       DB    '6',CR,LF,0    ;
  885.       RET            ;
  886. SHBTS3:      CALL    MILP        ;
  887.       DB    '8',CR,LF,0    ;
  888.       RET
  889. ;
  890. ;    SET LENGTH command table
  891. ;
  892. BITTBL:      DB    '5'+80H        ;"set bits 5"
  893.       DW    BIT5
  894.       DB    '6'+80H        ;"set bits 6"
  895.       DW    BIT6
  896.       DB    '7'+80H        ;"set bits 7"
  897.       DW    BIT7
  898.       DB    '8'+80H        ;"set bits 8"
  899.       DW    BIT8
  900.       DB    0        ;<<== end of bpc table
  901. ;
  902. ; General utility routines
  903. ;
  904. MILP:      MVI    C,ILP        ;IN-LINE PRINT
  905.       JMP    MEX
  906.       RET
  907. ;
  908. MTIME:      MVI    C,TIMER        ;MEX TIMER
  909.       JMP    MEX
  910.       RET
  911. ;
  912. CRLF:      CALL    MILP        ;PRINT CARRIAGE RETURN, LINE FEED
  913.       DB    CR,LF,0
  914.       RET
  915. ;
  916. ; Send string to the External Modem
  917. ;
  918. SMSEND:      MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  919.       CALL    MEX
  920.       JNZ    SMSEND
  921.       MOV    A,M        ;FETCH NEXT CHARACTER
  922.       INX    H
  923.       ORA    A        ;END?
  924.       RZ            ;DONE IF SO
  925.       MOV    B,A        ;NO, POSITION FOR SENDING
  926.       MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  927.       CALL    MEX
  928.       JMP    SMSEND
  929. ;
  930. ;==========================================================================
  931. ;                            Data Area
  932. ;==========================================================================
  933. ;
  934. ; Default UART parameters (Initalized for External RS-232)
  935. ;
  936. REG0:      DB    00011000B    ;RESET CHANNEL A
  937. REG3:      DB    11000001B    ;ENABLE RECEIVE AT 8 BITS/CHAR
  938. REG4:      DB    01000100B    ;NO PARITY, 1 STOP BIT, CLOCK X16
  939. REG5:      DB    11101010B    ;ENABLE TRANSMIT AT 8 BITS/CHAR
  940. ;
  941. ; Miscellaneous Default Data
  942. ;
  943. MSPDSV:      DB    0        ;SAVE EXTERNAL MODEM MSPEED
  944. MONFLG:      DB    0FFH        ;0: MONITOR OFF - 0FFH: MONITOR ON
  945. ANSFLG:      DB    0        ;0: ORIGINATE   - 0FFH: ANSWER
  946. SMINIT:   DB    'ATM1 S0=0 S7=30 Q0 X1',CR,0    ;MODEM INIT STRING
  947.       END
  948.