home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-4p.asm < prev    next >
Assembly Source File  |  1994-07-13  |  7KB  |  207 lines
  1. ; TRS-80 Model 4p internal modem overlay for MEX: revision 1.4
  2. ; Originally written: 04/16/84 by Ronald G. Fowler (V1.0)
  3. ;
  4. ; 11/22/85: Changed all portions of this code that are strictly for the
  5. ;           smartmodem so that this overlay will work with the TRS-80
  6. ;           Model 4p internal modem. (Bob Kitchen)
  7. ;
  8. ; The following notes are provided as information about the modification
  9. ; history of this overlay:
  10. ;
  11. ; 07/16/84: Added equate NUMRES to enable/disable numeric result code 
  12. ;        interpretation.  Under TurboDos, the first digit of the 
  13. ;        phone number was being interpreted as a result code as it 
  14. ;        was echoed by the Anchor modem as it dialed.  Set NUMRES false
  15. ;        to disable numeric results. (Bob Puckett)
  16. ;
  17. ; 06/06/84: Fixed problem for Anchor users, where, when the modem returned
  18. ;        "DIAL TONE", the "N" in "TONE" was being regarded as a NO-CONNECT
  19. ;        code.  Now we flush the entire result line before reading another.
  20. ;        Also added code for numeric version of "CONNECT 1200".  --RGF
  21. ;
  22. ; Small bug repaired: (V1.1) 05/14/84 (Steve Grandi): Smartmodem was not being 
  23. ;    flushed after a dial string so that last digit of the phone number 
  24. ;    was being interpreted as a numeric result code causing the program, 
  25. ;    for certain numbers, to give up even as the modem merrily dialed away.
  26. ;
  27. ; This module adapts MEX for the TRS-80 Model 4p internal modem.  The main
  28. ; function is to provide dialing capability; the disconnect vector is
  29. ; ancillary.  You may use this module as a model to develop dialing routines
  30. ; for other Radio Shack modems.  The only pertinent entry point is the DIAL
  31. ; routine; you'll find entry specs for that below.
  32. ;
  33. ; This overlay will work with any modem overlay that terminates prior to 0B00H
  34. ;
  35. FALSE    EQU    0
  36. TRUE    EQU    NOT FALSE
  37. ;
  38. ; SYSTEM CONSTANTS
  39. ;
  40. TPULSE    EQU    0105H        ;TONE/PULSE FLAG IN MODEM OVERLAY
  41. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  42. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  43. MEX    EQU    0D00H        ;"CALL MEX"
  44. ;
  45. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  46. ;
  47. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  48. TIMER    EQU    254
  49. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  50. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  51. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  52. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  53. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  54. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  55. ;
  56. CR    EQU    13
  57. LF    EQU    10
  58. ;
  59.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  60.     JMP    DIAL
  61. ;
  62. ; This is the DIAL routine called by MEX to dial a digit. The digit
  63. ; to be dialed is passed in the A register.  Note that two special
  64. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  65. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  66. ; in the accumulator prior to dialing a number.  Mex will also call
  67. ; dial with 255 in A as an indication that dialing is complete. Thus,
  68. ; the overlay may use these values to "block" the number, holding it
  69. ; in a buffer until it is completely assembled (in fact, that's the
  70. ; scheme employed here for the Smartmodem).
  71. ;
  72. ; After the 254-start-dial sequence, MEX will call the overlay with
  73. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  74. ; its, and will send each to the DIAL routine un-inspected (some modems,
  75. ; like the Smartmodem, allow special non-numeric characters in the
  76. ; phone number, and MEX may make no assumptions about these).
  77. ;
  78. ; After receiving the end-dial sequence (255) the overlay must take
  79. ; whatever end-of-dial actions are necessary *including* waiting for
  80. ; carrier at the distant end.  The overlay should monitor the keyboard
  81. ; during this wait (using the MEX keystat service call), and return
  82. ; an exit code to MEX in the A register, as follows:
  83. ;
  84. ;    0 - Carrier detected, connection established
  85. ;    1 - Far end busy (only for modems that can detect this condition)
  86. ;    2 - No answer (or timed out waiting for modem response)
  87. ;    3 - Keyboard abort (^C only: all others should be ignored)
  88. ;    4 - Error reported by modem
  89. ;
  90. ; <No other codes should be returned after an end-dial sequence>
  91. ;
  92. ; The overlay should not loop forever in the carrier-wait routine, but
  93. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  94. ; ms character wait) service call routine.
  95. ;
  96. ; The DIAL routine is free to use any of the registers, but must return
  97. ; the above code after an end-dial sequence
  98. ;
  99.     ORG    DIALOC
  100. ;
  101. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  102.     CPI    254        ;START DIAL?
  103.     JZ    STDIAL        ;JUMP IF SO
  104.     CPI    255        ;END DIAL?
  105.     JZ    ENDIAL        ;JUMP IF SO
  106. ;
  107. ; Not start or end sequence, must be a digit to be sent to the modem
  108. ;
  109.     MOV    M,A        ;PUT CHAR IN BUFFER
  110.     INX    H        ;ADVANCE POINTER
  111.     SHLD    DIALPT        ;STUFF PNTR
  112.     RET            ;ALL DONE
  113. ;
  114. ; Here on a start-dial sequence
  115. ;
  116. STDIAL:    LXI    H,DIALBF    ;SET UP BUFFER POINTER
  117.     SHLD    DIALPT
  118.     RET
  119. ;
  120. ; Here on an end-dial sequence
  121. ;
  122. ENDIAL:    MVI    M,'X'        ;4P MODEM START DIAL CHARACTER
  123.     INX    H
  124.     MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  125.     INX    H        ;FOLLOWED BY TERMINATOR
  126.     MVI    M,0
  127.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  128.     CALL    SMSEND        ;SEND IT
  129. WAITSM:    MVI    C,INMDM
  130.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  131.     JNC    WAITSM        ;LOOP UNTIL NO MORE CHARACTERS
  132. ;
  133. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  134. ; 30 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  135. ;
  136. RESULT:    MVI    C,30        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  137. SMWLP:    PUSH    B
  138.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  139.     MVI    C,TMDINP    ;DO TIMED INPUT
  140.     CALL    MEX
  141.     POP    B
  142.     JNC    SMTEST        ;JUMP IF MODEM HAD A CHAR
  143.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  144.     MVI    C,CHEKCC
  145.     CALL    MEX
  146.     POP    B
  147.     JNZ    SMNEXT        ;IF NOT, JUMP
  148.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  149.     MVI    C,SNDCHR
  150.     CALL    MEX
  151.     MVI    A,3        ;RETURN ABORT CODE
  152.     RET
  153. SMNEXT:    DCR    C        ;NO
  154.     JNZ    SMWLP        ;CONTINUE
  155. ;
  156. ; ONE HALF MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  157. ;
  158. SMTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  159.     RET
  160. ;
  161. ; MODEM GAVE US A RESULT, CHECK IT
  162. ;
  163. SMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  164.     CALL    SMANAL        ;TEST THE RESULT
  165.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  166.     PUSH    PSW        ;SAVE IT
  167. SMTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  168.     CALL    MEX
  169.     JC    SMCHEK        ;JUMP IF NO INPUT
  170.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  171.     JNZ    SMTLP        ;EAT ANY IN-BETWEEN
  172. SMCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  173.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  174.     RET
  175. ;
  176. SMANAL:    MVI    B,0        ;PREP CONNECT CODE
  177.     CPI    0AH        ;4P MODEM CONNECT CODE
  178.     RZ
  179.     INR    B        ;PREP NO CONNECT CODE
  180.     CPI    15H        ;4P MODEM NO CONNECT CODE
  181.     RZ
  182.     STC            ;UNKNOWN...
  183.     RET
  184. ;
  185. ; 4P MODEM UTILITY ROUTINE: SEND STRING TO MODEM
  186. ;
  187. SMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  188.     CALL    MEX
  189.     JNZ    SMSEND
  190.     MOV    A,M        ;FETCH NEXT CHARACTER
  191.     INX    H
  192.     ORA    A        ;END?
  193.     RZ            ;DONE IF SO
  194.     MOV    B,A        ;NO, POSITION FOR SENDING
  195.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  196.     CALL    MEX
  197.     JMP    SMSEND
  198. ;
  199. ; DATA AREA
  200. ;
  201. SMDIAL:    DB    '*C*MG@',125,'DT'
  202. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  203. DIALPT:    DS    2        ;DIAL POSITION POINTER
  204. ;
  205.     END
  206. DIAL:    DB    '*C*MG@',125,'DT'
  207. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL