home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-mr11.aqm / MXO-MR11.ASM
Assembly Source File  |  1985-12-08  |  44KB  |  1,106 lines
  1. ; MXO-MR11.ASM -- MEX Port Overlay file for the Morrow Descision 11  03-OCT-85
  2. ;-----------------------------------------------------------------------------;
  3. ; This overlay adapts the MEX modem program for the Morrow Micro  Decision 11.
  4. ; This MEX Port overlay digresses from pure by encompassing a Hayes Smartmodem
  5. ; feature in  the SET command.  If this offends you in anyway,  set the SMODEM
  6. ; flag to "NO" to eliminate.
  7. ;
  8. ; The SET command used in this overlay will allow the setting of the baud rate
  9. ; (speed) of the modem hardware port. As mentioned, the Smartmodem speaker is
  10. ; setable by the user  to one of three setting: OFF: such that  the speaker is
  11. ; always off, HALF: such that the  speaker is on during the  dialing sequence,
  12. ; but turns off when the carrier is detected,  and FULL: the speaker stays  on
  13. ; when carrier detected. This is useful when one doesn't wish the stereo to be
  14. ; drowned out by the Smartmodem dialing.
  15. ;
  16. ; A more  detailed description of the calling conventions used by this overlay
  17. ; overlay can be found in the PMMI modem overlay (MXO-PMxx.ASM where the  "xx"
  18. ; is the current version number).
  19. ;-----------------------------------------------------------------------------;
  20. ; History as a MEX overlay
  21. ;
  22. ; 10/02/85 - Stolen from MXO-SZ20.ASM                 (V1.1)    - Stuart Rose
  23. ;
  24. ;-----------------------------------------------------------------------------;
  25. ;
  26. OVERSION    equ    1    ; overlay version number
  27. OREVISION    equ    1    ; overlay revision level
  28. ;
  29. ;=============================================================================;
  30. ; CP/M system addresses                                  ;
  31. ;=============================================================================;
  32. ;
  33. WBOOT        equ    0000H    ; address of warm boot jump vector
  34. TPA        equ    0100H    ; address of transient program area
  35. ;
  36. ;=============================================================================;
  37. ; MEX system bytes. This overlay helps MEX remember the baud rate of the      ;
  38. ; modem port and speaker volume of the Smartmodem when hopping in and out of  ;
  39. ; MEX **DURING THE SAME CALL**. These values are used instead of the overlay  ;
  40. ; defaults (MSPEED and VOLUME respectively) when a call-in-progress is de-    ;
  41. ; tected on MEX startup. Then these values are used. To protect them, they    ;
  42. ; live in the system page (0000H-00FFH), in a location not used by the OS     ;
  43. ; (operating system). Generally 0040H-004FH is reserved for CBIOSes and is    ;
  44. ; fine for uses, as long as your CBIOS doesn't use it. If you are really un-  ;
  45. ; sure, set both values to 0000H, and this feature will be eliminated.          ;
  46. ;=============================================================================;
  47. ;
  48. MEXBAUD        equ    004FH    ; address of system byte for MEX baud rate
  49. MEXSPKR        equ    004EH    ; address of system byte for MEX speaker volume
  50. ;
  51. ;=============================================================================;
  52. ; MEX service processor address and functions                      ;
  53. ;=============================================================================;
  54. ;
  55. MEX        equ    0D00H    ; address of the MEX service processor
  56. INMDM        equ    255    ; A = char from modem,CARRY = no char in 100 ms
  57. TIMER        equ    254    ; delay B, in 100 ms units
  58. TMDINP        equ    253    ; wait B seconds for char, CARRY = no char
  59. CHEKCC        equ    252    ; check for ^C from keyboard, ZERO = present
  60. SNDRDY        equ    251    ; test for modem-send ready
  61. RCVRDY        equ    250    ; test for modem-receive ready
  62. SNDCHR        equ    249    ; send a character to the modem (after sndrdy)
  63. RCVCHR        equ    248    ; receive a character from modem (after rcvrdy)
  64. LOOKUP        equ    247    ; table search: see CMDTBL comments for info
  65. PARSFN        equ    246    ; parse filename from input stream
  66. PARSBD        equ    245    ; parse baud-rate from input stream
  67. SBLANK        equ    244    ; scan input stream to next non-blank
  68. EVALA        equ    243    ; evaluate numeric from input stream
  69. LKAHED        equ    242    ; get next char w/o removing from input stream
  70. GNC        equ    241    ; get next char from input stream, CARRY = none
  71. ILP        equ    240    ; inline print
  72. DECOUT        equ    239    ; decimal output
  73. PRBAUD        equ    238    ; print baud rate
  74. PRNTBL        equ    237    ; print command table CARRY SET for ^C abort
  75. PRID        equ    236    ; print current MEX ID string on console
  76. PRINT        equ    9    ; BDOS/MEX print-string function call
  77. CONOUT        equ    2    ; BDOS/MEX output a character to console call
  78. ;
  79. ;=============================================================================;
  80. ; Define new MEX modes (granted in MEX V1.10 and up)                  ;
  81. ;=============================================================================;
  82. ;
  83. CMDMOD    equ    0        ; 00 - MEX is in command mode
  84. TRMMOD    equ    1        ; 01 - MEX is in terminal mode
  85. SNDMOD    equ    2        ; 02 - SENDOUT active
  86. KEYMOD    equ    3        ; 03 - Keystring being transmitted
  87. XMDMSND    equ    4        ; 04 - File transfer: Christensen-protocol send
  88. XMDMRCV    equ    5        ; 05 - File transfer: Christensen-protocol rcv
  89. CISSND    equ    6        ; 06 - File transfer: CIS-protocol send
  90. CISRCV    equ    7        ; 07 - File transfer: CIS-protocol receive
  91. ;
  92. ;=============================================================================;
  93. ; define some ASCII control characters                          ;
  94. ;=============================================================================;
  95. ;
  96. NULL        equ    '@'-'@'    ; (^@) null
  97. BELL        equ    'G'-'@'    ; (^G) bell
  98. TAB        equ    'I'-'@'    ; (^I) tab
  99. CR        equ    'M'-'@'    ; (^M) carriage return
  100. LF        equ    'J'-'@'    ; (^J) line feed
  101. ESC        equ    '['-'@'    ; (^[) escape
  102. CTRL$Z        equ    'Z'-'@'    ; (^Z) control Z
  103. DEL        equ    7FH    ; delete
  104. EOS        equ    DEL    ; SNDLIN end-of-string character
  105. ;
  106. ;=============================================================================;
  107. ; define some boolean variables                              ;
  108. ;=============================================================================;
  109. ;
  110. YES        equ    0ffH    ; affirmative response
  111. NO        equ    000H    ; negative response
  112. TRUE        equ    YES    ; true (affirmative) response
  113. FALSE        equ    NO    ; false (negative) response
  114. ;
  115. ;=============================================================================;
  116. ; MEX dial subroutine return error codes                      ;
  117. ;=============================================================================;
  118. ;
  119. CARRIER        equ    0    ; CARRIER DETECTED return code
  120. BUSY        equ    1    ; FAR END BUSY return code
  121. NOANSWER    equ    2    ; NO ANSWER return code
  122. ABORT        equ    3    ; KEYBOARD ABORT return code
  123. ERROR        equ    4    ; MODEM ERROR return code
  124. NORING        equ    5    ; NO RING return code
  125. NODIALTONE    equ    6    ; NO DIAL TONE return code
  126.  
  127. ;=============================================================================;
  128. ; MEX system page parameters (are correct for MEX V1.1x)              ;
  129. ; see MEXPATxx for current values.                          ;
  130. ;=============================================================================;
  131. ;
  132. PROMPT        equ    MEX+13H    ; addr of address of id prompt
  133. CANCHR        equ    MEX+1CH    ; addr of cancel character
  134. ERRID        equ    MEX+2EH    ; addr of error id flag (0 = no id in err msg)
  135. ;
  136. ;=============================================================================;
  137. ; miscellaneous equates                                  ;
  138. ;=============================================================================;
  139. ;
  140. OFF        equ    '0'    ; Smartmodem code for speaker always off
  141. HALF        equ    '1'    ; Smartmodem code for speaker on until CD
  142. FULL        equ    '2'    ; Smartmodem code for speaker always on
  143. ;
  144. ;=============================================================================;
  145. ; MEX format baud rates                                  ;
  146. ;=============================================================================;
  147. ;
  148. MEX110        equ    0    ; MEX baud rate of 110
  149. MEX300        equ    1    ; MEX baud rate of 300
  150. MEX450        equ    2    ; MEX baud rate of 450
  151. MEX600        equ    3    ; MEX baud rate of 600
  152. MEX710        equ    4    ; MEX baud rate of 710
  153. MEX1200        equ    5    ; MEX baud rate of 1200
  154. MEX2400        equ    6    ; MEX baud rate of 2400
  155. MEX4800        equ    7    ; MEX baud rate of 4800
  156. MEX9600        equ    8    ; MEX baud rate of 9600
  157. MEX19200    equ    9    ; MEX baud rate of 19200
  158. ;
  159. ;=============================================================================;
  160. ; Baud rate parameters for Morrow Descision 11 Zilog DART              ;
  161. ;=============================================================================;
  162. ;
  163. BD300        equ    0C4H    ; 300 baud
  164. BD600        equ    084H    ; 600 baud
  165. BD1200        equ    044H    ; 1200 baud
  166. BD19200        equ    004H    ; 19200 baud
  167. ;
  168. ;=============================================================================;
  169. ; Morrow Descision 11 base port for modem serial port                  ;
  170. ;=============================================================================;
  171. ; 
  172. BASE        equ    062H    ; base port of modem port for MD-11
  173. ;
  174. ;=============================================================================;
  175. ; Morrow initialization values for modem port baud rate, and the Hayes        ;
  176. ; Smartmodem speaker volume (the last two values take on values stored in     ;
  177. ; the MEX scratch area of the system parameter page when re-entering MEX      ;
  178. ; with a call-in-progress).                              ;
  179. ;=============================================================================;
  180. ;
  181. MD$BAUD        equ    MEX1200    ; initial baud rate (speed) for Morrow modem
  182. MD$SPKR        equ    OFF    ; initial speaker volume, speaker always off
  183. ;
  184. ;=============================================================================;
  185. ; Port offsets (from BASE)                              ;
  186. ;=============================================================================;
  187. ;
  188. DPORT        equ    0    ; data port
  189. SPORT        equ    1    ; status port
  190. CPORT        equ    1    ; control port
  191. ;
  192. ;=============================================================================;
  193. ; UAR/T status bits (for Zilog and Plymouth DART)                  ;
  194. ;=============================================================================;
  195. ;
  196. TBMT        equ    04H    ; transmit buffer empty
  197. DAV        equ    01H    ; data available
  198. DCDLIN        equ    08H    ; carrier detect (use DCD line itself)
  199. ;DCDLIN        equ    20H    ; carrier detect (use CTS line)
  200. ;
  201. ;=============================================================================;
  202. ;  Overlay starts here                                  ;
  203. ;=============================================================================;
  204. ;
  205.     org    TPA
  206. ;
  207. ;=============================================================================;
  208. ; MDM7xx/MEX parameter page                              ;
  209. ;=============================================================================;
  210. ;
  211. JMPMEX:    DS    3        ;(for "jmp START" instruction)        100H
  212. PMODEM:    DB    NO        ;yes=PMMI S-100 Modem            103H
  213. SMODEM:    DB    YES        ;yes=HAYES Smartmodem, no=non-PMMI    104H
  214. TPULSE:    DB    'T'        ;T=touch, P=pulse (Smartmodem-only)    105H
  215. CLOCK:    DB    40        ;clock speed in MHz x10, 25.5 MHz max.    106H
  216.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  217. MSPEED:    DB    MD$BAUD        ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  218.                 ;6=2400 7=4800 8=9600 9=19200 default
  219. BYTDLY:    DB    0        ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  220.                 ;default time to send character in ter-
  221.                 ;minal mode file transfer for slow BBS.
  222. CRDLY:    DB    0        ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  223.                 ;default time for extra wait after CRLF
  224.                 ;in terminal mode file transfer
  225. COLUMS:    DB    5        ;number of DIR columns shown        10AH
  226. SETFLG:    DB    YES        ;yes=user-added Setup routine        10BH
  227. SCRTST:    DB    YES        ;Cursor control routine         10CH
  228. ACKNAK: DB    YES        ;yes=resend a record after any non-ACK    10DH
  229.                 ;no=resend a record after a valid-NAK
  230. BAKFLG:    DB    NO        ;yes=change any file same name to .BAK    10EH
  231. CRCDFL:    DB    YES        ;yes=default to CRC checking        10FH
  232. TOGCRC:    DB    YES        ;yes=allow toggling of CRC to Checksum    110H
  233. CVTBS:    DB    NO        ;yes=convert backspace to rub        111H
  234. TOGLBK:    DB    YES        ;yes=allow toggling of bksp to rub    112H
  235. ADDLF:    DB    NO        ;no=no LF after CR to send file in    113H
  236.                 ;terminal mode (added by remote echo)
  237. TOGLF:    DB    YES        ;yes=allow toggling of LF after CR    114H
  238. LOGOK:    DB    NO        ;yes=allow transmission of logon    115H
  239.                 ;write logon sequence at location LOGON
  240. SAVCCP:    DB    YES        ;yes=do not overwrite CCP        116H
  241. LOCXCHR:DB    NO        ;yes=local command if EXTCHR precedes    117H
  242.                 ;no=external command if EXTCHR precedes
  243. TOGEXC:    DB    YES        ;yes=allow toggling of EXTCHR        118H
  244. LSTTST:    DB    YES        ;yes=printer available on printer port    119H
  245. XOFTST:    DB    YES        ;yes=checks for XOFF from remote while    11AH
  246.                 ;sending a file in terminal mode
  247. XONWT:    DB    NO        ;yes=wait for XON after CR while    11BH
  248.                 ;sending a file in terminal mode
  249. TOGXOF:    DB    YES        ;yes=allow toggling of XOFF checking    11CH
  250. IGNCTL:    DB    NO        ;yes=CTL-chars above ^M not displayed    11DH
  251. EXTRA1:    DB    0        ;for future expansion            11EH
  252. ;
  253. ;=============================================================================;
  254. ; Terminal mode escape character (for MDM7xx only)                  ;
  255. ;=============================================================================;
  256. ;
  257. EXITCHR DB    'E'-'@'        ; ^E = Exit to main menu        11FH
  258. BRKCHR    DB    '@'-'@'        ; ^@ = Send 300 ms. break tone        120H
  259. NOCONN    DB    'N'-'@'        ; ^N = Disconnect from the phone line    121H
  260. LOGCHR    DB    'L'-'@'        ; ^L = Send logon            122H
  261. LSTCHR    DB    'P'-'@'        ; ^P = Toggle printer            123H
  262. UNSAVE    DB    'Z'-'@'        ; ^Z = Close input text buffer        124H
  263. TRNCHR    DB    'T'-'@'        ; ^T = Transmit file to remote        125H
  264. SAVCHR    DB    'A'-'@'        ; ^A = Open input text buffer        126H
  265. EXTCHR    DB    '\'-'@'        ; ^\ = Send next character        127H
  266. ;
  267. ;=============================================================================;
  268. ; Overlay parameter page (unused by MEX)                      ;
  269. ;=============================================================================;
  270. ;
  271.     ds    2        ;
  272. ;
  273. ;=============================================================================;
  274. ; Modem I/O routines                                  ;
  275. ;=============================================================================;
  276. ;
  277. MDMSTAT:JMP    INPSP        ; get modem status            12AH
  278.     DS    7
  279. ;
  280. MDMOUT:    JMP    OUTDP        ; output a character to the modem    134H
  281.     DS    7
  282. ;
  283. MDMIN:    JMP    INPDP        ; input a character from the modem    13EH
  284.     DS    7
  285. ;
  286. ;=============================================================================;
  287. ; Modem status register send/receive bit test routines                  ;
  288. ;=============================================================================;
  289. ;
  290. MASKR:    ANI    DAV    ! RET    ; bit to test for receive ready        148H
  291. TESTR:    CPI    DAV    ! RET    ; value of receive bit when ready    14BH
  292. MASKS:    ANI    TBMT    ! RET    ; bit to test for send ready        14EH
  293. TESTS:    CPI    TBMT    ! RET    ; value of send bit when ready        151H
  294.     DS    14        ;                    154H
  295. ;
  296. ;=============================================================================;
  297. ; MEX subroutine jump table                              ;
  298. ;=============================================================================;
  299. ;
  300. DIALV:    ds    3        ; Smartmodem dial a number        162H
  301. DISCV:    jmp    DISCON        ; disconnect from target system        165H
  302. GOODBV:    jmp    GOODBYE        ; MEX un-initialization subroutine    168H
  303. INMODV:    jmp    HELLO        ; MEX initialization subroutine        16BH
  304. NEWBDV:    jmp    BAUD        ; new baud rate subroutine        16EH
  305. NOPARV:    RET ! NOP ! NOP        ; no parity subroutine            171H
  306. PARITV:    RET ! NOP ! NOP        ; new parity subroutine            174H
  307. SETUPV:    jmp    SETCMD        ; Spider/Z SET command subroutine    177H
  308. SMENUV:    DS    3        ; not used by MEX            17AH
  309. VERSNV:    jmp    OVRVER        ; display overlay version subroutine    17DH
  310. BREAKV:    jmp    SBREAK        ; send a break tone subroutine        180H
  311. ILPRTV:    DS    3        ; inline print        (gone by MEX V2.0)    183H
  312. INBUFV:    DS    3        ; input buffer        (gone by MEX V2.0)    186H
  313. ILCMPV:    DS    3        ; line compare        (gone by MEX V2.0)    189H
  314. INMDMV:    DS    3        ; timed modem input (gone by MEX V2.0)    18CH
  315. NXTSNV:    DS    3        ; next screen        (gone by MEX V2.0)    18FH
  316. TIMERV:    DS    3        ; timer routine        (gone by MEX V2.0)    192H
  317. ;
  318. ;=============================================================================;
  319. ; CLREOS subroutine                                  ;
  320. ; This subroutine will clear the console screen from the current cursor          ;
  321. ; position, to the end of the console screen (insure that SCRTST (010AH)      ;
  322. ; is set to YES if you wish to use this subroutine).                  ;
  323. ;=============================================================================;
  324. ;
  325. CLREOS:    lxi    D,CLRE        ; clear to end-of-screen        195H
  326.     mvi    C,PRINT        ;
  327.     call    MEX        ;
  328.     ret            ;
  329. ;
  330. ;=============================================================================;
  331. ; CLRSCN subroutine                                  ;
  332. ; This subroutine will clear the console screen (insure that SCRTST (010AH)   ;
  333. ; is set to YES if you wish to use this subroutine).                  ;
  334. ;=============================================================================;
  335. ;
  336. CLRSCN:    lxi    D,CLRS        ; clear screen                19EH
  337.     mvi    C,PRINT        ;
  338.     call    MEX        ;
  339.     ret            ;
  340. ;
  341. ;=============================================================================;
  342. ; BOLD subroutine                                  ;
  343. ; This subroutine will turn on the bold attribute (insure that SCRTST (010AH) ;
  344. ; is set to YES if you wish to use this subroutine).                  ;
  345. ;=============================================================================;
  346. ;
  347. BOLD:    lda    SCRTST        ; termcap?
  348.     cpi    YES        ;
  349.     rnz            ; nope
  350.     lxi    D,BLD        ; yep, turn bold on
  351.     mvi    C,PRINT        ;
  352.     call    MEX        ;
  353.     ret            ;
  354. ;
  355. ;=============================================================================;
  356. ; UNBOLD subroutine                                  ;
  357. ; This subroutine will turn off the bold attribute (insure that SCRTST (010AH);
  358. ; is set to YES if you wish to use this subroutine).                  ;
  359. ;=============================================================================;
  360. ;
  361. UNBOLD:    lda    SCRTST        ; termcap?
  362.     cpi    YES        ;
  363.     rnz            ; nope
  364.     lxi    D,UNBLD        ; yep, turn bold off
  365.     mvi    C,PRINT        ;
  366.     call    MEX        ;
  367.     ret            ;
  368. ;
  369. ;=============================================================================;
  370. ; Escape sequences for MD-11s                              ;
  371. ;=============================================================================;
  372. ;
  373. CLRE:    db    ESC,'Y','$'    ; clear to end-of-screen
  374. CLRS:    db    ESC,'*','$'    ; clear screen 
  375. BLD:    db    '$'        ; turn on character bold attribute
  376. UNBLD:    db    '$'        ; turn off character bold attribute
  377. ;
  378. ;=============================================================================;
  379. ; OVRVER subroutine                                  ;
  380. ; This subroutine will print the overlay id and version on the console.          ;
  381. ;=============================================================================;
  382. ;
  383. OVRVER:    mvi    C,ILP        ; print overlay id and version number
  384.     call    MEX
  385.     db    'Morrow Micro Decision 11 Computer Port Overlay V'
  386.     db    OVERSION + '0','.',OREVISION + '0',CR,LF,0
  387.     call    CIPMSG        ; display "call in progress" if need be
  388.     rc            ;
  389.     mvi    C,ILP        ; aestetic newline
  390.     call    MEX        ;
  391.     db    CR,LF,0        ;
  392.     ret
  393. ;
  394. ;=============================================================================;
  395. ; GOODBYE subroutine                                  ;
  396. ; This subroutine is executed just prior to exiting from MEX to CP/M. All un- ;
  397. ; initialization procedures are done here.                      ;
  398. ;============================================================================;
  399. ;
  400. GOODBYE:call    CIPMSG        ; echo "call in progess" if need be
  401.     ret            ;
  402. ;
  403. ;=============================================================================;
  404. ; CIPMSG subroutine                                  ;
  405. ; This subroutine will display the "call in progress" message (Spider/Z users ;
  406. ; are forgetful) if BOTH a carriet is detected AND the current MEX modem port ;
  407. ; is not the current CP/M console.                          ;
  408. ;=============================================================================;
  409. ;
  410. CIPMSG:    call    CDTEST        ; gotta carrier?
  411.     rnc            ; nope, then don't display "call in progress"
  412.     call    BOLD        ; use bolding if possible
  413.     mvi    C,ILP        ; print a newline
  414.     call    MEX        ;
  415.     db    CR,LF,0        ;
  416.     call    IDMSG        ; blapp out ID prompt if need be
  417.     mvi    C,ILP        ; print "call in progess" message
  418.     call    MEX        ;
  419.     db    '[call in progress]',BELL,CR,LF,0
  420.     call    UNBOLD        ; undo bolding damage if need be
  421.     stc            ; show "call in progess" message printed
  422.     ret
  423. ;
  424. ;=============================================================================;
  425. ; SBREAK subroutine                                  ;
  426. ; This routine will mimic the function of the BREAK key by sending an          ;
  427. ; interrupt to the modem (transmit line held high) for a period of 300 ms.    ;
  428. ;=============================================================================;
  429. ;
  430. SBREAK: push    H        ; save registers
  431.     push    D        ;
  432.     push    B        ;
  433.     push    PSW        ;
  434.     mvi    A,0FAH        ; force break for 300 ms
  435.     mvi    B,3        ; set duration for 300 ms
  436.     call    TOUTCP        ; do it!
  437.     pop    PSW        ; restore registers
  438.     pop    B        ;
  439.     pop    D        ;
  440.     pop    H        ;
  441.     ret            ;
  442. ;
  443. ;=============================================================================;
  444. ; DISCON subroutine                                  ;
  445. ; This subroutine will disconnect the modem from the target computer. This    ;
  446. ; is done by dropping the DTR line to the modem for a period of 1.5 seconds   ;
  447. ; in theory, 300 ms is more than sufficient (this is what a BREAK key does),  ;
  448. ; but when the Smartmodem is dialing, a 300 ms pulse is not long enough to be ;
  449. ; recognized.                                      ;
  450. ;=============================================================================;
  451. ;
  452. DISCON:    push    H        ; save registers
  453.     push    D        ;
  454.     push    B        ;
  455.     push    PSW        ;
  456.     mvi    A,06AH        ; turn off DTR, no break sent
  457.     mvi    B,15        ; set duration for 1.5 seconds
  458.     call    TOUTCP        ; do it!
  459.     pop    PSW        ; restore registers
  460.     pop    B        ;
  461.     pop    D        ;
  462.     pop    H        ;
  463.     ret            ;
  464. ;
  465. ;=============================================================================;
  466. ; TOUTCP subroutine                                  ;
  467. ; This is a timed output to command port (OUTCP) subroutine. The value in the ;
  468. ; A register is output to the command port, then a time delay equal to the    ;
  469. ; value of the B register (in 100 ms units) is done.                  ;
  470. ;=============================================================================;
  471. ;
  472. TOUTCP:    push    PSW        ; save UAR/T command
  473.     mvi    A,5        ; write to control register 5
  474.     call    OUTCP        ;
  475.     pop    PSW        ; restore UAR/T command
  476.     call    OUTCP        ; send passed byte to CPORT
  477.     mvi    C,TIMER        ; wait alotted time
  478.     call    MEX        ;
  479.     mvi    A,5        ; write to control register 5
  480.     call    OUTCP        ;
  481.     mvi    A,0EAH        ; turn DTR back on, no break
  482.     call    OUTCP        ;
  483.     ret            ;
  484. ;
  485. ;=============================================================================;
  486. ; HELLO subroutine                                  ;
  487. ; This subroutine is used to initialize the modem and the modem port. This    ;
  488. ; is done via using some of the system reserved bytes in the CP/M system      ;
  489. ; parameter page (0000H - 00FFH). There is a 16 byte system scratch area      ;
  490. ; (0040H - 004FH) that is never referenced by CP/M. For the Spizer/Z, the     ;
  491. ; addresses 0040H - 0042H are reserved for the Jade Double-D Floppy Disk      ;
  492. ; Controller. All others are scratch. MEX uses 004FH as the byte reserved     ;
  493. ; for stating the current baud rate for the modem port, while 004EH is           ;
  494. ; reserved for the current Smartmodem speaker volume. These locations can     ;
  495. ; can be checked whenever re-entering MEX. Protocol used:              ;
  496. ;                                          ;
  497. ;    if a call is in progress (determined by the testing for a          ;
  498. ;    carrier detect (CDTEST)), MEX then uses the values stored in          ;
  499. ;    then MEX system reserved bytes for modem baud rate (the value          ;
  500. ;    is stored in MEX compatible format), and the Smartmodem speaker          ;
  501. ;    volume.                                      ;
  502. ;                                          ;
  503. ;    otherwise set the modem baud rate and Smartmodem speaker volume          ;
  504. ;    to the preset values (values set in this overlay or current values    ;
  505. ;       when CLONEing MEX).                              ;
  506. ;                                          ;
  507. ;=============================================================================;
  508. ;
  509. HELLO:    call    CDTEST        ; check for call in progress
  510.     jnc    COLDMEX        ; nope, initialize the modem and port
  511.  
  512. GETBAUD:lxi    H,MEXBAUD    ; valid MEX baud byte?
  513.     mov    A,H        ;
  514.     ora    L        ;
  515.     jz    GETSPKR        ; nope
  516.     lda    MEXBAUD        ; yep, get the system byte for MEX baud rate
  517.     sta    MSPEED        ; save it
  518.  
  519. GETSPKR:lxi    H,MEXSPKR    ; valid MEX speaker byte?
  520.     mov    A,H        ;
  521.     ora    L        ;
  522.     rz            ; nope
  523.     lda    MEXSPKR        ; yep, get the system byte for MEX speaker volume
  524.     sta    VOLUME        ; save it
  525.  
  526.     ret            ;
  527. ;
  528. ; cold starting MEX. load the baud rate and speaker volume with those values
  529. ; specified by this overlay.
  530. ;
  531. COLDMEX:lda    MSPEED        ; get the initial baud rate
  532.     call    BAUD        ; set it up
  533.     lda    VOLUME        ; get the initial speaker volume
  534.     call    SPEAKER        ; set it up
  535.     ret
  536. ;
  537. ;=============================================================================;
  538. ; IDMSG subroutine                                  ;
  539. ; this subroutine will check whether or not the ID prompt should be displayed ;
  540. ; prior to an error message. If so, the prompt will be displayed.          ;
  541. ;=============================================================================;
  542. ;
  543. IDMSG:    push    H        ; save registers
  544.     push    D        ;
  545.     push    B        ;
  546.     push    PSW        ;
  547.     lda    ERRID        ; ID printed in "call in progress" message?
  548.     cpi    NO        ;
  549.     jz    IDRET        ; nope, then don't!
  550.     mvi    C,PRID        ; yep, then print it!
  551.     call    MEX        ;
  552. IDRET:    pop    PSW        ; restore registers
  553.     pop    B        ;
  554.     pop    D        ;
  555.     pop    H        ;
  556.     ret            ;
  557. ;
  558. ;=============================================================================;
  559. ; CDTEST subroutine                                  ;
  560. ; This routine will test for a carrier detected on the designated modem          ;
  561. ; status line (eithe DCD or DSR, depending on the overlay equates). If a      ;
  562. ; carrier is detect then thus subroutine returns with the CARRY set.          ;
  563. ;=============================================================================;
  564. ;
  565. CDTEST:    mvi    A,0        ; read status register 0
  566.     call    OUTCP        ;
  567.     call    INPSP        ; look at the modem port status register
  568.     ani    DCDLIN        ; is there a carrier?
  569.     rz            ; nope, then return
  570.     stc            ; yep, set the CARRY and return
  571.     ret            ;
  572. ;
  573. ;=============================================================================;
  574. ; SET COMMAND:                                      ;
  575. ;                                          ;
  576. ; This command will allow the user to set a number of hardware dependent      ;
  577. ; functions. At the moment the allowable parameters are:              ;
  578. ;                                          ;
  579. ;    BAUD RATE:    This will allow the baud rate of the current user     ;
  580. ;            port to be changed on the fly. Valid baud rates       ;
  581. ;            are 300, 600, 1200, 19200.                       ;
  582. ;                                          ;
  583. ;    SPEAKER VOLUME:    This will allow the user to change the volume of      ;
  584. ;            the speaker of the Hayes Smartmodem. Valid volumes    ;
  585. ;            are OFF = speaker is always off, HALF = speaker          ;
  586. ;            is on until carrier is detected, FULL = speaker          ;
  587. ;            is always on.                          ;
  588. ;                                          ;
  589. ;    usage:                                      ;
  590. ;                                          ;
  591. ;            SET BAUD 9600                          ;
  592. ;            SET SPEAKER OFF                          ;
  593. ;                                          ;
  594. ;=============================================================================;
  595. ;
  596. SETCMD:    call    GETARG        ; any arguments?
  597.     jc    SHWALL        ; if not, go display set parmeters
  598.     LXI    D,CMDTBL
  599.     MVI    C,LOOKUP
  600.     CALL    MEX        ;parse argument
  601.     PUSH    H        ;save any parsed argument adrs on stack
  602.     RNC            ;if we have one, return to it
  603.     POP    H        ;oops, input not found in table
  604.     jmp    SETERR        ;
  605. ;
  606. ; Argument table (note last character of set parameter MUST have the MSB
  607. ; turned on. MEX uses this as a flag for the end-of-parameter).
  608. ;
  609. CMDTBL:    DB    '?'+80H            ; help
  610.     DW    SETHELP
  611.     DB    'BAU','D'+80H        ; "set baud"
  612.     DW    SETBAUD
  613.     DB    'SPEAKE','R'+80H    ; "set speaker"
  614.     DW    SETSPKR
  615.     DB    0            ;<<=== table terminator
  616. ;
  617. ;=============================================================================;
  618. ; "SET" command (equates to a "SHOW ALL" command)                  ;
  619. ;=============================================================================;
  620. ;
  621. SHWALL:    call    NEWLINE        ; start off with a newline character
  622.     call    BOLD        ; bold the console output
  623.     call    SHWBAUD        ; show the current baud rate
  624.     call    SHWSPKR        ; show the current speaker volume
  625.     call    UNBOLD        ; unbold the console output
  626.     call    NEWLINE        ; terminate with a newline character
  627.     ret            ;
  628. ;
  629. ;=============================================================================;
  630. ; "SET ?" command (output HELP message to console)                  ;
  631. ;=============================================================================;
  632. ;
  633. SETHELP:lda    SCRTST        ; cursor control ability?
  634.     cpi    NO        ;
  635.     cnz    CLRSCN        ; yep, then clear the screen
  636.     mvi    C,ILP        ; print out help message to console
  637.     call    MEX        ;
  638.     db    CR,LF
  639.     db    'SET BAUD ',0
  640.     call    BOLD
  641.     mvi    C,ILP
  642.     call    MEX
  643.     db    '<baud-rate>',CR,LF,0
  644.     call    UNBOLD
  645.     lda    SMODEM        ; got a Smartmodem?
  646.     cpi    NO        ;
  647.     jz    NOSM01        ; nope, then don't show "SET SPEAKER"
  648.     call    UNBOLD
  649.     mvi    C,ILP
  650.     call    MEX
  651.     db    'SET SPEAKER ',0
  652.     call    BOLD
  653.     mvi    C,ILP
  654.     call    MEX
  655.     db    '<volume>',CR,LF,0
  656. NOSM01:    mvi    C,ILP
  657.     call    MEX
  658.     db    CR,LF
  659.     db    'Baud rate is one of:',CR,LF,0
  660.     call    UNBOLD
  661.     mvi    C,ILP
  662.     call    MEX
  663.     db    '300 600 1200 19200',CR,LF
  664.     db    CR,LF,0
  665.     lda    SMODEM        ; got a Smartmodem?
  666.     cpi    NO        ;
  667.     jz    NOSM02        ; nope, then don't show volume value
  668.     call    BOLD
  669.     mvi    C,ILP
  670.     call    MEX
  671.     db    'Volume is one of:',CR,LF,0
  672.     call    UNBOLD
  673.     mvi    C,ILP
  674.     call    MEX
  675.     db    'OFF     : Smartmodem speaker is always off',CR,LF
  676.     db    'HALF    : Smartmodem speaker is on until carrier detect',CR,LF
  677.     db    'FULL    : Smartmodem speaker is always on',CR,LF
  678.     db    CR,LF,0
  679. NOSM02:    ret            ;
  680. ;
  681. ;=============================================================================;
  682. ; "SET BAUD" command                                  ;
  683. ;=============================================================================;
  684. ;
  685. SETBAUD:MVI    C,PARSBD    ;nope, function code: parse a baudrate
  686.     CALL    MEX        ;let MEX look up code
  687.     JC    BAUDERR        ;jump if invalid code
  688.     CALL    BAUD        ;no, try to set it
  689.     JC    BAUDERR        ;if not one of ours, bomb out
  690.     call    NEWLINE        ;show the current baud rate
  691.     call    SHWBAUD        ;
  692.     ret            ;
  693. ;
  694. ;=============================================================================;
  695. ; "SHOW BAUD" command                                  ;
  696. ;=============================================================================;
  697. ;
  698. SHWBAUD:mvi    C,ILP        ; nope, then display current baud rate
  699.     call    MEX        ;
  700.     db    'Modem baud rate is set to ',0
  701.     lda    MSPEED        ; get current baud rate
  702.     mvi    C,PRBAUD    ; let MEX print it
  703.     call    MEX
  704.     call    NEWLINE        ; terminate with newline character
  705.     ret
  706. ;
  707. ;=============================================================================;
  708. ; BAUD subroutine                                  ;
  709. ; This subroutine will set the baud of the current modem port. The new baud   ;
  710. ; rate is passed in the A register, and is also stored in the MEX parameter   ;
  711. ; page (MSPEED), and the MEX system reserved byte (MEXBAUD). If the new baud  ;
  712. ; rate specified is either illegal or not supported, this subroutine returns  ;
  713. ; with the CARRY set.                                  ;
  714. ;=============================================================================;
  715. ;
  716. BAUD:    PUSH    H        ;don't alter anybody
  717.     PUSH    D
  718.     PUSH    B
  719.  
  720.     MOV    E,A        ;MSPEED code to DE
  721.     MVI    D,0
  722.  
  723.     LXI    H,BAUDTBL    ; nope, then fine offset into table
  724.     DAD    D
  725.     MOV    A,M        ;fetch code
  726.     ORA    A        ;0? (means unsupported code)
  727.     jz    BADBAUD        ;yep, show it!
  728.     PUSH    PSW        ;no, set the rate
  729.     mvi    A,0        ; setup control register 0
  730.     call    OUTCP        ;
  731.     mvi    A,0        ;
  732.     call    OUTCP        ;
  733.     mvi    A,1        ; setup control register 1
  734.     call    OUTCP        ;
  735.     mvi    A,0        ;
  736.     call    OUTCP        ;
  737.     mvi    A,2        ; setup control register 2
  738.     call    OUTCP        ;
  739.     mvi    A,0        ;
  740.     call    OUTCP        ;
  741.     mvi    A,3        ; setup control register 3
  742.     call    OUTCP        ;
  743.     mvi    A,0C1H        ; Rx 8 bits, Rx enable
  744.     call    OUTCP        ;
  745.     mvi    A,4        ; setup control register 4
  746.     call    OUTCP        ;
  747.     pop    PSW        ; clock for baud rate, 1 stop bit, no parity
  748.     call    OUTCP        ;
  749.     mvi    A,5        ; setup control register 5
  750.     call    OUTCP        ;
  751.     mvi    A,0EAH        ; DTR on, Tx 8 bits, no break, Tx enable, RTS on
  752.     call    OUTCP        ;
  753.     mvi    A,6        ; setup control register 6
  754.     call    OUTCP        ;
  755.     mvi    A,0        ;
  756.     call    OUTCP        ;
  757.     mvi    A,7        ; setup control register 7
  758.     call    OUTCP        ;
  759.     mvi    A,0        ;
  760.     call    OUTCP        ;
  761.     MOV    A,E        ; get MEX format baud rate
  762.     STA    MSPEED        ; store in MEX
  763.     lxi    H,MEXBAUD    ; valid MEX baud byte in system page?
  764.     mov    A,H        ;
  765.     ora    L        ;
  766.     mov    A,E        ;
  767.     jz    NOMEXB        ; nope
  768.     STA    MEXBAUD        ; store it in the system byte for MEX baud rate
  769. NOMEXB:    ORA    A        ; return no-errors
  770.     jmp    BDEXIT        ;
  771.  
  772. BADBAUD:stc            ; set CARRY to show bad baud rate specified
  773.  
  774. BDEXIT:    POP    B
  775.     POP    D
  776.     POP    H
  777.     RET
  778. ;
  779. ; this is the baud rate converstion table. The MEX format baud rate value is
  780. ; used as an offset into this table. The grabbed value is the Interfacer 4
  781. ; mode register format containing the new baud rate.
  782. ;
  783. BAUDTBL:DB    0        ;110 (not supported)
  784.     DB    BD300        ;300
  785.     DB    0        ;450 (not supported)
  786.     DB    BD600        ;600
  787.     DB    0        ;710 (not supported)
  788.     DB    BD1200        ;1200
  789.     DB    0        ;2400 (not supported)
  790.     DB    0        ;4800 (not supported)
  791.     DB    0        ;9600 (not supported)
  792.     DB    BD19200        ;19200
  793. ;
  794. ;=============================================================================;
  795. ; "SET SPEAKER" command                                  ;
  796. ;=============================================================================;
  797. ;
  798. SETSPKR:lda    SMODEM        ; got a Smartmodem?
  799.     cpi    NO        ;
  800.     jz    SETERR        ; nope, then show a SET error
  801.  
  802.     mvi    C,SBLANK    ; yep, then scan for volume argument
  803.     call    MEX
  804.     jc    SPKRERR        ; if no argument, let user know
  805.     lxi    D,SPKTBL    ; parse the argument
  806.     mvi    C,LOOKUP
  807.     call    MEX        ; parse argument
  808.     jc    SPKRERR        ; bad volume argument
  809.  
  810.     mov    A,L        ; store the new speaker volume
  811.     call    SPEAKER        ; set the Smartmodem speaker volume
  812.     call    NEWLINE        ; show the new speaker volume
  813.     call    SHWSPKR        ;
  814.     ret            ;
  815. ;
  816. ; speaker table for MEX table search
  817. ;
  818. SPKTBL:    db    'OF','F'+80H    ; turn speaker off keyword
  819.     db    OFF,OFF        ; Smartmodem ATM code for it
  820.     db    'HAL','F'+80H    ; turn speaker off after carrier detect keyword
  821.     db    HALF,HALF    ; Smartmodem ATM code for it
  822.     db    'FUL','L'+80H    ; turn speaker on keyword
  823.     db    FULL,FULL    ; Smartmodem ATM code for it
  824.     db    0        ; argument table terminator
  825. ;
  826. ;=============================================================================;
  827. ; "SHOW SPEAKER" command                              ;
  828. ;=============================================================================;
  829. ;
  830. SHWSPKR:lda    SMODEM        ; got a Smartmodem?
  831.     cpi    NO        ;
  832.     rz            ; nope, then don't show speaker volume
  833.  
  834.     mvi    C,ILP        ; yep, then show the speaker volume
  835.     call    MEX        ;
  836.     db    'Smartmodem speaker ',0
  837.     mvi    C,ILP        ;
  838.     lda    VOLUME        ;
  839.     cpi    OFF        ; speaker always off
  840.     jz    SPKOFF        ;
  841.     cpi    HALF        ; speaker on until carrier detect
  842.     jz    SPKHALF        ;
  843.     cpi    FULL        ; speaker always on
  844.     jz    SPKFULL        ;
  845. SPKUNKN:call    MEX        ; speaker volume status unknown
  846.     db    'volume status not known',CR,LF,0
  847.     ret            ;
  848. SPKOFF:    call    MEX        ; speaker is turned off
  849.     db    'is always turned off',CR,LF,0
  850.     ret            ;
  851. SPKHALF:call    MEX        ; speaker is set to half
  852.     db    'is turned on until carrier detected',CR,LF,0
  853.     ret            ;
  854. SPKFULL:call    MEX        ; speaker is set to full
  855.     db    'is always turned on',CR,LF,0
  856.     ret            ;
  857. ;
  858. ;=============================================================================;
  859. ; SPEAKER subroutine                                  ;
  860. ; This subroutine will set the Smartmodem speaker to the requested volume.    ;
  861. ; The new volume value is passed in the A register, and is also stored in the ;
  862. ; MEX parameter page (VOLUME), and the MEX system reserved byte (MEXSPKR).    ;
  863. ;=============================================================================;
  864. ;
  865. SPEAKER:push    H        ; save registers
  866.     push    D        ;
  867.     push    B        ;
  868.     mov    E,A        ; save the new speaker volume
  869.     
  870.     lda    SMODEM        ; got a Smartmodem?
  871.     cpi    NO        ;
  872.     jz    SPKRET        ; nope, then don't change the speaker volume
  873.  
  874.     mov    A,E        ; restore the new speaker volume
  875.     sta    VOLUME        ; store the current volume for MEX
  876.     lxi    H,MEXSPKR    ; valid MEX speaker byte in system page?
  877.     mov    A,H        ;
  878.     ora    L        ;
  879.     mov    A,E        ;
  880.     jz    NOMEXS        ; nope
  881.     sta    MEXSPKR        ; store the current volume in reserved byte
  882.  
  883. NOMEXS:    call    SNDESC        ; send the Smartmodem escape seq. if need be
  884.     call    SNDATM        ; send the Smartmodem speaker volume code
  885.     call    SNDATO        ; send the Smartmodem on-line code if need be
  886.  
  887. SPKRET:    pop    B        ; restore registers
  888.     pop    D        ;
  889.     pop    H        ;
  890.     ret
  891. ;
  892. ;=============================================================================;
  893. ; xxxERR subroutines                                  ;
  894. ; These routines blapp out error messages on the console if the user somehow  ;
  895. ; screwed up the SET command line (bad syntax, or bad keyword values).        ;
  896. ;=============================================================================;
  897. ;
  898. SETERR:    call    IDMSG        ;print ID prompt if need be
  899.     MVI    C,ILP        ;inline print
  900.     CALL    MEX        ;
  901.     DB    '++ bad SET parameter specified ++',BELL,CR,LF,0
  902.     RET
  903. ;
  904. BAUDERR:call    IDMSG        ;print ID prompt if need be
  905.     MVI    C,ILP        ;inline print
  906.     CALL    MEX        ;
  907.     DB    '++ bad baud rate specifed ++',BELL,CR,LF,0
  908.     RET
  909. ;
  910. SPKRERR:call    IDMSG        ;print ID prompt if need be
  911.     MVI    C,ILP        ;inline print
  912.     CALL    MEX        ;
  913.     DB    '++ bad speaker volume specifed ++',BELL,CR,LF,0
  914.     RET
  915. ;
  916. ;=============================================================================;
  917. ; SNDSEC subroutine                                  ;
  918. ; This subroutine will place the Smartmodem in command state. If a carrier    ;
  919. ; is detected, the Smartmodem escape sequence is sent, sandwiched between     ;
  920. ; two guard time delays. An initial null is sent just incase we are in the    ;
  921. ; "just CONNECTed" case (IE: Smartmodem has connected to target computer,     ;
  922. ; but Morrow hasn't sent anything yet). If there is no carrier, then this   ;
  923. ; routine merely returns.                              ;
  924. ;=============================================================================;
  925. ;
  926. SNDESC:    call    CDTEST        ; check for call in progress
  927.     rnc            ; nope, then return
  928.     lxi    H,SMNULL    ; yep, send a null (just CONNECTed case)
  929.     call    SNDLIN        ;
  930.     mvi    B,12        ; yep, goto command mode
  931.     mvi    C,TIMER        ; wait 1.2 seconds
  932.     call    MEX        ;
  933.     lxi    H,SMESCAP    ; send '+++'
  934.     call    SNDLIN        ;
  935.     mvi    B,12        ; wait 1.2 seconds
  936.     mvi    C,TIMER        ;
  937.     call    MEX        ;
  938.     call    EATCODE        ; eat result code
  939.     ret            ;
  940. ;
  941. ;=============================================================================;
  942. ; SNDCAN subroutine                                  ;
  943. ; This subroutine will send the CANCEL character to the target computer          ;
  944. ; system. The primary use of this subroutine is to cancel the Smartmodem      ;
  945. ; escape sequence sent to the target system to place the Smartmodem in          ;
  946. ; command state. At the target computer end, there is an un-terminated          ;
  947. ; command ("+++") that should not be executed.                      ;
  948. ;=============================================================================;
  949. ;
  950. SNDCAN:    lda    CANCHR        ; get the CANCEL character
  951.     sta    CANMSG        ; store in the CANCEL character message
  952.     lxi    H,CANMSG    ; get the CANCEL character message address
  953.     call    SNDLIN        ; send it
  954.     ret            ;
  955. ;
  956. ;=============================================================================;
  957. ; SNDATM subroutine                                  ;
  958. ; This routine will send the Smartmodem code to set the speaker volume          ;
  959. ;=============================================================================;
  960. ;
  961. SNDATM:    lxi    H,ATMCODE    ; send 'ATM'
  962.     call    SNDLIN        ;
  963.     lxi    H,VOLUME    ; send the volume code
  964.     call    SNDLIN        ;
  965.     call    EATCODE        ; eat result code
  966.     ret            ;
  967. ;
  968. ;=============================================================================;
  969. ; SNDATO subroutine                                  ;
  970. ; This subroutine will send the code to place the Smartmodem back to on-line  ;
  971. ; state ONLY if a carrier is detected. If no carrier is detected, then this   ;
  972. ; subroutine merely returns.                              ;
  973. ;=============================================================================;
  974. ;
  975. SNDATO:    call    CDTEST        ; check for call in progess
  976.     rnc            ; nope, then return
  977.     lxi    H,ATOCODE    ; yep, then send 'ATO' (goto on-line mode)
  978.     call    SNDLIN        ;
  979.     call    EATCODE        ; eat result code
  980.     call    SNDCAN        ; send the cancel character (cancel SNDESC)
  981.     ret            ;
  982. ;
  983. ;=============================================================================;
  984. ; EATCODE subroutine                                  ;
  985. ; This subroutine will eat all the characters recieved from the modem until   ;
  986. ; a 100 ms "quiet" period is detected (used to eat Smartmodem result codes).  ;
  987. ; The initial delay is for the Smartmodem result code turn-around time).      ;
  988. ;=============================================================================;
  989. ;
  990. EATCODE:mvi    B,2        ; wait 200 ms for Smartmodem turn-around
  991.     mvi    C,TIMER        ;
  992.     call    MEX        ;
  993. EATCHAR:mvi    C,INMDM        ; eat a character
  994.     call    MEX        ;
  995.     jnc    EATCHAR        ; if more, then eat another character
  996.     ret            ; otherwise return
  997. ;
  998. ;=============================================================================;
  999. ; GETARG subroutine                                  ;
  1000. ; This subroutine will scan the input stream for an argument. If no argument  ;
  1001. ; present, then this subroutine returns with the CARRY set              ;
  1002. ;=============================================================================;
  1003. ;
  1004. GETARG:    mvi    C,SBLANK    ; scan input stream for <key-word>
  1005.     call    MEX        ;
  1006.     ret            ; and simply return
  1007. ;
  1008. ;=============================================================================;
  1009. ; EATARG subroutine                                  ;
  1010. ; This subroutine will eat (throw away) the remaining characters in the          ;
  1011. ; current argument. This is an aid for other routines which do not need to    ;
  1012. ; (and thus do not) check the entire argument for a unique match to be made   ;
  1013. ; (EG: "SET PORT C" and "SET PORT CONSOLE" will do the same thing, execept    ;
  1014. ; the SBLANK MEX function will see the next "argument" as being "ONSOLE"      ;
  1015. ; opposed to the line terminator).                          ;
  1016. ;=============================================================================;
  1017. ;
  1018. EATARG:    mvi    C,LKAHED    ; look ahead to next character in command line
  1019.     call    MEX        ;
  1020.     rc            ; return if done (burp)
  1021.     cpi    ' '        ; is it a blank?
  1022.     rz            ; yep, then we've finished eating the argument
  1023.     mvi    C,GNC        ; nope, eat the next character in command line
  1024.     call    MEX        ;
  1025.     jmp    EATARG        ; check the next character in command line
  1026. ;
  1027. ;=============================================================================;
  1028. ; NEWLINE subroutine                                  ;
  1029. ; This subroutine will send a newline character (CR-LF pair) to the console   ;
  1030. ;=============================================================================;
  1031. ;
  1032. NEWLINE:mvi    C,ILP        ; output a newline character to console
  1033.     call    MEX        ;
  1034.     db    CR,LF,0        ;
  1035.     ret            ;
  1036. ;
  1037. ;=============================================================================;
  1038. ; SNDLIN subroutine                                  ;
  1039. ; This routine will send a string to the modem port. Works similar to the     ;
  1040. ; BDOS 9 function. The string start address is in the HL register pair, and   ;
  1041. ; the end-of-string character is set to EOS.                      ;
  1042. ;=============================================================================;
  1043. ;
  1044. SNDLIN:    mvi    C,SNDRDY    ; is modem ready to read another character?
  1045.     call    MEX        ;
  1046.     jnz    SNDLIN        ; nope, wait for it
  1047.     mov    A,M        ; yep, get next character to send to modem
  1048.     cpi    EOS        ; end-of-string character?
  1049.     rz            ; yep, then return
  1050.     mov    B,A        ; nope, get the next character to send
  1051.     mvi    C,SNDCHR    ;
  1052.     call    MEX        ; send it!
  1053.     inx    H        ; bump up the string point
  1054.     jmp    SNDLIN        ; send the next character
  1055. ;
  1056. ;=============================================================================;
  1057. ; Smartmodem codes to do what we want it do (for "SNDATx" routines)          ;
  1058. ;=============================================================================;
  1059. ;
  1060. SMNULL:    db    NULL,EOS    ; null for justed CONNNECTed case
  1061. SMESCAP:db    '+++',EOS    ; Smartmodem code for goto command state
  1062. CANMSG:    db    '?',EOS        ; cancel character message string
  1063. ATMCODE:db    'ATM',EOS    ; Smartmodem code for speaker volume
  1064. VOLUME:    db    MD$SPKR,CR,EOS    ; initial speaker volume
  1065. ATOCODE:db    'ATO',CR,EOS    ; Smartmodem code for goto on-line state
  1066. ;
  1067. ;=============================================================================;
  1068. ; Modem input (get a character or status) driver                  ;
  1069. ;=============================================================================;
  1070. ;
  1071. INPSP:    MVI    A,SPORT        ; get modem status
  1072.     JMP    INP1
  1073. INPDP:    MVI    A,DPORT        ; get a character from the modem
  1074.     JMP    INP1        ;
  1075.  
  1076. INP1:    PUSH    B        ; save BC register pair
  1077.     MOV    C,A        ; save port offset
  1078.     mvi    A,BASE        ; get the base port
  1079.     ADD    C        ; add offset for desired port (data/status)
  1080.     STA    INP2+1        ; store for IN command
  1081. INP2:    IN    0        ; input data/status
  1082.     POP    B        ; restore BC register pair
  1083.     RET            ; and return
  1084. ;
  1085. ;=============================================================================;
  1086. ; Modem output (put a character or command) driver                  ;
  1087. ;=============================================================================;
  1088. ;
  1089. OUTDP:    push    B        ; save the BC register pair
  1090.     mvi    C,DPORT        ; put a character to the modem
  1091.     jmp    OUT1        ;
  1092. OUTCP:    push    B        ; save the BC register pair
  1093.     mvi    C,CPORT        ; change modem control register
  1094.     jmp    OUT1        ;
  1095.  
  1096. OUT1:    mov    B,A        ; save the output character
  1097.     mvi    A,BASE        ; get the base port address
  1098.     ADD    C        ; add offset for desired port (data/ctrl)
  1099.     sta    OUT2+1        ; store for OUT command
  1100.     mov    A,B        ; restore the output character
  1101. OUT2:    out    0        ; send it (or change mode/control port)
  1102.     pop    B        ; restore the BC register pair
  1103.     ret            ; return
  1104.  
  1105.     end
  1106.