home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-lb3.asm < prev    next >
Assembly Source File  |  1994-07-13  |  12KB  |  391 lines
  1. ; MXO-LB3.ASM- AMPRO "Little Board" overlay for MEX10.       04/04/85
  2. ;
  3. ; You will want to look this file over carefully. There are a number of
  4. ; options that you can use to configure the program to suit your taste.
  5. ; This file adapts the AMPRO "Little Board" computer to the modem program.  
  6. ;
  7. ; Edit this file for your preferences then follow the "TO USE:" example
  8. ; shown below.
  9. ;
  10. ; Use the "SET" command to change the baudrate when desired.  It starts
  11. ; out at 1200 baud when the program is first called up.
  12. ;
  13. ;    TO USE: First edit this file filling in answers for your own
  14. ;        equipment.  Then assemble with ASM.COM or equivalent
  15. ;        assembler.  Then use MLOAD to overlay the the results
  16. ;        of this program to the original .COM file.
  17. ;
  18. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  19. ; 04/04/84 - Added DISCV to allow modem disconnect on ESC N
  20. ;         (present GOODBY routine is only called when exiting
  21. ;         MEX to CPM)             -Norman Beeler     
  22. ; 03/29/85 - Added 2400 and 4800 baud capability -Norman Beeler
  23. ; 09/14/84 - Adapt for AMPRO "Little Board"    - Charlie Sanborn
  24. ; 05/28/84 - MEXify labels            - Biff Bueffel
  25. ; 05/23/84 - Corrected clear-screen problem    - Biff Bueffel    
  26. ; 05/22/84 - Rewritten for MEX10        - Biff Bueffel
  27. ; 11/11/83 - Renamed to M7KP-1.ASM, no changes    - Irv Hoff
  28. ; 07/27/83 - Renamed to work with MDM712    - Irv Hoff
  29. ; 07/01/83 - Revised to work with MDM711    - Irv Hoff
  30. ; 06/22/83 - Revised to work with MDM710    - Irv Hoff
  31. ; 05/25/83 - Revised to work with MDM709    - Irv Hoff
  32. ; 04/15/83 - Revised to work with MDM708    - Irv Hoff
  33. ; 04/11/83 - Updated to work with MDM707    - Irv Hoff
  34. ; 04/04/83 - Updated to work with MDM706    - Irv Hoff
  35. ; 02/27/83 - Updated to work with MDM705    - Irv Hoff
  36. ; 02/17/83 - Modified MDM703CF for Kaypro II
  37. ;         computers with external modems    - Irv Hoff
  38. ;
  39. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  40. ;
  41. BELL:        EQU    07H        ;bell
  42. CR:        EQU    0DH        ;carriage return
  43. ESC:        EQU    1BH        ;escape
  44. LF:        EQU    0AH        ;linefeed
  45. ;
  46. YES:        EQU    0FFH
  47. NO:        EQU    0
  48. ;
  49. ;
  50. PORT:        EQU    88H        ;Ampro "B" serial output port
  51. MODCT1:     EQU    PORT+4        ;Modem control port
  52. MODDAT:     EQU    PORT        ;Modem data port
  53. MODCT2:     EQU    PORT+4        ;Modem control port
  54. MDRCVB:     EQU    01H        ;Your bit to test for receive
  55. MDRCVR:     EQU    01H        ;Your value when receive ready
  56. MDSNDB:     EQU    04H        ;Your bit to test for send
  57. MDSNDR:     EQU    04H        ;Your value when send ready        
  58. ;
  59. ; MEX service processor stuff
  60. ;
  61. MEX    EQU    0D00H        ;address of the service processor
  62. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  63. TIMER    EQU    254        ;delay 100ms * reg B
  64. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  65. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  66. SNDRDY    EQU    251        ;test for modem-send ready
  67. RCVRDY    EQU    250        ;test for modem-receive ready
  68. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  69. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  70. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  71. PARSFN    EQU    246        ;parse filename from input stream
  72. BDPARS    EQU    245        ;parse baud-rate from input stream
  73. SBLANK    EQU    244        ;scan input stream to next non-blank
  74. EVALA    EQU    243        ;evaluate numeric from input stream
  75. LKAHED    EQU    242        ;get nxt char w/o removing from input
  76. GNC    EQU    241        ;get char from input, cy=1 if none
  77. ILP    EQU    240        ;inline print
  78. DECOUT    EQU    239        ;decimal output
  79. PRBAUD    EQU    238        ;print baud rate
  80. ;
  81. PRINT    EQU    9        ;MEX/BDOS print-string function call
  82. ;
  83.         ORG    100H
  84. ;
  85. ;
  86. ; Change the clock speed as needed for your system.
  87. ;
  88.         DS    3    ;(for  "JMP   START" instruction)
  89. ;
  90. PMODEM:     DB    NO    ;yes=PMMI S-100 Modem            103H
  91. SMODEM:     DB    YES    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  92. TPULSE:     DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  93. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  94.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  95. MSPEED:     DB    5    ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  96.                 ;6=2400 7=4800 8=9600 9=19200 default
  97. BYTDLY:     DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  98.                 ;default time to send character in ter-
  99.                 ;minal mode file transfer for slow BBS.
  100. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  101.                 ;default time for extra wait after CRLF
  102.                 ;in terminal mode file transfer
  103. COLUMS:     DB    5    ;number of DIR columns shown        10AH
  104. SETFLG:     DB    YES    ;yes=user-added Setup routine        10BH
  105. SCRTST:     DB    YES    ;Cursor control routine         10CH
  106.         DB    YES    ;yes=resend a record after any non-ACK    10DH
  107.                 ;no=resend a record after a valid NAK
  108. BAKFLG:     DB    NO    ;yes=change any file same name to .BAK    10EH
  109. CRCDFL:     DB    YES    ;yes=default to CRC checking        10FH
  110. TOGCRC:     DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  111. CVTBS:        DB    NO    ;yes=convert backspace to rub        111H
  112. TOGLBK:     DB    YES    ;yes=allow toggling of bksp to rub    112H
  113. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  114.                 ;terminal mode (added by remote echo)
  115. TOGLF:        DB    YES    ;yes=allow toggling of LF after CR    114H
  116.         DB    NO    ;yes=allow transmission of logon    115H
  117.                 ;write logon sequence at location LOGON
  118. SAVCCP:     DB    YES    ;yes=do not overwrite CCP        116H
  119.         DB    NO    ;yes=local command if EXTCHR precedes    117H
  120.                 ;no=external command if EXTCHR precedes
  121.         DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  122. LSTTST:     DB    YES    ;yes=printer available on printer port    119H
  123. XOFTST:     DB    NO    ;yes=chcks for XOFF from remote while    11AH
  124.                 ;sending a file in terminal mode
  125. XONWT:        DB    NO    ;yes=wait for XON after CR while    11BH
  126.                 ;sending a file in terminal mode
  127. TOGXOF:     DB    YES    ;yes=allow toggling of XOFF checking    11CH
  128. IGNCTL:     DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  129. EXTRA1:     DB    0    ;for future expansion            11EH
  130. EXITCHR:        DB    'E'-40H ;^E = Exit to main menu         11FH
  131. BRKCHR:     DB    '@'-40H ;^@ = Send a 300 ms. break tone     120H
  132. NOCONN:     DB    'N'-40H ;^N = Disconnect from the phone line    121H
  133. LOGCHR:     DB    'L'-40H ;^L = Send logon            122H
  134. LSTCHR:     DB    'P'-40H ;^P = Toggle printer            123H
  135. UNSAVE:     DB    'R'-40H ;^R = Close input text buffer        124H
  136. TRNCHR:     DB    'T'-40H ;^T = Transmit file to remote        125H
  137. SAVCHR:     DB    'Y'-40H ;^Y = Open input text buffer        126H
  138. EXTCHR:     DB    '^'-40H ;^^ = Send next character        127H
  139. ;
  140. ;
  141.         DS    2        ;                128H
  142. ;
  143. INCTL1:     MVI    A,10H        ;channel 0, reset interrupts.    12AH
  144.         OUT    MODCT1
  145.         IN    MODCT1        ;get the status bits
  146.         RET
  147.         DS    3
  148. ;
  149. OTDATA:     OUT    MODDAT ! RET    ;out modem data port        134H
  150.         DS    7
  151. INPORT:     IN    MODDAT ! RET    ;in modem data port        13EH
  152.         DS    7
  153. MASKR:        ANI    MDRCVB    ! RET    ;bit to test for receive ready    148H
  154. TESTR:        CPI    MDRCVR ! RET    ;value of receive bit when rdy    14BH
  155. MASKS:        ANI    MDSNDB    ! RET    ;bit to test for send ready    14EH
  156. TESTS:        CPI    MDSNDR    ! RET    ;value of send bit when ready    151H
  157.         DS    6
  158. ;
  159. OUTCTL1:    OUT    MODCT1    ! RET    ;out modem control port     15AH
  160. OUTCTL2:    OUT    MODCT2    ! RET    ;out modem status port        15DH
  161. ;
  162. ;
  163.         DS    2        ;                160H
  164.          DS    3        ;                162H
  165. DISCV:        JMP    GOODBY        ;disconnect on ^N
  166. GOODBV:     JMP    GOODBY        ;                168H
  167. INMODV:     JMP    NITMOD        ;go to user written routine    16BH
  168. NEWBDV:     JMP    NEWBAUD     ;Set new baudrate        16EH
  169.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    171H
  170.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    174H
  171. SETUPV:     JMP    SETCMD        ;                177H
  172.         DS    3        ;                17AH
  173. VERSNV:     JMP    SYSVER        ;                17DH
  174. BREAKV:     JMP    SBREAK        ;                180H
  175. ;
  176. ;
  177. ; Do not change the following six lines.
  178. ;
  179. ILPRTV:     DS    3        ;                183H
  180. INBUFV:     DS    3        ;                186H
  181. ILCMPV:     DS    3        ;                189H
  182. INMDMV:     DS    3        ;                18CH
  183.         DS    3        ;                18FH
  184. TIMERV:     DS    3        ;                192H
  185. ;
  186. ;
  187. ; Clear sequences -- CLREOS is clear to end of screen, CLRSCRN is clear
  188. ; entire screen.  Last entry must be 0.  Any other 0's act as NOP's.
  189. ;
  190. CLREOS:     LXI    D,EOSMSG
  191.         MVI    C,PRINT
  192.         CALL    MEX
  193.         RET            
  194. ;
  195. CLS:    LXI    D,CLSMSG
  196.         MVI    C,PRINT
  197.         CALL    MEX
  198.         RET            
  199. ;
  200. ;
  201. SYSVER:     MVI    C,ILP        ;                
  202.         CALL    MEX
  203.         DB    'Version for AMPRO "B" serial port @ 88H',CR,LF
  204.         DB    'Satsuma Group :CS: -- 09/14/84',CR,LF
  205.         DB    'Rev 3 04/04/85 :NLB:',CR,LF,0
  206.         RET
  207. ;
  208. ;
  209. ;
  210. ; This routine allows a 300 ms. break tone to be sent to reset some
  211. ; time-share computers.
  212. ;
  213. SBREAK:  MVI    A,5
  214.       OUT    MODCT1
  215.       MVI    A,7AH             ;SEND A BREAK TONE         
  216.       JMP    GOODBY1
  217. ;.....
  218. ;
  219. ;
  220. ; This routine sends a 300 ms. break tone and sets DTR low for the same
  221. ; length of time to disconnect some modems such as the Bell 212A, etc.
  222. ;
  223. GOODBY:  MVI    A,5
  224.       OUT    MODCT1        ;SEND TO THE STATUS PORT
  225.       MVI    A,78H        ;TURN OFF RTS
  226. ;
  227. GOODBY1: OUT    MODCT1
  228.       MVI    B,3        ;DELAY 300 MS.
  229.       MVI    C,TIMER
  230.       CALL    MEX
  231.       MVI    A,5
  232.       OUT    MODCT1
  233.       MVI    A,6AH           ;RESTORE TO NORMAL, 8 BITS, RTS ON, ETC.
  234.       OUT    MODCT1
  235.       RET
  236. ;.....
  237. ;
  238. ;
  239. ; AMPRO initialization -- set up Z80-DART & CTC Channel 01 (clock source)
  240. ;
  241. ;
  242. NITMOD:   MVI    A,00H        ;SELECT REG.
  243.       OUT    MODCT1
  244.       MVI    A,18H        ;THROW OUT OF MODE
  245.       OUT    MODCT1
  246.       MVI    A,04H        ;SELECT REG.
  247.       OUT    MODCT1
  248.       MVI    A,44H        ;SET ASCII PARAMETERS
  249.       OUT    MODCT1
  250.       MVI    A,03H        ;SELECT REG.
  251.       OUT    MODCT1
  252.       MVI    A,0C1H        ;ENABLE RECEIVE
  253.       OUT    MODCT1
  254.       MVI    A,05H        ;SELECT REG.
  255.       OUT    MODCT1
  256.       MVI    A,6AH           ;ENABLE SEND, DTR, RTS
  257.       OUT    MODCT1
  258. ;
  259. NITMOD1:  MVI    A,5        ;SET FILE TRANSFER TIME
  260.       STA    MSPEED
  261.       MVI    A,47H
  262.       OUT    50H        ;SEND TO 'CTC' TIMER
  263.  
  264. NITMOD2:  MVI    A,68H        ;INITIALIZE TO 1200 BAUD
  265.       OUT    50H        ;SEND TO 'CTC' TIMER
  266.       RET
  267. ;.....
  268. ;
  269. ;
  270. ; Sets the modem speed via the SET command.
  271. ;
  272. ;
  273. SETCMD:   MVI    C,SBLANK    ;Any arguments?
  274.       CALL    MEX
  275.       JC    TELL        ;If not, go display baud
  276.       LXI    D,CMDTBL
  277.       MVI    C,LOOKUP
  278.       CALL    MEX        ;Parse argument
  279.       PUSH    H        ;Save any parsed argument addrs on stack
  280.       RNC            ;If we have one, return to it
  281.       POP    H        ;Oops, input not found in table
  282.       MVI    C,ILP
  283.       CALL    MEX        ;Tell user input not valid
  284.       DB    CR,LF,'Only 300, 600, 1200, 2400, 4800 or 9600 allowed with SET'
  285.       DB    CR,LF,0
  286.       RET
  287. ;
  288. CMDTBL:   DB    '30','0'+80H
  289.       DW    OK300
  290.       DB    '60','0'+80H
  291.       DW    OK600
  292.       DB    '120','0'+80H
  293.       DW    OK1200
  294.       DB    '240','0'+80H
  295.       DW    OK2400
  296.       DB    '480','0'+80H
  297.       DW    OK4800
  298.       DB    '960','0'+80H
  299.       DW    OK9600
  300.       DB    0
  301. ;
  302. TELL:      MVI    C,ILP
  303.       CALL    MEX        ;Print current baud rate
  304.       DB    CR,LF,'Baud rate is now: ',0
  305.       LDA    MSPEED
  306.       MVI    C,PRBAUD
  307.       CALL    MEX
  308.       RET
  309. ;
  310. ;
  311. OK300      MVI    A,84H        ;Load DART Reg 4 with x32
  312.       STA    NITMOD+13
  313.       MVI    A,1
  314.       LHLD    BD300
  315.       JMP    LOADBD
  316. ;
  317. OK600      MVI    A,44H        ;Load DART Reg 4 with x16
  318.       STA    NITMOD+13
  319.       MVI    A,3
  320.       LHLD    BD600
  321.       JMP    LOADBD
  322. ;
  323. OK1200      MVI    A,44H        ;Same as for 600
  324.       STA    NITMOD+13
  325.       MVI    A,5
  326.       LHLD    BD1200
  327.       JMP    LOADBD
  328. ;
  329. OK2400      MVI    A,44H
  330.       STA    NITMOD+13
  331.       LHLD    BD2400
  332.       JMP    LOADBD
  333. ;
  334. OK4800      MVI    A,44H
  335.       STA    NITMOD+13
  336.       LHLD    BD4800
  337.       JMP   LOADBD    
  338. ;
  339. OK9600      MVI    A,44H        ;As above
  340.       STA    NITMOD+13
  341.       MVI    A,8
  342.       LHLD    BD9600
  343. ;
  344. LOADBD:   STA    NITMOD1+1    ;CHANGE TIME-TO-SEND TO MATCH BAUDRATE
  345.       MOV    A,L        ;GET BAUDRATE BYTE
  346.       STA    NITMOD2+1    ;SEND TO 'CTC' FOR NEW BAUDRATE
  347.       JMP    NITMOD        ;REINITIALIZE TO NEW BAUDRATE, THEN DONE
  348. ;
  349. ;
  350. NEWBAUD:  CPI    1
  351.       JZ    OK300
  352.       CPI    3
  353.       JZ    OK600
  354.       CPI    5
  355.       JZ    OK1200
  356.       CPI    6
  357.       JZ    OK2400
  358.       CPI    7
  359.       JZ    OK4800
  360.       CPI    8
  361.       JZ    OK9600
  362.       RET
  363. ;
  364. ;
  365. ; TABLE OF BAUDRATE PARAMETERS
  366. ;
  367. BD300:      DW    00D0H
  368. BD600:      DW    00D0H
  369. BD1200:   DW    0068H
  370. BD2400      DW    0034H
  371. BD4800      DW    001AH
  372. BD9600:   DW    000DH
  373. ;
  374. BAUDBUF:  DB    10,0
  375.       DS    10
  376. ;
  377. ; NOTE: The following two lines are terminal dependent, and are
  378. ; currently set for a VT-100. Change for your terminal.
  379. ;
  380. EOSMSG:   DB    01BH,5BH,4AH,'$'           
  381. CLSMSG:   DB    01BH,5BH,66,1BH,5BH,4AH,'$'
  382. ;-----------------------------------------------------------------------
  383. ;
  384. ;
  385. ; NOTE:  MUST TERMINATE PRIOR TO 0B00 (with Smartmodem)
  386. ;                 
  387. ;
  388.       END
  389. ;
  390.  
  391.