home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / modems / modem7 / m7jc-2.aqm / M7JC-2.ASM
Assembly Source File  |  1985-02-09  |  14KB  |  459 lines
  1. ; M7JC-2.ASM Apple/J-Cat overlay file for MDM727.  03/10/84
  2. ;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  3. ;
  4. ; This file is a patch of  M7AP-1.ASM overlay designed to
  5. ; allow auto-dialing through a Novation J-Cat modem.
  6. ; 
  7. ; The equates and patches in this file are set up for the combination
  8. ; of an Apple Super Serial Card in slot 2, with a Novation J-Cat modem.
  9. ; The J-cat is 300-baud only, so I have eliminated the routine for
  10. ; changing baud rate that was in the original.
  11. ;
  12. ; In order to dial with the J-Cat, the modem's OHK line (pin 7 on the
  13. ; modem's card-edge connector; blue unconnected line in the DB25 
  14. ; connector provided with the modem) must be connected to the Apple's
  15. ; AN(1) annunciator (pin 14 on the game I/O socket). {Actually, it
  16. ; could be connected to one of the other annunciator ports, if the
  17. ; "onhook" and "offhook" equates below are changed to refer to that
  18. ; annunciator.}
  19. ;            -- David W. Walker 71076,411
  20. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  21. ;  
  22. ; This overlay file enables Apple II computers with the Apple Super
  23. ; Serial card and external modem to use the MDM727 phone modem program.
  24. ; It also supports the following Apple modem configurations:
  25. ;
  26. ;    a) CCS 7710 serial interface and external modem
  27. ;    b) SSM serial interface and external modem
  28. ;    c) Apple communications interface and external modem
  29. ;
  30. ; You will want to look this file over carefully. There are a number of
  31. ; options that you can use to configure the program to suit your taste.
  32. ; Much of the information contained here is not in the MDM727.ASM file.
  33. ;
  34. ; Edit this file for your preferences then follow the "TO USE:" example.
  35. ;
  36. ;    TO USE: First edit this file filling in answers for your own
  37. ;        equipment.  Then assemble with ASM.COM or equivalent
  38. ;        assembler.  Then use DDT to overlay the the results
  39. ;        of this program to the original .COM file:
  40. ;
  41. ;        A>DDT MDM727.COM
  42. ;        DDT VERS 2.2
  43. ;        NEXT  PC
  44. ;        4900 0100
  45. ;        -IM7JC-1.HEX        (note the "I" command)
  46. ;        -R            ("R" loads in the .HEX file)
  47. ;        NEXT  PC
  48. ;        4900 0000
  49. ;        -G0            (return to CP/M)
  50. ;        A>SAVE 73 MDM727.COM    (now have a modified .COM file)
  51. ;
  52. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  53. ;
  54. ; 03/10/84 - Addresses for MDM727        - D. W. Walker
  55. ; 02/19/84 - Addresses for MDM724           - D. W. Walker
  56. ; 10/04/83 - J-Cat dialing routines added    - D. W. Walker
  57. ; 07/27/83 - Renamed to work with MDM712    - Irv Hoff
  58. ; 07/01/83 - Revised to work with MDM711    - Irv Hoff
  59. ; 06/22/83 - Revised to work with MDM710    - Irv Hoff
  60. ; 05/27/83 - Updated to work with MDM709    - Irv Hoff
  61. ; 05/15/83 - Revised to work with MDM708    - Irv Hoff
  62. ; 04/11/83 - Updated to work with MDM707    - Irv Hoff
  63. ; 04/04/83 - Updated to work with MDM706    - Irv Hoff
  64. ; 02/27/83 - Updated to work with MDM705    - Irv Hoff
  65. ; 02/12/83 - Used MDM703CF to make this file
  66. ;         for Apple computers using a var-
  67. ;         iety of serial interface cards
  68. ;         with external modem.        - Bruce Kargol
  69. ;
  70. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  71. ;
  72. BELL:        EQU    07H    ;bell
  73. CR:        EQU    0DH    ;carriage return
  74. ESC:        EQU    1BH    ;escape
  75. LF:        EQU    0AH    ;linefeed
  76. ;
  77. YES:        EQU    0FFH
  78. NO:        EQU    0
  79. ;
  80. ;
  81. CCS:        EQU    NO    ;YES for CCS 7710
  82. COMCARD:    EQU    NO    ;YES for Apple comcard
  83. SSC:        EQU    YES    ;YES for Super Serial Card
  84. SSM:        EQU    NO    ;YES for SSM serial card
  85. ;
  86.          IF    CCS
  87. MODDATP:    EQU    0E0A1H    ;data port of CCS 7710
  88. MODCTL1:    EQU    0E0A0H    ;status port of CCS 7710
  89.           ENDIF        ;endif CCS
  90. ;
  91.          IF    COMCARD
  92. MODDATP:    EQU    0E0AFH    ;data port of Comcard
  93. MODCTL1:    EQU    0E0AEH    ;status port of Comcard
  94.          ENDIF        ;endif Comcard
  95. ;
  96.          IF    SSM
  97. MODDATP:    EQU    0E0A5H    ;data port of SSM
  98. MODCTL1:    EQU    0E0A4H    ;status port of SSM
  99.          ENDIF        ;endif SSM
  100. ;
  101.          IF    SSC
  102. MODDATP:    EQU    0E0A8H    ;data port of Apple Super Serial Card 
  103. MODCTL1:    EQU    0E0A9H    ;modem status port of Super Serial Card
  104. COMMAND:     EQU     0E0AAH    ;SSC command register
  105. MODBDP:        EQU    0E0ABH    ;SSC ACIA control register
  106. ;
  107. MODRCVB:    EQU    08H     ;bit to test for received data
  108. MODRCVR:    EQU    08H     ;modem receive ready
  109. MODSNDB:    EQU    10H    ;bit to test for ready to send
  110. MODSNDR:    EQU    10H    ;modem send ready bit
  111. DTR         EQU     0BH     ;dtr,xmit on(rts low),irq disabled
  112.          ENDIF        ;endif SSC
  113. ;
  114. ;
  115. ; Apple status bit equates for CCS, Comcard and SSM
  116. ;
  117.          IF    NOT SSC
  118. MODSNDB:    EQU    02H    ;bit to test for send
  119. MODSNDR:    EQU    02H    ;value when ready
  120. MODRCVB:    EQU    01H    ;bit to test for receive
  121. MODRCVR:    EQU    01H    ;value when ready
  122.          ENDIF        ;not SSC
  123. ;
  124. ;  Equates for routines in the body of MDM727.COM, needed to make
  125. ;  the J-Cat auto-dialing routines work with the PMMI routines in
  126. ;  MDM727:
  127. ;
  128. ;
  129. DIAL15:        EQU    05DFH
  130. DIALAGN:    EQU    05FBH
  131. CONMADE:    EQU    06A9H
  132. DIALA2:        EQU    0725H
  133. DIALBGN:    EQU    07A9H
  134. DISCONNT:    EQU    0820H
  135. WAIT:        EQU    09BEH
  136. FNKCHR:        EQU    12C9H
  137. RESTART:    EQU    141FH
  138. INITADR:    EQU    1484H
  139. RETURN:        EQU    196EH
  140. GOLIST:        EQU    2033H
  141. BREAK:        EQU    2098H
  142. TYPE:        EQU    2B71H     
  143. ;
  144. ; Values for Novation J-Cat using Ann(1) as offhook line
  145. ;
  146. ONHOOK        EQU    0E05AH
  147. OFFHOOK        EQU    0E05BH
  148. ;
  149. ;
  150.         ORG    100H
  151. ;
  152. ;
  153. ; Change the clock speed to match your equipment
  154. ;
  155.         DS    3    ;(for  "JMP   START" instruction)
  156. ;
  157. ; J-Cat dialing routines patched over PMMI routines {DWW 10-04-83}
  158. ; IF J-Cat OHK line is not connected, set both PMMIMODEM and
  159. ; SMARTMODEM to NO
  160. ;
  161. PMMIMODEM:    DB    YES    ;yes=J-Cat auto-dial enabled         103H
  162. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-pmmi    104H
  163. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  164. CLOCK:        DB    20    ;clock speed in MHz x10, 25.5 MHz max.    106H
  165.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  166. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  167.                 ;6=2400 7=4800 8=9600 9=19200 default
  168. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  169.                 ;default time to send character in ter-
  170.                 ;minal mode file transfer for slow BBS.
  171. CRDLY:        DB    3    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  172.                 ;default time for extra wait after CRLF
  173.                 ;in terminal mode file transfer
  174. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  175. SETUPTST:    DB    NO    ;yes=user-added Setup routine        10BH
  176. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  177. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  178.                 ;no=resend a record after a valid NAK
  179. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  180. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  181. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  182. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  183. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  184. ADDLF:        DB    NO    ;no=no LF after CR to send file in'    113H
  185.                 ;terminal mode (added by remote echo)
  186. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  187. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  188.                 ;write logon sequence at location LOGON
  189. SAVCCP:        DB    NO     ;yes=do not overwrite CCP        116H
  190. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  191.                 ;no=external command if EXTCHR precedes
  192. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  193. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  194. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  195.                 ;sending a file in terminal mode
  196. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  197.                 ;sending a file in terminal mode
  198. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  199. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  200. EXTRA1:        DB    0    ;for future expansion            11EH
  201. EXTRA2:        DB    0    ;for future expansion            11FH
  202. BRKCHR:        DB    '@'-40H    ;^@ = Send 300 ms. break tone        120H
  203. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  204. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  205. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  206. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  207. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  208. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  209. EXTCHR:        DB    '\'-40H    ;^\ = Send next character        127H
  210.         DS    2        ;                128H
  211. ;
  212. IN$MODCTL1:    LDA    MODCTL1 ! RET    ;in modem control port             12AH
  213.         DS    6
  214. OUT$MODDATP:    STA    MODDATP ! RET    ;out modem data port        134H
  215.         DS    6
  216. IN$MODDATP:    LDA    MODDATP ! RET    ;in modem data port        13EH
  217.         DS    6        ;spares if needed
  218. ;
  219. ANI$MODRCVB:    ANI    MODRCVB ! RET    ;bit to test for receive ready    148H
  220. CPI$MODRCVR:    CPI    MODRCVR ! RET    ;value of rcv. bit when ready    14BH
  221. ANI$MODSNDB:    ANI    MODSNDB ! RET    ;bit to test for send ready    14EH
  222. CPI$MODSNDR:    CPI    MODSNDR ! RET    ;value of send bit when ready    151H
  223.         DS    12        ;PMMI only calls        154H
  224. ;
  225. LOGONPTR:    DW    LOGON        ;for user message.        160H
  226.         DS    6        ;                162H
  227. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  228. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  229.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    16EH
  230.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    171H
  231.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    174H
  232. JMP$SETUPR:    JMP    SETUPR        ;                177H
  233. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  234. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  235. JMP$BREAK:    JMP    SENDBRK        ;                180H
  236. ;
  237. ;
  238. ; Do not change the following six lines.
  239. ;
  240. JMP$ILPRT:    DS    3        ;                183H
  241. JMP$INBUF    DS    3        ;                186H
  242. JMP$INLNCOMP:    DS    3        ;                189H
  243. JMP$INMODEM    DS    3        ;                18CH
  244. JMP$NXTSCRN:    DS    3        ;                18FH
  245. JMP$TIMER:    DS    3        ;                192H
  246. ;
  247. ;
  248. CLREOS:        CALL    JMP$ILPRT    ;                195H
  249. EOSCLR:        DB    esc,'Y',0,0,0    ;                198H
  250.         RET            ;                19DH
  251. ;
  252. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  253.         DB    esc,'*',0,0,0    ;                1A1H
  254.         RET            ;                1A6H
  255. ;
  256. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  257.         DB    'Version for Apple II with J-Cat modem'
  258.         DB    CR,LF,0
  259.         RET
  260. ;.....
  261. ;
  262. ;
  263. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  264. ;     end of your last routine should terminate by 0400H (601 bytes
  265. ;     available after start of SYSVER) if using the Hayes Smartmodem
  266. ;     or by address 0C00H (2659 bytes) otherwise.
  267. ;
  268. ;
  269. ; You can put in a message at this location which can be called up with
  270. ; CTL-O if TRANLOGON has been set TRUE.  You can put in several lines if
  271. ; desired.  End with a 0.
  272. ;
  273. ; 
  274. LOGON:        DB    'Logon message here',0
  275. ;
  276. ; The following is used to initialize the Apple SSC on execution of the
  277. ; program.
  278. ;
  279. INITMOD:  mvi    a,1            ;default transfer time to 300
  280.       sta    mspeed
  281.       mvi    a,DTR
  282.       sta    COMMAND
  283.       lda    MODBDP            ;current baudrate from moddll
  284.           ani   0f0h            ;zero the last 4 bits
  285. ;
  286. initmod1: ori   06h            ;get default baudrate (300)
  287.       ani    9fh            ;set 8 data bits
  288.       ani    7fh            ;set 1 stop bit
  289.       sta    MODBDP            ;store default baudrate
  290.       ret
  291. ;.....
  292. ;
  293. SETUPR:   jmp    initmod
  294. ;
  295. ; J-Cat is 300 baud only -- no need to change
  296. ;
  297. ;.....
  298. ;
  299. ; send break through SSC -- 233 msec space
  300. ;
  301. SENDBRK:
  302.     lda    COMMAND     
  303.     push    psw    ; save register content
  304.     ori    0ch    ; set bits 2,3
  305.     sta    COMMAND ; break line
  306.     push    b
  307.     lxi    b,233    ; wait 233 msec
  308.     call    delay
  309.     pop    b
  310.     pop    psw    ; get original register
  311.     sta    COMMAND ; restore it
  312.     ret
  313. ;
  314. GOODBYE:
  315.     sta    ONHOOK
  316.     push    b
  317.     lxi    b,25    ;on hook for 25 msec
  318.     call    delay
  319.     pop    b
  320.     sta    OFFHOOK
  321.     push    b
  322.     lxi    b,20    ;off hook for 20 msec
  323.     call    delay
  324.     pop    b
  325.     sta    ONHOOK    ;final disconnect
  326.     RET
  327. ;
  328. ; wait for the number of millisecs in B,C
  329.  
  330. delay:    push    d    ;save d,e
  331.     inr    b    ;bump b for later dcr
  332. ;
  333. delay1    mvi    e,126    ;delay count for 1 millisec (Apple Z80 clock=2.041mhz)
  334.  
  335. delay2    dcr    e    ;count
  336.     jnz    delay2    ;  down
  337.  
  338.     dcr    c    ;more millisecs?
  339.     jnz    delay1    ;  yes
  340.     dcr    b    ;no - more in hi byte?
  341.     jnz    delay1    ;  yes
  342.     pop    d    ;  no,    restore d,e
  343.     ret
  344. ;
  345. ;-----------------------------------------------------------------------
  346. ;
  347. ; The following routine can be used to display commands on the screen
  348. ; of interest to users of this equipment.  
  349. ;
  350. SPCLMENU: RET
  351. ;
  352. ;-----------------------------------------------------------------------
  353. ;
  354. ;
  355. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  356. ;                 0C00H (without Smartmodem)
  357. ;
  358. ;-----------------------------------------------------------------------
  359. ;
  360. ; J-Cat Dialing Routines
  361. ;
  362. ; Wait for carrier
  363. ;
  364.     org    DIAL15
  365.          
  366.     mvi    d,20h    ; mask for carrier detected bit
  367.     mvi    c,96h    ; limit time waiting for carrier
  368.     call    WAIT
  369.     jnc    CONMADE
  370.     call    hangup
  371.     jmp    DIALAGN
  372.  
  373. ; Dial a digit
  374.  
  375.     org    DIALA2+8
  376.  
  377. pulse:    push    b
  378.     sta    ONHOOK
  379.     lxi    b,61    ;pulse
  380.     call    delay
  381.     sta    OFFHOOK
  382.     lxi    b,39    ;delay between pulses
  383.     call    delay
  384.     pop    b
  385.     dcr    c    ;any more pulses?
  386.     jnz    pulse    ;yes, do them
  387.     lxi    b,300    ;300-millisec delay between digits
  388.     call    delay
  389.     ret
  390.  
  391. ; Wait 2 seconds for dial tone
  392.  
  393.     org    DIALBGN+5     
  394.  
  395.     mvi    a,dtr
  396.     sta    MODCTL1    ; enable modem
  397.     sta    offhook    ; connect phone
  398.     lxi    b,2000
  399.     call    delay
  400.     ora    a    ; clear carry
  401.     ret
  402.  
  403. ; Hang up phone
  404.  
  405.     org    DISCONNT
  406.  
  407. hangup:    jmp goodbye
  408.     
  409. ; Check for carrier
  410.  
  411.     org    WAIT+5
  412.     lda    MODCTL1 ;get modem status
  413.               
  414. ; Patch out PMMI-specific routines, etc.
  415.     
  416.     org    RESTART+20H
  417.     cnz    SETUPR        ; original calls address not used here
  418.  
  419.     org    RETURN+23H
  420.     call    JMP$INITMOD    ; J-Cat needs re-init after dialing
  421.  
  422.     org    BREAK
  423.     jmp    JMP$BREAK    ; don't use PMMI break routine
  424.  
  425. ; The Microsoft CP/M BIOS implementation always returns FALSE
  426. ; for the status of the LST: device, so the MDM727 printer output
  427. ; routine never sends anything to the printer.  To repair that, the
  428. ; simplest patch is to skip over the LST: status test in MDM727.
  429. ; That requires a printer fast enough to keep up with the screen
  430. ; output.  At 300 baud, that may be feasible:
  431.  
  432.     org GOLIST+4
  433.     nop            ; patch out return if LST: not ready
  434.  
  435. ; Another cure, if your printer card can deliver a status byte, would
  436. ; be to patch in a status test (returning zero if printer not ready,
  437. ; non-zero if printer can accept a character) in some unused space
  438. ; and patch a CALL to that routine at GOLIST.  That requires yet another
  439. ; patch, because the INITADR routine in MDM727 automatically patches a
  440. ; call to the BIOS LISTST routine at GOLIST.  Here's an example, for a
  441. ; Videx PSIO card (serial port) in slot 1:
  442.  
  443.     org    0D00H    ; unused space
  444. PRNTST:    lda    0E099H    ; PSIO status port
  445.     ani    10H    ; check bit 4
  446.     ret        ; carry set = ready
  447.  
  448.     org    INITADR+15h
  449.     NOP
  450.     NOP
  451.     NOP
  452.  
  453.     org    GOLIST
  454.     call    PRNTST
  455.     ora    a    ; duplicate original code
  456.     rz
  457.  
  458.     END
  459.