home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / mex / mxo-sy21.asm < prev    next >
Assembly Source File  |  1994-07-13  |  29KB  |  852 lines
  1. ;    Title    'MEX overlay for the Sanyo MBC-1000 Computer'
  2. ;
  3. ;
  4. ; This file adapts the Sanyo MBC-1000 computer to the MEX modem program.
  5. ; 
  6. ;
  7. REV    EQU    21        ;overlay revision level
  8. ;
  9. ; 09/15/84: Revision 2.1  A major revision.  Added features of SET SPKR,
  10. ;    SET WAIT, and SET DIAL, and disable auto-answer.  All the routines 
  11. ;    were borrowed from MXM-US13.ASM but with great difficulty and much
  12. ;    alteration.  Added conditional assembly for smartmodem (SMMODEM) &
  13. ;    ANCHOR, added DELAY to slow modem commands where the Anchor can 
  14. ;    catch them, and fixed a revision 2.0 bug where the SET status would
  15. ;    lose the current baudrate info.  This revision tested with an Anchor
  16. ;    Mark XII Smartmodem until all works.  Other smartmodems may require
  17. ;    revision of delays and timing constants.  Sanyo does not make pin 8
  18. ;    of the RS-232C connector available so the DCD (Data Carrier Detect)
  19. ;    cannot be sensed and the Carrier Check and Carrier Show (CARRCK and
  20. ;    CARRSH) portions were eliminated. Altered the SET status display to
  21. ;    suit my taste and always provide status with help commands. Other
  22. ;    modems are cautioned that their unique portions are essentially
  23. ;    untested.  Tested with MX-SM13A & MEX111.       ((Bob Sandel))     
  24. ;
  25. ; 08/09/84: Revision 2.0  Combined MXO-SY11 and M7SY-3.ASM
  26. ;    Added variables PTIMER, PBAUD, SQWV2 & N8251. Cleaned up some minor bugs
  27. ;    in the OR routine for the 8251 output & insured out of mode state always
  28. ;    occurs in SBAUD.  Added comments where changes were made.   (Bob Sandel)
  29. ;
  30. ;--------------------------------------------------------------------
  31. ;
  32. ;  THIS MODIFICATION MAKES USE OF TIMER 2 OF THE 8253 PROGRAMMABLE
  33. ;  INTERVAL TIMER (IC4) ON THE SERIAL I/O BOARD OF THE SANYO MBC-1000.
  34. ;
  35. ;  To use this program, the serial I/O board must be modified as follows:
  36. ;
  37. ;  1. Cut etch from IC18 Pin 1 to JP2 Pin 8.
  38. ;  2. Install jumper from IC18 Pin 1 to IC4 Pin 18.
  39. ;  3. Install jumper from IC4 Pin 17 to JP2 Pin 8.
  40. ;  4. Install jumper from IC4 Pin 16 to IC4 Pin 14.
  41. ;  5. Move jumper strap to JP2 Pin 8 for programmable baud rate, other
  42. ;     pins (1-7) can still be used for standard baud rate selections.
  43. ;  6. Hardware modification is now complete.
  44. ;
  45. ; You will want to look this file over carefully. There are a number of
  46. ; options that you can use to configure the program to suit your taste.;
  47. ; Edit for your preferences then follow the "TO USE:" example shown below.
  48. ;
  49. ; Use the "SET" command to change the baudrate when desired.  It starts
  50. ; out at 1200 baud when the program is first called up.  Because of tem- 
  51. ; perature and component variations, you mave have to alter the timing
  52. ; parameters BD110-BD19K, plus or minus 1 or 2 numbers, if CRC errors 
  53. ; occur frequently during transmission and reception.
  54. ;
  55. ; Only 300 & 1200 Baud are enabled; info for other baudrates is located
  56. ; in table form above INITBD. For full capability, N8251 would have to
  57. ; be implemented via a second lookup table.
  58. ;
  59. ;
  60. ; _______________________________________________________________________
  61. ;
  62. ; Note that all overlays may freely use memory up to 0CFFH.  If your
  63. ; overlay must work with the MEX Smartmodem overlay (MXO-SMxx.ASM) or
  64. ; the MEX DATEC 212 overlay (MXO-DT10.ASM), the physical modem overlay
  65. ; should terminate by 0AFFH.
  66. ;
  67. ; The SET command allows the user to change the baud rates, and the
  68. ; parity.  The parity options are: No parity (NONE); Even parity (EVEN);
  69. ; Even parity with 8 data bits (EVEN8); Odd parity (ODD); and Odd parity
  70. ; with 8 data bits (ODD8).  EVEN8 and ODD8 are for special purposes and
  71. ; will most likely never be used.
  72. ;_______________________________________________________________________
  73. ;
  74. ; Misc equates
  75. ;
  76. YES     EQU    0FFH
  77. NO      EQU    0
  78. NA      EQU    0FFH        ;Value for baud rate not available
  79. ;
  80. SMMODEM EQU     YES             ;Yes=Smartmodem
  81. ANCHOR  EQU     YES             ;Anchor has no speaker or programmable wait
  82.                                 ;No=Hayes, U.S. Robotics  
  83. BELL    EQU    07H        ;bell
  84. TAB     EQU    09H             ;tab
  85. LF      EQU    0AH        ;line feed
  86. CR      EQU    0DH        ;carriage return
  87. ESC     EQU    1BH        ;escape
  88. TPA     EQU     0100H           ;Transient Program Area
  89. MEX     EQU     0D00H           ;Address of the service processor 
  90. ;
  91. ;
  92. ; The following information was altered for the Sanyo MBC-1000
  93. ;
  94. PORT:   EQU     0A5H    ;Sanyo 8251 modem USART control port
  95. PTIMER  EQU     0A3H    ;8253 programmable interval timer control
  96. PBAUD   EQU     0A2H    ;8253 data port (square wave, n/2+n/2)
  97. ;
  98. MODCTL:    EQU    PORT    ;MODEM CONTROL PORT
  99. MODDAT:    EQU    PORT-1    ;MODEM DATA PORT
  100. ;
  101. MDRCVB: EQU     00000010B       ;bit to test for RECEIVE
  102. MDRCVR: EQU     00000010B       ;value when READY
  103. MDSNDB: EQU     00000001B       ;bit to test for SEND
  104. MDSNDR: EQU     00000001B       ;value when READY
  105. EVEN    EQU     01111000B       ;EVEN parity, 7 data bits
  106. EVEN8   EQU     01111100B       ;EVEN parity, 8 data bits
  107. ODD     EQU     01011000B       ; ODD parity, 7 data bits
  108. ODD8    EQU     01011100B       ; ODD parity, 8 data bits
  109. NONE    EQU     01001100B       ;  no parity, 8 data bits = NONE
  110. ;
  111. ;
  112. SQWV2   EQU     10010110B      ;Configures 8253 Timer-2 for square waves
  113. N8251   EQU     00000010B      ;See 8251 lookup table below (150-1200 baud)
  114. ;
  115. ;  Progammable Baud Rate factors (theoretical)        
  116. ;
  117. ;  Minor adjustment of 8253 n +1,-1 may be required    8253      8251 
  118. ;                                                      ----      ----
  119. BD110:          EQU     NA              ;NO 110    |    2C        03
  120. BD300:          EQU     041H            ; <300>    |    40        02
  121. BD450:          EQU     NA              ;NO 450    |    2B        02    
  122. BD600:          EQU     NA              ;NO 600    |    20        02
  123. BD710:          EQU     NA              ;NO 710    |    1B        02
  124. BD1200:         EQU     010H            ;<1200>    |    10        02
  125. BD2400:         EQU     NA              ;NO 2400   |    80        01
  126. BD4800:         EQU     NA              ;NO 4800   |    40        01
  127. BD9600:         EQU     NA              ;NO 9600   |    20        01 
  128. BD19K:          EQU     NA              ;NO 19200  |    10        01
  129. ;
  130. ;
  131. INITBD:        EQU    5        ;Initial baud rate (1200)
  132. ;
  133. ; Control bytes
  134. ;
  135. RESET1  EQU     10000111B               ;Initialize UART
  136. RESET2  EQU     01000000B               ;Internal reset
  137. CHIPSET EQU     00100111B               ;DTR, RTS, RE, TE
  138. DISCNT  EQU     00010111B               ;no DTR, RTS, RE, TE
  139. ;
  140. BREAK   EQU     CHIPSET OR 8H   ;BREAK character
  141. ;
  142. ;
  143. ; MEX service processor stuff ... MEX supports an overlay service
  144. ; processor, located at 0D00H (and maintained at this address from
  145. ; version to version).  If your overlay needs to call BDOS for any
  146. ; reason, it should call MEX instead; function calls below about
  147. ; 240 are simply passed on to the BDOS (console and list I/O calls
  148. ; are specially handled to allow modem port queueing, which is why
  149. ; you should call MEX instead of BDOS).  MEX uses function calls
  150. ; above about 244 for special overlay services (described below).
  151. ;
  152. ; Some sophisticated overlays may need to do file I/O; if so, use
  153. ; the PARSFN MEX call with a pointer to the FCB in DE to parse out
  154. ; the name.  This FCB should support a spare byte immediately pre-
  155. ; ceeding the actual FCB (to contain user # information).  If you've
  156. ; used MEX-10 for input instead of BDOS-10 (or you're parsing part
  157. ; of a SET command line that's already been input), then MEX will
  158. ; take care of DU specs, and set up the FCB accordingly.  There-
  159. ; after all file I/O calls done through the MEX service processor
  160. ; will handle drive and user with no further effort necessary on
  161. ; the part of the programmer.
  162. ;
  163. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  164. TIMER    EQU    254        ;delay 100ms * reg B
  165. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  166. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  167. SNDRDY    EQU    251        ;test for modem-send ready
  168. RCVRDY    EQU    250        ;test for modem-receive ready
  169. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  170. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  171. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  172. PARSFN    EQU    246        ;parse filename from input stream
  173. BDPARS    EQU    245        ;parse baud-rate from input stream
  174. SBLANK    EQU    244        ;scan input stream to next non-blank
  175. EVALA    EQU    243        ;evaluate numeric from input stream
  176. LKAHED    EQU    242        ;get nxt char w/o removing from input
  177. GNC    EQU    241        ;get char from input, cy=1 if none
  178. ILP    EQU    240        ;inline print
  179. DECOUT    EQU    239        ;decimal output
  180. PRBAUD    EQU    238        ;print baud rate
  181. ;
  182. ;
  183. CONOUT    EQU    2        ;simulated BDOS function 2: console char out
  184. PRINT    EQU    9        ;simulated BDOS function 9: print string
  185. INBUF    EQU    10        ;input buffer, same structure as BDOS 10
  186. ;
  187.     ORG    TPA        ;we begin
  188. ;
  189. ;
  190.     DS    3        ;MEX has a JMP START here
  191. ;
  192. ; The following variables are located at the beginning of the program
  193. ; to facilitate modification without the need of re-assembly. They will
  194. ; be moved in MEX 2.0.
  195. ;
  196. PMODEM: DB    NO              ;yes=PMMI modem \ / These 2 locations are not
  197. SMODEM: DB    SMMODEM         ;yes=Smartmodem / \ referenced by MEX
  198. TPULSE: DB      'P'             ;T=touch, P=pulse (not referenced by MEX)
  199. CLOCK:  DB      40              ;clock speed x .1, up to 25.5 mhz.
  200. MSPEED: DB      INITBD          ;sets initial baud rate
  201.                                 ;0=110    1=300  2=450  3=600  4=710
  202.                                 ;5=1200 6=2400 7=4800 8=9600 9=19200
  203. BYTDLY: DB    5        ;default time to send character in
  204.                                 ;terminal mode file transfer (0-9)
  205.                                 ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  206. CRDLY:  DB    5        ;end-of-line delay after CRLF in terminal
  207.                                 ;mode file transfer for slow BBS systems
  208.                                 ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  209. COLUMS: DB    5        ;number of directory columns
  210. SETFL:  DB    YES        ;yes=user-defined SET command
  211. SCRTST: DB    YES        ;yes=if home cursor and clear screen
  212.                                 ;routine at CLRSCRN
  213.         DB    0        ;was once ACKNAK, now spare
  214. BAKFLG: DB    NO        ;yes=make .BAK file
  215. CRCDFL:    DB    YES        ;yes=default to CRC checking
  216.                                 ;no=default to Checksum checking
  217. TOGCRC: DB    YES        ;yes=allow toggling of Checksum to CRC
  218. CVTBS:  DB    NO        ;yes=convert backspace to rub
  219. TOGLBK: DB    YES        ;yes=allow toggling of bksp to rub
  220. ADDLF:  DB    NO        ;no=no LF after CR to send file in
  221.                                 ;terminal mode (added by remote echo)
  222. TOGLF:  DB    YES        ;yes=allow toggling of LF after CR
  223. TRNLOG: DB    NO        ;yes=allow transmission of logon
  224.                                 ;write logon sequence at location LOGON
  225. SAVCCP: DB    YES        ;yes=do not overwrite CCP
  226. LOCNXT: DB    NO        ;yes=local cmd if EXTCHR precedes
  227.                                 ;no=not local cmd if EXTCHR precedes
  228. TOGLOC: DB    YES        ;yes=allow toggling of LOCNXTCHR
  229. LSTTST: DB    YES        ;yes=allow toggling of printer on/off
  230.                                 ;in terminal mode. Set to no if using
  231.                                 ;the printer port for the modem
  232. XOFTST: DB    NO        ;yes=allow testing of XOFF from remote
  233.                                 ;while sending a file in terminal mode
  234. XONWT:  DB    NO        ;yes=wait for XON after sending CR while
  235.                                 ;transmitting a file in terminal mode    
  236. TOGXOF: DB    YES        ;yes=allow toggling of XOFF testing
  237. IGNCTL: DB    YES        ;yes=do not send control characters
  238.                                 ;above CTL-M to CRT in terminal mode
  239.                                 ;no=send any incoming CTL-char to CRT
  240. EXTRA1: DB    0        ;for future expansion
  241. EXTRA2: DB    0        ;for future expansion
  242. BRKCHR: DB    '@'-40H        ;^@ = Send a 300 ms. break tone
  243. NOCONN: DB    'N'-40H        ;^N = Disconnect from phone line
  244. LOGCHR: DB    'L'-40H        ;^L = Send logon
  245. LSTCHR: DB    'P'-40H        ;^P = Toggle printer
  246. UNSVCH: DB    'R'-40H        ;^R = Close input text buffer
  247. TRNCHR: DB    'T'-40H        ;^T = Transmit file to remote
  248. SAVCHR: DB    'Y'-40H        ;^Y = Open input text buffer
  249. EXTCHR: DB    '^'-40H        ;^^ = Send next character
  250. ;
  251. ; Equates used only by PMMI routines grouped together here.
  252. ;
  253.     DS    2        ;not used
  254. ;
  255. ; Low-level modem I/O routines: this will be replaced with
  256. ; a jump table in MEX 2.0 (you can insert jumps here to longer
  257. ; routines if you'd like ... I'd recommend NOT putting part of
  258. ; a routine in this area, then jumping to the rest of the routine
  259. ; in the non-fixed area; that will complicate the 2.0 conversion)
  260. ;
  261. INCTL:    IN    MODCTL        ;in modem control port
  262.     RET
  263.     DB    0,0,0,0,0,0,0    ;spares if needed
  264. ;
  265. OTDATA:    OUT    MODDAT        ;out modem data port
  266.     RET
  267.     DB    0,0,0,0,0,0,0    ;spares if needed
  268. ;
  269. INPORT:    IN    MODDAT        ;in modem data port
  270.     RET
  271.     DB    0,0,0,0,0,0,0    ;spares if needed
  272. ;
  273. ; Bit-test routines.  These will be merged with the above
  274. ; routines in MEX 2.0 to provide a more reasonable format
  275. ;
  276. MASKR:    ANI MDRCVB ! RET    ;bit to test for receive ready
  277. TESTR:    CPI MDRCVR ! RET    ;value of receive bit when ready
  278. MASKS:    ANI MDSNDB ! RET    ;bit to test for send ready
  279. TESTS:    CPI MDSNDR ! RET    ;value of send bit when ready
  280. ;
  281. ;
  282. ; Unused area: was once used for special PMMI functions,
  283. ; Now used only to retain compatibility with MDM overlays.
  284. ; You may use this area for any miscellaneous storage you'd
  285. ; like but the length of the area *must* be 12 bytes.
  286. ;
  287.     DS    12
  288. ;
  289. ; Special modem function jump table: if your overlay cannot handle
  290. ; some of these, change the jump to "DS 3", so the code present in
  291. ; MEX will be retained.
  292. ;
  293. LOGON:    DS    2        ;needed for MDM compat, not ref'd by MEX
  294. DIALV:    DS    3        ;dial digit in A (see info at PDIAL)
  295. DISCV:    DS    3        ;disconnect the modem
  296. GOODBV: JMP    DUMMY        ;called before exit to CP/M
  297. INMODV: JMP    NITMOD        ;initialization. Called at cold-start
  298. NEWBDV: JMP    SBAUD        ;set baud rate
  299. NOPARV: DS    3        ;set for no parity (called after transfer)
  300. PARITV: DS    3        ;set modem parity (called before transfer)
  301. SETUPV: JMP    SETCMD        ;SET command
  302. SPMENV: DS    3        ;not used with MEX
  303. VERSNV: JMP    SYSVER        ;Overlay's voice in the sign-on message
  304. BREAKV: JMP    SBREAK        ;send a break
  305. ;
  306. ; The following jump vector provides the overlay with access to special
  307. ; routines in the main program (retained and supported in the main pro-
  308. ; gram for MDM overlay compatibility). These should not be modified by
  309. ; the overlay.
  310. ;
  311. ; Note that for MEX 2.0 compatibility, you should not try to use these
  312. ; routines, since this table will go away with MEX 2.0 (use the MEX
  313. ; service call processor instead).
  314. ;
  315. ILPRTV:    DS    3        ;replace with MEX function 9
  316. INBUFV:    DS    3        ;replace with MEX function 10
  317. ILCMPV:    DS    3        ;replace with table lookup funct. 247
  318. INMDMV:    DS    3        ;replace with MEX function 255
  319. NXSCRV:    DS    3        ;not supported by MEX (returns w/no action)
  320. TIMERV:    DS    3        ;replace with MEX function 254
  321. ;
  322. ;
  323. ; Clear/screen and clear/end-of-screen. Each routine must use the
  324. ; full 9 bytes alloted (may be padded with nulls).
  325. ;
  326. ; These routines (and other screen routines that MEX 2.0 will sup-
  327. ; port) will be accessed through a jump table in 2.0, and will be
  328. ; located in an area that won't tie the screen functions to the
  329. ; modem overlay (as the MDM format does).
  330. ;
  331. CLREOS:    LXI    D,EOSMSG
  332.         MVI    C,PRINT
  333.         CALL    MEX
  334.         RET
  335. ;
  336. ;
  337. CLS:    LXI    D,CLSMSG        ;null unless patched
  338.         MVI    C,PRINT
  339.         CALL    MEX
  340.         RET
  341. ;
  342. ;------------------------------------------------------------
  343. ;
  344. ;    *** END OF FIXED FORMAT AREA ***
  345. ;
  346. ;------------------------------------------------------------
  347. ;
  348. ; strings to clear-to-end-of-screen, and clear-screen
  349. ;
  350. EOSMSG:    DB    0,0,0,0,0,0,'$'        ;clear to end-of-screen (0 for pause)
  351. CLSMSG:    DB    1AH,0,0,0,0,0,'$'    ;clear whole screen (0 for pause)
  352. ;
  353. ; Modem initialization.
  354. ;
  355. NITMOD: MVI     A,SQWV2         ;Initialize 8253 chip so counter 2 becomes
  356.         OUT     PTIMER          ;baud rate programmable clock (square wave)
  357.         LDA    MSPEED
  358.         CALL    SBAUD        ;set the baudrate
  359.  ;
  360.    IF SMMODEM                   ;if smartmodem, send start-up cmd(s)
  361. INITSM:
  362.         LXI     H,INISTR        ;point to initialization string
  363. SENDLP: MVI     C,SNDRDY        ;MEX service function # 251                         
  364.         CALL    MEX             ;test for modem-send-ready
  365.         JNZ     SENDLP          ;loop if not ready
  366.         MOV     A,M             ;get character
  367.         INX     H               ;increment to next character address
  368.         CPI     '$'             ;end-of-string ?
  369.         JZ      INITEX          ;Yes, exit
  370.         MOV     B,A             ;No, put character in B
  371.         MVI     C,SNDCHR        ;MEX service function # 249
  372.         CALL    MEX             ;let MEX output character to modem
  373.         CALL    DELAY           ;needed for Anchor: others ???
  374.         JMP     SENDLP          ;loop 'til end-of message
  375. ;
  376. INITEX: MVI     B,5             ;wait 0.5 sec for modem to say "OK"
  377.         MVI     C,TIMER         ;MEX service function # 254
  378.         CALL    MEX             ;kill time
  379. ;
  380.    ENDIF                        ;Smartmodem
  381. ; 
  382.        RET
  383. ;
  384. DELAY:  MVI    B,1             ;now set for 100 milliseconds
  385.         MVI     C,TIMER         ;play with values until modem works
  386.         CALL    MEX
  387.         RET          
  388. ;
  389. ; You may define an intialization string in INISTR to set up smartmodem
  390. ; in any configuration desired. String must end with a '$'
  391. ;
  392. ;
  393. ; Command string sent to modem after I/O initialization
  394. ;
  395.   IF SMMODEM
  396. ;
  397. INISTR:
  398.         DB      'ATV0',CR       ; Disable verbose mode
  399.         DB    'ATS0=0',CR    ; Disable auto-answer
  400.    ENDIF                        ; Smartmodem 
  401. ;
  402.    IF SMMODEM AND NOT ANCHOR    ; Pls check that your modem supports 
  403.     DB    'ATX1',CR    ; Send extended result codes
  404. SPBYTE:    DB    'ATM1',CR    ; Speaker on 'til connect
  405. WABYTE:    DB    'ATS7=30',CR    ; Wait 30 seconds for carrier
  406.    ENDIF                        ; END of smartmodem AND not Anchor
  407. ;
  408.    IF SMMODEM                   ; continuation after Anchor part    
  409.         DB    'ATV1',CR    ; Set verbose result codes
  410.         DB      '$'             ; end-of-string :Must be here 
  411. ;
  412.    ENDIF                        ;Smartmodem 
  413. ;
  414.         RET
  415. ;
  416. ; Send-break routine
  417. ;
  418. SBREAK: MVI     A,BREAK
  419.         OUT     MODCTL
  420.         MVI     B,2             ;wait 200 ms
  421.         MVI     C,TIMER
  422.         CALL    MEX
  423.         MVI     A,CHIPSET       ;reset break
  424.         OUT     MODCTL
  425.         RET
  426. ;
  427. ; Exit routine --  called just before MEX exits to CP/M
  428. ;
  429. DUMMY:    RET            ;we don't need one
  430. ;
  431. ;
  432. ; Set Baud Rate
  433. ;
  434. ; New baud-rate code in A.
  435. ; NOTE: this routine (ie, the one vectored through NEWBDV) should
  436. ; update MSPEED with the passed code, but ONLY if that rate is
  437. ; supported by the hardware.
  438. ;
  439. ;     A=0:   110 baud       A=1:   300 baud      A=2:   450 baud
  440. ;     A=3:   600 baud       A=4:   710 baud      A=5:  1200 baud
  441. ;     A=6:  2400 baud       A=7:  4800 baud      A=8: 19200 baud
  442. ;
  443. SBAUD:    PUSH    H        ;don't alter anybody
  444.     PUSH    D
  445.     PUSH    B
  446.     MOV    C,A        ;save baud rate code  
  447.     MVI    B,0
  448.     LXI    H,BTABL        ;Get baudrate value
  449.     DAD    B               ;HL now contains address of baudrate number
  450.     MOV    A,M             ;A  now contains baudrate n
  451.     CPI    NA        ;See if baud rate valid
  452.     STC            ;set for not valid
  453.     JZ    NOTVAL        ;not valid
  454. ;
  455.                                 ;Set hardware/software implemented baudrate
  456.     OUT     PBAUD           ;8253 now set
  457. ;
  458.     MVI     A,RESET1        ;Insure out-of-mode state
  459.     OUT     MODCTL          ;Modem status port
  460.     MVI     A,RESET1        ;Do it again
  461.         OUT     MODCTL          ;For slight extra delay
  462.     MVI    A,RESET2        ;Then reset the USART 
  463.     OUT    MODCTL          ;Modem status port
  464.     XTHL            ;delay -- must be in pairs
  465.     XTHL
  466.         MVI     A,N8251         ;This factor works for the range 150-1200 baud
  467.     LXI    H,PARITY        ;A contains baudrate factor
  468.         ORA     M               ;OR parity and data length w baudrate factor    
  469.     OUT    MODCTL          ;8251 Mode now set
  470.     MOV     A,C        ; get baud rate code
  471.     STA    MSPEED        ;save baud rate code
  472.     MVI    A,CHIPSET    ;set chip for I/O
  473.     OUT    MODCTL          ;8251 Command now set
  474.     IN      MODDAT          ;Clear data port
  475.     XRA    A        ;clear carry flag
  476. NOTVAL:    POP    B
  477.     POP    D
  478.     POP    H
  479.     RET
  480. ;
  481. ; Parity control byte location
  482. ;
  483. PARITY:    DB    NONE
  484. ;
  485. ; Baud rate table
  486. ;
  487. BTABL:    DB    BD110
  488.     DB    BD300
  489.     DB    BD450
  490.     DB    BD600
  491.     DB    BD710
  492.     DB    BD1200
  493.     DB    BD2400
  494.     DB    BD4800
  495.     DB    BD9600
  496.     DB    BD19K
  497. ; 
  498. ; Sign-on message
  499. ; 
  500. SYSVER:    
  501.         LXI     D,SOMESG    ; Point to signon message
  502.         MVI     C,PRINT         ; MEX print string
  503.         CALL    MEX        ; Print message on term
  504. ;
  505. CARRSH:                ; Carrier Show & Carrier Detect deleted
  506. CARRCK: RET                     ; No carrier detect capability
  507. ;
  508. ;
  509. SOMESG:
  510.     DB    'Sanyo MBC-1000 programmable baudrate version '
  511.         DB    REV/10+'0','.'
  512.     DB    REV MOD 10+'0',CR,LF,'$'
  513. ;
  514. ;
  515. ; Newline on console
  516. ;
  517. CRLF:    MVI    A,CR
  518.     CALL    TYPE
  519.     MVI    A,LF        ;fall into TYPE
  520. ;
  521. ; type char in A on console
  522. ;
  523. TYPE:    PUSH    H        ;save 'em
  524.     PUSH    D
  525.     PUSH    B
  526.     MOV    E,A        ;align output character
  527.     MVI    C,CONOUT    ;print via MEX
  528.     CALL    MEX
  529.     POP    B
  530.     POP    D
  531.     POP    H
  532.     RET
  533. ;
  534. ;------------------------------------------------------------
  535. ;
  536. ; The remainder of this overlay implements a very versatile
  537. ; SET command
  538. ;
  539. ; Control is passed here after MEX parses a SET command.
  540. ;
  541. SETCMD:    CALL    CRLF            ;for better readability
  542.         MVI    C,SBLANK    ;any arguments?
  543.     CALL    MEX
  544.     JC    SETSHO        ;if not, go print out values
  545.     LXI    D,CMDTBL    ;parse command
  546.     CALL    TSRCH        ;from table
  547.     PUSH    H        ;any address on stack
  548.     RNC            ;if we have one, execute it
  549.     POP    H        ;nope, fix stack
  550. SETERR:    LXI    D,SETEMS    ;print error
  551.     MVI    C,PRINT
  552.     CALL    MEX
  553.     RET
  554. ;
  555. SETEMS:    DB    CR,LF,'SET command error',CR,LF,'$'
  556. ;
  557. ; SET command table ... note that tables are constructed of command-
  558. ; name (terminated by high bit=1) followed by word-data-value returned
  559. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  560. ; a binary zero.
  561. ;
  562. ; Note that LOOKUP attempts to find the next item in the input stream
  563. ; in the table passed to it in HL ... if found, the table data item is
  564. ; returned in HL; if not found, LOOKUP returns carry set.
  565. ;
  566. CMDTBL:    DB    '?'+80H            ;"set ?"
  567.     DW    STHELP
  568.     DB    'BAU','D'+80H        ;"set baud"
  569.     DW    STBAUD
  570.     DB    'PARIT','Y'+80H        ;"set parity"
  571.     DW    STPAR
  572. ;
  573.    IF NOT ANCHOR                ; Anchor has no speaker or prog. wait
  574.     DB    'SPK','R'+80H    ; "set spkr"
  575.     DW    STSPKR
  576.     DB    'WAI','T'+80H    ; "set wait"
  577.         DW    STWAIT
  578.    ENDIF                        ;not Anchor modem
  579. ;
  580.     DB    'DIA','L'+80H    ; "set dial"
  581.     DW    STDIAL
  582. ;
  583.  
  584.     DB    0        ;<<=== table terminator
  585. ;
  586. ; SET <no-args>: print current statistics
  587. ;
  588. SETSHO:    
  589.     LXI    H,SHOTBL    ;get table of SHOW subroutines
  590. SETSLP:    MOV    E,M        ;get table address
  591.     INX    H
  592.     MOV    D,M
  593.     INX    H
  594.     MOV    A,D        ;end of table?
  595.     ORA    E
  596.     JZ      sthelp          ;exit with help menu if so
  597.     PUSH    H        ;save table pointer
  598.     XCHG            ;adrs to HL
  599.     CALL    GOHL        ;do it
  600.     CALL    CRLF        ;print newline
  601.     MVI    C,CHEKCC    ;check for console abort
  602.     CALL    MEX
  603.     POP    H        ;it's done
  604.     JNZ    SETSLP        ;continue if no abort
  605.     RET
  606. ;
  607. GOHL:    PCHL
  608. ;
  609. ;
  610. ; table of SHOW subroutines
  611. ; 
  612. SHOTBL:    DW    BDSHOW
  613.     DW    PSHOW
  614.   IF NOT ANCHOR                 ;Anchor has no speaker or prog. wait
  615.     DW    SPSHOW
  616.       DW    WASHOW
  617.   ENDIF                         ;not Anchor
  618.     DW    DISHOW
  619.     DW    0        ; <<== table terminator
  620. ;
  621. ;
  622. ; SET ?  processor
  623. ;
  624. STHELP:    LXI    D,HLPMSG
  625.     MVI    C,PRINT
  626.     CALL    MEX
  627.     RET
  628. ;
  629. ; The help message
  630. ;
  631. HLPMSG:    DB    CR,LF,'SET commands:',CR,LF
  632. ;
  633.     DB    CR,LF,'SET BAUD 300 <or> 1200'
  634. ;
  635.     DB    CR,LF,'SET PARITY EVEN[8] <or> ODD[8] <or> NONE'
  636. ; 
  637.    IF NOT ANCHOR                 ; Anchor has no speaker or prog.wait
  638. ;
  639.         DB    CR,LF,'SET SPKR <OFF> or <ON> or <DEBUG>'
  640.         DB    CR,LF,'SET WAIT <30> or <60> or <90>'
  641.    ENDIF                         ; not Anchor    
  642. ;
  643.     DB    CR,LF,'SET DIAL <TOUCH> or <PULSE>'
  644. ;
  645.     DB    CR,LF,LF,'$'
  646. ;
  647. ; SET BAUD processor
  648. ;
  649. STBAUD:    MVI    C,BDPARS    ;function code
  650.     CALL    MEX        ;let MEX look up code
  651.     JC    SETERR        ;invalid code
  652.     CALL    SBAUD        ;no, try to set it
  653.     JC    SETERR        ;not-supported code
  654.         JMP     SETSHO          ;review parameters
  655. ;
  656. BDSHOW:    CALL    ILPRT        ;display baud
  657.     DB    'Baud rate: ',0
  658.     LDA    MSPEED
  659.     MVI    C,PRBAUD    ;use MEX routine
  660.     CALL    MEX
  661.         CALL    CRLF
  662.     RET
  663. ;
  664. ; SET PARITY processor
  665. ;
  666. STPAR:    LXI    D,PARTBL    ;lookup next input item in table
  667.     CALL    TSRCH
  668.     JC    SETERR          ;if not found, error
  669.     MOV    A,L             ;get parity code
  670.     STA    PARITY        ;store it 
  671.     LDA    MSPEED        ;get baud rate code 
  672.     CALL    SBAUD           ;set parity
  673.         JMP     SETSHO          ;review parameters
  674. ;
  675. PSHOW:    CALL    ILPRT           ;show parity
  676.     DB    'Parity:    ',0
  677.     LXI    H,PARFND        ;find proper message
  678.     LDA    PARITY          ;get parity value
  679.     MOV    B,A
  680. FNDP:    MOV    A,M             ;see if parity value matches
  681.     ORA    A               ;first see if zero
  682.     JZ    SETERR          ;should never get here
  683.     CMP    B               ;match?
  684.     INX    H               ;point to first letter of message
  685.     JZ    CDISP           ;matches, type message
  686. FNDNXT:    MOV    A,M
  687.     ORA    A        ;see if end of last message
  688.     INX    H
  689.     JP    FNDNXT        ;not finished
  690.     INX    H        ;increment past parity byte
  691.     JMP    FNDP
  692. ;
  693. ; PARITY argument table
  694. ; Format of the table is:  Starting at PARTBL, the name is
  695. ; given (ending with 80H bit set), then the one byte code
  696. ; for setting that parity.  The next byte duplicates the
  697. ; NEXT parity code (used in PSHOW).  The byte at PARFND
  698. ; duplicates the first parity code.
  699. ;
  700. PARFND:    DB    EVEN
  701. PARTBL:    DB    'EVE','N'+80H    ;even parity, 7 data bits
  702.     DB    EVEN,EVEN8
  703.     DB    'EVEN','8'+80H    ;even parity, 8 data bits
  704.     DB    EVEN8,ODD
  705.     DB    'OD','D'+80H    ; odd parity, 7 data bits
  706.     DB    ODD,ODD8
  707.     DB    'ODD','8'+80H    ; odd parity, 8 data bits
  708.     DB    ODD8,NONE
  709.     DB    'NON','E'+80H    ;  no parity, 8 data bits
  710.     DB    NONE,0
  711. ;
  712.     DB    0        ;<<== table terminator
  713. ;
  714. ;
  715. ;
  716.    IF NOT ANCHOR                ; Anchor does not have speaker
  717. ;
  718. ; SET SPKR processor
  719. ;
  720. STSPKR:    LXI    D,SPKTBL    ; lookup next input item in table
  721.     CALL    TSRCH
  722.     JC    SETERR        ; if not found, error
  723.     STA    SPBYTE+1    ; store the spkr command
  724.     CALL    NITMOD        ; (re)initialize modem
  725.     JMP    SETSHO        ; review parameters
  726. ;
  727. SPSHOW:    CALL    ILPRT        ; show spkr mode
  728.     DB    'Speaker:   ' ,0
  729.     LDA    SPBYTE+1    ; get spkr byte
  730.     CPI    '1'
  731.     JZ    SPONPT        ; spkr on part-time
  732.     CPI    '2'
  733.     JZ    SPON        ; spkr on continuously
  734. ;
  735. SPOFF:    CALL    ILPRT
  736.     DB    'OFF',0
  737.     RET
  738. ;
  739. SPONPT:    CALL    ILPRT
  740.     DB    'ON until connect',0
  741.     RET
  742. ;
  743. SPON:    CALL    ILPRT
  744.     DB    'ON always',0
  745.     RET
  746. ;
  747. SPKTBL:    DB    'OF','F'+80H    ; set spkr off
  748.     DB    '0',0
  749.     DB    'O','N'+80H    ; set spkr on 'til connect    
  750.     DB    '1',0
  751.     DB    'DEBU','G'+80H    ; set spkr on continuously
  752.     DB    '2',0
  753.      DB    0        ; <<=== table terminator
  754. ;
  755. ;
  756. ;
  757. ; SET WAIT processor
  758. ;
  759. STWAIT:    LXI    D,WAITBL    ; lookup next input item in table
  760.     CALL    TSRCH           ; search for parameter value
  761.     JC    SETERR        ; if not found, error
  762.     STA    WABYTE+5    ; store the wait msb value
  763.     MVI    A,'0'        ; fake lsbyte
  764.     STA    WABYTE+6    ; store the wait lsb value
  765.     CALL    NITMOD        ; (re)initialize modem
  766.     JMP    SETSHO        ; review parameters
  767. ;
  768. WASHOW:    CALL    ILPRT
  769.     DB    'Wait:      ',0
  770.     LDA    WABYTE+5
  771.     CALL    TYPE        ; show msb
  772.     LDA    WABYTE+6
  773.     CALL    TYPE        ; show lsb
  774.     CALL    ILPRT
  775.     DB    ' seconds for carrier',0
  776.     RET
  777. ;
  778. WAITBL:    DB    '3','0'+80H    ; "set wait 30"
  779.     DB    '3',0
  780.     DB    '6','0'+80H    ; "set wait 60"
  781.     DB    '6',0
  782.     DB    '9','0'+80H    ; "set wait 90"
  783.     DB    '9',0
  784.     DB    0        ; <<=== table terminator
  785. ;
  786.    ENDIF                        ;not Anchor
  787. ;
  788. ;
  789. ;
  790. ; SET DIAL processor
  791. ;
  792. STDIAL:    LXI    D,DIATBL    ; lookup next input item in table
  793.     CALL    TSRCH           ; search for parameter value
  794.     JC    SETERR        ; if not found, error
  795.     STA    TPULSE        ; store the dial command
  796.     JMP    SETSHO        ; review parameters
  797. ;
  798. DISHOW:    CALL    ILPRT        ; show dial mode
  799.     DB    'Dial:      ',0
  800.     LDA    TPULSE        ; get dial byte
  801.     CPI    'T'
  802.     JZ    TTONE        ; touch tone 
  803. ;
  804. PDIAL:    CALL    ILPRT
  805.     DB    'Pulse',0
  806.     RET
  807. ;
  808. TTONE:    CALL    ILPRT
  809.     DB    'Touch Tone',0
  810.     RET
  811. ;
  812. ; DIAL argument table
  813. ;
  814. DIATBL:    DB    'TOUC','H'+80H    ; touch tone
  815.     DB    'T',0
  816.     DB    'PULS','E'+80H    ; pulse dial
  817.     DB    'P',0
  818.     DB    0        ; <<=== table terminator
  819. ; 
  820. ;
  821. ;
  822. ;  Print message ending with 80H bit set
  823. ;
  824. CDISP:    MOV    A,M        ;get character to print
  825.     INX    H        ;point to next character
  826.     PUSH    PSW        ;save 80H bit
  827.     ANI    7FH        ;strip 80H bit just in case
  828.     CALL    TYPE
  829.     POP    PSW
  830.     ORA    A
  831.     JM    CRLF        ;finished
  832.     JMP    CDISP
  833. ;
  834. ; Compare next input-stream item in table @DE; CY=1
  835. ; if not found, else HL=matched data item
  836. ;
  837. TSRCH:    MVI    C,LOOKUP    ;get function code
  838.     JMP    MEX        ;pass to MEX processor
  839. ;
  840. ; Print in-line message ... blows away C register
  841. ;
  842. ILPRT:    MVI    C,ILP        ;get function code
  843.     JMP    MEX        ;go do it
  844. ;
  845. ;
  846. ;------------------------------------------------------------
  847. ;
  848. ; End of Sanyo MBC-1000 MEX modem overlay
  849. ;
  850. ;------------------------------------------------------------
  851. ;
  852.     END