home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxm-sm16.asm < prev    next >
Assembly Source File  |  1994-07-13  |  12KB  |  395 lines
  1. ;    TITLE 'MEX SMARTMODEM OVERLAY V1.6'
  2. ;
  3. ; (DELETE ABOVE TITLE LINE IF ASSEMBLING WITH ASM)
  4. ;
  5. ; Smartmodem overlay for MEX: revision 1.5
  6. ; Written 04/16/84 by Ronald G. Fowler (V1.0)
  7. ;
  8. ; 02/20/85: Converted for MEX 1.2 - Al Jewer
  9. ;
  10. ; 07/01/87: Slight modification to allow cycling of phone numbers. Since the
  11. ;        Hayes doesn't detect a busy signal, hitting the space bar
  12. ;        during a dial will force a busy signal to be returned to MEX.
  13. ;        This subtracts from MexPlus compatibility, as MexPlus does
  14. ;        this itself.                (Brent B. Powers) (v1.6)
  15. ;
  16. ; 07/16/84: Added equate NUMRES to enable/disable numeric result code 
  17. ;        interpretation.  Under TurboDos, the first digit of the 
  18. ;        phone number was being interpreted as a result code as it 
  19. ;        was echoed by the Anchor modem as it dialed.  Set NUMRES false
  20. ;        to disable numeric results. (Bob Puckett)
  21. ;
  22. ; 06/06/84: Fixed problem for Anchor users, where, when the modem returned
  23. ;        "DIAL TONE", the "N" in "TONE" was being regarded as a NO-CONNECT
  24. ;        code.  Now we flush the entire result line before reading another.
  25. ;        Also added code for numeric version of "CONNECT 1200".  --RGF
  26. ;
  27. ; Small bug repaired: (V1.1) 05/14/84 (Steve Grandi): Smartmodem was not being 
  28. ;    flushed after a dial string so that last digit of the phone number 
  29. ;    was being interpreted as a numeric result code causing the program, 
  30. ;    for certain numbers, to give up even as the modem merrily dialed away.
  31. ;
  32. ; This modules adapts MEX for the DC Hayes Smartmodem (as well
  33. ; as many others -- including US Robotics -- that use a similar
  34. ; command language). The main function of this module is to pro-
  35. ; vide dialing capability; the disconnect vector is ancillary.
  36. ; You may use this module as a model to develop dialing routines
  37. ; for non-standard modems (e.g., the Racal-Vadic).  The only
  38. ; pertinent entry point is the DIAL routine; you'll find entry
  39. ; specs for that below.
  40. ;
  41. ; The only conditional you might want to change in this
  42. ; module is the DISC equate below -- if left on, MEX will
  43. ; use the Smartmodem's disconnect code.  If you prefer to
  44. ; provide your own in your overlay's DISCV vector (e.g.,
  45. ; by dropping DTR), then set DISC to FALSE and re-assemble.
  46. ; (If you don't understand this, then play it safe, and
  47. ; leave the equate set as it is).
  48. ; NOTE: Leave DISC set TRUE for MEX 1.2x
  49. ;
  50. ; This overlay will work with any modem overlay that terminates
  51. ; prior to 0B00H
  52. ;
  53. FALSE    EQU    0
  54. TRUE    EQU    NOT FALSE
  55. ;
  56. ;
  57. NUMRES    EQU    FALSE        ; TRUE = INTERPRET NUMERIC RESULT CODES
  58.                 ; FALSE = IGNORE NUMERIC RESULT CODES
  59. ;
  60. DISC    EQU    TRUE        ;<<== CHANGE TO FALSE IF YOU DISC. WITH DTR
  61.                 ;    leave set TRUE for MEX 1.2
  62. ;
  63. ;
  64. ;
  65. ; NOTE: This overlay converted for MEX 1.2 compatiblility 
  66. ;     and 8086 translation 2/20/85 by Al Jewer. 
  67. ;
  68. YES    EQU    0FFH        ;THIS IS FOR 8086 TRANSLATOR - DO NOT CHANGE
  69. NO    EQU    0
  70. I8080    EQU    YES        ;DEFINE PROCESSOR TYPE
  71. I8086    EQU    NO
  72. MEX2    EQU    NO        ;SET TRUE IF MEX 2.X, FALSE IF MEX 1.X
  73. TPULSV    EQU    0105H        ;TONE/PULSE FLAG IN MODEM OVERLAY
  74. NDISCV    EQU    015FH        ;NEW SMART MODEM DISCONNECT HERE
  75. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  76. DISCV    EQU    0165H        ;LOCATION OF HARDWARE DISCONNECT VECTOR 
  77. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  78. MEXLOC    EQU    0D00H        ;"CALL MEX" HERE
  79. SMTABL    EQU    0D55H        ;SMARTMODEM INIT, DE-INIT AND SSET VECTORS
  80. ;
  81. ;
  82. ;
  83. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  84. ;
  85. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  86. TIMER    EQU    254
  87. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  88. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  89. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  90. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  91. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  92. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  93. ILP    EQU    240        ;INLINE PRINT
  94. ;
  95. CR    EQU    13
  96. LF    EQU    10
  97. ;
  98. ; ***** CODE STARTS HERE *****
  99. ;
  100. ;
  101. IF (NOT MEX2)
  102. ;
  103. ; HACKERS NOTE:
  104. ;        This file contains control characters used by our
  105. ; 8080-8086 translator, XLAT. These are in the form of "\" characters
  106. ; inserted as the first character of the comment field. Please do
  107. ; not change or delete these, so that future versions of this overlay
  108. ; will directly convert to 8086 operation. Thanks,    - al
  109. ;
  110. ; For MEX 1.2, the first byte of the overlay MUST contain a "jump" opcode.
  111. ; The is a 0C3H for 8080 and a 0E9H for 8086. MEX 1.2 checks this byte
  112. ; before it loads the overlay, to make sure you don't load the wrong 
  113. ; type of overlay. This byte will not affect pre- 1.2 versions.
  114. ;
  115. ; Also, MEX 1.2 contains a new vector at 15FH which is the smart-modem
  116. ; disconnect vector (now separate from the hardware vector at 165H).
  117. ; The hardware vector typically toggles the DTR line to cause a hangup, 
  118. ; while the smart-modem vector sends the hangup string to the modem.
  119. ; Mex 1.2 will ignore the vector at 165H in this overlay.
  120. ;
  121.     ORG    100H        ;BASE OF TPA
  122. IF I8080
  123.     DB    0C3H        ;DEFINE 8080 OVERLAY
  124. ENDIF    ;I8080
  125. IF I8086
  126.     DB    0E9H        ;8086 FLAG
  127. ENDIF    ;I8086
  128. ;
  129.     ORG    TPULSV
  130. TPULSE:    DB    'T'        ;TOUCHTONE FLAG
  131. ;
  132.     IF    DISC        ;IF PROVIDING DISCONNECT CODE
  133.     ORG    NDISCV        ;SMART MODEM DISCONNECT VECTOR (MEX 1.20)
  134.     JMP    DISCON
  135.     ELSE
  136.     RET            ;FOR MEX 1.2, IN CASE SOMEBODY SCREWS UP....
  137.     ENDIF
  138. ;
  139.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  140.     JMP    DIAL
  141. ;
  142.     IF    DISC        ;IF PROVIDING DISCONNECT CODE
  143.     ORG    DISCV        ;OVERLAY THE VECTOR (MEX 1.1X)
  144.     JMP    DISCON
  145.     ENDIF
  146. ;
  147. ;    
  148. ENDIF    ;NOT MEX2
  149. ;
  150. IF MEX2
  151. ;
  152. ; (note: re-enable ASEG & CSEG if MEX2)
  153. ;
  154. ;    ASEG            ;JUMP TABLE IS ABSOLUTE
  155. ;
  156.     ORG    10FH        ;MEX2 JUMPS START HERE
  157.     JMP    DIAL        ;FIRST IS DIAL VECTOR
  158.     DS    3        ;THEN HARDWARE DISCONNECT VECTOR
  159.     JMP    DISCON        ;THEN SOFTWARE DISCONNECT VECTOR
  160.     JMP    JUSTRT        ;SMART MODEM INIT
  161.     JMP    JUSTRT        ;SMART MODEM DEINIT
  162.     JMP    NOTIMP        ;SSET COMMAND
  163. ;
  164. ;    CSEG            ;REST IS CODE SEGMENT
  165. ;
  166. ENDIF    ;MEX2
  167. ;
  168. ;
  169. ; This is the DIAL routine called by MEX to dial a digit. The digit
  170. ; to be dialed is passed in the A register.  Note that two special
  171. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  172. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  173. ; in the accumulator prior to dialing a number.  Mex will also call
  174. ; dial with 255 in A as an indication that dialing is complete. Thus,
  175. ; the overlay may use these values to "block" the number, holding it
  176. ; in a buffer until it is completely assembled (in fact, that's the
  177. ; scheme employed here for the Smartmodem).
  178. ;
  179. ; After the 254-start-dial sequence, MEX will call the overlay with
  180. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  181. ; its, and will send each to the DIAL routine un-inspected (some modems,
  182. ; like the Smartmodem, allow special non-numeric characters in the
  183. ; phone number, and MEX may make no assumptions about these).
  184. ;
  185. ; After receiving the end-dial sequence (255) the overlay must take
  186. ; whatever end-of-dial actions are necessary *including* waiting for
  187. ; carrier at the distant end.  The overlay should monitor the keyboard
  188. ; during this wait (using the MEX keystat service call), and return
  189. ; an exit code to MEX in the A register, as follows:
  190. ;
  191. ;    0 - Carrier detected, connection established
  192. ;    1 - Far end busy (only for modems that can detect this condition)
  193. ;    2 - No answer (or timed out waiting for modem response)
  194. ;    3 - Keyboard abort (^C only: all others should be ignored)
  195. ;    4 - Error reported by modem
  196. ;
  197. ; <No other codes should be returned after an end-dial sequence>
  198. ;
  199. ; The overlay should not loop forever in the carrier-wait routine, but
  200. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  201. ; ms character wait) service call routine.
  202. ;
  203. ; The DIAL routine is free to use any of the registers, but must return
  204. ; the above code after an end-dial sequence
  205. ;
  206. IF (NOT MEX2)
  207.     ORG    DIALOC
  208. ENDIF    ;NOT MEX2
  209. ;
  210. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  211.     CPI    254        ;START DIAL?
  212.     JZ    STDIAL        ;\JUMP IF SO
  213.     CPI    255        ;END DIAL?
  214.     JZ    ENDIAL        ;\JUMP IF SO
  215. ;
  216. ; Not start or end sequence, must be a digit to be sent to the modem
  217. ;
  218.     MOV    M,A        ;PUT CHAR IN BUFFER
  219.     INX    H        ;\ADVANCE POINTER
  220.     SHLD    DIALPT        ;STUFF PNTR
  221.     RET            ;ALL DONE
  222. ;
  223. ; Here on a start-dial sequence
  224. ;
  225. STDIAL:    LXI    H,DIALBF    ;SET UP BUFFER POINTER
  226.     SHLD    DIALPT
  227.     RET
  228. ;
  229. ; Here on an end-dial sequence
  230. ;
  231. ENDIAL:    MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  232.     INX    H        ;\FOLLOWED BY TERMINATOR
  233.     MVI    M,0
  234.     LDA    TPULSE        ;GET OVERLAY'S TOUCH-TONE FLAG
  235.     STA    SMDIAL+3    ;PUT INTO STRING
  236.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  237.     CALL    SMSEND        ;SEND IT
  238. WAITSM:    MVI    C,INMDM
  239.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  240.     JNC    WAITSM        ;\LOOP UNTIL NO MORE CHARACTERS
  241. ;
  242. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  243. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  244. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  245. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  246. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  247. ; WAIT TO 20 SECONDS).
  248. ;
  249. RESULT:    MVI    C,60        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  250. SMWLP:    PUSH    B
  251.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  252.     MVI    C,TMDINP    ;DO TIMED INPUT
  253.     CALL    MEX
  254.     POP    B
  255.     JNC    SMTEST        ;\JUMP IF MODEM HAD A CHAR
  256.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  257.     MVI    C,CHEKCC
  258.     CALL    MEX
  259.     POP    B
  260.     JZ    BREAK        ; JUMP IF BREAK FOUND AT KBD
  261.     CPI    ' '        ; SPACE HIT?
  262.     JNZ    SMNEXT        ; NO BREAK, NO CYCLE, CONTINUE
  263.     CALL    BREAK        ; SPACE BAR HIT, SHUT DOWN MODEM
  264.     MVI    A,1        ; AND RETURN BUSY CODE
  265.     RET
  266. BREAK:    MVI    B,CR        ; SHUT DOWN THE MODEM
  267.     MVI    C,SNDCHR
  268.     CALL    MEX
  269.     MVI    A,3        ; RETURN ABORT IF 3
  270.     RET
  271. SMNEXT:    DCR    C        ;NO
  272.     JNZ    SMWLP        ;\CONTINUE
  273. ;
  274. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  275. ;
  276. SMTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  277.     RET
  278. ;
  279. ; MODEM GAVE US A RESULT, CHECK IT
  280. ;
  281. SMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  282.     CALL    SMANAL        ;TEST THE RESULT
  283.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  284.     PUSH    PSW        ;SAVE IT
  285. SMTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  286.     CALL    MEX
  287.     JC    SMCHEK        ;\JUMP IF NO INPUT
  288.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  289.     JNZ    SMTLP        ;\EAT ANY IN-BETWEEN
  290. SMCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  291.     JC    RESULT        ;\IF RESULT UNKNOWN, IGNORE IT
  292.     RET
  293. ;
  294. SMANAL:    MVI    B,0        ;PREP CONNECT CODE
  295.     CPI    'C'        ;"CONNECT"?
  296.     RZ            ;\R1\
  297.  
  298.     IF     NUMRES
  299.     CPI    '1'        ;NUMERIC VERSION OF "CONNECT"
  300.     RZ            ;\R1\
  301.     CPI    '5'        ;NUMERIC VERSION OF "CONNECT 1200"
  302.     RZ            ;\R1\
  303.     ENDIF
  304.  
  305.     INR    B        ;PREP BUSY CODE B=1
  306.     CPI    'B'
  307.     RZ            ;\R1\
  308.     INR    B        ;PREP NO CONNECT MSG B=2
  309.     CPI    'N'        ;N=NO CONNECT
  310.     RZ            ;\R1\
  311.  
  312.     IF     NUMRES
  313.     CPI    '3'        ;NUMERIC VERSION OF "NO CONNECT"
  314.     RZ            ;\R1\
  315.     ENDIF
  316.  
  317.     MVI    B,4        ;PREP MODEM ERROR
  318.     CPI    'E'        ;E=ERROR
  319.     RZ            ;\R1\
  320.  
  321.     IF    NUMRES
  322.     CPI    '4'        ;NUMERIC VERSION OF "ERROR"
  323.     RZ            ;\R1\
  324.     ENDIF
  325.  
  326.     STC            ;UNKNOWN...
  327. R1:    RET
  328. ;
  329. ; FOLLOWING ROUTINE DISCONNECTS THE MODEM USING SMARTMODEM
  330. ; CODES. ALL REGISTERS ARE AVAILABLE FOR THIS FUNCTION.
  331. ; NOTHING RETURNED TO CALLER.
  332. ;
  333.     IF    DISC
  334. ;
  335. DISCON:    MVI    B,20
  336.     MVI    C,TIMER        ;WAIT 2 SECONDS
  337.     CALL    MEX
  338.     LXI    H,SMATN        ;SEND '+++'
  339.     CALL    SMSEND
  340.     MVI    B,20        ;WAIT 2 MORE SECONDS
  341.     MVI    C,TIMER
  342.     CALL    MEX
  343.     LXI    H,SMDISC    ;SEND 'ATH'
  344.     CALL    SMSEND
  345.     MVI    B,1        ;WAIT 1 SECOND
  346.     MVI    C,TIMER
  347.     CALL    MEX
  348.     RET
  349. ;
  350. SMATN:    DB    '+++',0
  351. SMDISC:    DB    'ATH',CR,0
  352. ;
  353.     ENDIF
  354. ;
  355. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  356. ;
  357. SMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  358.     CALL    MEX
  359.     JNZ    SMSEND        ;\
  360.     MOV    A,M        ;FETCH NEXT CHARACTER
  361.     INX    H        ;\
  362.     ORA    A        ;END?
  363.     RZ            ;\R1\DONE IF SO
  364.     MOV    B,A        ;NO, POSITION FOR SENDING
  365.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  366.     CALL    MEX
  367.     JMP    SMSEND        ;\
  368. ;
  369. ; DATA AREA
  370. ;
  371. SMDIAL:    DB    'ATDT '
  372. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  373. DIALPT:    DS    2        ;DIAL POSITION POINTER
  374. ;
  375. ;
  376. NOTIMP:    MVI    C,ILP
  377.     CALL    MEX
  378.     DB    CR,LF,'Not Implemented',CR,LF,0
  379. JUSTRT:    RET
  380. ;
  381. ;
  382.     ORG    MEXLOC        ;"CALL MEX"
  383. MEX:
  384. ;
  385. ;
  386. IF (NOT MEX2)
  387.     ORG    SMTABL        ;TABLE OF SMART MODEM VECTORS HERE
  388. ;
  389.     DW    JUSTRT        ;SMART MODEM INIT
  390.     DW    NOTIMP        ;SSET COMMAND (NOT IMPLEMENTED)
  391.     DW    JUSTRT        ;SMART MODEM EXIT 
  392. ENDIF    ;NOT MEX2
  393. ;
  394.     END
  395.