home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-rs32.asm < prev    next >
Assembly Source File  |  1994-07-13  |  28KB  |  924 lines
  1. ;    Title    'MEX overlay - TRS-80 MOD IV vers 3.2'    
  2. ;                      Montezuma Micro CP/M 2.2
  3. ;
  4. ;******************************************************************************
  5. ;    R E V I S I O N       H I S T O R Y
  6. ;******************************************************************************
  7. ;
  8. ; VERSION 3.2 09/15/86 - Bug Fixed.  When exiting MEX to CP/M, interrupts
  9. ;             were not shut off properly and would cause the machine to go
  10. ;             into never-never land. 
  11. ;                Fred LaForest
  12. ;
  13. ; VERSION 3.1 08/21/86 - Bug fixed.  If the input buffer was filled before it 
  14. ;             could be emptied, the count of characters went past
  15. ;             the configured maximum number of spaces in the buffer.
  16. ;                Fred LaForest
  17. ;
  18. ; VERSION 3.0 08/18/86 - Major revision level change.  I removed the auto
  19. ;             answer code, it is modem dependent and belongs in a 
  20. ;             modem overlay.  All smart modem code is gone.  The SET
  21. ;             command code has been tightened up.  
  22. ;             At higher speeds, the Mod 4 loses characters during
  23. ;             screen scrolling.  Configurable code has been added to
  24. ;             use interrupts to process UART input.  This eliminates
  25. ;             almost all character dropouts during screen processing.
  26. ;                Fred LaForest
  27. ;                3235 Edgeworth
  28. ;                Ferndale, MI 48220
  29. ;                GENIE: FALAFOREST
  30. ;
  31. ;******************************************************************************
  32. ;
  33. ; VERSION 2.1 08/06/86 - Correct modem control to properly handle changes
  34. ;             in word length, parity, and stop bits.  Changes
  35. ;             to these parameters by the SET command were never
  36. ;             communicated to the UART.
  37. ;                Fred LaForest
  38. ;
  39. ; VERSION 2.0 10/06/85 - Change to the printer status routine.  Now
  40. ;             checks all four possible printer states.
  41. ;             Ver.114 changed ^C address from AUTO ANSWER.
  42. ;             Added code at STANS to find the correct 
  43. ;             address.
  44. ;                            Ed Richter 
  45. ;                        71455,1133
  46. ; VERSION 1.9 09/12/85 - Minor change to eliminate some un-necessay
  47. ;             code when using the AUTO ANSWER mode. See
  48. ;             NOMXOSM.
  49. ;                        Ed Richter
  50. ; VERSION 1.8 05/05/85 - Included the changes from the file 
  51. ;             MXO-RS17.FIX. The baud rate detect now works.
  52. ;                        Ed Richter
  53. ; VERSION 1.7 01/25/85 - ^C in "auto-answer now aborts to CPM, not
  54. ;             MEX.(sorry bout that one) Added code to
  55. ;             determine baud rate in "auto-answer".
  56. ;             Changed "NITMOD" to default  to the baud 
  57. ;             rate selected by "MSPEED"     
  58. ;                        Ed Richter
  59. ; VERSION 1.6 01/21/85 - A system reset seems a little drastic
  60. ;                        so added code for a ^C abort to auto
  61. ;              answer. Also added "number of rings" 
  62. ;             equate.
  63. ;                         Ed Richter
  64. ; VERSION 1.5 11/17/84 - Added SET ANSWER ON command
  65. ;             (For Hayes-compatible modems
  66. ;              only...see NOTE below.)
  67. ;                        Thom Foulks
  68. ; VERSION 1.3 10/10/84 - Fixed bug in the Printer ready test
  69. ;                                                 Ed Richter
  70. ; VERSION 1.2 09/18/84 - Added the comments to 1.1 and changed the
  71. ;             configuration of the SET message that is
  72. ;             output to the console
  73. ;                           Ed Richter 
  74. ; VERSION 1.1 09/16/84 - Added code to fully control the SIO USART
  75. ;                 via the SET command. This overlay now 
  76. ;             supports-- SET BAUD -- SET PARITY --
  77. ;             SET STOP BITS -- SET WORD LENGTH --
  78. ;                                                   Ed Richter
  79. ;
  80. ; MEX TRS-80 MOD IV OVERLAY VERSION 1.0: Written 09/10/84 by Ed Richter 
  81. ; 
  82. ; This file was derived from the MDM7xx overlay M7R4-5.ASM, and the 
  83. ; file MXOPM10.ASM. It is a MEX overlay for use with the TRS-80 MOD
  84. ; IV, and an external modem. It has a SET command that supports 300
  85. ; though 9600 baud.
  86. ;
  87. ;******************************************************************************
  88.  
  89. REV:    EQU    32        ;MEX Overlay revision number
  90. ;
  91. CR:    EQU    0DH        ;carriage return
  92. LF:    EQU    0AH        ;linefeed
  93. ONV:    EQU    0FH        ;reverse video on
  94. INV:    EQU    0EH        ;reverse video off
  95. TPA:    EQU    0100H        ;start of program
  96. TAB:    EQU    09H    
  97. YES:    EQU    0FFH        ;true
  98. NO:    EQU    0        ;not true
  99.  
  100. ;******************************************************************************
  101. ;
  102. ;    UART equates and port equates
  103. ;
  104. ;******************************************************************************
  105. ;
  106. ;    ***********  Important NOTICE  ***********
  107. ;
  108. ;    The following equate, MMINTR, is set to YES if you want input
  109. ;    characters from the UART to be captured by the TRS-80 Mod 4 interrupt
  110. ;    circuitry.  This virtually eliminates all lost characters during 
  111. ;    screen scrolling.  This means you can tell any RCPM or BBS that you 
  112. ;    don't need ANY nulls (0).  
  113. ;
  114. ;    A BIG assumption is that you are a MOD 4 using Montezuma Micro CP/M
  115. ;    implementation.  The initialization code searchs through the BIOS for
  116. ;    the TWO places which disable interrupts and really don't need this type
  117. ;    of protection.  They are th keyboard handler and the video screen memory
  118. ;    handler.  They only switch out RAM between F800h and FFFFh.  This does
  119. ;    NOT overlap any user program in TPA.  
  120. ;
  121. ;    The technique used to find the two BIOS locations can be modified for
  122. ;    other machines or CP/M implementations.
  123. ;
  124. ;    NOTE!!!;  If you DO NOT want to use interrupt processing, set MMINTR to
  125. ;    NO.  This will revert this overlay to the older port polling method
  126. ;    which is used in older overlays for the Mod 4.
  127. ;
  128. ;
  129. MMINTR        EQU    YES    ;Set YES if you are using Montezuma Micro CP/M
  130. ;                ;AND you wish to use interrupt input processing
  131. ;                ;Set NO if you DO NOT want interrupt processing
  132. ;                ;and want the older port polling method
  133. ;
  134. ;    TRS 80 Communications port information
  135. ;
  136. PORT:        EQU    0E8H    ;master reset port   
  137. MODCT1:        EQU    PORT+2    ;modem control port
  138. MODDAT:        EQU    PORT+3    ;modem data in port
  139. MODCT2:        EQU    PORT+2    ;not used mod iv
  140. BAUDRP:        EQU    PORT+1    ;baud rate port
  141. MDRCVB:        EQU    080H    ;bit to test for receive
  142. MDRCVR:        EQU    080H    ;value when ready
  143. MDSNDB:        EQU    040H    ;bit to test for send
  144. MDSNDR:        EQU    040H    ;value when ready
  145.  
  146. ;
  147. ;    UART Control Bit Configuration
  148. ;
  149. U$WORD:        EQU    060h    ;Word length mask 
  150. U$WRD5:        EQU    000H    ;Word length of 5 bits
  151. U$WRD6:        EQU    040H    ;Word length of 6 bits
  152. U$WRD7:        EQU    020H    ;Word length of 7 bits
  153. U$WRD8:        EQU    060H    ;Word length of 8 bits
  154. U$PART:        EQU    088H    ;Parity control mask
  155. U$PREV:        EQU    080H    ;Parity EVEN
  156. U$PROD:        EQU    000H    ;Parity ODD
  157. U$PROF:        EQU    008H    ;Parity OFF
  158. U$PRON:        EQU    000h    ;Parity ON
  159. U$STOP:        EQU    010H    ;Stop bits mask
  160. U$STP1:        EQU    000H    ;Stop bits 1
  161. U$STP2:        EQU    010H    ;Stop bits 2
  162. U$XMIT:        EQU    004H    ;Set to enable transmit
  163. U$RTS:        EQU    002H    ;Set for RTS
  164. U$RTSO:        EQU    000H    ;Clear to turn on RTS
  165. U$DTR:        EQU    001H    ;Set for DTR off
  166. U$DTRO:        EQU    000H    ;Clear to turn on DTR
  167. ;
  168. ;    Default UART configurations and bit masks
  169. ;
  170. DEFCTB:        EQU    U$PROF+U$WRD8+U$STP1+U$DTRO+U$XMIT+U$RTSO
  171. DFBAUD:        EQU    6    ;0=110 1=300 2=450 3=600 4=710 5=1200    
  172.                 ;6=2400 7=4800 8=9600 9=19200 default
  173. CTSMSK:        EQU    020H        ;carrier detect mask
  174. ISOCD:        EQU    0DFH        ;port ready mask
  175. PRPORT:        EQU    0F8H        ;printer port
  176. PRSTAT:        EQU    0F0H        ;printer ready mask
  177. BRKMSK:        EQU    0FFH-U$XMIT    ;send break
  178. DTRMSK:        EQU    0FFH-U$DTR-U$RTS ;drop dtr
  179.  
  180. ;******************************************************************************
  181. ;
  182. ;    MEX SERVICE PROCESSOR STUFF
  183. ;
  184. ;******************************************************************************
  185. MEX:        EQU    0D00H    ;address of the service processor
  186. INMDM:        EQU    255    ;get char from port,CY=no more in 100ms
  187. TIMER:        EQU    254    ;delay 100 ms * reg b
  188. TMDINP:        EQU    253    ;b=# secs to wait for char,CY=no char
  189. CHEKCC:        EQU    252    ;check for ^C from kbd, Z=present
  190. SNDRDY:        EQU    251    ;test for modem-send ready
  191. RCVRDY:        EQU    250    ;test for modem-receive ready
  192. SNDCHR:        EQU    249    ;send to modem (after SNDRDY)
  193. RCVCHR:        EQU    248    ;recv a char from modem after (RCVRDY)
  194. LOOKUP:        EQU    247    ;table search: see CMDTBL for info 
  195. PARSFN:        EQU    246    ;parse filename from input stream 
  196. BDPARS:        EQU    245    ;parse baud-rate from input stream
  197. SBLANK:        EQU    244    ;scan input stream to next non-blank
  198. EVALA:        EQU    243    ;evaluate numeric from input stream
  199. LKAHED:        EQU    242    ;get nxt char w/o removing from input
  200. GNC:        EQU    241    ;get char from input, CY=1 if none
  201. ILP:        EQU    240    ;inline print
  202. DECOUT:        EQU    239    ;decimal output
  203. PRBAUD:        EQU    238    ;print baud rate
  204. CONOUT:        EQU    2    ;simulated BDOS funct 2:CONSOLE OUT
  205. PRINT:        EQU    9    ;simulated BDOS funct 9: PRINT STRING
  206. INBUF:        EQU    10    ;input buffer, same as BDOS FUNCT 10
  207.  
  208. ;******************************************************************************
  209. ;
  210. ;    Place the printer test routine address here
  211. ;
  212. ;******************************************************************************
  213.  
  214.         ORG    0D11H    ;install printer ready test
  215.         DW    PRTSTS
  216.  
  217. ;******************************************************************************
  218. ; 
  219. ;    Low address MEX flags and configuration constants go here
  220. ;
  221. ;******************************************************************************
  222.  
  223.         ORG    TPA
  224. ;
  225.         DS    3    ;(for  "JMP   START" instruction)
  226. PMODEM:        DS    1    ;Not used by MEX            103H
  227. SMODEM:        DS    1    ;Not used by MEX
  228. TPULSE:        DS    1    ;Not used by MEX             105H
  229. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  230.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  231. MSPEED:        DB    DFBAUD    ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  232.                 ;6=2400 7=4800 8=9600 9=19200 default
  233. BYTDLY:        DB    0    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  234.                 ;default time to send character in ter-
  235.                 ;minal mode file transfer for slow BBS.
  236. CRDLY:        DB    0    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  237.                 ;default time for extra wait after CRLF
  238.                 ;in terminal mode file transfer
  239. COLUMS:        DB    4    ;number of DIR columns shown        10AH
  240. SETFL:        DB    YES    ;yes=user-added Setup routine        10BH
  241. SCRTST:        DB    YES    ;Cursor control routine         10CH
  242.         DS    1    ;reserved (old ACKNAK flag)        10DH
  243. BAKFLG:        DB    YES     ;yes=change any file same name to .BAK    10EH
  244. CRCDFL:        DB    YES    ;yes=default to CRC checking        10FH
  245. TOGCRC:        DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  246. CVTBS:        DB    NO    ;yes=convert backspace to rub        111H
  247. TOGLBK:        DB    YES    ;yes=allow toggling of bksp to rub    112H
  248. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  249.                 ;terminal mode (added by remote echo)
  250. TOGLF:        DB    YES    ;yes=allow toggling of LF after CR    114H
  251. TRNLOG:        DB    NO    ;yes=allow transmission of logon    115H
  252.                 ;write logon sequence at location LOGON
  253. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  254. LOCNXT:        DB    NO    ;yes=local command if EXTCHR precedes    117H
  255.                 ;no=external command if EXTCHR precedes
  256. TOGLOC:        DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  257. LSTTST:        DB    YES    ;yes=allow toggling of printer on/off    119H
  258. XOFTST:        DB    YES    ;yes=checks for XOFF from remote while    11AH
  259.                 ;sending a file in terminal mode
  260. XONWT:        DB    YES    ;yes=wait for XON after CR while    11BH
  261.                 ;sending a file in terminal mode
  262. TOGXOF:        DB    YES    ;yes=allow toggling of XOFF checking    11CH
  263. IGNCTL:        DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  264. EXTRA1:        DB    0    ;for future expansion            11EH
  265. EXTRA2:        DB    0    ;for future expansion            11FH
  266. BRKCHR:        DB    'K'-40H    ;^K = Send 300 ms. break tone        120H
  267. NOCONN:        DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  268. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  269. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  270. UNSVCH:        DB    'R'-40H    ;^R = Close input text buffer        124H
  271. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  272. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  273. EXTCHR:        DB    '^'-40h    ;^^ = Send next character        127H
  274.         DS    2
  275. INCTL1:        JMP     STATSND    ;go to "get status"             12AH
  276.         DS    7
  277. OTDATA:        OUT    MODDAT  ! RET    ;out modem data port        134H
  278.         DS    7
  279.         IF    NOT MMINTR    ;If not interupt driven
  280. INPORT:        IN    MODDAT  ! RET    ;in modem data port
  281.         ENDIF
  282.         IF    MMINTR        ;If interrupts are used
  283. INPORT:        JMP    INT$GET        ;Get a char from buffer
  284.         ENDIF        
  285.         DS    7
  286. MASKR:        ANI    MDRCVB    ! RET    ;bit to test for receive ready    148H
  287. TESTR:        CPI    MDRCVR    ! RET    ;value of rcv. bit when ready    14BH
  288. MASKS:        ANI    MDSNDB    ! RET    ;bit to test for send ready    14EH
  289. TESTS:        CPI    MDSNDR    ! RET    ;value of send bit when ready    151H
  290.         DS    12        ;unused by MEX
  291. LOGON:        DS    2        ;for user message        160H
  292. DIALV:        DS    3        ;autodial rtn jump        162H
  293. DISCV:        JMP    DISCON        ;disconnect rtn            165H
  294.  
  295.         IF    NOT MMINTR
  296. GOODBV:        DS    3        ;not needed            168H
  297.         ENDIF
  298.         IF    MMINTR        ;Interrupt processing
  299. GOODBV:        JMP    INT$BYE        ;Restore system vectors        168H
  300.         ENDIF
  301.  
  302. INMODV:        JMP    NITMOD        ;go to user written routine    16BH
  303. NEWBDV:        JMP    PBAUD        ;set new baud-rate           16EH
  304. NOPARV:        DS    3        ;(by-pass PMMI routine)        171H
  305. PARITV:        DS    3        ;(by-pass PMMI routine)        174H
  306. SETUPV:        JMP    SETCMD        ;initialize USART and modem    177H
  307. SPMENV:        DS    3        ;not used with MEX        17AH
  308. VERSNV:        JMP    SYSVER        ;print header msg        17DH
  309. BREAKV:        JMP    PBREAK        ;send header            180H
  310. ; Do not change the following six lines.
  311. ILPRTV:        DS    3        ;                183H
  312. INBUFV:        DS    3        ;                186H
  313. ILCMPV:        DS    3        ;                189H
  314. INMDMV:        DS    3        ;                18CH
  315. NXSCRV:        DS    3        ;                18FH
  316. TIMERV:        DS    3        ;                192H
  317.  
  318. ;******************************************************************************
  319. ;
  320. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  321. ; SCRNTEST to YES at 010AH (above).
  322. ;
  323. ;******************************************************************************
  324.  
  325. CLREOS:        LXI    D,EOSMSG    ;clear to end of screen         195H
  326.         CALL    MPRINT        ;                198H
  327.         RET            ;                19DH
  328. ;
  329. CLS:        LXI    D,CLSMSG    ;clear sreen            19EH
  330.         CALL    MPRINT        ;                1A1H
  331.         RET            ;                1A6H
  332.     
  333. ;
  334. SYSVER:        LXI    D,SOMESG    ;print the sys version msg    1A7H
  335.         CALL    MPRINT        
  336. ;
  337. ;    Print out a message telling of carrier status
  338. ;
  339. CARRSH        LXI    D,NOMESG    ;no carrier present msg
  340.         CALL    CARRCK
  341.         CNZ    MPRINT        ;print if no carrier
  342.         LXI    D,CARMSG    ;carrier present
  343.         CALL    MPRINT        ;say so and continue
  344.         RET
  345.  
  346. ;******************************************************************************
  347. ;
  348. ;    UART controling and accessing routines
  349. ;
  350. ;******************************************************************************
  351. ;
  352. ;    This area resets the SIO-UART DTR reinitializes all control parameters
  353. ;
  354. NITMOD:          MVI    A,1
  355.           OUT    PORT        ;reset the USART to
  356.           LDA    CURURT        ;Get the current UART parameters
  357.           OUT    MODCT1
  358.         LDA    MSPEED        ;Get startup baud rate
  359.         CALL    PBAUD        ;Set up baud rate generator
  360.         IF    MMINTR        ;Are we interrupt processing?
  361.         CALL    INT$SET        ;Yes, Set up needed vectors
  362.         ENDIF
  363.         RET
  364.  
  365. ;
  366. ;    Send a break tone to reset some time-share computers.
  367. ;
  368. PBREAK:        LDA    CURURT        ;Get modem control bits
  369.         ANI    BRKMSK        ;send break
  370.         OUT    MODCT1
  371.           MVI    B,3        
  372.           MVI    C,TIMER
  373.           CALL    MEX        ;delay 300 msec
  374.         LDA    CURURT        ;Get current bits
  375.           OUT    MODCT1
  376.          RET
  377.  
  378. ;
  379. ;    Routine to return status of the modem port
  380. ;
  381. STATSND:    IN    MODCT1        ;in modem contol port
  382.         PUSH     B        ;just in case
  383.         ANI    ISOCD        ;isolate status and clear CD bit
  384.         IF    MMINTR
  385.         ANI    0FFH-MDRCVB    ;Clear any receive status
  386.         ENDIF
  387.         MOV    B,A        ;save status
  388.         IF    MMINTR
  389.         CALL    INT$TST        ;Test for input
  390.         ORA    B        ;Include other bits
  391.         MOV    B,A        ;Save in B
  392.         ENDIF
  393.         IN     PORT        ;get CD bit
  394.         ANI    CTSMSK        ;isolate CD bit
  395.         ORA    B        ;merge CD with status
  396.         POP    B        ;restore B
  397.         RET
  398.  
  399. ;
  400. ;    Determine the carrier detect status  0=CARRIER
  401. ;
  402. CARRCK:        IN    PORT        ;get carrier bit
  403.         ANI    CTSMSK
  404.         RET
  405.  
  406. ;
  407. ;    This routine will hang up the phone by dropping DTR.
  408. ;
  409. DISCON:          LDA    CURURT        ;Get current modem bits
  410.         ANI    BRKMSK
  411.         ORI    U$DTR+U$RTS    ;Shut off DTR
  412.               OUT    MODCT1        ;send cmd
  413.           MVI    B,5        
  414.           MVI    C,TIMER
  415.           CALL    MEX        ;delay 500 msec
  416.         LDA    CURURT        ;Get current bits
  417.           OUT    MODCT1
  418.           RET
  419.  
  420. ;******************************************************************************
  421. ;    
  422. ;    Baud rate set routine 
  423. ;
  424. ;    A = MEX baud rate code
  425. ;
  426. ;******************************************************************************
  427. PBAUD:          PUSH    H        ;save everybody
  428.           PUSH    B
  429.           PUSH    D
  430.         MOV    E,A        ;get speed
  431.         MVI    D,0        ;zero the other half of reg pair
  432.         LXI    H,BAUDTB    ;get baud rate table address
  433.         DAD    D        ;add speed offset
  434.         MOV    A,M        ;get baud rate  
  435.         ORA    A        ;0=not valid baud rate
  436.         JZ    PBEXIT        ;not valid baud rate then exit
  437.         OUT    BAUDRP        ;good baud rate then set it
  438.         MOV    A,E        ;get speed 
  439.         STA    MSPEED        ;set speed
  440.         JMP    PBEXIT1        ;return 
  441. PBEXIT:        STC
  442. PBEXIT1:    POP    B        ;no carrier or incorrect baud rate
  443.           POP    D
  444.           POP       H
  445.           RET
  446. ;
  447. BAUDTB:        DB    0,055H,0,0,0         ;110,300,450,610,710
  448.         DB    077H,0AAH,0CCH,0EEH,0FFH ;1200,2400,4800,9600,19200
  449.  
  450. ;******************************************************************************
  451. ;
  452. ;    Test for printer ready
  453. ;
  454. ;******************************************************************************
  455. PRTSTS:          IN    PRPORT        ;get printer status
  456.           ANI    PRSTAT        ;isolate it
  457.           XRI    030H        ;invert it
  458.         JZ    PRTSTS1        ;return if not ready A=00
  459.           MVI    A,01H        ;get "A" ready to zero  
  460. PRTSTS1:    DCR    A        ;A = 0 not ready
  461.         RET            ;A = FF ready
  462.  
  463. ;******************************************************************************
  464. ;
  465. ;    Sets the communications parameters via the SET command
  466. ;
  467. ;******************************************************************************
  468. SETCMD:        MVI    C,SBLANK    ;any arguments
  469.         CALL    MEX
  470.         JC    SETSHO        ;if not print out values
  471. ;
  472. ;    First determine the parameter they wish to change
  473. ;
  474.         LXI    D,CMDTBL    ;parse commands
  475.         CALL    TSRCH        ;from table
  476.         JC    SETERR        ;Word was not found
  477.         MOV    A,H        ;Get MS table address byte
  478.         ORA    A        ;Test for zero
  479.         JZ    SETTBL        ;Go Get next parameter
  480.         PCHL            ;Jump to special routine
  481. ;
  482. ;    All table look up errors come here
  483. ;
  484. SETERR:          LXI    D,SETEMS    ;no then print error
  485.           CALL    MPRINT
  486.           RET
  487.  
  488. SETEMS:          DB    CR,LF,'SET command error',CR,LF,LF,'$'
  489.  
  490. ;
  491. ;    This routine will field parameter changes for WORD, PARITY and STOP BITS
  492. ;
  493. SETTBL:        LXI    D,STTABL    ;Get address of table
  494.         DAD    D        ;HL -> next parameter input table
  495.         XCHG            ;DE -> the table now
  496.         CALL    TSRCH        ;from table
  497.         JC    SETERR        ;Word was not found
  498.         LDA    CURURT        ;Get current UART parameters
  499.         ANA    L        ;Mask out bit under review
  500.         ORA    H        ;Set new bits
  501.         STA    CURURT        ;Store new parameters
  502.         OUT    MODCT1        ;Tell UART of the changes
  503.         RET            ;Return to MEX
  504.  
  505. ;
  506. ;    Set the baud rate from the set command
  507. ;
  508. STBAUD:        LXI    D,STBDTB    ;Get the legal choices table
  509.         CALL    TSRCH        ;Search the table
  510.         JC    SETERR        ;When in doubt, do without
  511.         MOV    A,L        ;Get the MEX speed code
  512.         STA    MSPEED        ;Inform MEX of speed change
  513.         MOV    A,H        ;Get UART code
  514.         OUT    BAUDRP        ;Tell the UART baud rate generator
  515.         RET            ;Return to MEX
  516.  
  517. ;
  518. ;    Print out a helpful description of the SET command
  519. ;
  520. STHELP:        LXI    D,SOMESG    ;Get Overlay version message
  521.         CALL    MPRINT        ;Print the version
  522.         LXI    D,HLPMSG    ;Get address of SET command
  523.         CALL    MPRINT
  524.         RET            ;Return to MEX
  525.  
  526. ;
  527. ;    Show the settings of the current parameters
  528. ;
  529. SETSHO:        CALL    CLS        ;clear screen
  530.         CALL    SYSVER        ;Print version and carrier status
  531.  
  532.         LXI    D,BAUDMSG    ;Print baud rate message
  533.         CALL    MPRINT        ;Print it
  534.         LDA    MSPEED        ;get MSPEED to determine present
  535.         MVI    C,PRBAUD    ;baud rate
  536.         CALL    MEX
  537.  
  538.         LXI    D,STOPMSG    ;Insert Stop bits message
  539.         CALL    MPRINT
  540.         LDA    CURURT        ;Get UART settings
  541.         ANI    U$STP2        ;How many bits
  542.         MVI    A,'1'        ;Assume 1 bit
  543.         JZ    STSHS1        ;Jump if so
  544.         MVI    A,'2'        ;Must be 2
  545. STSHS1:        CALL    TYPE        ;Tell operator
  546.  
  547.         LXI    D,WLMSG        ;Start word length message
  548.         CALL    MPRINT
  549.         LDA    CURURT        ;Get UART settings
  550.         ANI    U$WORD        ;Isolate byte length
  551.         MVI    C,'5'        ;5 bits?
  552.         JZ    STSHLG        ;Yes
  553.         MVI    C,'6'
  554.         CPI    U$WRD6        ;6 bits?
  555.         JZ    STSHLG
  556.         MVI    C,'7'        ;7 bits?
  557.         CPI    U$WRD7
  558.         JZ    STSHLG
  559.         MVI    C,'8'        ;Must be 8 bits then
  560. STSHLG:        MOV    A,C        ;Put char into A
  561.         CALL    TYPE        ;Output to the screen
  562.  
  563.         LXI    D,PARMSG    ;Start parity message
  564.         CALL    MPRINT
  565.         LDA    CURURT        ;Get UART settings
  566.         ANI    U$PART        ;Isolate parity info
  567.         LXI    D,POFMSG    ;Assume off
  568.         CPI    U$PROF        ;Off?
  569.         JZ    STSHPT        ;Yes
  570.         LXI    D,EVEMSG    ;Even parity?
  571.         CPI    U$PREV
  572.         JZ    STSHPT        ;Yes
  573.         LXI    D,ODDMSG    ;Must be ODD
  574. STSHPT:        CALL    MPRINT
  575.  
  576.         RET    
  577.  
  578. ;******************************************************************************
  579. ;
  580. ;    MEX service routine front ends
  581. ;
  582. ;******************************************************************************
  583.  
  584. TSRCH:        MVI    C,LOOKUP    ;Table lookup routine
  585.           JMP    MEX
  586. ;
  587. MPRINT:        MVI    C,PRINT        ;MEX print function
  588.         JMP    MEX
  589. ;
  590. CRLF:        MVI    A,CR        ;newline on console
  591.         CALL    TYPE
  592.         MVI    A,LF
  593. TYPE:        PUSH    H        ;save em
  594.         PUSH    D
  595.         PUSH    B
  596.         MOV    E,A
  597.         MVI    C,CONOUT    ;align output char
  598.         CALL    MEX        ;print via mex
  599.         POP    B        ;restore em
  600.         POP    D
  601.         POP    H
  602.         RET        
  603.  
  604.  
  605.         IF    MMINTR        ;Gen if interrupts wanted
  606.  
  607. ;******************************************************************************
  608. ;
  609. ;    I N T E R R U P T    P R O C E S S I N G
  610. ;
  611. ;******************************************************************************
  612. ;
  613. ;    Search the BIOS for the interrupt disable in the video handler
  614. ;    and the keyboard handler.  Replace the DI with NOP and note their
  615. ;    addresses.  Replace the 38H vector with a jump to our interrupt
  616. ;    handling routine.
  617. ;
  618. INT$SET:    LHLD    0001H        ;Get start address of BIOS
  619.         LXI    B,0B00H        ;Max search size of BIOS
  620.         LXI    D,INT$NOP    ;Table to save BIOS addresses
  621.  
  622. IS$LP1:        MVI    A,0F3H        ;Code for 'DI'
  623.         DB    0EDH,0B1H    ;CPIR, look for DI
  624.         JNZ    IS$SDN        ;Search is done
  625.  
  626. IS$TST:        PUSH    H        ;Save regs
  627.         PUSH    D
  628.         PUSH    B
  629.         LXI    D,I$STR        ;Get remainder of code string
  630.         MVI    B,4        ;Compare next four bytes
  631. IS$LP2:        LDAX    D        ;Get byte from string
  632.         INX    D        ;Bump ptr
  633.         CMP    M        ;Compare to BIOS bytes
  634.         INX    H
  635.         JNZ    IS$LE2        ;Not the same
  636.         DB    10H,(IS$LP2-$-1) AND 0FFH ;DJNZ IS$LP2
  637. IS$LE2:        POP    B        ;Restore regs
  638.         POP    D
  639.         POP    H
  640.         JNZ    IS$LP1        ;Jump if not found
  641.  
  642.         DCX    H        ;We found a DI!
  643.         XRA    A
  644.         MOV    M,A        ;Put NOP where DI was
  645.         XCHG
  646.         MOV    M,E        ;Put DI address into table
  647.         INX    H
  648.         MOV    M,D
  649.         INX    H
  650.         XCHG
  651.         INX    H        ;Restore HL
  652.         JMP    IS$LP1        ;Look for more 'DI's
  653.          
  654. IS$SDN:        XRA    A        ;Clear A
  655.         STAX    D        ;Clear the last entr
  656.         INX    D
  657.         STAX    D
  658.         LHLD    INT$NOP        ;Test for any 'DI's found
  659.         MOV    A,H
  660.         ORA    L
  661.         JZ    IS$NONE        ;No DI strings found, error!
  662. ;
  663. ;    Set up all vectors
  664. ;
  665.         LDA    0038H        ;Get old vector contents
  666.         LHLD    0039H
  667.         STA    INT$VCT        ;Save it for later
  668.         SHLD    INT$VCT+1
  669.         MVI    A,0C3H        ;Form a JMP instruction
  670.         LXI    H,INT$RTN    ; to the interrupt service routine
  671.         STA    0038H        ;Store new vector
  672.         SHLD    0039H
  673.  
  674.         LXI    H,INT$BUF    ;HL -> start of buffer
  675.         SHLD    INT$INP        ;Set up pointers
  676.         SHLD    INT$OUTP    ;into the buffer
  677.         XRA    A        ;Clear A regs
  678.         STA    INT$CNT        ;Count of chars in buffer
  679. ;
  680. ;    Set up interrupt hardware and GO
  681. ;
  682.         MVI    A,020H        ;Interrupt on UART data input ready
  683.         OUT    0E0H        ;Set up interrupt mask
  684.         RET            ;Return to the caller
  685.  
  686. IS$NONE:    LXI    D,I$NODI    ;Print error message
  687.         CALL    MPRINT
  688.         JMP    0000H        ;Return to CP/M
  689.  
  690. ;
  691. ;    I N T $ B Y E    ---   Restore all vectors and return
  692. ;
  693. INT$BYE:    DI            ;Disable interrupts
  694.         LXI    H,INT$NOP    ;Point to DI address table
  695. IB$LP1:        MOV    E,M        ;Load an address
  696.         INX    H
  697.         MOV    D,M
  698.         INX    H
  699.         MOV    A,D        ;Test for end of table
  700.         ORA    E
  701.         JZ    IB$VCT        ;Exit when DI's replaced
  702.         LDA    INT$BYE        ;Get a DI
  703.         STAX    D        ;Store it
  704.         JMP    IB$LP1        ;Loop for the next one
  705.     
  706. IB$VCT:        LDA    INT$VCT        ;Get old 38H vector data
  707.         LHLD    INT$VCT+1
  708.         STA    0038H        ;Restore data
  709.         SHLD    0039H
  710.  
  711.         XRA    A        ;Clear A reg
  712.         OUT    0E0H        ;Disallow all interrupts
  713.         RET            ;Return to caller
  714.  
  715. ;
  716. ;    I N T $ R T N    ----  Interrupt service routine
  717. ;
  718. INT$RTN:    PUSH    PSW        ;Save flags
  719.         IN    MODCT1        ;Get UART flags
  720.         ANI    MDRCVR        ;Isolate data ready bit
  721.         CPI    MDRCVB        ;Anythin' ther?
  722.         JNZ    IR$RET        ;No, return
  723.  
  724.         IN    MODDAT        ;Get the data byte
  725.         PUSH    H        ;Save another reg
  726.         LHLD    INT$INP        ;Get our ptr
  727.         MOV    M,A        ;Save the data byte
  728.         CALL    INT$BMP        ;Bump the ptr    
  729.         SHLD    INT$INP        ;Save ptr
  730.  
  731.         LDA    INT$CNT        ;Increment count
  732.         INR    A        ;Add one to the count
  733.         CPI    INTSIZ+1    ;Max saved chars?
  734.         JC    IR$SVCT        ;No, Save new count
  735.         LHLD    INT$OUTP    ;Get the output pointer
  736.         CALL    INT$BMP        ;Bump it ahead of the input ptr
  737.         SHLD    INT$OUTP
  738.         MVI    A,INTSIZ    ;Reload max size 
  739. IR$SVCT:    STA    INT$CNT        ;Save updated count
  740.         POP    H        ;Restore H
  741.  
  742. IR$RET:        IN    0E0H        ;Read int status reg
  743.         POP    PSW
  744.         EI            ;Reenable interrupts
  745.         DB    0EDH,04DH    ;RETI
  746.  
  747. ;
  748. ;    I N T $ T S T    ---    Test buffer for pending data
  749. ;
  750. INT$TST:    DI            ;Disable interrupts
  751.         LDA    INT$CNT        ;Get the count
  752.         ORA    A        ;Test for zero
  753.         EI            ;Enable interrupts
  754.         RZ            ;Return if no data
  755.         MVI    A,MDRCVR    ;Get data ready bit
  756.         RET            ;Return
  757.  
  758. ;
  759. ;    I N T $ G E T     ---    Get a data byte from the buffer
  760. ;
  761. INT$GET:    DI            ;Disable interrupts
  762.         LDA    INT$CNT        ;Get byte count
  763.         ORA    A        ;Test for anything
  764.         JZ    IG$RET        ;Nothing, return
  765.         DCR    A        ;Subtract one
  766.         STA    INT$CNT        ;Update count
  767.         PUSH    H        ;Save HL reg
  768.         PUSH    B        ;And BC
  769.         LHLD    INT$OUTP    ;Get buffer ptr
  770.         MOV    B,M        ;Load a byte from the buffer
  771.         CALL    INT$BMP        ;Bump the pointer
  772.         SHLD    INT$OUTP    ;Save updated ptr
  773.         MOV    A,B        ;Get data byte again
  774.         POP    B        ;Restore regs
  775.         POP    H
  776.  
  777. IG$RET:        EI            ;Enable interupts
  778.         RET            ;Return to caller             
  779.  
  780. ;
  781. ;    Routine to bump the buffer pointer and reset it to the buffer 
  782. ;    start if we overrun the end
  783. ;
  784. INT$BMP:    INX    H        ;Bump ptr
  785.         MOV    A,L        ;Get LS byte
  786.         CPI    (INT$BUF+INTSIZ) AND 0FFH ;Buffer end?
  787.         RNZ            ;No, return with the ptr as is
  788.         LXI    H,INT$BUF    ;Get buffer stat addr
  789.         RET            ;Return the reset ptr
  790.  
  791. ;
  792. ;    Interrupt Routine Data, Pointer, and Buffer area
  793. ;
  794. I$NODI:        DB    'Non standard BIOS -- Cannot continue',CR,LF,'$'  
  795.  
  796. I$STR:        DB    03EH,08EH,0D3H,084H ;MVI A,8EH   OUT 84H
  797.  
  798. INT$VCT:    DS    3        ;Old 38H vector data
  799. INT$NOP:    DS    2*5        ;Up to 5 DI's
  800.  
  801. INTSIZ:        EQU    200        ;Buffer up to 200 characters
  802. INT$CNT:    DB    0        ;Count of bytes in buffer
  803. INT$INP:    DW    INT$BUF        ;Interrput service rtn ptr
  804. INT$OUTP:    DW    INT$BUF        ;MEX buffer ptr
  805. INT$BUF:    DS    INTSIZ        ;Pending data buffer
  806.  
  807.         ENDIF
  808.  
  809.  
  810.  
  811. ;******************************************************************************
  812. ;
  813. ;    Message and data area
  814. ;
  815. ;******************************************************************************
  816.  
  817. CURURT:    DB    DEFCTB        ;Current UART configuration bits
  818.  
  819. BAUDMSG:DB    CR,LF,'Baud Rate:    $'
  820. STOPMSG:DB    CR,LF,'Stop bits:    $'
  821. WLMSG:    DB    CR,LF,'Word length:    $'
  822. PARMSG:    DB    CR,LF,'Parity:        $'
  823.  
  824. POFMSG:    DB    'off$',CR,LF
  825. ODDMSG:    DB    'on and odd$',CR,LF
  826. EVEMSG:    DB    'on and even$',CR,LF
  827.  
  828. CLSMSG:    DB    CR,LF,1AH,'$'
  829. EOSMSG:    DB    CR,LF,19H,'$'
  830.  
  831. SOMESG:    DB    'TRS Mod 4 CP/M 2.2 overlay V'
  832.     DB    REV/10+'0'
  833.     DB    '.'
  834.     DB    REV MOD 10+'0'
  835.     IF    MMINTR
  836.     DB    ' (Interrupt Driven)'
  837.     ENDIF
  838.     DB    CR,LF,'$'
  839.  
  840. NOMESG:    DB    ONV,'no $'
  841. CARMSG:    DB    ONV,'carrier present',INV,CR,LF,'$'
  842.  
  843. ;***************************************************************************
  844. ;
  845. ;    MEX legal command tables
  846. ;
  847. ;***************************************************************************
  848.  
  849. CMDTBL:    DB    '?'+80H        ;"set ?"
  850.     DW    STHELP
  851.     DB    'BAU','D'+80H    ;"set baud ?'
  852.     DW    STBAUD
  853.     DB    'WOR','D'+80H    ;set word length
  854.     DW    STWORD-STTABL
  855.     DB    'PARIT','Y'+80H ;set parity
  856.     DW    STPAR-STTABL
  857.     DB    'STO','P'+80H    ;set stop bits
  858.     DW    STSTOP-STTABL
  859.     DB    0    
  860.  
  861. ;
  862. ;    UART data format parameters
  863. ;
  864. STTABL:                ;Start of UART control parameters
  865.  
  866. STSTOP:    DB    '1'+80h        ;Legal stop bits settings
  867.     DB    0FFH-U$STOP,U$STP1
  868.     DB    '2'+80h        ;2 bits
  869.     DB    0FFH-U$STOP,U$STP2
  870.     DB    0
  871.  
  872. STPAR:    DB    'OD','D'+80h    ;Odd parity and ON
  873.     DB    0FFH-U$PART,U$PROD+U$PRON
  874.     DB    'EVE','N'+80h    ;Even parity and ON
  875.     DB    0FFH-U$PART,U$PREV+U$PRON
  876.     DB    'OF','F'+80h    ;Parity OFF
  877.     DB    0FFH-U$PART,U$PROF
  878.     DB    0
  879.  
  880. STWORD:    DB    '5'+80h        ;5 Bits per byte
  881.     DB    0FFH-U$WORD,U$WRD5
  882.     DB    '6'+80h        ;6 Bits per byte
  883.     DB    0FFH-U$WORD,U$WRD6
  884.     DB    '7'+80h        ;7 Bits per byte
  885.     DB    0FFH-U$WORD,U$WRD7
  886.     DB    '8'+80h        ;8 Bits per byte
  887.     DB    0FFH-U$WORD,U$WRD8
  888.     DB    0
  889.  
  890. ;
  891. ;    Legal baud settings table
  892. ;
  893. STBDTB:    DB    '30','0'+80H    ;300 Baud
  894.     DB    1,055H        ;MEX speed,UART baud speed
  895.     DB    '120','0'+80H    ;1200 Baud
  896.     DB    5,077H
  897.     DB    '240','0'+80H    ;2400 Baud
  898.     DB    6,0AAH
  899.     DB    '480','0'+80H    ;4800 Baud
  900.     DB    7,0CCH
  901.     DB    '960','0'+80H    ;9600 Baud
  902.     DB    8,0EEH
  903.     DB    '1920','0'+80H    ;19200 Baud
  904.     DB    9,0FFH
  905.     DB    0
  906.  
  907. ;
  908. ;    Help menu for SET command
  909. ;
  910. HLPMSG:    DB    CR,LF,'SET BAUD 300 <or> 1200 <or> 2400 <or> 4800 <or> 9600'
  911.     DB    CR,LF,'SET PARITY OFF <or> ODD <or> EVEN'
  912.     DB    CR,LF,'SET WORD 5 <or> 6 <or> 7 <or> 8'
  913.     DB    CR,LF,'SET STOP 1 <or> 2'
  914.     DB    CR,LF,'$'        
  915. ;
  916. ;-----------------------------------------------------------------------------
  917. ; NOTE:  MUST TERMINATE PRIOR TO 0B00H (with Smartmodem or Anchor)
  918. ;-----------------------------------------------------------------------------
  919. ; End of TRS-80 MOD IV  MEX modem overlay
  920. ;
  921. ;******************************************************************************
  922.  
  923.      END    ;
  924. S-80 MOD IV  MEX modem overlay