home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-pm22.asm < prev    next >
Assembly Source File  |  1994-07-13  |  38KB  |  1,361 lines
  1.     Title    'MEX overlay for the PMMI version 2.2'
  2. ;
  3. ; Ignore the Title error message if using ASM.
  4. ;
  5. REV    equ    22        ; overlay revision number
  6. LVL    equ    'c'        ; overlay level ( as in Revision 2.2a )
  7. ;
  8. ; MEX PMMI OVERLAY VERSION 1.0: written 04/27/84            by Ron Fowler
  9. ;
  10. ;  "   "      "       "    2.0: generally rewritten 9/18/84 by Fred M. Spinner
  11. ;  "   "      "       '    2.1: rewritten 09/27/84 by Bill Norris
  12. ;  "   "      "       "    2.2:     "     10/30/84 by Bill Norris
  13. ;
  14. ;
  15. ; Version 2.2 notes:        Added 'SET EXTRA' command.  This is a toggle
  16. ;                  that allows you to see on the console when
  17. ;                  certain overlay functions are invoked.
  18. ;                Corrected a minor bug in the clear screen and
  19. ;                  clear to end of screen functions.
  20. ;                Added 15 to SET PPS command.
  21. ;                Added SET ONLINE ( SET OFFHOOK synonym )
  22. ;                OFF-HOOK and ON-HOOK have been changed from
  23. ;                  scattered in-line calls to subroutines.
  24. ;                Renamed SET FIDGET to SET ICD (intercall delay)
  25. ;                Renamed SET IDG    to SET IDD (interdigit delay)
  26. ;                The default PMMI base port was changed to 80h
  27. ;                  in version 2.1 due to conflicts with several
  28. ;                  disk controller boards.  If your PMMI is not
  29. ;                  addressed at this port, just use the SET BASE
  30. ;                  command (and CLONE) if you don't want to edit
  31. ;                  and re-assemble this file.
  32. ;                Speeded up keyboard abort (^X and ^C). ^S also
  33. ;                  accepted here (during dialing of a number).
  34. ;                Phone number '#' is replaced at dial time from
  35. ;                  the keyboard.
  36. ;
  37. ;
  38. ; Version 2.1 notes:        Unifies scattered PMMI I/O; allows modification
  39. ;                  of the PMMI base port with SET BASE command.
  40. ;                No PMMI I/O is done in-line.  It is all done
  41. ;                  using subroutine calls.  This should make all
  42. ;                  modifications simpler (including future
  43. ;                  changes to support MEX 2.x).
  44. ;                Base port address is printed in signon message.
  45. ;                SET FIDGET added (delay between calls).
  46. ;                BASE/FIDGET changes are preserved through CLONEs.
  47. ;                Uses BDOS 6 to force BUSY instead of using hard
  48. ;                coded keyboard I/O for the CTRLX function. (See
  49. ;                description in Version 2.0 notes below).
  50. ;
  51. ;
  52. ; Version 2.0 9/18/84:  Numerous bugs repaired.  The offhook command
  53. ; now actually takes the modem off hook.  The DTR bytes were swapped
  54. ; in 1.1 so that baud rates over 300 would barf.  This has been repaired
  55. ; The SET MODE command is no longer available.  Use SET ORIG, ORG, or
  56. ; ORIGINATE and SET ANS or ANSWER to switch modes.  The actual routine
  57. ; to switch modes has been re-written from scratch, also.  Overlay version
  58. ; message more verbose (better looking, also) now.  If your know your  
  59. ; keyboard (terminal)'s Status and Data Port and also know the value
  60. ; (bit) to check for for keyboard input, you can also implement the CTRLX
  61. ; feature which is handy to have if you know a number is busy and you
  62. ; want to call the next, etc. without further delays.  The keyboard info
  63. ; goes under KSTAT, KPORT, KBIT, and KVAL which mean Keyboard/Terminal status 
  64. ; port, Keyboard data port, AND bit to status input, and value to check for
  65. ; after status is ANDed, respectively.   Set CTRLX to YES if you have
  66. ; this information and want to use this feature, or set it to NO to use
  67. ; the standard MEX keyboard trap.
  68. ;
  69. ;                Fred M. Spinner
  70. ;
  71. ;
  72. ; (V1.1) 05/17/84 (Jim Byram) : Small bugs repaired.  Answer-mode
  73. ; bit (ANBIT) and originate-mode bit (ORBIT) were reversed; fixed
  74. ; SET MODE help message.
  75. ;
  76. ; This is a MEX overlay file for the PMMI modem.  You can use it as
  77. ; a model for designing your own modem overlay (or you can use any
  78. ; existing MDM7 overlay, if available).
  79. ;
  80. ; If you use this as a template for writing your own overlay, and
  81. ; distribute it to others, please pare down these comments as much
  82. ; as possible (to keep the overlays small). I'll maintain this file
  83. ; with as many notes and references as possible, but this will hope-
  84. ; fully be the only "big" overlay.
  85. ;
  86. ; There are advantages to recoding your overlay to conform to the
  87. ; techniques presented here: MEX 2.0 will likely have a much simpler
  88. ; overlay structure; if you stick to the label names and coding
  89. ; suggestions used here, you'll easily be able to follow the overlay
  90. ; upgrade instructions when MEX 2.0 hits the streets. Also, you can
  91. ; make use of the MEX service processor to write a very versatile
  92. ; SET command (as done here).
  93. ;
  94. ; Note that all overlays may freely use memory up to 0CFFH.  If your
  95. ; overlay must work with the MEX Smartmodem overlay (MXO-SMxx.ASM),
  96. ; the physical modem overlay should terminate by 0AFFH.
  97. ;
  98. ; For purposes of example, this is a "full-featured" MEX overlay.  In
  99. ; practice, your overlay may be much simpler (all that is really re-
  100. ; quired is the modem I/O code; fancy stuff like the SET command, and
  101. ; even the disconnect routine, may be left open.  You will need DIAL
  102. ; code, though, unless your modem doesn't support autodialing).
  103. ;
  104. ;------------------------------------------------------------
  105. ;
  106. ; Misc equates
  107. ;
  108. NO    equ    0
  109. YES    equ    0FFh
  110. TPA    equ    100h
  111. CR    equ    13
  112. LF    equ    10
  113. BS    equ    8
  114. TAB    equ    9
  115. ESC    equ    27
  116. CTRLX    equ    YES        ;YES, if use ^X for fake "BUSY"
  117. CONTX    equ    'X'-40h
  118.  
  119.  
  120. ;
  121. ; Equates used only by PMMI routines grouped together here.
  122. ;
  123. ;
  124. ; PMMI port definitions
  125. ;
  126. PORT    equ    080h        ;PMMI base port (data or status)
  127.                 ; PORT now also used by NITMOD.
  128.  
  129. MODCT1    equ    0        ;modem control port (added to base port).
  130. MODDAT    equ    MODCT1+1    ;modem data port      "
  131. BAUDRP    equ    MODCT1+2    ;modem baud rate port "
  132. MODCT2    equ    MODCT1+3    ;modem status port    "
  133. ;
  134. ; PMMI bit definitions
  135. ;
  136. MDRCVB    equ    02h        ;modem receive bit (DAV)
  137. MDRCVR    equ    02h        ;modem receive ready
  138. MDSNDB    equ    01h        ;modem send bit
  139. MDSNDR    equ    01h        ;modem send ready bit
  140. ;
  141. ; 
  142. CTSMSK    equ    4        ;mask for CTS bit
  143. BRKMSK    equ    0FBh        ;mask to set break
  144. PARMSK    equ    0CFh        ;mask to remove parity bits
  145. OPARIT    equ    00h        ;odd-parity bits
  146. EPARIT    equ    20h        ;even-parity bits
  147. NPARIT    equ    10h        ;no-parity bits
  148. MODEMK    equ    0FCh        ;mode mask
  149. ANMODE    equ    1Eh        ;answer mode
  150. ANBIT    equ    2        ;answer-mode bit
  151. ORIGMD    equ    1Dh        ;originate mode
  152. ORBIT    equ    1        ;originate-mode bit
  153. WTCTS    equ    150        ;number of seconds (x5) to wait for the
  154.                 ;computer to answer after PMMI auto-dial
  155.                 ;100=20 sec, 150=30 sec, 255=51 sec.
  156.                 ;any number 0-255 acceptable
  157. ;
  158. ;    
  159. ; Modem control command words
  160. ;
  161. BRKMASK    equ    0        ;tele line on hook (break while dialing)
  162. CLEAR    equ    3Fh        ;idle mode
  163. DTMSK    equ    1        ;dial tone mask
  164. MAKEM    equ    1        ;tele line make (off hook)
  165. RBLMT    equ    35        ;7 seconds to wait til no-ring-heard msg
  166. RBWAIT    equ    50        ;5 second delay before redialing PMMI
  167. SMRWT    equ    15        ;1.5 sec delay before redialing HAYES
  168. TMPUL    equ    80h        ;timer pulses mask bit
  169. TRATE    equ    250        ;value for 0.1 second
  170. ;
  171. ;
  172. ; MEX service processor stuff ... MEX supports an overlay service
  173. ; processor, located at 0D00H (and maintained at this address from
  174. ; version to version).  If your overlay needs to call BDOS for any
  175. ; reason, it should call MEX instead; function calls below about
  176. ; 240 are simply passed on to the BDOS (console and list I/O calls
  177. ; are specially handled to allow modem port queueing, which is why
  178. ; you should call MEX instead of BDOS).  MEX uses function calls
  179. ; above about 244 for special overlay services (described below).
  180. ;
  181. ; Some sophisticated overlays may need to do file I/O; if so, use
  182. ; the PARSFN MEX call with a pointer to the FCB in DE to parse out
  183. ; the name.  This FCB should support a spare byte immediately pre-
  184. ; ceeding the actual FCB (to contain user # information).  If you've
  185. ; used MEX-10 for input instead of BDOS-10 (or you're parsing part
  186. ; of a SET command line that's already been input), then MEX will
  187. ; take care of DU specs, and set up the FCB accordingly.  There-
  188. ; after all file I/O calls done through the MEX service processor
  189. ; will handle drive and user with no further effort necessary on
  190. ; the part of the programmer.
  191. ;
  192. MEX    equ    0D00h        ;address of the service processor
  193. INMDM    equ    255        ;get char from port to A, CY=no more in 100 ms
  194. TIMER    equ    254        ;delay 100ms * reg B
  195. TMDINP    equ    253        ;B=# secs to wait for char, cy=no char
  196. CHEKCC    equ    252        ;check for ^C from KBD, Z=present
  197. SNDRDY    equ    251        ;test for modem-send ready
  198. RCVRDY    equ    250        ;test for modem-receive ready
  199. SNDCHR    equ    249        ;send a character to the modem (after sndrdy)
  200. RCVCHR    equ    248        ;recv a char from modem (after rcvrdy)
  201. LOOKUP    equ    247        ;table search: see CMDTBL comments for info
  202. PARSFN    equ    246        ;parse filename from input stream
  203. BDPARS    equ    245        ;parse baud-rate from input stream
  204. SBLANK    equ    244        ;scan input stream to next non-blank
  205. EVALA    equ    243        ;evaluate numeric from input stream
  206. LKAHED    equ    242        ;get nxt char w/o removing from input
  207. GNC    equ    241        ;get char from input, cy=1 if none
  208. ILP    equ    240        ;inline print
  209. DECOUT    equ    239        ;decimal output
  210. PRBAUD    equ    238        ;print baud rate
  211. ;
  212. ;
  213. CONOUT    equ    2        ;simulated BDOS function 2: console char out
  214. PRINT    equ    9        ;simulated BDOS function 9: print string
  215. INBUF    equ    10        ;input buffer, same structure as BDOS 10
  216. ;
  217.     org    TPA        ;we begin
  218. ;
  219. ;
  220.     ds    3        ;MEX has a JMP START here
  221. ;
  222. ; The following variables are located at the beginning of the program
  223. ; to facilitate modification without the need of re-assembly. They will
  224. ; be moved in MEX 2.0.
  225. ;
  226. PMODEM:    db    YES        ;yes=PMMI modem \ / These 2 locations are not
  227. SMODEM:    db    NO        ;yes=Smartmodem / \ referenced by MEX
  228. TPULSE:    db    'T'        ;T=touch, P=pulse (not referenced by MEX)
  229. CLOCK:    db    55        ;clock speed x .1, up to 25.5 mhz.
  230. MSPEED:    db    1        ;sets display time for sending a file
  231.                 ;0=110    1=300  2=450  3=600  4=710
  232.                 ;5=1200 6=2400 7=4800 8=9600 9=19200
  233. BYTDLY:    db    5        ;default time to send character in
  234.                 ;terminal mode file transfer (0-9)
  235.                 ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  236. CRDLY:    db    5        ;end-of-line delay after CRLF in terminal
  237.                 ;mode file transfer for slow BBS systems
  238.                 ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  239. COLUMS:    db    5        ;number of directory columns
  240. SETFL:    db    YES        ;yes=user-defined SET command
  241. SCRTST:    db    NO        ;yes=if home cursor and clear screen
  242.                 ;routine at CLRSCRN
  243.     db    0        ;was once ACKNAK, now spare
  244. BAKFLG:    db    NO        ;yes=make .BAK file
  245. CRCDFL:    db    YES        ;yes=default to CRC checking
  246.                 ;no=default to Checksum checking
  247. TOGCRC:    db    YES        ;yes=allow toggling of Checksum to CRC
  248. CVTBS:    db    NO        ;yes=convert backspace to rub
  249. TOGLBK:    db    YES        ;yes=allow toggling of bksp to rub
  250. ADDLF:    db    NO        ;no=no LF after CR to send file in
  251.                 ;terminal mode (added by remote echo)
  252. TOGLF:    db    YES        ;yes=allow toggling of LF after CR
  253. TRNLOG:    db    YES        ;yes=allow transmission of logon
  254.                 ;write logon sequence at location LOGON
  255. SAVCCP:    db    YES        ;yes=do not overwrite CCP
  256. LOCNXT:    db    NO        ;yes=local cmd if EXTCHR precedes
  257.                 ;no=not local cmd if EXTCHR precedes
  258. TOGLOC:    db    YES        ;yes=allow toggling of LOCNXTCHR
  259. LSTTST:    db    YES        ;yes=allow toggling of printer on/off
  260.                 ;in terminal mode. Set to no if using
  261.                 ;the printer port for the modem
  262. XOFTST:    db    NO        ;yes=allow testing of XOFF from remote
  263.                 ;while sending a file in terminal mode
  264. XONWT:    db    NO        ;yes=wait for XON after sending CR while
  265.                 ;transmitting a file in terminal mode    
  266. TOGXOF:    db    YES        ;yes=allow toggling of XOFF testing
  267. IGNCTL:    db    NO        ;yes=do not send control characters
  268.                 ;above CTL-M to CRT in terminal mode
  269.                 ;no=send any incoming CTL-char to CRT
  270. EXTRA1:    db    0        ;for future expansion
  271. EXTRA2:    db    0        ;for future expansion
  272. BRKCHR:    db    '@'-40h        ;^@ = Send a 300 ms. break tone
  273. NOCONN:    db    'N'-40h        ;^N = Disconnect from phone line
  274. LOGCHR:    db    'L'-40h        ;^L = Send logon
  275. LSTCHR:    db    'P'-40h        ;^P = Toggle printer
  276. UNSVCH:    db    'R'-40h        ;^R = Close input text buffer
  277. TRNCHR:    db    'T'-40h        ;^T = Transmit file to remote
  278. SAVCHR:    db    'Y'-40h        ;^Y = Open input text buffer
  279. EXTCHR:    db    '^'-40h        ;^^ = Send next character
  280. PRATE:    db    167        ;125=20pps dialing, 250=10pps
  281.     db    0        ;not used
  282. ;
  283. ; Low-level modem I/O routines: this will be replaced with
  284. ; a jump table in MEX 2.0 (you can insert jumps here to longer
  285. ; routines if you'd like ... I'd recommend NOT putting part of
  286. ; a routine in this area, then jumping to the rest of the routine
  287. ; in the non-fixed area; that will complicate the 2.0 conversion)
  288.  
  289. INCTL1:    jmp    iCTL1        ;in modem control port
  290.     db    0,0,0,0,0,0,0
  291.  
  292. OTDATA:    jmp    oDATA
  293.     db    0,0,0,0,0,0,0
  294.  
  295. INPORT:    jmp    iDATA
  296.     db    0,0,0,0,0,0,0
  297.  
  298.  
  299. ; Bit-test routines.  These will be merged with the above
  300. ; routines in MEX 2.0 to provide a more reasonable format
  301. ;
  302. MASKR:    ani MDRCVB        ;bit to test for receive ready
  303.     ret
  304. TESTR:    cpi MDRCVR        ;value of receive bit when ready
  305.     ret
  306. MASKS:    ani MDSNDB        ;bit to test for send ready
  307.     ret
  308. TESTS:    cpi MDSNDR        ;value of send bit when ready
  309.     ret
  310.  
  311. ;
  312. ; Unused area: was once used for special PMMI functions,
  313. ; Now used only to retain compatibility with MDM overlays.
  314. ; You may use this area for any miscellaneous storage you'd
  315. ; like but the length of the area *must* be 12 bytes.
  316. ;
  317.     ds    12
  318. ;
  319. ; Special modem function jump table: if your overlay cannot handle
  320. ; some of these, change the jump to "DS 3", so the code present in
  321. ; MEX will be retained.  Thus, if your modem can't dial, change the
  322. ; JMP PDIAL at DIALV to DS 3, and MEX will print a "not-implemented"
  323. ; diagnostic for any commands that require dialing.
  324. ;
  325. ; DIALV  dials the digit in A. See the comments at PDIAL for specs.
  326. ;
  327. ; DISCV  disconnects the modem
  328. ;
  329. ; GOODBV is called just before MEX exits to CP/M.  If your overlay
  330. ;        requires some exit cleanup, do it here.
  331. ;
  332. ; INMODV is called when MEX starts up; use INMODV to initialize the modem.
  333. ;
  334. ; NEWBDV is used for phone-number baud rates and is called with a baud-rate
  335. ;        code in the A register, value as follows:
  336. ;
  337. ;     A=0:   110 baud       A=1:   300 baud      A=2:   450 baud
  338. ;     A=3:   600 baud       A=4:   710 baud      A=5:  1200 baud
  339. ;     A=6:  2400 baud       A=7:  4800 baud      A=8: 19200 baud
  340. ;
  341. ;        If your overlay supports the passed baud rate, it should store the
  342. ;     value passed in A at MSPEED (107H), and set the requested rate. If
  343. ;     the value passed is not supported, you should simply return (with-
  344. ;     out modifying MSPEED) -or- optionally request a baud-rate from the
  345. ;     user interactively.
  346. ;
  347. ; NOPARV is called at the end of each file transfer; your overlay may simply
  348. ;     return here, or you may want to restore parity if you set no-parity
  349. ;     in the following vector (this is the case with the PMMI overlay).
  350. ;     
  351. ; PARITV is called at the start of each file transfer; your overlay may simply
  352. ;     return here, or you may want to enable parity detection (this is the
  353. ;     case with the PMMI overlay).
  354. ;
  355. ; SETUPV is the user-defined command ... to use this routine to build your own
  356. ;     MEX command, set the variable SETFL (117H) non-zero, and add your SET
  357. ;     code.  You can use the routine presented in the PMMI overlay as a 
  358. ;     guide for parsing, table lookup, etc.
  359. ;
  360. ; SPMENU is provided only for MDM compatibility, and is not used by MEX 1.0 for
  361. ;     any purpose (it will be gone in MEX 2).
  362. ;
  363. ; VERSNV is called immediately after MEX prints its sign-on message at cold
  364. ;     startup -- use this to identify your overlay in the sign-on message
  365. ;     (include overlay version number in the line).
  366. ; BREAKV is provided for sending a BREAK (<ESC>-B in terminal mode).  If your
  367. ;     modem doesn't support BREAK, or you don't care to code a BREAK rou-
  368. ;     tine, you may simply execute a RET instruction.
  369. ;
  370. LOGON:    ds    2        ;needed for MDM compat, not ref'd by MEX
  371. DIALV:    jmp    PDIAL        ;dial digit in A (see info at PDIAL)
  372. DISCV:    jmp    PDISC        ;disconnect the modem
  373. GOODBV:    jmp    DUMMY        ;called before exit to CP/M
  374. INMODV:    jmp    NITMOD        ;initialization. Called at cold-start
  375. NEWBDV:    jmp    PBAUD        ;set baud rate
  376. NOPARV:    jmp    NOPAR        ;set modem for no-parity
  377. PARITV:    jmp    PARITY        ;set modem parity
  378. SETUPV:    jmp    SETCMD        ;SET cmd: jump to a RET if you don't write SET
  379. SPMENV:    ds    3        ;not used with MEX
  380. VERSNV:    jmp    SYSVER        ;Overlay's voice in the sign-on message
  381. BREAKV:    jmp    PBREAK        ;send a break
  382. ;
  383. ; The following jump vector provides the overlay with access to special
  384. ; routines in the main program (retained and supported in the main pro-
  385. ; gram for MDM overlay compatibility). These should not be modified by
  386. ; the overlay.
  387. ;
  388. ; Note that for MEX 2.0 compatibility, you should not try to use these
  389. ; routines, since this table will go away with MEX 2.0 (use the MEX
  390. ; service call processor instead).
  391. ;
  392. ILPRTV:    ds    3        ;replace with MEX function 9
  393. INBUFV:    ds    3        ;replace with MEX function 10
  394. ILCMPV:    ds    3        ;replace with table lookup funct. 247
  395. INMDMV:    ds    3        ;replace with MEX function 255
  396. NXSCRV:    ds    3        ;not supported by MEX (returns w/no action)
  397. TIMERV:    ds    3        ;replace with MEX function 254
  398. ;
  399. ;
  400. ; Clear/screen and clear/end-of-screen. Each routine must use the
  401. ; full 9 bytes alloted (may be padded with nulls).
  402. ;
  403. ; These routines (and other screen routines that MEX 2.0 will sup-
  404. ; port) will be accessed through a jump table in 2.0, and will be
  405. ; located in an area that won't tie the screen functions to the
  406. ; modem overlay (as the MDM format does).
  407. ;
  408.  
  409. CLREOS:    lxi    h,SCRTST
  410.     lxi    d,EOSMSG
  411.     jmp    PRMAYBE
  412.  
  413.  
  414. CLS:    lxi    h,SCRTST
  415.     lxi    d,CLSMSG
  416.     jmp    PRMAYBE
  417.  
  418. ;
  419. ;------------------------------------------------------------
  420. ;
  421. ;    *** END OF FIXED FORMAT AREA ***
  422. ;
  423. ;------------------------------------------------------------
  424. ;
  425.  
  426. ; Data area
  427. ERRFLG:    db    0        ;connection error code
  428. UCTLB:    db    ORIGMD        ;uart-control byte image
  429. BAUDSV:    db    52        ;current baud rate (dflt 300)
  430. MODCTB:    db    07FH        ;modem control byte
  431. INTERD:    db    2        ;inter-digit delay in 100's of ms
  432. PRXTRA:    db    YES        ; Diagnostic prints upon function usage
  433. WTNUM:    db    WTCTS        ;
  434. OFFHK:    db    0        ;
  435.                 ;
  436. BPTAB:    db    '0123456789ABCDEF', 80h
  437. NITBYT:    db    PORT        ; Should be the PMMI base port.  Original port
  438.                 ; is C0 hex.  Recommended alternate is 80 hex.
  439. DIALFLG: db    0        ;
  440. ABOBYT:    db    0        ;
  441. TEMP:    dw    0        ;
  442.  
  443.  
  444. PRMAYBE: mov    a,m
  445.     ora    a
  446.     rz
  447. PRMBOK:    mvi    c,PRINT
  448.     jmp    MEX
  449.  
  450. iCTL1:    mvi    a,MODCT1
  451.     jmp    BPIN
  452. iCTL2:    mvi    a,MODCT2
  453.     jmp    BPIN
  454. iDATA:    mvi    a,MODDAT    ;in modem data port
  455.     jmp    BPIN
  456. iBDRP:    mvi    a,BAUDRP
  457.     jmp    BPIN
  458.  
  459. oCTL1:    push    psw
  460.     mvi    a,MODCT1
  461.     jmp    BPOUT
  462. oCTL2:    push    psw
  463.     mvi    a,MODCT2
  464.     jmp    BPOUT
  465. oDATA:    push    psw        ;out modem data port
  466.     mvi    a,MODDAT
  467.     jmp    BPOUT
  468. oBDRP:    push    psw
  469.     mvi    a,BAUDRP
  470.     jmp    BPOUT
  471.  
  472. BPIN:    push    b
  473.     mov    b,a
  474.     lda    NITBYT
  475.     add    b
  476.     sta    BPINX+1
  477. BPINX:    in    $-$
  478.     pop    b
  479.     ret
  480.  
  481. BPOUT:    push    b
  482.     mov    b,a
  483.     lda    NITBYT
  484.     add    b
  485.     sta    BPOUTX+1
  486.     pop    b
  487.     pop    psw
  488. BPOUTX:    out    $-$
  489.     ret
  490.  
  491.  
  492. ; Modem initialization.  This overlay doesn't do any initialization.
  493. ; (if we did, we'd disconnect a call already in progress).
  494.  
  495. NITMOD:    lda    NITBYT        ; Convert hex byte to ascii nibble.
  496.     rar
  497.     rar
  498.     rar
  499.     rar
  500.     ani    0Fh
  501.     mvi    d,0
  502.     mov    e,a
  503.     lxi    h,BPTAB
  504.     dad    d
  505.     mov    a,m
  506.     sta    BPMSG        ; Store base port in sign-on message.
  507.     mvi    a,LVL
  508.     sta    LEVEL
  509.     ret
  510.  
  511.  
  512. ; PMMI send-break routine
  513. PBREAK:    lda    MODCTB        ;get the last modem control byte
  514.     ani    BRKMSK        ;set the transmit break bit low
  515.     call    oCTL2        ;send it to the modem
  516.     mvi    b,2
  517.     call    TIMERV        ;send a space tone for 200 ms.
  518.     lda    MODCTB        ;get the last modem control byte
  519.     call    oCTL2        ;restore to normal
  520.     lxi    h,PRXTRA
  521.     lxi    d,BRKMSG
  522.     jmp    PRMAYBE
  523.  
  524. BRKMSG:    db    '.break. $'
  525.  
  526.  
  527. ;  Setup PMMI for odd/even parity.
  528. PARITY:    lda    UCTLB        ;send what's in the image byte
  529.     jmp    oCTL1
  530.  
  531.  
  532. ; set no-parity
  533. NOPAR:    lda    UCTLB        ;get uart/modem control byte
  534.     ani    PARMSK        ;reset parity bits
  535.     ori    NPARIT        ;add no-parity bits
  536.     jmp    oCTL1
  537.  
  538.  
  539. ; disconnect the modem
  540. PDISC:    call    HUKONN        ; Hang up
  541.     call    oCTL2        ; clear DAV, ESD, etc
  542.     push    b        ;
  543.     lxi    h,PRXTRA    ;
  544.     lxi    d,DSC1MSG    ;
  545.     call    PRMAYBE        ;
  546.     mvi    b,20        ;wait for PMMI to disconnect (2 sec) %%* 1 to 2
  547.     mvi    c,TIMER        ;0.1 second per timer interval
  548.     call    MEX        ;
  549.     lxi    h,PRXTRA    ;
  550.     lxi    d,DSC2MSG    ;
  551.     call    PRMAYBE        ;
  552.     pop    b        ;
  553.     ret            ;
  554.  
  555. DSC1MSG: db    '.di$'
  556. DSC2MSG: db    'sc. $'
  557.  
  558. ; exit routine
  559. DUMMY:    ret            ;we don't need one
  560. ;
  561. ;
  562. ;------------------------------------------------------------
  563. ;
  564. ;        <PMMI DIALING ROUTINES BEGIN>
  565. ;
  566. ; This is the DIAL routine called by MEX to dial a digit. The digit
  567. ; to be dialed is passed in the A register.  Note that two special
  568. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  569. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  570. ; in the accumulator prior to dialing a number.  Mex will also call
  571. ; dial with 255 in A as an indication that dialing is complete. Thus,
  572. ; the overlay may use these values to "block" the number, holding it
  573. ; in a buffer until it is completely assembled (we don't do this with
  574. ; the PMMI, however; we just dial the digits as they come in).
  575. ;
  576. ; After the 254-start-dial sequence, MEX will call the overlay with
  577. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  578. ; its, and will send each to the DIAL routine un-inspected (some modems,
  579. ; like the Smartmodem, allow special non-numeric characters in the
  580. ; phone number, and MEX may make no assumptions about these). This
  581. ; dialing routine validates digits, and ignores any except 0-9 and
  582. ; comma (uses comma to simulate Smartmodem delay).
  583. ;
  584. ; After receiving the end-dial sequence (255) the overlay must take
  585. ; whatever end-of-dial actions are necessary *including* waiting for
  586. ; carrier at the distant end.  The overlay should monitor the keyboard
  587. ; during this wait (using the MEX keystat service call), and return
  588. ; an exit code to MEX in the A register, as follows:
  589. ;
  590. ;    0 - Carrier detected, connection established
  591. ;    1 - Far end busy (only for modems that can detect this condition)
  592. ;    2 - No answer (or timed out waiting for modem response)
  593. ;    3 - Keyboard abort (^C only: all others should be ignored)
  594. ;    4 - Error reported by modem
  595. ;
  596. ; <No other codes should be returned after an end-dial sequence>
  597. ;
  598. ; The overlay should not loop forever in the carrier-wait routine, but
  599. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  600. ; ms character wait) service call routine.
  601. ;
  602. ; The DIAL routine is free to use any of the registers, but must return
  603. ; the above code after an end-dial sequence
  604. ;
  605. ;
  606. PDIAL:    cpi    254        ;start-dial?
  607.     jz    STDIAL        ;
  608.     cpi    255        ;end-dial
  609.     jz    ENDIAL        ;
  610.                 ;
  611.     push    psw        ;
  612.     mvi    a,7        ;
  613.     sta    DIALFLG        ;
  614.     pop    psw        ;
  615.                 ;
  616. PDIAL1:    cpi    ','        ;smartmodem pause command
  617.     jnz    PDIAL2        ;if not pause, continue
  618.     mvi    b,10        ;delay 1 second
  619.     jmp    TIMOUT        ;
  620.  
  621.  
  622. PDIAL2:    cpi    '#'        ;
  623.     jnz    CKDIG        ;
  624.     mvi    a,BS        ;
  625.     call    PUT1C        ;
  626. PDIAL3:    call    GET1C        ;
  627.     jz    PDIAL3        ;
  628.     call    PUT1C        ;
  629.     jmp    PDIAL1        ;
  630.  
  631.  
  632. CKDIG:    cpi    '9'+1        ; digits are 0-9
  633.     rnc            ; too big...
  634.     sui    '0'        ;
  635.     rc            ; too small....
  636.     jnz    DIALIT        ; just right...
  637.     mvi    a,10        ; convert zero to 10 pulses
  638.  
  639. ; Send a digit to the modem.
  640. DIALIT:    mov    c,a        ; save the digit
  641.     lda    ERRFLG        ; before we try to dial...
  642.     ora    a        ; ...check dialtone error flag
  643.     rnz            ; ...if no DT, exit now
  644.     lda    PRATE        ; value for dial speed
  645.     call    oBDRP        ;
  646.     call    WAITLO        ; wait for timer lo
  647.     call    WAITHI        ; wait for timer hi
  648.  
  649.     call    GET1C        ;
  650. DIAL1:    cpi    3        ; ^C ?
  651.     jz    DIALX        ;
  652.     cpi    24        ; ^X ?
  653.     jz    DIALX        ;
  654.     cpi    19        ; ^S ?
  655.     jnz    DIGLP        ;
  656.  
  657. DIALP:    call    GET1C        ; Wait for a character
  658.     jz    DIALP        ;
  659.     cpi    19        ;
  660.     jmp    DIGLP        ;
  661.                 ;
  662. DIALX:    sta    ABOBYT        ;
  663.  
  664. DIGLP:    lda    ABOBYT        ;
  665.     ora    a        ;
  666.     jnz    DIGLP2        ;
  667.                 ;
  668.     call    HUKOFF        ; Go off-hook
  669.     call    WAITLO        ;
  670.     call    HUKONN        ;
  671.     call    WAITHI        ;
  672. DIGLP2:    dcr    c        ;
  673.     jnz    DIGLP        ; send rest of digit
  674.     lda    ABOBYT        ;
  675.     ora    a        ;
  676.     rnz            ;
  677.                 ;
  678.     call    HUKOFF        ;
  679.     lda    INTERD        ; get inter-digit delay
  680.     mov    b,a        ;
  681.     jmp    TIMOUT        ;
  682.  
  683.  
  684. ; Wait for  negative edge of timer pulse
  685. WAITLO:    call    iBDRP
  686.     ani    TMPUL
  687.     jnz    WAITLO
  688.     ret
  689.  
  690.  
  691. ; Wait for positive edge of timer pulse
  692. WAITHI:    call    iBDRP
  693.     ani    TMPUL
  694.     jz    WAITHI
  695.     ret
  696.  
  697.  
  698. ; Start-dial sequence: disconnect, wait for dial-tone
  699. STDIAL:    xra    a        ; reset error flag
  700.     sta    ERRFLG        ;
  701.     call    PDISC        ; on-hook
  702.     call    HUKOFF        ;
  703.     call    PROFFH        ; (possibly) print .off hook. message
  704.  
  705. ; Wait routine will return with carry set if unable to get dialtone.
  706.     mvi    d,DTMSK        ;dial tone mask
  707.     mvi    e,50        ;waits up to 10 sec. for dial tone
  708.     call    WAIT        ;wait for dial tone
  709.     rnc            ;if dial tone within 10 seconds
  710.  
  711.     sta    ERRFLG        ;(action on error deferred until 
  712.     call    PDISC        ;no tone, hang up
  713.     ret            ;   dialing is completed)
  714.  
  715.  
  716. ; End-dial sequence
  717. ENDIAL:    call    ENDIT        ;close out dialing
  718.     push    psw        ;
  719.     xra    a        ;
  720.     sta    DIALFLG        ;
  721.     sta    ABOBYT        ;
  722.     pop    psw        ;
  723.     ora    a        ;successfully connected?
  724.     rz            ;exit now if so
  725.     push    psw        ;nope, save the error code
  726.     call    PDISC        ;shut down the modem
  727.     pop    psw        ;
  728.     ret            ;
  729.  
  730.  
  731. ENDIT:    lda    ERRFLG        ;no-dialtone error from STDIAL?
  732.     ora    a
  733.     rnz            ;if so, return the error here
  734.     call    OFF        ;go off-hook
  735.     lda    UCTLB        ;get uart/modem control byte
  736.     call    oCTL1        ;send it
  737.     mvi    d,4        ;clear-to-send mask
  738.                 ;
  739.     lda    WTNUM        ;
  740.     mov    e,a        ;
  741.     call    WAIT        ;
  742.     rnc            ;return A=0 if good
  743.                 ;
  744.     cpi    'C'-40h        ;keyboard abort?
  745.     rz            ;if so return it
  746.                 ;
  747.     if    CTRLX        ;
  748.     cpi    1        ;Fake busy?
  749.     rz            ;Return if so
  750.     endif            ;CTRLX
  751.                 ;
  752.     mvi    a,2        ;nope, convert error to "no answer"
  753.     ret            ;
  754.  
  755. ;    <end of PMMI dialing routines>
  756. ;------------------------------------------------------------
  757.  
  758.  
  759. ;    Go Off-Hook
  760. OFF:    lda    BAUDSV        ;set current baud rate
  761.     call    oBDRP        ;
  762.     lda    MODCTB        ;Load current DTR
  763.     call    oCTL2        ;
  764.     call    HUKOFF        ;
  765.     lda    UCTLB        ;
  766.     call    oCTL1        ;
  767.     mvi    b,2        ;wait 200 ms    %%* changed from 1 to 2.
  768.     call    TIMOUT        ;    
  769.     lda    DIALFLG        ;
  770.     ora    a        ;
  771.     jz    PRONLN        ;
  772.     xra    a        ;
  773.     sta    DIALFLG        ;
  774. PRWAIT:    lxi    h,PRXTRA    ;
  775.     lxi    d,WAITMSG    ;
  776.     jmp    PRMAYBE        ;
  777.  
  778. PROFFH:    lxi    h,PRXTRA    ;
  779.     lxi    d,OFFHMSG    ;
  780.     jmp    PRMAYBE        ;
  781.  
  782. PRONLN:    lxi    h,PRXTRA    ;
  783.     lxi    d,ONLNMSG    ;
  784.     jmp    PRMAYBE        ;
  785.  
  786. OFFHMSG: db    '.off-h. $'    ; Force PMMI to on-line status.
  787. ONLNMSG: db    '.on-line. $'    ; Force PMMI to on-line status.
  788. WAITMSG: db    '.wait. $'    ; Force PMMI to   "      " and wait
  789.                 ;  for either a carrier or timeout.
  790.  
  791.  
  792. HUKOFF:    mvi    a,255        ; Go Off-Hook
  793.     sta    OFFHK        ;
  794.     mvi    a,MAKEM        ;
  795.     jmp    oCTL1        ;
  796.  
  797.  
  798. HUKONN:    xra    a        ; Go On-Hook
  799.     sta    OFFHK        ;
  800.     mvi    a,BRKMASK    ;
  801.     jmp    oCTL1        ;
  802.  
  803.  
  804.  
  805.  
  806. ; Time-out routine.  Must be called with mask in D reg. for input at
  807. ; relative port 2 and number of seconds (times 10) in E reg.
  808. WAIT:    mvi    b,2        ; 200 ms
  809.     call    TIMOUT        ; wait for timer to go high then low
  810.     call    iBDRP        ; pmmiaddr+2 (modem status port)
  811.     ana    d        ; (cts or dialtone mask)
  812.     rz            ; active low, so return on 0
  813.  
  814.     if    not CTRLX    ;
  815.     mvi    c,CHEKCC    ;not yet, check for console-abort
  816.     call    MEX        ;abort?
  817.     mvi    a,3        ;set error code 3 if abort active
  818.     stc            ;
  819.     rz            ;return if aborted
  820.     endif            ;not CTRLX
  821.  
  822.     if    CTRLX        ;
  823.     lda    ABOBYT        ;
  824.     ora     a        ;
  825.     jz    WAIT0        ;
  826.     push    psw        ;
  827.     xra    a        ;
  828.     sta    ABOBYT        ;
  829.     pop    psw        ;
  830.     jmp    WAIT1        ;
  831.  
  832. WAIT0:    call    GET1C        ;
  833.     jz    WAITOR        ;
  834.                 ;
  835. WAIT1:    cpi    CONTX        ;'^X?'
  836.     jnz    WAIT2        ;no, check for ^C
  837.     call    GET1C        ;Clear out garbage
  838.     mvi    a,1        ;yes, return fake error code
  839.     stc            ;
  840.     ret            ;
  841. WAIT2:    cpi    3        ;Duplicate MEX ^C trap
  842.     jnz    WAITOR        ;Not ^C, continue
  843.     call    GET1C        ;Clear out garbage
  844.     mvi    a,3        ;"ABORT" error
  845.     stc            ;Yes, pass error 
  846.     ret            ;code and return
  847.     endif            ;CTRLX
  848.  
  849.  
  850. WAITOR:    dcr    e        ;
  851.     jnz    WAIT        ; nope, downcount
  852.     inr    a        ; set error=4 (modem error); cy already set
  853.     ret            ;
  854.  
  855.  
  856. GET1C:    push    h
  857.     push    d
  858.     push    b
  859.     mvi    c,6
  860.     mvi    e,0FFh
  861.     call    5
  862.     pop    b
  863.     pop    d
  864.     pop    h
  865.     ani    7Fh
  866.     ret
  867.  
  868.  
  869. PUT1C:    push    h
  870.     push    d
  871.     push    b
  872.     mvi    c,6
  873.     mov    e,a
  874.     call    5
  875.     pop    b
  876.     pop    d
  877.     pop    h
  878.     ret
  879.  
  880.  
  881. ; Set baud-rate code in A (if supported by your modem overlay).  PMMI
  882. ; supports only five rates, which are validated here. NOTE: this routine
  883. ; (ie, the one vectored through NEWBDV) should update MSPEED with the
  884. ; passed code, but ONLY if that rate is supported by the hardware.
  885. PBAUD:    push    h        ;don't alter anybody
  886.     push    d
  887.     push    b
  888.     mov    e,a        ;code to DE
  889.     mvi    d,0
  890.     lxi    h,BAUDTB    ;offset into table
  891.     dad    d
  892.     mov    a,m        ;fetch code
  893.     ora    a        ;0? (means unsupported code)
  894.     stc            ;return error for STBAUD caller
  895.     jz    PBEXIT        ;exit if so
  896.     call    oBDRP        ;good rate, set it
  897.     sta    BAUDSV        ;save it
  898.     mov    a,e        ;get speed code back
  899.     sta    MSPEED        ;make it current
  900.     call    GETDTR        ;get correct DTR based on baud rate
  901.     sta    MODCTB        ;save the code
  902.     call    CARRCK        ;is a connection in progress?
  903.     jnz    PBEXIT        ;skip this if not
  904.     lda    MODCTB        ;yep, set up DTR
  905.     call    oCTL2
  906.  
  907. PBEXIT:    lxi    h,PRXTRA
  908.     lxi    d,BDSTMSG
  909.     call    PRMAYBE
  910.     pop    b        ;all done
  911.     pop    d
  912.     pop    h
  913.     ret
  914.  
  915. BDSTMSG: db    '.bd-rt. $'
  916.  
  917. ; table of baud rate divisors for supported rates
  918. BAUDTB:    db    142,052,035,026,022    ;110,300,450,610,710
  919.     db    0,0,0,0,0        ;1200,2400,4800,9600,19200
  920.  
  921.  
  922. ; Sign-on message
  923. SYSVER:    lxi    d,LINMSG
  924.     mvi    c,PRINT
  925.     call    MEX
  926.     lxi    d,SOMESG
  927.     mvi    c,PRINT
  928.     call    MEX
  929.     lxi    d,bpmess
  930.     mvi    c,PRINT
  931.     call    MEX
  932. CARRSH:    lxi    d,NOMESG        ;tell about carrier
  933.     call    CARRCK            ;check for it
  934.     mvi    c,PRINT
  935.     cz    CMSG
  936.     cnz    MEX
  937.     lxi    d,LINMSG
  938.     mvi    c,PRINT
  939.     call    MEX
  940.     lxi    d,GRBMSG
  941.     mvi    c,PRINT
  942.     call    MEX
  943.     ret
  944. CMSG:    push    psw
  945.     mvi    c,PRINT
  946.     lxi    d,CARMSG
  947.     call    MEX
  948.     pop    psw
  949.     ret
  950.  
  951.  
  952. SOMESG: db    '* PMMI overlay version - '  
  953.     db    REV/10+'0'
  954.     db    '.'
  955.     db    REV MOD 10+'0'
  956. LEVEL:    db    '   *',CR,LF,'$'
  957. BPMESS:    db    '* Base port = '
  958. BPMSG:    db    'x0 hex.          *'
  959. NLMSG:    db    cr,lf,'$'
  960.  
  961. NOMESG:    db    '* No carrier present.          *$'
  962. CARMSG:    db    '* Carrier IS present.          *$'
  963. LINMSG:    db    CR,LF,'********************************',CR,LF,'$'
  964. GRBMSG:    db    CR,LF,'$'
  965. ;
  966. ;
  967. ; get DTR port value based on baud rate
  968. ;
  969. GETDTR:    lda    BAUDSV
  970.     cpi    52        ;>300?
  971.     mvi    a,05Fh        ;set speed configuration (ARRRRRRGGGGHHHH.)
  972.     rc            ;done if so (Swapped in version 2.0)
  973.     mvi    a,07Fh        ;reset speed config bit (ARRRRRRGGGGGHHHH.)
  974.     ret
  975.  
  976.  
  977. ; check the PMMI for carrier-present (NZ=no)
  978. CARRCK:    call    iBDRP        ;get status byte
  979.     ani    CTSMSK
  980.     rnz
  981.     push    psw
  982.     mvi    a,255
  983.     sta    OFFHK
  984.     pop    psw
  985.     ret
  986.  
  987.  
  988. ; Newline on console
  989. CRLF:    mvi    a,CR
  990.     call    TYPE
  991.     mvi    a,LF        ;fall into TYPE
  992.  
  993.  
  994. ; type char in A on console
  995. TYPE:    push    h        ;save 'em
  996.     push    d
  997.     push    b
  998.     mov    e,a        ;align output character
  999.     mvi    c,CONOUT    ;print via MEX
  1000.     call    MEX
  1001.     pop    b
  1002.     pop    d
  1003.     pop    h
  1004.     ret
  1005.  
  1006.  
  1007. ; strings to clear-to-end-of-screen, and clear-screen
  1008. ; Note: these are dummy strings, not intended to be displayed...
  1009. EOSMSG:    db    ' -clr eos- $'    ;clear to end-of-screen
  1010. CLSMSG:    db    ' -clr all- $'    ;clear whole screen
  1011.  
  1012.  
  1013. ;
  1014. ;------------------------------------------------------------
  1015. ;
  1016. ; The remainder of this overlay implements a very versatile
  1017. ; SET command -- if you prefer not to write a SET for your
  1018. ; modem, you may delete the code from here to the END statement.
  1019. ;
  1020. ;
  1021. ; Control is passed here after MEX parses a SET command.
  1022. ;
  1023. SETCMD:    mvi    c,SBLANK    ;any arguments?
  1024.     call    MEX
  1025.     jc    SETSHO        ;if not, go print out values
  1026.     lxi    d,CMDTBL    ;parse command
  1027.     call    TSRCH        ;from table
  1028.     push    h        ;any address on stack
  1029.     rnc            ;if we have one, execute it
  1030.     pop    h        ;nope, fix stack
  1031. SETERR:    lxi    d,SETEMS    ;print error
  1032.     mvi    c,PRINT
  1033.     call    MEX
  1034.     ret
  1035. ;
  1036. SETEMS:    db    CR,LF,'SET command error',CR,LF,'$'
  1037. ;
  1038. ; SET command table ... note that tables are constructed of command-
  1039. ; name (terminated by high bit=1) followed by word-data-value returned
  1040. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  1041. ; a binary zero.
  1042. ;
  1043. ; Note that LOOKUP attempts to find the next item in the input stream
  1044. ; in the table passed to it in HL ... if found, the table data item is
  1045. ; returned in HL; if not found, LOOKUP returns carry set.
  1046. ;
  1047. CMDTBL:    db    '?'+80h            ; "set ?"
  1048.     dw    STHELP            ;
  1049.     db    'BAU','D'+80h        ; "set baud"
  1050.     dw    STBAUD            ;
  1051.     db    'ID','D'+80h        ; "set id"
  1052.     dw    SETIDD            ;
  1053.     db    'ANSWE','R'+80h        ; "set answer"
  1054.     dw    STANSW            ;
  1055.     db    'AN','S'+80h        ; "set ans" (same as above)
  1056.     dw    STANSW            ;
  1057.     db    'ORIGINAT','E'+80h    ; "set originate"
  1058.     dw    STORIG            ;
  1059.     db    'ORI','G'+80h        ; "set orig" (same as above)
  1060.     dw    STORIG            ;
  1061.     db    'OR','G'+80h        ; "set org" (same as above)
  1062.     dw    STORIG            ;
  1063.     db    'OFFHOO','K'+80h    ; "set offhook"
  1064.     dw    OFF            ;
  1065.     db    'ONLIN','E'+80h        ; "set online" (same as offhook)
  1066.     dw    OFF            ;
  1067.     db    'ONHOO','K'+80h        ; "set onhook"
  1068.     dw    PDISC            ;
  1069.     db    'OFFLIN','E'+80h    ; "set offline" (same as onhook)
  1070.     dw    PDISC            ;
  1071.     db    'PP','S'+80h        ; "set pps"
  1072.     dw    SETPPS            ;
  1073.     db    'BAS','E'+80h        ; "set PMMI base port."
  1074.     dw    SETBP            ;
  1075.     db    'IC','D'+80h        ; "set delay between calls"
  1076.     dw    SETICD            ;
  1077.     db    'EXTR','A'+80h        ; "set extra print mode"
  1078.     dw    SETXTRA            ;
  1079.     db    'XYZZ','Y'+80h        ;
  1080.     dw    XYZZY            ;
  1081.                     ;
  1082.     db    0            ; <<=== table terminator
  1083. ;
  1084. ; SET <no-args>: print current statistics
  1085. ;
  1086. SETSHO:    call    SYSVER        ;show carrier present/not present
  1087.     lxi    h,SHOTBL    ;get table of SHOW subroutines
  1088. SETSLP:    mov    e,m        ;get table address
  1089.     inx    h
  1090.     mov    d,m
  1091.     inx    h
  1092.     mov    a,d        ;end of table?
  1093.     ora    e
  1094.     rz            ;exit if so
  1095.     push    h        ;save table pointer
  1096.     xchg            ;adrs to HL
  1097.     call    GOHL        ;do it
  1098.     call    CRLF        ;print newline
  1099.     mvi    c,CHEKCC    ;check for console abort
  1100.     call    MEX
  1101.     pop    h        ;it's done
  1102.     jnz    SETSLP        ;continue if no abort
  1103.     call    CRLF
  1104.     ret
  1105.  
  1106. GOHL:    pchl
  1107.  
  1108.  
  1109. ; table of SHOW subroutines
  1110. SHOTBL:    dw    BDSHOW
  1111.     dw    MDSHOW
  1112.     dw    SHOICD
  1113.     dw    SHOIDD
  1114.     dw    SHOPPS
  1115.     dw    SHOXTRA
  1116.     dw    CRLF
  1117.     dw    0        ;<<== table terminator
  1118.  
  1119. ;
  1120. ; SET ?  processor
  1121. ;
  1122. STHELP:    lxi    d,HLPMSG
  1123.     mvi    c,PRINT
  1124.     call    MEX
  1125.     ret
  1126. ;
  1127. ; The help message
  1128. ;
  1129. HLPMSG:    db    cr,lf,'SET command, for the PMMI S-100 modem (r.i.p.)'
  1130.     db    cr,lf
  1131.     db    cr,lf,'SET ANSWER <or> SET ANS     ... put PMMI in answer mode'
  1132.     db    cr,lf,'SET BASE <hex #>            ... set new PMMI base port'
  1133.     db    cr,lf,'SET BAUD <value>            ... set baud rate'
  1134.     db    cr,lf,'    BAUD values allowed are:    110, 300, 450, 600, and 710'
  1135.     db    cr,lf,'SET EXTRA <value>           ... OFF if <value> == 0, else ON'
  1136.     db    cr,lf,'    EXTRA function diagnostics displayed: BAUD RATE, BREAK,'
  1137.     db    cr,lf,'          DISCONNECT, OFF-HOOK, and WAIT (for answer tone)'
  1138.     db    cr,lf,'SET ICD <value>'
  1139.     db          '             ... intercall delay; 150 == 30 seconds'
  1140.     db    cr,lf,'SET IDD <value>             ... interdigit delay in 100''s msec'
  1141.     db    cr,lf,'SET OFFHOOK <or> SET ONLINE ... force PMMI online'
  1142.     db    cr,lf,'SET ONHOOK <or> SET OFFHOOK ... disconnect without message'
  1143.     db    cr,lf,'SET ORIGINATE <or> SET ORIG ... put PMMI in originate mode'
  1144.     db    cr,lf,'SET PPS <value>             ... may be 10, 15 or 20 pulses/sec.'
  1145.     db    cr,lf
  1146.     db    cr,lf, '$'
  1147.  
  1148.  
  1149. ; SET BAUD processor
  1150. STBAUD:    mvi    c,BDPARS    ;function code
  1151.     call    MEX        ;let MEX look up code
  1152.     jc    SETERR        ;invalid code
  1153.     call    PBAUD        ;no, try to set it
  1154.     jc    SETERR        ;not-supported code
  1155. BDSHOW:    call    ILPRT        ;display baud
  1156.     db    'Baud rate: ', tab, '   ', 0
  1157.     lda    MSPEED
  1158.     mvi    c,PRBAUD    ;use MEX routine
  1159.     call    MEX
  1160.     ret
  1161.  
  1162.  
  1163. ; SET MODE processor
  1164. MDSHOW:    call    ILPRT        ;show mode
  1165.     db    'Mode:', tab, tab, '   ', 0
  1166.     lda    UCTLB        ;get UART B image
  1167.     ani    ORBIT        ;orig?
  1168.     jz    MDORIG
  1169.     call    ILPRT
  1170.     db    'Originate', 0
  1171.     ret
  1172.  
  1173. MDORIG:    call    ILPRT
  1174.     db    'Answer', 0
  1175.     ret
  1176.  
  1177. STORIG: mvi    l,ORBIT 
  1178.     jmp    CHGAO
  1179.  
  1180. STANSW: mvi    l,ANBIT
  1181. CHGAO:    lda    UCTLB
  1182.     ani    MODEMK
  1183.     ora    l
  1184.     sta    UCTLB
  1185.     call    OHKBYT
  1186.     jnz    MDSHOW
  1187.     call    oCTL1
  1188.     call    OFF
  1189.     jmp    MDSHOW
  1190.  
  1191. OHKBYT:    lda    OFFHK
  1192.     cma
  1193.     ora    a
  1194.     ret
  1195.  
  1196. ;
  1197. ; SET PPS command processor
  1198. ;
  1199. SETPPS:    lxi    d,PPSTBL    ;get value
  1200.     call    TSRCH
  1201.     jc    SETERR        ;not found in table? error out
  1202.     mov    a,l        ;yep, set it
  1203.     sta    PRATE
  1204. SHOPPS:    call    ILPRT
  1205.     db    'PPS rate: ', tab, '   ', 0
  1206.     lda    PRATE        ;display PPS
  1207.     cpi    250
  1208.     jnz    SHO2
  1209.     call    ILPRT
  1210.     db    '10', 0
  1211.     ret
  1212. SHO2:    cpi    125
  1213.     jnz    SHO3
  1214.     call    ILPRT
  1215.     db    '20',0
  1216.     ret
  1217. SHO3:    call    ILPRT
  1218.     db    '15',0
  1219.     ret
  1220.  
  1221.  
  1222. PPSTBL:    db    '1','0'+80H    ;"set pps 10"
  1223.     dw    250
  1224.     db    '1','5'+80h    ;"set pps 15"
  1225.     dw    167
  1226.     db    '2','0'+80H    ;"set pps 20"
  1227.     dw    125
  1228.     db    0        ;<<=== table terminator
  1229. ;
  1230. ; SET IDIG command processor
  1231. ;
  1232. SETIDD:    mvi    c,EVALA
  1233.     call    MEX        ;get numeric
  1234.     mov    a,h        ;validate
  1235.     ora    a
  1236.     jnz    SETERR
  1237.     mov    a,l
  1238.     sta    INTERD        ;set new rate
  1239. SHOIDD:    call    ILPRT
  1240.     db    'Inter-digit delay: ', 0
  1241.     lda    INTERD        ;get value
  1242.     mov    l,a        ;move delay to HL
  1243.     mvi    h,0
  1244.     mvi    c,DECOUT    ;print it
  1245.     call    MEX
  1246.     call    ILPRT
  1247.     db    '00 ms',0
  1248.     ret
  1249.  
  1250.  
  1251. ; Set BASE PORT command processor.
  1252. SETBP:    mvi    c,SBLANK
  1253.     call    MEX
  1254.     mvi    c,GNC        ;get char from input, cy=1 if none
  1255.     call    MEX
  1256.     call    UPPER
  1257.     mov    l,a        ; Character to test is in L.
  1258.     shld    TEMP
  1259.  
  1260.     lxi    b,BPTAB-1
  1261.     lxi    d,10h
  1262.     lxi    h,-10h
  1263.  
  1264. SETLP:    inx    b        ; Advance to next allowable character.
  1265.     dad    d        ; Add 10 hex to base port address.
  1266.     ldax    b        ;
  1267.     ora    a        ;
  1268.     jm    SETNG        ; Jump if character typed not in allowable set.
  1269.     push    h        ;
  1270.     lhld    TEMP        ;
  1271.     cmp    l        ; Valid port requested?
  1272.     shld    TEMP        ;
  1273.     pop    h        ; Restore new base port.
  1274.     jnz    SETLP        ; No match, try again.
  1275.     sta    BPMSG        ; Patch sign-on message with Port # (ascii).
  1276.     mov    a,l        ;
  1277.     sta    NITBYT        ; Save base port (hex) for I/O and for CLONING.
  1278.     ret
  1279.  
  1280.  
  1281. BPNOGO:    db    7, '  ****  Invalid port  ****', cr, lf, '$'
  1282. SETNG:    lxi    d,BPNOGO
  1283.     mvi    c,PRINT
  1284.     jmp    MEX
  1285.  
  1286.  
  1287. SETICD:    mvi    c,EVALA
  1288.     call    MEX        ;get numeric
  1289.     mov    a,h        ;validate
  1290.     ora    a
  1291.     jnz    SETERR
  1292.     mov    a,l
  1293.     sta    WTNUM        ;set new rate
  1294. SHOICD:    call    ILPRT
  1295.     db    'Inter-call delay:  ', 0
  1296.     lda    WTNUM        ;get value
  1297.     mov    l,a        ;move delay to HL
  1298.     mvi    h,0
  1299.     mvi    c,DECOUT    ;print it
  1300.     call    MEX
  1301.     call    ILPRT
  1302.     db    ' ticks. (150 ticks=30 seconds)', 0
  1303.     ret
  1304.  
  1305. SETXTRA: mvi    c,EVALA
  1306.     call    MEX
  1307.     mov    a,h
  1308.     ora    a
  1309.     jnz    SETERR
  1310.     mov    a,l
  1311.     sta    PRXTRA
  1312. SHOXTRA: call    ILPRT
  1313.     db    'Extra print mode:  ',0
  1314.     lda    PRXTRA
  1315.     ora    a
  1316.     lxi    d,ONNMSG
  1317.     jnz    SHOXT2
  1318.     lxi    d,OFFMSG
  1319. SHOXT2:    jmp    PRMBOK
  1320.  
  1321. ONNMSG:    db    'ON$'
  1322. OFFMSG:    db    'OFF$'
  1323.  
  1324.  
  1325. ; Compare next input-stream item in table @DE; CY=1
  1326. ; if not found, else HL=matched data item
  1327. TSRCH:    mvi    c,LOOKUP    ;get function code
  1328.     jmp    MEX        ;pass to MEX processor
  1329.  
  1330.  
  1331. XYZZY:    call ILPRT
  1332.     db    'Nothing happens...', 0
  1333.     ret
  1334.  
  1335.  
  1336. ; Print in-line message
  1337. ILPRT:    mvi    c,ILP        ;get function code
  1338.     jmp    MEX        ;go do it
  1339.  
  1340.  
  1341. TIMOUT:    mvi    c,TIMER        ;
  1342.     jmp    MEX        ;
  1343.  
  1344.  
  1345. UPPER:    cpi    'a'
  1346.     rc
  1347.     cpi    'z'+1
  1348.     rnc
  1349.     sui    'a'-'A'
  1350.     ret
  1351.  
  1352.  
  1353. ;------------------------------------------------------------
  1354. ;
  1355. ; End of PMMI MEX modem overlay
  1356. ;
  1357. ;------------------------------------------------------------
  1358.  
  1359.  
  1360.     end
  1361.