home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-al10.asm < prev    next >
Assembly Source File  |  1994-07-13  |  11KB  |  341 lines
  1. ; MXO-AL10.ASM -- ALTOS SERIES 5 overlay file for MEX10.   05/26/84    
  2. ;
  3. ; You will want to look this file over carefully. There are a number of
  4. ; options that you can use to configure the program to suit your taste.
  5. ; This file adapts the ALTOS SERIES 5 computers to MEX10.
  6. ;
  7. ; This uses the CPMSETUP.COM file that came with your ALTOS SERIES 5.
  8. ;
  9. ; First run CPMSETUP and set the printer (serial) for 300 baud.  This
  10. ; will write the boot track data so every time you boot that disk your
  11. ; serial port is set for 300 baud.  Do the same for 1200 baud mode and
  12. ; boot as needed.  Use port labled J9 (far right) on the back of the
  13. ; Altos (DP25).  Remember the J9 port is wired as a modem port so you
  14. ; will need to rewire the modem cable to the correct pins (data out to
  15. ; data receive, pins 2 and 3 and CTS -- clear to send,    etc...).
  16. ;
  17. ; Use the "SET" command to change the baudrate when desired.  It starts
  18. ; out at 300 baud when the program is first called up.
  19. ;
  20. ;    TO USE: First edit this file filling in answers for your own
  21. ;        equipment.  Then assemble with ASM.COM or equivalent
  22. ;        assembler.  Then use MLOAD to overlay the the results
  23. ;        of this program to the original .COM file.
  24. ;
  25. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  26. ; 05/26/84 - MEXified the overlay.        - Biff Bueffel
  27. ; 11/11/84 - Renamed to M7AL-1.ASM, no changes    - Irv Hoff
  28. ; 07/27/83 - Renamed to work with MDM712    - Irv Hoff
  29. ; 07/17/83 - Revised to work with MDM711    - Irv Hoff
  30. ; 07/02/83 - Modified MDM710XE for ALTOS
  31. ;         SERIES 5 computers with external
  32. ;         modem                - Jeff King
  33. ;
  34. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  35. ;
  36. BELL:        EQU    07H        ;bell
  37. CR:        EQU    0DH        ;carriage return
  38. ESC:        EQU    1BH        ;escape
  39. LF:        EQU    0AH        ;linefeed
  40. ;
  41. YES:        EQU    0FFH
  42. NO:        EQU    0
  43. ;
  44. ; MEX service processor stuff
  45. ;
  46. MEX    EQU    0D00H        ;address of the service processor
  47. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  48. TIMER    EQU    254        ;delay 100ms * reg B
  49. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  50. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  51. SNDRDY    EQU    251        ;test for modem-send ready
  52. RCVRDY    EQU    250        ;test for modem-receive ready
  53. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  54. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  55. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  56. PARSFN    EQU    246        ;parse filename from input stream
  57. BDPARS    EQU    245        ;parse baud-rate from input stream
  58. SBLANK    EQU    244        ;scan input stream to next non-blank
  59. EVALA    EQU    243        ;evaluate numeric from input stream
  60. LKAHED    EQU    242        ;get nxt char w/o removing from input
  61. GNC    EQU    241        ;get char from input, cy=1 if none
  62. ILP    EQU    240        ;inline print
  63. DECOUT    EQU    239        ;decimal output
  64. PRBAUD    EQU    238        ;print baud rate
  65. ;
  66. PRINT    EQU    9        ;MEX/BDOS print-string function call
  67.  
  68. ;
  69. PORT:        EQU    1EH        ;ALTOS SERIES 5 serial output port
  70. MODCTL1:    EQU    PORT+1        ;Modem control port
  71. MODDATP:    EQU    PORT        ;Modem data port
  72. MODCTL2:    EQU    PORT+1        ;Modem status port
  73. MODRCVB:    EQU    01H        ;Your bit to test for receive
  74. MODRCVR:    EQU    01H        ;Your value when receive ready
  75. MODSNDB:    EQU    04H        ;Your bit to test for send
  76. MODSNDR:    EQU    04H        ;Your value when send ready        
  77. ;
  78. ;
  79.         ORG    100H
  80. ;
  81. ;
  82. ; Change the clock speed to suit your system
  83. ;
  84.         DS    3    ;(for  "JMP   START" instruction)
  85. ;
  86.         DB    NO    ;yes=PMMI S-100 Modem            103H
  87.         DB    NO    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  88. TOUCHPULSE:    DB    'T'     ;T=touch, P=pulse (Smartmodem-only)     105H
  89. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  90.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  91. MSPEED:     DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  92.                 ;6=2400 7=4800 8=9600 9=19200 default
  93. BYTDLY:     DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  94.                 ;default time to send character in ter-
  95.                 ;minal mode file transfer for slow BBS.
  96. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  97.                 ;default time for extra wait after CRLF
  98.                 ;in terminal mode file transfer
  99. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  100. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  101. SCRNTEST:    DB    NO    ;cursor control routine         10CH
  102. ACKNAK:     DB    YES    ;yes=resend a record after any non-ACK    10DH
  103.                 ;no=resend a record after a valid NAK
  104. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  105. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  106. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  107. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  108. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  109. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  110.                 ;terminal mode (added by remote echo)
  111. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  112.         DB    NO    ;yes=allow transmission of logon    115H
  113.                 ;write logon sequence at location LOGON
  114. SAVCCP:     DB    YES    ;yes=do not overwrite CCP        116H
  115. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  116.                 ;no=external command if EXTCHR precedes
  117. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  118. LSTTST:     DB    YES    ;yes=printer available on printer port    119H
  119. XOFFTST:    DB    NO    ;yes=check for XOFF from remote while    11AH
  120.                 ;sending a file in terminal mode
  121. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  122.                 ;sending a file in terminal mode
  123. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  124. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  125. EXTRA1:     DB    0    ;for future expansion            11EH
  126. EXTRA2:     DB    0    ;for future expansion            11FH
  127. BRKCHR:     DB    '@'-40H ;^@ = Send a 300 ms. break tone         120H
  128. 20H
  129. NOCONNCT:    DB    'N'-40H ;^N = Disconnect from the phone line    121H
  130. LOGCHR:     DB    'L'-40H ;^L = Send logon                        122H
  131. LSTCHR:     DB    'P'-40H ;^P = Toggle printer                    123H
  132. UNSAVE:     DB    'R'-40H ;^R = Close input text buffer           124H
  133. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote           125H
  134. SAVECHR:    DB    'Y'-40H ;^Y = Open input text buffer            126H
  135. EXTCHR:     DB    '^'-40H ;^^ = Send next character               127H
  136. ;
  137. ;
  138.         DS    2        ;                128H
  139. IN$MODCTL1:    MVI    A,10H        ;channel 0, reset interrupts    12AH
  140.         OUT    MODCTL1
  141.         IN    MODCTL1     ;get the status bits
  142.         RET
  143.         DS    3
  144. ;
  145. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  146.         DS    7
  147. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  148.         DS    7
  149. ANI$MODRCVB:    ANI    MODRCVB ! RET    ;bit to test for receive ready    148H
  150. CPI$MODRCVR:    CPI    MODRCVR ! RET    ;value of receive bit when rdy    14BH
  151. ANI$MODSNDB:    ANI    MODSNDB ! RET    ;bit to test for send ready    14EH
  152. CPI$MODSNDR:    CPI    MODSNDR ! RET    ;value of send bit when ready    151H
  153.         DS    6        ;                154H
  154. OUT$MODCTL1:    OUT    MODCTL1 ! RET    ;out modem control port     15AH
  155. OUT$MODCTL2:    OUT    MODCTL2 ! RET    ;out modem status port        15DH
  156. ;
  157. ;
  158.         DS    2        ;Not used by MEX.        160H
  159.         DS    6        ;                162H
  160. JMP$GOODBYE:    JMP    GOODBYE     ;                168H
  161. JMP$INITMOD:    JMP    INITMOD     ;go to user written routine    16BH
  162. JMP$NEWBAUD:    JMP      NEWBAUD        ;Change baudrate        16EH
  163.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    171H
  164.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    174H
  165. JMP$SETUPR:    JMP    SETUPR        ;                177H
  166.         DS    3        ;Not used by MEX        17AH
  167. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  168. JMP$BREAK:    JMP    SENDBRK     ;                180H
  169. ;
  170. ;
  171. ; Do not change the following six lines.
  172. ;
  173. JMP$ILPRT:    DS    3        ;                183H
  174. JMP$INBUF    DS    3        ;                186H
  175. JMP$INLNCOMP:    DS    3        ;                189H
  176. JMP$INMODEM    DS    3        ;                18CH
  177. JMP$NXTSCRN:    DS    3        ;                18FH
  178. JMP$TIMER:    DS    3        ;                192H
  179. ;
  180. ;
  181. ; Clear sequences -- CLREOS is clear to end of screen, CLRSCRN is clear
  182. ; entire screen.  
  183. ;
  184. CLREOS:        LXI    D,EOSMSG
  185.         MVI    C,PRINT
  186.         CALL    MEX
  187.         RET            
  188. ;
  189. CLRSCRN:    LXI    D,CLSMSG
  190.         MVI    C,PRINT
  191.         CALL    MEX
  192.         RET            
  193. ;
  194. SYSVER:        MVI    C,ILP        ;                1A7H
  195.         CALL    MEX
  196.         DB    'Version for ALTOS SERIES 5 at serial port 1E'
  197.         DB    CR,LF,0
  198.         RET
  199. ;
  200. ; This routine allows a 300 ms. break tone to be sent to reset some
  201. ; time-shar computers.
  202. ;
  203. SENDBRK:  MVI    A,5
  204.       OUT    MODCTL1
  205.       MVI    A,0F8H        ;SEND A BREAK TONE
  206.       JMP    GOODBYE1
  207. ;.....
  208. ;
  209. ;
  210. ; This routine sends a 300 ms. break tone and sets DTR low for the same
  211. ; length of time to disconnect some modems such as the Bell 212A, etc.    
  212. ;
  213. GOODBYE:  MVI    A,5
  214.       OUT    MODCTL1     ;SEND TO THE STATUS PORT
  215.       MVI    A,068H        ;TURN OFF DRT
  216. ;
  217. GOODBYE1: OUT    MODCTL1
  218.       MVI    B,3        ;WAIT FOR 300 MS.
  219.       MVI    C,TIMER
  220.       CALL    MEX
  221.       MVI    A,5
  222.       OUT    MODCTL1
  223.       MVI    A,0E8H        ;RESTORE TO NORMAL, 8 BITS, DTR ON, ETC.
  224.       OUT    MODCTL1
  225.       RET
  226. ;.....
  227. ;
  228. ;    
  229. ; Altos series 5 initialization -- sets CTC timer 00H for send and receive
  230. ; baudrate.
  231. ;
  232. INITMOD:  MVI    A,0        ;SELECT REGISTER
  233.       OUT    MODCTL1
  234.       MVI    A,18H        ;THROW OUT OF MODE
  235.       OUT    MODCTL1
  236.       MVI    A,04H        ;SELECT REGISTER
  237.       OUT    MODCTL1
  238.       MVI    A,44H        ;SET ASCII PARAMETERS
  239.       OUT    MODCTL1
  240.       MVI    A,03H        ;SELECT REG.
  241.       OUT    MODCTL1
  242.       MVI    A,0C1H        ;ENABLE RECEIVE
  243.       OUT    MODCTL1
  244.       MVI    A,05H        ;SELECT REG.
  245.       OUT    MODCTL1
  246.       MVI    A,0EAH        ;ENABLE SEND, 'DTR', 'RTS'
  247.       OUT    MODCTL1
  248. ;
  249. INITMOD1: MVI    A,1        ;DEFAULT TRANSFER TIME TO 300 BAUD
  250.       STA    MSPEED
  251.       MVI    A,47H        ;DEFAULT TO 300 BAUD
  252.       OUT    00H        ;SEND TO 'CTC' TIMER
  253. ;
  254. INITMOD2: MVI    A,05H        ;INITIALIZE TO 300 BAUD
  255.       OUT    00H
  256.       RET
  257. ;.....
  258. ;
  259. ;
  260. ; Setup routine to allow changing modem speed with the SET command.
  261. ;
  262. ;
  263. SETUPR:      MVI    C,SBLANK    ;Any arguments?
  264.       CALL    MEX
  265.       JC    TELL        ;If not, go display baud
  266.       LXI    D,CMDTBL
  267.       MVI    C,LOOKUP
  268.       CALL    MEX        ;Parse argument
  269.       PUSH    H        ;Save any parsed argument addrs on stack
  270.       RNC            ;If we have one, return to it
  271.       POP    H        ;Oops, input not found in table
  272.       MVI    C,ILP
  273.       CALL    MEX        ;Tell user input not valid
  274.       DB    CR,LF,'Only 300 or 1200 allowed on SET command',CR,LF,0
  275.       RET
  276. ;
  277. CMDTBL:      DB    '30','0'+80H
  278.       DW    OK300
  279.       DB    '120','0'+80H
  280.       DW    OK1200
  281.       DB    0
  282. ;
  283. TELL:      MVI    C,ILP
  284.       CALL    MEX        ;Print current baud rate
  285.       DB    CR,LF,'Baud rate is now: ',0
  286.       LDA    MSPEED
  287.       MVI    C,PRBAUD
  288.       CALL    MEX
  289.       RET
  290. ;
  291. ;
  292. OK300:      MVI    A,1
  293.       LHLD    BD300
  294.       JMP    LOADBD
  295. ;
  296. OK600:      MVI    A,3
  297.       LHLD    BD600
  298.       JMP    LOADBD
  299. ;
  300. OK1200:   MVI    A,5
  301.       LHLD    BD1200
  302.       JMP    LOADBD
  303. ;
  304. OK9600:   MVI    A,8
  305.       LHLD    BD9600
  306. ;
  307. LOADBD:   STA    INITMOD1+1    ;CHANGE TIME-TO-SEND TO MATCH BAUDRATE
  308.       MOV    A,L        ;GET BAUDRATE BYTE
  309.       STA    INITMOD2+1    ;SEND TO 'CTC' TIMER FOR NEW BAUDRATE
  310.       JMP    INITMOD1    ;REINITIALIZE TO NEW BAUDRATE, THEN DONE
  311. ;
  312. ;
  313. NEWBAUD:  CPI    1
  314.       JZ    OK300
  315.       CPI    5
  316.       JZ    OK1200
  317.       RET
  318. ;
  319. ;
  320. ; TABLE OF BAUDRATE PARAMETERS
  321. ;
  322. BD300:      DW    0005H
  323. BD600:      DW    0006H    
  324. BD1200:   DW    0007H
  325. BD9600:   DW    000EH
  326. ;
  327. BAUDBUF:  DB    10,0
  328.       DS    10
  329. ;
  330. EOSMSG:      DB    0,0,0,0,'$'              
  331. CLSMSG:      DB    0,0,0,0,'$'
  332. ;
  333. ; NOTE:  MUST TERMINATE PRIOR TO 0B00H (with Smartmodem)
  334. ;                 0D00H (without Smartmodem)
  335. ;
  336.       END
  337. ;
  338.  
  339.  
  340.  
  341.