home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-gb11.asm < prev    next >
Assembly Source File  |  1994-07-13  |  13KB  |  459 lines
  1.     title    'CompuPro overlay for Interfacer 3/4'
  2. ;
  3. ; MXO-GB11.ASM -- MEX Overlay file for the CompuPro I3/I4 & SS1.  06/16/84
  4. ;
  5. ; This overlay adapts the MEX modem program to the CompuPro Interfacer 3 or
  6. ; Interfacer 4 or System Support 1 serial cards using the 2651 USART chip.
  7. ;
  8. ;
  9. ; This overlay is capable of setting baud rate and setting port number
  10. ; (via the SET command), setting baud rate from the phone library, dis-
  11. ; connecting the  modem, and sending a break.
  12. ;
  13. REV    EQU    11    ;V 1.1
  14. ;
  15. ; NOTE TO INTERFACER 4 USERS:
  16. ; The 'MIDDLE' serial port and the Centronics port can have their addresses
  17. ; changed using a hardware option.  Godbout did this to maintain software
  18. ; compatibility with their bios.  In order to prevent problems, use the
  19. ; 'RIGHT' serial port (RELATIVE USER 5) instead of the center serial
  20. ; port (RELATIVE USER 6).  Also, read page 19 of the manual, the modem
  21. ; port will probably have to be set up in the 'MASTER MODE'.  While 
  22. ; you're reading the manual, read the section on 'WAIT STATE LOGIC'.
  23. ; I'm using a CPU-Z running at 6Mhz, with a 300 baud modem and two wait
  24. ; states (jumper at J7).  Without them, I get 'o's for 'n's and 'g's
  25. ; for 'f's, and the checksums are never right.    (AWW 12/20/83)
  26. ;
  27. ; Calling conventions for the various overlay entry points are detailed more
  28. ; fully in the PMMI overlay (MXO-PMxx.ASM, where xx=revision number)
  29. ;
  30. ; History as a MEX overlay
  31. ;
  32. ; 06/16/84 - Baud rate can now be automaticaly selected by MEX
  33. ;         when making a call with CAL command. Also Baud rate
  34. ;         is now correctly initialized.     - Alex Soya
  35. ;
  36. ; 05/12/84 - SET port (0-7, S -- S=SS1)           - Ron Fowler
  37. ; 05/11/84 - MEXified the overlay           - Ron Fowler
  38. ;
  39. ; History as an MDM7 overlay
  40. ;
  41. ; 11/20/83 - Interfacer 4 note added        - A.W. Warren
  42. ; 11/11/83 - Renamed to M7IN-1.ASM, no changes    - Irv Hoff
  43. ; 07/27/83 - Renamed to work with MDM712    - Irv Hoff
  44. ; 07/11/83 - Modifed somewhat for MDM711    - Irv Hoff
  45. ; 07/08/83 - Adapted from MDM711GP.ASM        - Paul Traina
  46. ;
  47. ;
  48. ; MEX service processor stuff
  49. ;
  50. MEX    EQU    0D00H        ;address of the service processor
  51. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  52. TIMER    EQU    254        ;delay 100ms * reg B
  53. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  54. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  55. SNDRDY    EQU    251        ;test for modem-send ready
  56. RCVRDY    EQU    250        ;test for modem-receive ready
  57. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  58. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  59. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  60. PARSFN    EQU    246        ;parse filename from input stream
  61. BDPARS    EQU    245        ;parse baud-rate from input stream
  62. SBLANK    EQU    244        ;scan input stream to next non-blank
  63. EVALA    EQU    243        ;evaluate numeric from input stream
  64. LKAHED    EQU    242        ;get nxt char w/o removing from input
  65. GNC    EQU    241        ;get char from input, cy=1 if none
  66. ILP    EQU    240        ;inline print
  67. DECOUT    EQU    239        ;decimal output
  68. PRBAUD    EQU    238        ;print baud rate
  69. ;
  70. PRINT    EQU    9        ;BDOS/MEX print-string function call
  71. ;
  72. BELL    EQU    7        ;bell
  73. TAB    EQU    9
  74. CR    EQU    13        ;carriage return
  75. LF    EQU    10        ;linefeed
  76. ESC    EQU    1BH        ;escape
  77. YES    EQU    0FFH
  78. NO    EQU    0
  79. ;
  80. ; Interfacer 3/4 and SS1 port equates
  81. ; 
  82. INBASE    EQU    010H        ;base port of CompuPro I3 or I4 card(s)
  83. SSBASE    EQU    05CH        ;base of serial section of CompuPro SS1
  84. ;
  85. UPORT    EQU    INBASE+7    ;user (chip select) port
  86. ;
  87. ; Port offsets
  88. ;
  89. DPORT:    EQU    0        ;data port
  90. SPORT:    EQU    1        ;status port
  91. MPORT:    EQU    2        ;mode port
  92. CPORT:    EQU    3        ;control port
  93. ;
  94. TBMT:    EQU    01H        ;transmit buffer empty
  95. DAV:    EQU    02H        ;data available
  96. ;
  97. ; Baud rate parameters
  98. ;
  99. BD300:    EQU    35H        ;300 baud
  100. BD600:    EQU    36H        ;600 baud
  101. BD1200: EQU    37H        ;1200 baud
  102. BD4800: EQU    3CH        ;4800 baud
  103. BD9600: EQU    3EH        ;9600 baud
  104. BD19200 EQU    3FH        ;19200 baud
  105. ;
  106.     ORG    100H
  107. ;
  108. ; Change the clock speed to suit your system
  109. ;
  110.     DS    3        ;(for  "JMP   START" instruction)
  111.  
  112.     DB    NO        ;yes=PMMI S-100 Modem            103H
  113.     DB    YES        ;yes=HAYES Smartmodem, no=non-PMMI    104H
  114.     DB    'T'        ;T=touch, P=pulse (Smartmodem-only)    105H
  115. CLOCK:    DB    60        ;clock speed in MHz x10, 25.5 MHz max.    106H
  116.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  117. MSPEED: DB    5        ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  118.                 ;6=2400 7=4800 8=9600 9=19200 default
  119. BYTDLY: DB    5        ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  120.                 ;default time to send character in ter-
  121.                 ;minal mode file transfer for slow BBS.
  122. CRDLY:    DB    5        ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  123.                 ;default time for extra wait after CRLF
  124.                 ;in terminal mode file transfer
  125. COLUMS: DB    5        ;number of DIR columns shown        10AH
  126. SETFLG: DB    YES        ;yes=user-added Setup routine        10BH
  127. SCRTST: DB    YES        ;Cursor control routine            10CH
  128.     DB    YES        ;yes=resend a record after any non-ACK    10DH
  129.                 ;no=resend a record after a valid-NAK
  130. BAKFLG: DB    YES        ;yes=change any file same name to .BAK    10EH
  131. CRCDFL: DB    NO        ;yes=default to CRC checking        10FH
  132. TOGCRC: DB    YES        ;yes=allow toggling of CRC to Checksum    110H
  133. CVTBS:    DB    NO        ;yes=convert backspace to rub        111H
  134. TOGLBK: DB    YES        ;yes=allow toggling of bksp to rub    112H
  135. ADDLF:    DB    NO        ;no=no LF after CR to send file in    113H
  136.                 ;terminal mode (added by remote echo)
  137. TOGLF:    DB    YES        ;yes=allow toggling of LF after CR    114H
  138.     DB    YES        ;yes=allow transmission of logon    115H
  139.                 ;write logon sequence at location LOGON
  140. SAVCCP: DB    YES        ;yes=do not overwrite CCP        116H
  141.     DB    NO        ;yes=local command if EXTCHR precedes    117H
  142.                 ;no=external command if EXTCHR precedes
  143.     DB    YES        ;yes=allow toggling of LOCONEXTCHR    118H
  144. LSTTST: DB    YES        ;yes=printer available on printer port    119H
  145. XOFTST: DB    NO        ;yes=checks for XOFF from remote while    11AH
  146.                 ;sending a file in terminal mode
  147. XONWT:    DB    NO        ;yes=wait for XON after CR while    11BH
  148.                 ;sending a file in terminal mode
  149. TOGXOF: DB    YES        ;yes=allow toggling of XOFF checking    11CH
  150. IGNCTL: DB    NO        ;yes=CTL-chars above ^M not displayed    11DH
  151. EXTRA1: DB    0        ;for future expansion            11EH
  152. EXITCHR DB    'E'-40H        ;^E = Exit to main menu            11FH
  153. BRKCHR: DB    '@'-40H        ;^@ = Send 300 ms. break tone        120H
  154. NOCONN: DB    'N'-40H        ;^N = Disconnect from the phone line    121H
  155. LOGCHR: DB    'L'-40H        ;^L = Send logon            122H
  156. LSTCHR: DB    'P'-40H        ;^P = Toggle printer            123H
  157. UNSAVE: DB    'R'-40H        ;^R = Close input text buffer        124H
  158. TRNCHR: DB    'T'-40H        ;^T = Transmit file to remote        125H
  159. SAVCHR: DB    'Y'-40H        ;^Y = Open input text buffer        126H
  160. EXTCHR: DB    '^'-40H        ;^^ = Send next character        127H
  161.     DS    2        ;unused by MEX                128H
  162. ;
  163. INCTL1: JMP    INSP        ;go input status port            12AH
  164.     DS    7
  165. ;
  166. OTDATA: JMP    OUTDP        ;go output data port            134H
  167.     DS    7
  168. ;
  169. INPORT: JMP    INDP        ;go input data port            13EH
  170.     DS    7
  171. ;
  172. MASKR:    ANI    DAV    ! RET    ;bit to test for receive ready        148H
  173. TESTR:    CPI    DAV    ! RET    ;value of rcv. bit when ready        14BH
  174. MASKS:    ANI    TBMT    ! RET    ;bit to test for send ready        14EH
  175. TESTS:    CPI    TBMT    ! RET    ;value of send bit when ready        151H
  176.     DS    14        ;                    156H
  177. ;
  178. ;
  179.     DS    3        ;DIALV: not done here (maybe MXO-SM)    162H
  180. DISCV:    JMP    DISCON        ;disconnect
  181. GOODBV: JMP    GOODBY        ;                    168H
  182. INMODV: JMP    NITMOD        ;go to user written routine        16BH
  183. NEWDBV: JMP    PBAUD        ;NEWBDV                    16EH
  184.     RET ! NOP ! NOP        ;NOPARV                    171H
  185.     RET ! NOP ! NOP        ;PARITV                    174H
  186. SETUPV: JMP    SETCMD        ;                    177H
  187.     DS    3        ;not used by MEX            17AH
  188. VERSNV: JMP    SYSVER        ;                    17DH
  189. BREAKV: JMP    SBREAK        ;                    180H
  190. ;
  191. ; Do not change the following six lines (they provide access to routines
  192. ; in MEX that are present to support MDM7 overlays -- they will likely
  193. ; be gone by MEX v2.0).
  194. ;
  195. ILPRTV: DS    3        ;                    183H
  196. INBUFV    DS    3        ;                    186H
  197. ILCMPV: DS    3        ;                    189H
  198. INMDMV: DS    3        ;                    18CH
  199.     DS    3        ;                    18FH
  200. TIMERV    DS    3        ;                    192H
  201. ;
  202. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  203. ; SCRTEST to YES at 010AH (above).
  204. ;
  205. CLREOS: LXI    D,EOSMSG    ;                    195H
  206.     MVI    C,PRINT
  207.     CALL    MEX
  208.     RET
  209. ;
  210. CLS:    LXI    D,CLSMSG    ;                    19EH
  211.     MVI    C,PRINT
  212.     CALL    MEX
  213.     RET
  214. ;                                    1A7H
  215. ;
  216. ; end of fixed area
  217. ;
  218. SYSVER: MVI    C,ILP        ;in-line print
  219.     CALL    MEX
  220.     DB    'Interfacer/SS1 V.'
  221.     DB    REV/10+'0'
  222.     DB    '.'
  223.     DB    REV MOD 10+'0'
  224.     DB    CR,LF,0
  225.     RET
  226. ;
  227. ; Routine to exit just prior to exit-to-cpm
  228. ;
  229. GOODBY: RET            ;not done here
  230. ;
  231. ; Send break to remote
  232. ;
  233. SBREAK: MVI    A,2FH        ;send break for 300ms
  234.     JMP    DISC1
  235. ;
  236. ; Disconnect the modem
  237. ;
  238. DISCON: XRA    A        ;turn off DTR
  239. DISC1:    PUSH    PSW
  240.     CALL    STPORT        ;select port
  241.     POP    PSW
  242.     CALL    OUTCP        ;send passed byte to CPORT
  243.     MVI    B,3        ;turn off DTR for 300 ms.
  244.     MVI    C,TIMER
  245.     CALL    MEX
  246.     MVI    A,27H        ;turn DTR back on
  247.     CALL    OUTCP
  248.     RET
  249. ;
  250. ; Initialize the port; either set an initial baud rate, or (if
  251. ; your system is capable of it) query the current rate and set
  252. ; MSPEED value.     We can do neither here, so we assume a value
  253. ; for MSPEED -- if it's not the current value, the user must
  254. ; execute a SET command to bring MSPEED into agreement with the
  255. ; current baud rate.
  256. ;
  257. NITMOD: MVI    A,5
  258.     STA    MSPEED
  259.     CALL    PBAUD
  260.     RET
  261. ;
  262. ; SET command: select baud rate, port number. Port number may be any of
  263. ; 0,1,2,3,4,5,6,7,S  (S=SS1), baud rate any of 300, 600, 1200, 4800
  264. ; 9600, 19200.    Special set-port syntax allows baud rate after port
  265. ; number.  Examples:
  266. ;
  267. ;    SET PORT 3
  268. ;    SET PORT 5 1200
  269. ;    SET PORT S 300
  270. ;    SET BAUD 9600
  271. ;
  272. SETCMD: MVI    C,SBLANK    ;any arguments?
  273.     CALL    MEX
  274.     JC    TELL        ;if not, go display port/baud
  275.     LXI    D,CMDTBL
  276.     MVI    C,LOOKUP
  277.     CALL    MEX        ;parse argument
  278.     PUSH    H        ;save any parsed argument adrs on stack
  279.     RNC            ;if we have one, return to it
  280.     POP    H        ;oops, input not found in table
  281. SETERR: MVI    C,ILP        ;inline print
  282.     CALL    MEX
  283.     DB    CR,LF,'SET command error',CR,LF,0
  284.     RET
  285. ;
  286. ; Argument table
  287. ;
  288. CMDTBL: DB    '?'+80H        ;help
  289.     DW    STHELP
  290.     DB    'BAU','D'+80H    ;"set baud"
  291.     DW    STBAUD
  292.     DB    'POR','T'+80H    ;"set port"
  293.     DW    SETPOR
  294.     DB    0        ;<<=== table terminator
  295. ;
  296. ; "SET ?" processor
  297. ;
  298. STHELP: MVI    C,ILP        ;inline print
  299.     CALL    MEX
  300.     DB    CR,LF,'SET BAUD <rate>'
  301.     DB    CR,LF,'SET PORT <port-number>'
  302.     DB    CR,LF
  303.     DB    CR,LF,'Baud rate is one of:'
  304.     DB    CR,LF,'   300 600 1200 4800 9600 19200'
  305.     DB    CR,LF,'Port number is one of:'
  306.     DB    CR,LF,'   0-7 : interfacer 3 or 4 port number'
  307.     DB    CR,LF,'   S   : System Support I serial port'
  308.     DB    CR,LF,0
  309.     RET
  310. ;
  311. ; "SET BAUD" processor
  312. ;
  313. STBAUD: MVI    C,BDPARS    ;function code: parse a baudrate
  314.     CALL    MEX        ;let MEX look up code
  315.     JC    SETERR        ;jump if invalid code
  316.     CALL    PBAUD        ;no, try to set it
  317.     JC    SETERR        ;if not one of ours, bomb out
  318. BDSHOW: MVI    C,ILP        ;inline print
  319.     CALL    MEX        ;display baud
  320.     DB    'Baud: ',0
  321.     LDA    MSPEED        ;get current baud rate
  322.     MVI    C,PRBAUD    ;let MEX print it
  323.     CALL    MEX
  324.     RET
  325. ;
  326. ; SET PORT processor
  327. ;
  328. SETPOR: MVI    C,SBLANK    ;scan to argument
  329.     CALL    MEX
  330.     JC    SETERR        ;if no arg, bomb out
  331.     MVI    C,GNC        ;else consume it
  332.     CALL    MEX
  333.     CPI    'S'        ;SS1?
  334.     JZ    SETSS1        ;jump if so
  335.     CPI    's'
  336.     JZ    SETSS1
  337.     SUI    '0'        ;convert
  338.     JC    SETERR
  339.     CPI    7+1
  340.     JNC    SETERR
  341.     JMP    SETX        ;go put away port #
  342. SETSS1: MVI    A,0FFH        ;SS1 token
  343. SETX:    STA    PORT
  344.     MVI    C,SBLANK    ;any thing more?
  345.     CALL    MEX
  346.     JNC    STBAUD        ;if so, go parse as baud rate
  347. ;
  348. TELL:    MVI    C,ILP
  349.     CALL    MEX
  350.     DB    CR,LF,'Port: ',0
  351.     LDA    PORT
  352.     CPI    0FFH        ;SS1?
  353.     JNZ    TELL1        ;jump if not
  354.     MVI    A,'S'-'0'    ;set SS1, and avoid a JMP
  355. TELL1:    ADI    '0'        ;get port # in ASCII
  356.     STA    PORTAS
  357.     MVI    C,ILP
  358.     CALL    MEX
  359. PORTAS: DB    '    ',0
  360.     JMP    BDSHOW
  361. ;
  362. ; This routine sets baud rate passed as MSPEED code in A.
  363. ; Returns CY=1 if baud rate not supported (if supported,
  364. ; this routine must set the new MSPEED code).
  365. ;
  366. PBAUD:    PUSH    H        ;don't alter anybody
  367.     PUSH    D
  368.     PUSH    B
  369.     MOV    E,A        ;MSPEED code to DE
  370.     MVI    D,0
  371.     LXI    H,BAUDTB    ;offset into table
  372.     DAD    D
  373.     MOV    A,M        ;fetch code
  374.     ORA    A        ;0? (means unsupported code)
  375.     STC            ;prep carry in case unsupported
  376.     JZ    PBEXIT        ;exit if bad
  377.     PUSH    PSW        ;no, set the rate
  378.     MVI    A,04EH        ;first, set 8 bits, no parity, 1 stop
  379.     CALL    OUTMP
  380.     POP    PSW        ;get baud code back
  381.     CALL    OUTMP
  382.     MVI    A,27H        ;turn on DTR, etc
  383.     CALL    OUTCP
  384.     MOV    A,E        ;get MSPEED code back
  385.     STA    MSPEED        ;set it
  386.     ORA    A        ;return no-errors
  387. PBEXIT: POP    B
  388.     POP    D
  389.     POP    H
  390.     RET
  391. ;
  392. BAUDTB: DB    0        ;110 (not supported)
  393.     DB    BD300        ;300
  394.     DB    0        ;450 (not supported)
  395.     DB    BD600        ;600
  396.     DB    0        ;710 (not supported)
  397.     DB    BD1200        ;1200
  398.     DB    0        ;2400 (not supported)
  399.     DB    BD4800        ;4800
  400.     DB    BD9600        ;9600
  401.     DB    BD19200        ;19200
  402. ;
  403. ;    Port access routines
  404. ;
  405. ; Input
  406. ;
  407. INSP:    MVI    A,SPORT        ;in status-port
  408.     JMP    INP1
  409. INDP:    MVI    A,DPORT        ;in data-port
  410. INP1:    PUSH    B        ;can't alter BC
  411.     MOV    C,A        ;2661-relative port number in C
  412.     CALL    STPORT        ;set port #
  413.     ADD    C        ;A=absolute port #
  414.     POP    B        ;restore BC
  415.     STA    INP2+1        ;put port # in the code
  416. INP2:    IN    0        ;do the input
  417.     RET
  418. ;
  419. ; Output
  420. ;
  421. OUTDP:    PUSH    B        ;out data-port
  422.     MVI    C,DPORT
  423.     JMP    OUT1
  424. OUTMP:    PUSH    B        ;out mport
  425.     MVI    C,MPORT
  426.     JMP    OUT1
  427. OUTCP:    PUSH    B        ;out control port
  428.     MVI    C,CPORT
  429. OUT1:    MOV    B,A        ;B=char to send
  430.     CALL    STPORT        ;set port #
  431.     ADD    C        ;A=absolute port #
  432.     STA    OUT2+1        ;put port # in the code
  433.     MOV    A,B        ;A=char to send
  434. OUT2:    OUT    0        ;send it
  435.     POP    B
  436.     RET
  437. ;
  438. ; Set port #, return base adrs
  439. ;
  440. STPORT: LDA    PORT        ;get current port #
  441.     CPI    0FFH        ;255 implies SS1
  442.     JNZ    STIN        ;jump if not SS1
  443.     MVI    A,SSBASE    ;it's SS1, return base adrs
  444.     RET
  445. STIN:    OUT    UPORT        ;set IN 3/4 user #
  446.     MVI    A,INBASE    ;return base port
  447.     RET
  448. ;
  449. ;
  450. PORT:    DB    6        ;initial port #=ss1
  451. ;
  452. ; Clear-to-end-of-screen and clear-screen sequences
  453. ;
  454. EOSMSG: DB    ESC,'T','$'
  455. CLSMSG: DB    26,'$'
  456. ;
  457. ;
  458.     END
  459.