home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / modems / modem2 / mboot3.asm < prev    next >
Assembly Source File  |  1983-09-09  |  8KB  |  566 lines
  1. ;
  2. ; MBOOT.ASM ver 3.0
  3. ; (revised 5 Nov 80)
  4. ;
  5. ;MODEM BOOT PROGRAM by Keith Petersen, W8SDZ.
  6. ;Thanks to John Taylor for idea of incorporating
  7. ;simple terminal routine.  Based on MODEM.ASM V2.0,
  8. ;by Ward Christensen with enhancements from MODEM527.
  9. ;
  10. ;CP/M - CP/M file transfer program (receive-only)
  11. ;
  12. ;This program is intended for use as a way to
  13. ;initially transfer MODEM.COM or MODEM.ASM to
  14. ;a new user.  It may be used with almost any
  15. ;modem (see equates).  If PMMI or D.C. Hayes modem
  16. ;is used, then uses 'ORIGINATE' mode, 300 baud.
  17. ;
  18. ;A simple terminal routine at start of program allows
  19. ;user to communicate with a remote system prior to
  20. ;receiving a file to make it possible to down-load
  21. ;a file without intervention on the part of the host
  22. ;system's operator.
  23. ;
  24. ;COMMANDS:  MBOOT FILENAME.FILETYPE
  25. ; or  MBOOT A:FILENAME.FILETYPE
  26. ; or  MBOOT B:FILENAME.FILETYPE
  27. ;
  28. ;The program will operate as a dumb terminal until
  29. ;an 'ESC' key is typed (ctrl-[).  It then branches
  30. ;to the receive routine.  The user may also exit
  31. ;to CP/M without opening the receive file by typing
  32. ;ctrl-E from the terminal.  The values for the escape
  33. ;and exit keys may be changed in accordance with the
  34. ;needs of the user - some keyboards do not have the
  35. ;'ESC' key and/or provision for control characters.
  36. ;See equates.
  37. ;
  38. ;NOTE: Comments for the source code and tabs have been
  39. ;removed to make this file easier to transport from one
  40. ;system to another.  (KBP)
  41. ;
  42. FALSE EQU 0
  43. TRUE  EQU NOT FALSE
  44. ;
  45. STDCPM EQU TRUE  ;TRUE, IS STANDARD CP/M
  46. ALTCPM EQU FALSE ;TRUE, IS ALTERNATE CP/M FOR H8 OR TRS80
  47. ;
  48.  IF STDCPM
  49. BASE EQU 0
  50.  ENDIF
  51. ;
  52.  IF ALTCPM
  53. BASE EQU 4200H
  54.  ENDIF
  55. ;
  56. EXITCHR EQU 05H ;CTL-E TO EXIT TERM MODE TO CP/M
  57. ESC     EQU 1BH ;ESCAPE TO EXIT TERM MODE TO FILE RCVE
  58. ;
  59. FASTCLK EQU FALSE ;TRUE FOR 4 MHZ CLOCK
  60. ;
  61. PMMI EQU TRUE  ;TRUE, IS PMMI MODEM
  62. DCH  EQU FALSE ;TRUE, IS D.C. HAYES MODEM
  63. ;
  64. ;IF YOU ARE USING AN EXTERNAL MODEM (NOT S-100 PLUG-IN)
  65. ;CHANGE THESE EQUATES FOR YOUR MODEM PORT REQUIREMENTS
  66. ;
  67. INITREQ EQU FALSE ;TRUE, IF MODEM PORT INIT. REQ'D
  68. INITC1  EQU 0AAH ;1ST INIT CHAR TO CTL PORT FOR USART
  69. INITC2  EQU 40H  ;2ND  "
  70. INITC3  EQU 4EH  ;3RD  "
  71. INITC4  EQU 37H  ;4TH  "
  72. ;
  73.  IF NOT PMMI AND NOT DCH
  74. MODCTLP EQU 02H ;PUT YOUR MODEM CONTROL PORT HERE
  75. MODSNDB EQU 80H ;YOUR BIT TO TEST FOR SEND
  76. MODSNDR EQU 80H ;YOUR VALUE WHEN READY
  77. MODRCVB EQU 40H ;YOUR BIT TO TEST FOR RECEIVE
  78. MODRCVR EQU 40H ;YOUR VALUE WHEN READY
  79. MODDATP EQU 03H ;YOUR MODEM DATA PORT
  80.  ENDIF  ;END OF EXTERNAL MODEM EQUATES
  81. ;
  82.  IF PMMI
  83. MODCTLP EQU 0C0H
  84. MODSNDB EQU 1
  85. MODSNDR EQU 1
  86. MODRCVB EQU 2
  87. MODRCVR EQU 2
  88. MODDATP EQU 0C1H
  89. BAUDRP  EQU 0C2H
  90. MODCTL2 EQU 0C3H
  91. ORIGMOD EQU 1DH
  92. ANSWMOD EQU 1EH
  93.  ENDIF
  94. ;
  95.  IF DCH
  96. MODCTLP EQU 82H
  97. MODSNDB EQU 2
  98. MODSNDR EQU 2
  99. MODRCVB EQU 1
  100. MODRCVR EQU 1
  101. MODDATP EQU 80H
  102. MODCTL2 EQU 81H
  103. ORIGMOD EQU 87H
  104. ANSWMOD EQU 83H
  105.  ENDIF
  106. ;
  107. ERRLIM EQU 10
  108. ;
  109. SOH EQU 1
  110. EOT EQU 4
  111. ACK EQU 6
  112. NAK EQU 15H
  113. CAN EQU 18H
  114. LF  EQU 10
  115. CR  EQU 13
  116. ; 
  117. BDOS EQU BASE+5
  118. FCB  EQU BASE+5CH
  119. ;
  120.  ORG BASE+100H
  121. ;
  122.  LXI H,0
  123.  DAD SP
  124.  SHLD STACK
  125.  LXI SP,STACK
  126.  CALL INITADR
  127.  CALL ILPRT
  128.  DB 'MBOOT as of '
  129.  DB '11/5/80',CR,LF,0
  130.  LDA FCB+1
  131.  CPI ' '
  132.  JNZ TERMI
  133.  CALL ILPRT
  134.  DB '++NO FILE NAME SPECIFIED++',CR,LF,0
  135.  JMP EXIT
  136. ;
  137. TERMI CALL INITMOD
  138.  IN MODDATP
  139.  IN MODDATP
  140.  CALL ILPRT
  141.  DB CR,LF,'TERMINAL MODE',CR,LF
  142.  DB 'CTL-E exits to CP/M, ESC starts file transfer'
  143.  DB CR,LF,0
  144. ;
  145. TERM CALL STAT
  146.  JZ TERML
  147.  CALL KEYIN
  148.  CPI EXITCHR
  149.  JZ EXIT
  150.  CPI ESC
  151.  JZ RCVFIL
  152.  OUT MODDATP
  153. ;
  154.  IF NOT DCH
  155. TERML IN MODCTLP
  156.  ENDIF
  157. ;
  158.  IF DCH
  159. TERML IN MODCTL2
  160.  ENDIF
  161. ;
  162.  ANI MODRCVB
  163.  CPI MODRCVR
  164.  JNZ TERM
  165.  IN MODDATP
  166.  ANI 7FH
  167.  CALL TYPE
  168.  JMP TERM
  169. ;
  170. RCVFIL CALL ERASFIL
  171.  CALL MAKEFIL
  172.  CALL ILPRT
  173.  DB 'FILE OPEN, READY TO RECEIVE',CR,LF,0
  174. ;
  175. RCVLP CALL RCVSECT
  176.  JC RCVEOT
  177.  CALL WRSECT
  178.  CALL INCRSNO
  179.  CALL SENDACK
  180.  JMP RCVLP
  181. ;
  182. RCVEOT CALL WRBLOCK
  183.  CALL SENDACK
  184.  CALL CLOSFIL
  185.  CALL ERXIT
  186.  DB CR,LF,'TRANSFER COMPLETE$' 
  187. ;
  188. RCVSECT XRA A
  189.  STA ERRCT
  190. ;
  191. RCVRPT MVI B,10
  192.  CALL RECV
  193.  JC RCVSERR
  194.  CPI SOH
  195.  JZ RCVSOH
  196.  ORA A
  197.  JZ RCVRPT
  198.  CPI EOT
  199.  STC
  200.  RZ
  201. ;
  202. RCVSERR MVI B,1
  203.  CALL RECV
  204.  JNC RCVSERR
  205.  MVI A,NAK
  206.  CALL SEND
  207.  LDA ERRCT
  208.  INR A
  209.  STA ERRCT
  210.  CPI ERRLIM
  211.  JC RCVRPT
  212. ;
  213. RCVSABT CALL CLOSFIL
  214.  CALL ERXIT
  215.  DB '++UNABLE TO RECEIVE BLOCK'
  216.  DB CR,LF,'++ABORTING++$'
  217. ;
  218. RCVSOH MVI B,1
  219.  CALL RECV
  220.  JC RCVSERR
  221.  MOV D,A
  222.  MVI B,1
  223.  CALL RECV
  224.  JC RCVSERR
  225.  CMA
  226.  CMP D
  227.  JZ RCVDATA
  228.  JMP RCVSERR
  229. ;
  230. RCVDATA MOV A,D
  231.  STA RCVSNO
  232.  MVI C,0
  233.  LXI H,BASE+80H
  234. ;
  235. RCVCHR MVI B,1
  236.  CALL RECV
  237.  JC RCVSERR
  238.  MOV M,A
  239.  INR L
  240.  JNZ RCVCHR
  241.  MOV D,C
  242.  MVI B,1
  243.  CALL RECV
  244.  JC RCVSERR
  245.  CMP D
  246.  JNZ RCVSERR
  247.  LDA RCVSNO
  248.  MOV B,A
  249.  LDA SECTNO
  250.  CMP B
  251.  JZ RECVACK
  252.  INR A
  253.  CMP B
  254.  JNZ ABORT
  255.  RET
  256. ;
  257. RECVACK CALL SENDACK
  258.  JMP RCVSECT
  259. ;
  260. SENDACK MVI A,ACK
  261. ;
  262. SEND PUSH PSW
  263.  ADD C
  264.  MOV C,A
  265. ;
  266.  IF NOT DCH
  267. SENDW IN MODCTLP
  268.  ENDIF
  269. ;
  270.  IF DCH
  271. SENDW IN MODCTL2
  272.  ENDIF
  273. ;
  274.  ANI MODSNDB
  275.  CPI MODSNDR
  276.  JNZ SENDW
  277.  POP PSW
  278.  OUT MODDATP
  279.  RET
  280. ;
  281. ABORT LXI SP,STACK
  282. ;
  283. ABORTL MVI B,1
  284.  CALL RECV
  285.  JNC ABORTL
  286.  MVI A,CAN
  287.  CALL SEND
  288. ;
  289. ABORTW MVI B,1
  290.  CALL RECV
  291.  JNC ABORTW
  292.  MVI A,' '
  293.  CALL SEND
  294.  CALL ERXIT
  295.  DB 'MBOOT PROGRAM CANCELLED$'
  296. ;
  297. INCRSNO LDA SECTNO
  298.  INR A
  299.  STA SECTNO
  300.  RET
  301. ;
  302. ERASFIL LXI D,FCB
  303.  MVI C,17
  304.  CALL BDOS
  305.  INR A
  306.  RZ
  307.  CALL ILPRT
  308.  DB '++FILE EXISTS, TYPE Y TO ERASE: ',0
  309.  CALL KEYIN
  310.  PUSH PSW
  311.  CALL TYPE
  312.  CALL CRLF
  313.  POP PSW
  314.  ANI 5FH
  315.  CPI 'Y'
  316.  JNZ MXIT
  317.  LXI D,FCB
  318.  MVI C,19
  319.  JMP BDOS
  320. ;
  321. MAKEFIL LXI D,FCB
  322.  MVI C,22
  323.  CALL BDOS
  324.  INR A
  325.  RNZ
  326.  CALL ERXIT
  327.  DB '++ERROR - CAN''T MAKE FILE',CR,LF
  328.  DB '++DIRECTORY MUST BE FULL$'
  329. ;
  330. CLOSFIL LXI D,FCB
  331.  MVI C,16
  332.  CALL BDOS
  333.  INR A
  334.  RNZ
  335.  CALL ERXIT
  336.  DB '++CAN''T CLOSE FILE$'
  337. ;
  338. WRSECT LHLD SECPTR
  339.  XCHG
  340.  LXI H,BASE+80H
  341.  CALL MOVE128
  342.  XCHG
  343.  SHLD SECPTR
  344.  LDA SECINBF
  345.  INR A
  346.  STA SECINBF
  347.  CPI 16
  348.  RNZ
  349. ;
  350. WRBLOCK LDA SECINBF
  351.  ORA A
  352.  RZ
  353.  MOV C,A
  354.  LXI D,DBUF
  355. ;
  356. DKWRLP PUSH H
  357.  PUSH D
  358.  PUSH B
  359.  MVI C,26
  360.  CALL BDOS
  361.  LXI D,FCB
  362.  MVI C,21
  363.  CALL BDOS
  364.  POP B
  365.  POP D
  366.  POP H
  367.  ORA A
  368.  JNZ WRERR
  369.  LXI H,80H
  370.  DAD D
  371.  XCHG
  372.  DCR C
  373.  JNZ DKWRLP
  374.  XRA A
  375.  STA SECINBF
  376.  LXI H,DBUF
  377.  SHLD SECPTR
  378. ;
  379. RSDMA LXI D,BASE+80H
  380.  MVI C,26
  381.  JMP BDOS
  382. ;
  383. WRERR CALL RSDMA
  384.  CALL ILPRT
  385.  DB '++ERROR WRITING FILE',CR,LF,0
  386.  JMP ABORT
  387. ;
  388. RECV PUSH D
  389. ;
  390.  IF FASTCLK
  391.  MOV A,B
  392.  ADD A
  393.  MOV B,A
  394.  ENDIF
  395. ;
  396. MSEC LXI D,50000
  397. ;
  398.  IF NOT DCH
  399. MWTI IN MODCTLP
  400.  ENDIF
  401. ;
  402.  IF DCH
  403. MWTI IN MODCTL2
  404.  ENDIF
  405. ;
  406.  ANI MODRCVB
  407.  CPI MODRCVR
  408.  JZ MCHAR
  409.  DCR E
  410.  JNZ MWTI
  411.  DCR D
  412.  JNZ MWTI
  413.  DCR B
  414.  JNZ MSEC
  415.  POP D
  416.  STC
  417.  RET
  418. ;
  419. MCHAR IN MODDATP
  420.  POP D
  421.  PUSH PSW
  422.  ADD C
  423.  MOV C,A
  424.  POP PSW
  425.  ORA A
  426.  RET
  427. ;
  428. INITADR LHLD BASE+1
  429.  LXI D,3
  430.  DAD D
  431.  SHLD VSTAT+1
  432.  DAD D
  433.  SHLD VKEYIN+1
  434.  DAD D
  435.  SHLD VTYPE+1
  436.  RET
  437. ;
  438. INITMOD EQU $
  439. ;
  440.  IF INITREQ 
  441.  MVI A,INITC1
  442.  OUT MODCTLP
  443.  NOP ! NOP ! NOP
  444.  NOP ! NOP
  445.  MVI A,INITC2
  446.  OUT MODCTLP
  447.  NOP ! NOP ! NOP
  448.  NOP ! NOP
  449.  MVI A,INITC3
  450.  OUT MODCTLP
  451.  NOP ! NOP ! NOP
  452.  NOP ! NOP
  453.  MVI A,INITC4
  454.  OUT MODCTLP
  455.  NOP ! NOP ! NOP
  456.  NOP ! NOP
  457.  ENDIF
  458. ;
  459.  IF PMMI
  460.  MVI A,52
  461.  OUT BAUDRP
  462.  MVI A,7FH
  463.  OUT MODCTL2
  464.  ENDIF
  465. ;
  466.  IF DCH
  467.  MVI A,16H
  468.  OUT MODCTL2
  469.  ENDIF
  470. ;
  471.  IF PMMI OR DCH
  472. ;
  473.  LXI H,4000
  474. ;
  475. OFFDLY DCR L
  476.  JNZ OFFDLY
  477.  DCR H
  478.  JNZ OFFDLY
  479.  MVI A,ORIGMOD 
  480.  OUT MODCTLP
  481.  ENDIF
  482. ;
  483.  RET  ;<--THIS RET MUST BE HERE
  484. ;
  485. CRLF MVI A,CR
  486.  CALL TYPE
  487.  MVI A,LF
  488. ;
  489. TYPE PUSH PSW
  490.  PUSH B
  491.  PUSH D
  492.  PUSH H
  493.  MOV C,A
  494. VTYPE CALL $-$
  495.  POP H
  496.  POP D
  497.  POP B
  498.  POP PSW
  499.  RET
  500. ;
  501. STAT PUSH B
  502.  PUSH D
  503.  PUSH H
  504. VSTAT CALL $-$
  505.  POP H
  506.  POP D
  507.  POP B
  508.  ORA A
  509.  RET
  510. ;
  511. KEYIN PUSH B
  512.  PUSH D
  513.  PUSH H
  514. VKEYIN CALL $-$
  515.  POP H
  516.  POP D
  517.  POP B
  518.  ANI 7FH
  519.  RET
  520. ;
  521. ILPRT XTHL
  522. ;
  523. ILPLP MOV A,M
  524.  ORA A
  525.  JZ ILPRET
  526.  CALL TYPE
  527.  INX H
  528.  JMP ILPLP
  529. ;
  530. ILPRET XTHL
  531.  RET
  532. ;
  533. ERXIT POP D
  534.  MVI C,9
  535.  CALL BDOS
  536. ;
  537. MXIT CALL ILPRT
  538.  DB CR,LF,'DON''T FORGET TO DISCONNECT MODEM'
  539.  DB CR,LF,0
  540. ;
  541. EXIT LHLD STACK
  542.  SPHL
  543.  RET
  544. ;
  545. MOVE128 MVI B,128
  546. ;
  547. MOVE MOV A,M
  548.  STAX D
  549.  INX H
  550.  INX D
  551.  DCR B
  552.  JNZ MOVE
  553.  RET
  554. ;
  555. RCVSNO DB 0
  556. SECTNO DB 0
  557. ERRCT DB 0
  558. EOFLG DB 0
  559. SECPTR DW DBUF
  560. SECINBF DB 0
  561.  DS 60
  562. STACK DS 2
  563. DBUF EQU $
  564. ;
  565.  END
  566.