home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / modems / modem7 / m7mfio-2.asm < prev    next >
Assembly Source File  |  1994-07-13  |  13KB  |  386 lines
  1. ; M7MFIO-2.ASM  For Electralogics Inc. MFIO.  04/30/84
  2. ; 
  3. ; You will want to look this file over carefully. There are a number of
  4. ; options that you can use to configure the program to suit your taste.
  5. ; This file places particular emphasis on using the Electralogics MFIO
  6. ; board with 8250 serial I/O.  Much of the information contained here is
  7. ; not in the main file.  
  8. ;
  9. ; Set serial port desired at 'sio' equate
  10. ;
  11. ; Use the "SET" command to change baudrate when desired.
  12. ;
  13. ; Edit this file for your preferences then follow the "TO USE:" example
  14. ; shown below.
  15. ;
  16. ;
  17. ;    TO USE: First edit this file filling in answers for your own
  18. ;        equipment.  Then assemble with ASM.COM or equivalent
  19. ;        assembler.  Then use DDT to overlay the the results
  20. ;        of this program to the original .COM file:
  21. ;
  22. ;        A>DDT MDM7xx.COM
  23. ;        DDT VERS 2.2
  24. ;        NEXT  PC
  25. ;        4x00 0100
  26. ;        -IM7MFIO-2.HEX        (note the "I" command)
  27. ;        -R            ("R" loads in the .HEX file)
  28. ;        NEXT  PC
  29. ;        4x00 0000
  30. ;        -G0            (return to CP/M)
  31. ;        A>SAVE 73 MDM7xx.COM    (now have a modified .COM file)
  32. ;               ^
  33. ;                       May vary depending upon version of MDM7xx
  34. ;
  35. ;----------------------------------------------------------------------------
  36. ; NOTE:
  37. ; 
  38. ; The MFIO is a very complex I/O board containing 8 serial ports, 2 parallel
  39. ; ports, a real time clock, and vectored interrupt controller. All of the
  40. ; above facilities can be accessed by the use of only 9 I/O port addresses.
  41. ; This requires that the active I/O block number be stored somewhere in memory
  42. ; so that when the current I/O operation is completed, the MFIO can be
  43. ; restored to its previous I/O block (normally the system console). I have
  44. ; selected location 0000FH for the purpose and called it 'BLKSTAT'.
  45. ; Any other unused memory location is equally suitable.
  46. ;
  47. ; If this procedure is adopted in all BIOS I/O routines, all that needs
  48. ; to be done in any other I/O routine is to select the current I/O block,
  49. ; set up the MFIO command port for that block and store that value at
  50. ; location 'BLKSTAT'. Following is my CONIN routine as an example:
  51. ;
  52. ;    CONIN:    mvi    a,sio0        ; set sio0 for console I/O
  53. ;        out    cmdport        ;  and tell MFIO
  54. ;        in    linstat        ; read the line status register
  55. ;        ani    ckrb        ;  & mask console kb rdy bit
  56. ;        jz    conin        ;   loop till ready
  57. ;        in    keydat        ; read sio0 data register
  58. ;        ani    7fh        ;  strip the parity bit
  59. ;        push    psw        ;   save the byte
  60. ;        lda    blkstat        ;    & get the previous I/O block
  61. ;        out    cmdport        ;   restore MFIO to prev block
  62. ;        pop    psw        ;  get the keyboard data byte
  63. ;        ret            ; and bail out
  64. ;
  65. ; The routine "mxdin" located near the end of this program is called from
  66. ; all routines which use BIOS I/O calls that utilize MFIO resources (in my
  67. ; system, ALL I/O except the disks is MFIO-oriented). Its only purpose is
  68. ; to ensure that the system keep track of the MFIO resource blocks. If you
  69. ; get really complicated (interrupts, for example) you may need to push 
  70. ; and pop them using a 'stack'.
  71. ; 'nuff said. Luck!!
  72. ; 
  73. ;                    - Bill Harnell
  74. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  75. ;
  76. ; 04/30/84 - Renamed and Revised for MDM7xx     - Dennis Recla
  77. ;
  78. ; 08/14/83 - Revised to work with MFIO.         - Vic Kass
  79. ;            CONIN and CONOUT routines
  80. ;            in your BIOS must reset
  81. ;            modem port after any access!
  82. ;
  83. ;
  84. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  85. ;
  86. BELL:        EQU    07H        ;bell
  87. CR:        EQU    0DH        ;carriage return
  88. ESC:        EQU    1BH        ;escape
  89. LF:        EQU    0AH        ;linefeed
  90. ;
  91. YES:        EQU    0FFH
  92. NO:        EQU    0
  93. ;
  94. ;
  95. ; Change the value at MODDATP if it does not match what you are using.
  96. ;
  97. sio:        equ    02H
  98. blkstat:    equ    0000fh        ;location to store current I/O block
  99. cmdport:    equ    48H
  100. ;
  101. MODDATP:    EQU    40H        ;data port for MFIO
  102. MODCTL1:    EQU    MODDATP+5    ;status port for MFIO
  103. MODRCVB:    EQU    1        ;bit to test for received data
  104. MODRCVR:    EQU    1        ;modem receive ready
  105. MODSNDB:    EQU    20H        ;bit to test for ready to send
  106. MODSNDR:    EQU    20H        ;modem send ready bit
  107. ;
  108. ;
  109.         ORG    100H
  110. ;
  111. ; Change the clock speed if needed, to match your system
  112. ;
  113.         DS    3    ;(for  "JMP   START" instruction)
  114. ;
  115. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  116. SMARTMODEM:    DB    NO    ;yes=Smartmodem
  117. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  118. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  119.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  120. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  121.                 ;6=2400 7=4800 8=9600 9=19200 default
  122. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  123.                 ;default time to send character in ter-
  124.                 ;minal mode file transfer for slow BBS.
  125. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  126.                 ;default time for extra wait after CRLF
  127.                 ;in terminal mode file transfer
  128. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  129. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  130. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  131. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  132.                 ;no=resend a record after a valid NAK
  133. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  134. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  135. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  136. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  137. TOGGLEBK:    DB    NO    ;yes=allow toggling of bksp to rub    112H
  138. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  139.                 ;terminal mode (added by remote echo)
  140. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  141. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  142.                 ;write logon sequence at location LOGON
  143. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  144. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  145.                 ;no=external command if EXTCHR precedes
  146. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  147. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  148. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  149.                 ;sending a file in terminal mode
  150. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  151.                 ;sending a file in terminal mode
  152. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  153. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  154. EXTRA1:        DB    0    ;for future expansion            11EH
  155. EXTRA2:        DB    0    ;for future expansion            11FH
  156. BRKCHR:        DB    '@'-40H    ;^@ = Send a 300 ms. break tone        120H
  157. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  158. LOGCHR:        DB    'O'-40H    ;^O = Send logon            122H
  159. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  160. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  161. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  162. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  163. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  164. ;
  165. ;
  166.         DS    2        ;                128H
  167. ;
  168. IN$MODCTL1:    call    mxdin        ;set & store current I/O block
  169.         IN    MODCTL1 ! RET    ;in modem control port             12AH
  170.         DS    4
  171. OUT$MODDATP:    call    mxdin
  172.         OUT    MODDATP ! RET    ;out modem data port        134H
  173.         DS    4
  174. IN$MODDATP:    call    mxdin
  175.         IN    MODDATP ! RET    ;in modem data port        13EH
  176.         DS    4
  177. ANI$MODRCVB:    ANI    MODRCVB ! RET    ;bit to test for receive ready    148H
  178. CPI$MODRCVR:    CPI    MODRCVR ! RET    ;value of rcv. bit when ready    14BH
  179. ANI$MODSNDB:    ANI    MODSNDB ! RET    ;bit to test for send ready    14EH
  180. CPI$MODSNDR:    CPI    MODSNDR ! RET    ;value of send bit when ready    151H
  181.         DS    12        ;PMMI only calls        154H
  182. ;
  183. ;
  184. LOGONPTR:    DW    LOGON        ;for user message.        160H
  185.         DS    6        ;                162H
  186. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  187. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  188.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    16EH
  189.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    171H
  190.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    174H
  191. JMP$SETUPR:    JMP    SETUPR        ;                177H
  192. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  193. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  194. JMP$BREAK:    JMP    SENDBRK        ;                180H
  195. ;
  196. ;
  197. ; Do not change the following six lines.
  198. ;
  199. JMP$ILPRT:    DS    3        ;                183H
  200. JMP$INBUF    DS    3        ;                186H
  201. JMP$INLNCOMP:    DS    3        ;                189H
  202. JMP$INMODEM    DS    3        ;                18CH
  203. JMP$NXTSCRN:    DS    3        ;                18FH
  204. JMP$TIMER    DS    3        ;                192H
  205. ;
  206. ;
  207. ; Set the following clear screen codes for your terminal type
  208. ;
  209. CLREOS:        CALL    JMP$ILPRT    ;                195H
  210.         DB    ESC,'Y',0,0,0    ;                198H
  211.         RET            ;                19DH
  212. ;
  213. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  214.         DB    ESC,'+',0,0,0    ;                1A1H
  215.         RET            ;                1A6H
  216. ;
  217. ;
  218. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  219.         DB    'Version for Electralogics Incorporated MFIO'
  220.         DB    CR,LF,0
  221.         RET
  222. ;.....
  223. ;
  224. ;
  225. ;-----------------------------------------------------------------------
  226. ;
  227. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  228. ;     end of your last routine should terminate by 0400H (601 bytes
  229. ;     available after start of SYSVER) if using the Hayes Smartmodem
  230. ;     or by address 0C00H (2659 bytes) otherwise.
  231. ;
  232. ;-----------------------------------------------------------------------
  233. ;
  234. ; You can put in a message at this location which can be called up with
  235. ; CTL-O if TRANLOGON has been set TRUE.  You can put in several lines if
  236. ; desired.  End with a 0.
  237. ;
  238. LOGON:      DB    'Hello...... >> Bill Harnell<< here....',CR,LF,0
  239. ;.....
  240. ;
  241. ;
  242. ; This routine sends a 300 ms. break tone to reset some time-share
  243. ; computers.
  244. ;
  245. SENDBRK:  call    mxdin        ;set & store current I/O block
  246.       MVI    A,40H        ;SET BREAK TONE
  247.       OUT    MODDATP+3
  248.       JMP    GOODBYE1    ;SEND A 300 MS. BREAK TONE
  249. ;.....
  250. ;
  251. ;
  252. ; This routine sends a 300 ms. break tgone and set DTR low for the same
  253. ; length of time to disconnect some modems such as the Bell 212A, etc.
  254. ;
  255. GOODBYE:  call    mxdin
  256.       XRA    A
  257.       OUT    MODDATP+4    ;SET DTR AND RTS LOW
  258.       MVI    A,40H        ;SET BREAK TONE
  259.       OUT    MODDATP+3
  260. ;
  261. GOODBYE1: MVI    B,3        ;WAIT 300 MS.
  262.       CALL    JMP$TIMER
  263.       MVI    A,03H        ;RESET TO NORMAL 8 BITS
  264.       OUT    MODDATP+3
  265.       MVI    A,01H
  266.       OUT    MODDATP+4    ;RESET DTR HIGH
  267.       RET
  268. ;.....
  269. ;
  270. ;
  271. ; The following is used to initialize the MFIO 8250 I/O port 'SIO'
  272. ;
  273. INITMOD:  MVI    A,1        ;default transfer speed to 300 baud
  274.       call    mxdin
  275.       STA    MSPEED
  276.       DI            ;turn off interrupts for init.
  277.       XRA    A
  278.       OUT    MODDATP+1    ;interrupt enable register
  279.       MVI    A,80H        ;insure out of mode to set baud rate
  280.       OUT    MODDATP+3    ;line control register
  281.       OUT    MODDATP+3
  282. ;
  283. LSPSPD:      MVI    A,80H        ;default 'LSP' speed for 300 baud
  284.       OUT    MODDATP        ;register for 'LSP' speed if enabled
  285. ;
  286. MSPSPD:      MVI    A,01H        ;default 'MSP' speed for 300 baud
  287.       OUT    MODDATP+1    ;register for 'MSP' speed if enabled
  288. ;
  289.       MVI    A,03H        ;8-level, 1 stop bit, no parity
  290.       OUT    MODDATP+3    ;line control register
  291.       MVI    A,01H        ;set 'DTR' for proper modem output level
  292.       OUT    MODDATP+4    ;modem control register
  293.       EI            ;restore interrupts to normal
  294.       RET
  295. ;.....
  296. ;
  297. ;
  298. ; The following routine changes the baud rate for the MFIO with the SET
  299. ; command.
  300. ;
  301. SETUPR:      call    mxdin
  302.       LXI    D,BAUDBUF    ;point to input buffer for INLNCOMP
  303.       CALL    JMP$ILPRT
  304.       DB    'Input Baud Rate (300, 1200, etc.): ',0
  305.       CALL    JMP$INBUF
  306.       LXI    D,BAUDBUF+2
  307.       CALL    JMP$INLNCOMP    ;compare BAUDBUF+2 with characters below
  308.       DB    '300',0
  309.       JNC    OK300        ;go if got match
  310.       CALL    JMP$INLNCOMP
  311.       DB    '450',0
  312.       JNC    OK450
  313.       CALL    JMP$INLNCOMP
  314.       DB    '600',0
  315.       JNC    OK600
  316.       CALL    JMP$INLNCOMP
  317.       DB    '1200',0
  318.       JNC    OK1200
  319.       CALL    JMP$INLNCOMP
  320.       DB    '9600',0
  321.       JNC    OK9600
  322.       CALL    JMP$ILPRT    ;all matches failed - tell operator
  323.       DB    '++ Incorrect entry ++',CR,LF,BELL,0
  324.       JMP    SETUPR        ;try again
  325. ;
  326. OK300:      MVI    A,1        ;MSPEED 300 baud value
  327.       LHLD    BD300        ;get 300 baud parameters in HL
  328.       JMP    LOADBD        ;go load them
  329. ;
  330. OK450:      MVI    A,2
  331.       LHLD    BD450
  332.       JMP    LOADBD
  333.  
  334. OK600:      MVI    A,3
  335.       LHLD    BD600
  336.       JMP    LOADBD
  337. ;
  338. OK1200:      MVI    A,5
  339.       LHLD    BD1200
  340.       JMP    LOADBD
  341. ;
  342. OK9600:      MVI    A,8
  343.       LHLD    BD9600
  344. ;
  345. LOADBD:      STA    INITMOD+1    ;store speed to show transfer time 
  346.       MOV    A,L        ;get least significant baud rate byte
  347.       STA    LSPSPD+1    ;store in INITMOD
  348.       MOV    A,H        ;get most signifcant baud rate byte
  349.       STA    MSPSPD+1    ;store in INITMOD
  350.       JMP    INITMOD        ;reset MFIO 8250
  351. ;
  352. ;
  353. ; Table of baud rate parameters
  354. ;
  355. BD300:      DW    0180H
  356. BD450:      DW    0100H
  357. BD600:      DW    00C0H
  358. BD1200:      DW    0060H
  359. BD9600:      DW    000CH
  360. ;
  361. BAUDBUF:  DB    10,0
  362.       DS    10
  363. ;
  364. ;-----------------------------------------------------------------------
  365. ;
  366. ; This routine can be used for your equipment, be sure to end with RET
  367. ; If using the Hayes Smartmodem this is unavailable without a special
  368. ; change.
  369. ;
  370. SPCLMENU: RET
  371. ;
  372. ;-----------------------------------------------------------------------
  373. ;
  374. mxdin:    push    psw
  375.     mvi    a,sio
  376.     out    cmdport
  377.     sta    blkstat        ;store current I/O block
  378.     pop    psw
  379.     ret
  380. ;
  381. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  382. ;                 0C00H (without Smartmodem)
  383. ;
  384.       END
  385. ;
  386.