home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / modems / modem7 / m7-2710.asm < prev    next >
Assembly Source File  |  1994-07-13  |  11KB  |  346 lines
  1.  
  2. ; M7-2710.ASM -- California Computer Systems 2710 Serial I/O
  3. ;
  4. ;                        By Dennis Recla  04/11/84
  5. ;
  6. ;
  7. ; You will want to look this file over carefully. There are a number of
  8. ; options that you can use to configure the program to suit your taste.
  9. ; This file places particular emphasis on using the CCS 2710 board
  10. ; with 8250 serial I/O at location 78H.  Much of the information contained 
  11. ; here is not in the main file.  If not using the CCS 2710 Serial I/O
  12. ; some of the routines here will illustrate what you could do with your
  13. ; unit.
  14. ;
  15. ; Use the "SET" command to change baudrate when desired.
  16. ;
  17. ; Edit this file for your preferences then follow the "TO USE:" example
  18. ; shown below.
  19. ;
  20. ;
  21. ;    TO USE: First edit this file filling in answers for your own
  22. ;        equipment.  Then assemble with ASM.COM or equivalent
  23. ;        assembler.  Then use DDT to overlay the the results
  24. ;        of this program to the original .COM file:
  25. ;
  26. ;        A>DDT MDM7xx.COM
  27. ;        DDT VERS 2.2
  28. ;        NEXT  PC
  29. ;        4X00 0100
  30. ;        -IM7-2710.HEX        (note the "I" command)
  31. ;        -R            ("R" loads in the .HEX file)
  32. ;        NEXT  PC
  33. ;        4X00 0000
  34. ;        -G0            (return to CP/M)
  35. ;        A>SAVE 66 MDM7xx.COM    (now have a modified .COM file)
  36. ;
  37. ;                       ^
  38. ;                      Value may vary with version of MDM7xx
  39. ; 
  40. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  41. ; 
  42. ;        M7-2710.ASM             Dennis Recla  04/11/84
  43. ;
  44. ;
  45. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  46. ;
  47. BELL:        EQU    07H        ;bell
  48. CR:        EQU    0DH        ;carriage return
  49. ESC:        EQU    1BH        ;escape
  50. LF:        EQU    0AH        ;linefeed
  51. ;
  52. YES:        EQU    0FFH
  53. NO:        EQU    0
  54. ;
  55. ;
  56. ; Change the value at MODDATP if it does not match what you are using.
  57. ;
  58. MODDATP:    EQU    078H        ;data port for CCS 2710 Board
  59. MODCTL1:    EQU    MODDATP+5    ;status port for CCS 2710
  60. MODRCVB:    EQU    1        ;bit to test for received data
  61. MODRCVR:    EQU    1        ;modem receive ready
  62. MODSNDB:    EQU    20H        ;bit to test for ready to send
  63. MODSNDR:    EQU    20H        ;modem send ready bit
  64. ;
  65. ;
  66.         ORG    100H
  67. ;
  68. ; Change the clock speed if needed, to match your system
  69. ;
  70.         DS    3    ;(for  "JMP   START" instruction)
  71. ;
  72. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  73. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-Hayes    104H
  74. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  75. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  76.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  77. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  78.                 ;6=2400 7=4800 8=9600 9=19200 default
  79. BYTDLY:        DB    8    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  80.                 ;default time to send character in ter-
  81.                 ;minal mode file transfer for slow BBS.
  82. CRDLY:        DB    8    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  83.                 ;default time for extra wait after CRLF
  84.                 ;in terminal mode file transfer
  85. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  86. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  87. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  88. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  89.                 ;no=resend a record after a valid NAK
  90. BAKUPBYTE:    DB    YES    ;yes=change any file same name to .BAK    10EH
  91. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  92. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  93. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  94. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  95. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  96.                 ;terminal mode (added by remote echo)
  97. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  98. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  99.                 ;write logon sequence at location LOGON
  100. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  101. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  102.                 ;no=external command if EXTCHR precedes
  103. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  104. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  105. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  106.                 ;sending a file in terminal mode
  107. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  108.                 ;sending a file in terminal mode
  109. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  110. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  111. EXTRA1:        DB    0    ;for future expansion            11EH
  112. EXTRA2:        DB    0    ;for future expansion            11FH
  113. BRKCHR:        DB    '@'-40H    ;^@ = Send a 300 ms. break tone        120H
  114. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  115. LOGCHR:        DB    'O'-40H    ;^O = Send logon            122H
  116. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  117. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  118. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  119. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  120. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  121. ;
  122. ;
  123.         DS    2        ;                128H
  124. ;
  125. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port             12AH
  126.         DS    7
  127. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  128.         DS    7
  129. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  130.         DS    7
  131. ANI$MODRCVB:    ANI    MODRCVB ! RET    ;bit to test for receive ready    148H
  132. CPI$MODRCVR:    CPI    MODRCVR ! RET    ;value of rcv. bit when ready    14BH
  133. ANI$MODSNDB:    ANI    MODSNDB ! RET    ;bit to test for send ready    14EH
  134. CPI$MODSNDR:    CPI    MODSNDR ! RET    ;value of send bit when ready    151H
  135.         DS    12        ;PMMI only calls        154H
  136. ;
  137. ;
  138. LOGONPTR:    DW    LOGON        ;for user message.        160H
  139.         DS    6        ;                162H
  140. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  141. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  142.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    16EH
  143.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    171H
  144.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    174H
  145. JMP$SETUPR:    JMP    SETUPR        ;                177H
  146. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  147. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  148. JMP$BREAK:    JMP    SENDBRK        ;                180H
  149. ;
  150. ;
  151. ; Do not change the following six lines.
  152. ;
  153. JMP$ILPRT:    DS    3        ;                183H
  154. JMP$INBUF    DS    3        ;                186H
  155. JMP$INLNCOMP:    DS    3        ;                189H
  156. JMP$INMODEM    DS    3        ;                18CH
  157. JMP$NXTSCRN:    DS    3        ;                18FH
  158. JMP$TIMER    DS    3        ;                192H
  159. ;
  160. ;
  161. ; The following clear the screen for the Televideo 950 terminal
  162. ;
  163. CLREOS:        CALL    JMP$ILPRT    ;                195H
  164.         DB    ESC,'t',0,0,0,0,0,0,0    ;            198H
  165.         RET            ;                19DH
  166. ;
  167. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  168.         DB    ESC,'*',0,0,0,0,0,0,0    ;            1A1H
  169.         RET            ;                1A6H
  170. ;
  171. ;
  172. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  173.         DB    'Version for CCS 2710 @ 78H with 8250 I/O'
  174.         DB    CR,LF,0
  175.         RET
  176. ;.....
  177. ;
  178. ;
  179. ;-----------------------------------------------------------------------
  180. ;
  181. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  182. ;     end of your last routine should terminate by 0400H (601 bytes
  183. ;     available after start of SYSVER) if using the Hayes Smartmodem
  184. ;     or by address 0C00H (2659 bytes) otherwise.
  185. ;
  186. ;-----------------------------------------------------------------------
  187. ;
  188. ; You can put in a message at this location which can be called up with
  189. ; CTL-O if TRANLOGON has been set TRUE.  You can put in several lines if
  190. ; desired.  End with a 0.
  191. ;
  192. LOGON:      DB    'Hello ...Hello...  Anyone there ???',CR,LF,0
  193. ;.....
  194. ;
  195. ;
  196. ; This routine sends a 300 ms. break tone to reset some time-share
  197. ; computers.
  198. ;
  199. SENDBRK:  MVI    A,40H        ;SET BREAK TONE
  200.       OUT    MODDATP+3
  201.       JMP    GOODBYE1    ;SEND A 300 MS. BREAK TONE
  202. ;.....
  203. ;
  204. ;
  205. ; This routine sends a 300 ms. break tgone and set DTR low for the same
  206. ; length of time to disconnect some modems such as the Bell 212A, etc.
  207. ;
  208. GOODBYE:  XRA    A
  209.       OUT    MODDATP+4    ;SET DTR AND RTS LOW
  210.       MVI    A,40H        ;SET BREAK TONE
  211.       OUT    MODDATP+3
  212. ;
  213. GOODBYE1: MVI    B,3        ;WAIT 300 MS.
  214.       CALL    JMP$TIMER
  215.       MVI    A,03H        ;RESET TO NORMAL 8 BITS
  216.       OUT    MODDATP+3
  217.       MVI    A,01H
  218.       OUT    MODDATP+4    ;RESET DTR HIGH
  219.       RET
  220. ;.....
  221. ;
  222. ;
  223. ; The following is used to initialize the CCS 2710 8250 I/O port
  224. ;
  225. INITMOD:  MVI    A,1        ;default transfer speed to 300 baud
  226.       STA    MSPEED
  227.       DI            ;turn off interrupts for init.
  228.       XRA    A
  229.       OUT    MODDATP+1    ;interrupt enable register
  230.       MVI    A,80H        ;insure out of mode to set baud rate
  231.       OUT    MODDATP+3    ;line control register
  232.       OUT    MODDATP+3
  233. ;
  234. LSPSPD:      MVI    A,80H        ;default 'LSP' speed for 300 baud
  235.       OUT    MODDATP        ;register for 'LSP' speed if enabled
  236. ;
  237. MSPSPD:      MVI    A,01H        ;default 'MSP' speed for 300 baud
  238.       OUT    MODDATP+1    ;register for 'MSP' speed if enabled
  239. ;
  240.       MVI    A,03H        ;8-level, 1 stop bit, no parity
  241.       OUT    MODDATP+3    ;line control register
  242.       MVI    A,01H        ;set 'DTR' for proper modem output level
  243.       OUT    MODDATP+4    ;modem control register
  244.       EI            ;restore interrupts to normal
  245.       RET
  246. ;.....
  247. ;
  248. ;
  249. ; The following routine changes the baud rate for the CCS 2710 with the SET
  250. ; command.
  251. ;
  252. SETUPR:      LXI    D,BAUDBUF    ;point to input buffer for INLNCOMP
  253.       CALL    JMP$ILPRT
  254.       DB    'Input Baud Rate (300, 450, 600, 1200, 2400, 4800, 9600): ',0
  255.       CALL    JMP$INBUF
  256.       LXI    D,BAUDBUF+2
  257.       CALL    JMP$INLNCOMP    ;compare BAUDBUF+2 with characters below
  258.       DB    '300',0
  259.       JNC    OK300        ;go if got match
  260.       CALL    JMP$INLNCOMP
  261.       DB    '450',0
  262.       JNC    OK450
  263.       CALL    JMP$INLNCOMP
  264.       DB    '600',0
  265.       JNC    OK600
  266.       CALL    JMP$INLNCOMP
  267.       DB    '1200',0
  268.       JNC    OK1200
  269.       CALL  JMP$INLNCOMP
  270.       DB    '2400',0
  271.       JNC   OK2400
  272.       CALL  JMP$INLNCOMP
  273.       DB    '4800',0
  274.       JNC   OK4800
  275.       CALL    JMP$INLNCOMP
  276.       DB    '9600',0
  277.       JNC    OK9600
  278.       CALL    JMP$ILPRT    ;all matches failed - tell operator
  279.       DB    '++ Incorrect entry ++',CR,LF,BELL,0
  280.       JMP    SETUPR        ;try again
  281. ;
  282. OK300:      MVI    A,1        ;MSPEED 300 baud value
  283.       LHLD    BD300        ;get 300 baud parameters in HL
  284.       JMP    LOADBD        ;go load them
  285. ;
  286. OK450:      MVI    A,2
  287.       LHLD    BD450
  288.       JMP    LOADBD
  289.  
  290. OK600:      MVI    A,3
  291.       LHLD    BD600
  292.       JMP    LOADBD
  293. ;
  294. OK1200:      MVI    A,5
  295.       LHLD    BD1200
  296.       JMP    LOADBD
  297. ;
  298. OK2400:   MVI   A,6
  299.       LHLD  BD2400
  300.       JMP   LOADBD
  301. ;
  302. OK4800:   MVI   A,7
  303.       LHLD  BD4800
  304.       JMP   LOADBD
  305. ;
  306. OK9600:      MVI    A,8
  307.       LHLD    BD9600
  308. ;
  309. LOADBD:      STA    INITMOD+1    ;store speed to show transfer time 
  310.       MOV    A,L        ;get least significant baud rate byte
  311.       STA    LSPSPD+1    ;store in INITMOD
  312.       MOV    A,H        ;get most signifcant baud rate byte
  313.       STA    MSPSPD+1    ;store in INITMOD
  314.       JMP    INITMOD        ;reset CCS 2710 Serial I/O 8250
  315. ;
  316. ;
  317. ; Table of baud rate parameters
  318. ;
  319. BD300:      DW    0180H
  320. BD450:      DW    0100H
  321. BD600:      DW    00C0H
  322. BD1200:      DW    0060H
  323. BD2400:   DW    0030H
  324. BD4800:   DW    0018H
  325. BD9600:      DW    000CH
  326. ;
  327. BAUDBUF:  DB    14,0
  328.       DS    14
  329. ;
  330. ;-----------------------------------------------------------------------
  331. ;
  332. ; This routine can be used for your equipment, be sure to end with RET
  333. ; If using the Hayes Smartmodem this is unavailable without a special
  334. ; change.
  335. ;
  336. SPCLMENU: RET
  337. ;
  338. ;-----------------------------------------------------------------------
  339. ;
  340. ;
  341. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  342. ;                 0C00H (without Smartmodem)
  343. ;
  344.       END
  345. ;
  346.