home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / modems / modem7 / m7p1-1.aqm / M7P1-1.ASM
Assembly Source File  |  1985-02-09  |  15KB  |  456 lines
  1. ; M7P1-1.ASM MODEM7 OVERLAY (MDM712 and later) FOR PMC MICROMATE 101
  2. ;   Beta test version 1
  3. ;
  4. ; History:
  5. ;
  6. ; 01/13/84 Revised per M7GP-1.ASM -- the General purpose overlay file
  7. ;          for MDM7xx dated 11/11/83 and name changed for MDM716
  8. ;          Bill Wells, University of California, Berkeley CA.
  9. ; 11/01/83 IN$MODDATP modified to output 00H then 10H per page 75
  10. ;          of the MicroMate User's Guide (instead of only 10H)
  11. ;          Bill Wells, University of California, Berkeley CA.
  12. ; 10/31/83 BSD Unix communication defaults set by Bill Wells, UCB
  13. ;          Bill Wells, University of California, Berkeley CA.
  14. ;        XOFFTST = YES      (Unix ports use XON/XOFF)
  15. ;               CRCDFLT = NO       (umodem & tmodem do not have CRC)
  16. ;               IGNORCTL = NO      (so vi, more, & tset work)
  17. ; 10/09/83 Modified for MDM712 by Jim Warner, UCSC
  18. ;          BAUDMATCH routine changed to query user about setting of
  19. ;          the IGNORCTL. SET$BAUDRATE, AACCOR, and YES$CNTRL added.
  20. ; 10/02/83 Modified for MDM712 by Greg Small and Bill Wells,
  21. ;          University of California, Berkeley CA.
  22. ; 07/02/83 Patches (MDM709PM.ASM) for MDM709
  23. ;          SETLPR, BAUDMATCH, MSPEED$INIT, BIOSPB, BIOSPB1 added.
  24. ;          Jim Warner - University of California, Santa Cruz.
  25. ;
  26. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  27. ;
  28. ; Notes by Jim Warner:
  29. ;
  30. ;  The baud rate stuff in this adaptation is a little strange.
  31. ;  The initial BAUD rate is whatever it was when the program was
  32. ;  entered.  The hardware is read to determine what that is and
  33. ;  MSPEED is changed to agree with it.  A request for a new BAUD
  34. ;  rate is translated in Digital Research's official BAUD rate
  35. ;  code and poked into a data structure called the Device Table.
  36. ;  Finally, the hardware gets poked to agree with the table by
  37. ;  calling the BIOS routine responsible for intializing devices.
  38. ;
  39. ;  We'll need to see the CP/M 3 System System Guide to find out
  40. ;  if this is done right.
  41. ;
  42. ;    /////////////////////////////////////////
  43. ;    /                    /
  44. ;    /    - - W A R N I N G - -        /
  45. ;    /                    /
  46. ;    /    This code uses CP/M 3 dependent    /
  47. ;    /    stuff.                /
  48. ;    /                    /
  49. ;    /////////////////////////////////////////
  50. ;
  51. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  52. ;
  53. ; Use the "SET" command to change the baudrate when desired. 
  54. ;
  55. ;    To use:    First edit this file, filling in answers for your own
  56. ;        equipment. Then assemble with MAC.COM or equivalent
  57. ;        assembler. Use SID to overlay the results of this
  58. ;        program on the original .COM file:
  59. ;
  60. ;        A>save            (this is for CP/M 3)
  61. ;
  62. ;        A>sid mdm7xx.com
  63. ;        CP/M 3 SID - Version 3.0
  64. ;        NEXT MSZE  PC  END
  65. ;        4580 4580 0100 D9FF
  66. ;        #rm7p1-1.hex        (note the "r" command)
  67. ;        NEXT MSZE  PC  END
  68. ;        040B 4580 0100 D9FF
  69. ;        #G0            (return to CP/M)
  70. ;
  71. ;        CP/M 3 SAVE - Version 3.0
  72. ;        Enter file (type RETURN to exit): mdm7p1.com
  73. ;        Beginning hex address: 0100
  74. ;        Ending hex address: 457F    (MSZE - 1)
  75. ;
  76. ;        A>
  77. ;
  78. ; NEXT, MSZE, PC, END, and Ending hex addresses shown are for MDM716
  79. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  80. ;
  81. ; M7GP-1.ASM 11/11/83:
  82. ; 
  83. BELL:        EQU    07H        ;bell
  84. CR:        EQU    0DH        ;carriage return
  85. ESC:        EQU    1BH        ;escape
  86. LF:        EQU    0AH        ;linefeed
  87. ;
  88. YES:        EQU    0FFH
  89. NO:        EQU    0
  90. ;
  91. ; PMC Micromate Model 101 dependant stuff from MDM712PM.ASM - 10/09/83
  92. ; Patches for overlaying distribution version  of MDM712 for use with
  93. ; the PMC-101.  Jim Warner - Univ of Cal Santa Cruz.
  94. ;
  95. PORT:        EQU    89H    ;PMC SERIAL MODEM PORT
  96. MODCTL1:    EQU    PORT+2    ;Modem control port                 gts
  97. MODCTL2:    EQU    PORT+2    ;Modem control port                 gts
  98. MODDATP:    EQU    PORT    ;Modem data port
  99. MODRCVB:    EQU    01H    ;Your bit to test for receive
  100. MODRCVR:    EQU    01H    ;Your value when receive ready.
  101. MODSNDB:    EQU    04H    ;Your bit to test for send.
  102. MODSNDR:    EQU    04H    ;Your value when xmitter available.
  103. ;
  104. P$BAUD        EQU    93H    ;Upper nibble = TERMNL
  105. P$GETBAUD    EQU    95H    ;Lower nibble = MODEM
  106. ;
  107. ; M7GP-1.ASM 11/11/83:
  108. ; Change the following information to match your equipment
  109. ;
  110. ; PORT:        EQU    0C0H
  111. ; MODCTL1:    EQU    PORT        ;MODEM CONTROL PORT
  112. ; MODDATP:    EQU    PORT+1        ;MODEM DATA IN PORT
  113. ; MODDATO:    EQU    PORT+1        ;MODEM DATA OUT PORT
  114. ; MODDCDB:    EQU    4        ;CARRIER DETECT BIT
  115. ; MODDCDA:    EQU    0        ;VALUE WHEN ACTIVE
  116. ; BAUDRP:        EQU    PORT+2        ;BAUD RATE PORT
  117. ; MODCTL2:    EQU    PORT+3        ;2ND MODEM CONTROL PORT
  118. ; MODRCVB:    EQU    2        ;BIT TO TEST FOR RECEIVE
  119. ; MODRCVR:    EQU    2        ;VALUE WHEN READY
  120. ; MODSNDB:    EQU    1        ;BIT TO TEST FOR SEND
  121. ; MODSNDR:    EQU    1        ;VALUE WHEN READY
  122. ;
  123. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  124. ; M7GP-1.ASM 11/11/83 with Unix communication defaults, Bill Wells:
  125. ;
  126.         ORG    100H
  127. ;
  128. ;
  129. ; Change the clock speed to suit your system
  130. ;
  131.         DS    3    ;(for  "JMP   START" instruction)
  132. ;
  133. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  134. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  135. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  136. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  137.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  138. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  139.                 ;6=2400 7=4800 8=9600 9=19200 default
  140. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  141.                 ;default time to send character in ter-
  142.                 ;minal mode file transfer for slow BBS.
  143. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  144.                 ;default time for extra wait after CRLF
  145.                 ;in terminal mode file transfer
  146. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  147. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH jw
  148. SCRNTEST:    DB    NO    ;Cursor control routine         10CH
  149. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  150.                 ;no=resend a record after a valid-NAK
  151. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  152. CRCDFLT:    DB    NO    ;yes=default to CRC checking        10FH wcw
  153. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  154. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  155. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  156. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  157.                 ;terminal mode (added by remote echo)
  158. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  159. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  160.                 ;write logon sequence at location LOGON
  161. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  162. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  163.                 ;no=external command if EXTCHR precedes
  164. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  165. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  166. XOFFTST:    DB    YES    ;yes=checks for XOFF from remote while    11AH wcw
  167.                 ;sending a file in terminal mode
  168. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  169.                 ;sending a file in terminal mode
  170. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  171. IGNORCTL:    DB    NO    ;yes=CTL-chars above ^M not displayed    11DH wcw
  172. EXTRA1:        DB    0    ;for future expansion            11EH
  173. EXTRA2:        DB    0    ;for future expansion            11FH
  174. BRKCHR:        DB    '@'-40H    ;^@ = Send 300 ms. break tone        120H
  175. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  176. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  177. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  178. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  179. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  180. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  181. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  182. ;
  183. ;
  184.         DS    2        ;                128H
  185. ;
  186. ; M7GP-1.ASM 11/11/83:
  187. ; IN$MODCTL1:    IN    MODCTL1 !; RET    ;in modem control port        12AH
  188. ;        DS    7
  189. ;
  190. ; M712PM.ASM 10/09/83 by Jim Warner, modified by Bill Wells 11/01/83
  191. IN$MODCTL1:    XRA    A        ;Output 00H to command port    12AH wcw
  192.         OUT    MODCTL1         ;                               12BH wcw
  193.         MVI    A,10H        ;Output 10H to command port     12DH jw
  194.         OUT    MODCTL1         ;                               12FH jw
  195.         IN    MODCTL1        ;Get status bits.               131H jw
  196.         RET                     ;                               133H
  197. ;
  198. ; M7GP-1.ASM 11/11/83:
  199. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  200.         DS    7               ;                               137H
  201. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  202.         DS    7               ;                               141H
  203. ANI$MODRCVB:    ANI    MODRCVB    ! RET    ;bit to test for receive ready    148H
  204.  
  205. CPI$MODRCVR:    CPI    MODRCVR    ! RET    ;value of rcv. bit when ready    14BH
  206. ANI$MODSNDB:    ANI    MODSNDB    ! RET    ;bit to test for send ready    14EH
  207. CPI$MODSNDR:    CPI    MODSNDR    ! RET    ;value of send bit when ready    151H
  208.         DS    6        ;                154H
  209. ;
  210. OUT$MODCTL1:    OUT    MODCTL1    ! RET    ;out modem control port #2    15AH
  211. OUT$MODCTL2:    OUT    MODCTL2    ! RET    ;out modem control port #1    15DH
  212. ;
  213. LOGONPTR:    DW    LOGON        ;for user message.        160H
  214.         DS    6        ;                162H
  215. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  216. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  217.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    16EH
  218.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    171H
  219.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    174H
  220. JMP$SETUPR:    JMP    SETUPR        ;                177H
  221. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  222. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  223. JMP$BREAK:    JMP    SENDBRK        ;                180H
  224. ;
  225. ;
  226. ; Do not change the following six lines.
  227. ;
  228. JMP$ILPRT:    DS    3        ;                183H
  229. JMP$INBUF    DS    3        ;                186H
  230. JMP$INLNCOMP:    DS    3        ;                189H
  231. JMP$INMODEM    DS    3        ;                18CH
  232. JMP$NXTSCRN:    DS    3        ;                18FH
  233. JMP$TIMER    DS    3        ;                192H
  234. ;
  235. ;
  236. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  237. ; SCRNTEST to YES at 010AH (above).
  238. ;
  239. CLREOS:        CALL    JMP$ILPRT    ;                195H
  240.         DB    0,0,0,0,0    ;                198H
  241.         RET            ;                19DH
  242. ;
  243. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  244.         DB    0,0,0,0,0    ;                1A1H
  245.         RET            ;                1A6H
  246.     
  247. ;
  248. ; M712PM.ASM 10/09/83 by Jim Warner, modified by Bill Wells 01/13/84
  249. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  250.         DB    'Modem 7 for PMC Micromate Model 101 - '
  251.         DB    'UC Beta Test Version 1 - 01/14/84'
  252.         DB    CR,LF,0
  253.         LXI    D,LOGON
  254.         MVI    C,9
  255.         CALL    5
  256.         CALL    MSPEED$INIT
  257.         RET
  258. ;.....
  259. ;
  260. ; M7GP-1.ASM 11/11/83:
  261. ;-----------------------------------------------------------------------
  262. ;
  263. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  264. ;     end of your last routine should terminate by 0400H (601 bytes
  265. ;     available after start of SYSVER) if using the Hayes Smartmodem
  266. ;     or by address 0C00H (2659 bytes) otherwise.
  267. ;
  268. ;-----------------------------------------------------------------------
  269. ;
  270. ; You can put in a message at this location which can be called up with
  271. ; CTL-O if TRANLOGON has been set TRUE.  You can put in several lines if
  272. ; desired.  End with a 0.
  273. ;
  274. ; M712PM.ASM 10/09/83 by Jim Warner
  275. LOGON:        DB    'Do not use this program to filch'
  276.         DB    ' copyrighted software.',CR,LF,0,'$'
  277. ;.....
  278. ; M7GP-1.ASM 11/11/83:
  279. ;
  280. ;
  281. ; Add your own routine here to send a break tone to reset some time-sharing
  282. ; computers, if desired.
  283. ; 
  284. SENDBRK:    RET
  285. ;.....
  286. ;
  287. ;
  288. ; Add your own routine here to put DTR low and/or send a break tone.
  289. ; Check other routines such as MDM709DP.ASM (M7DP-1.ASM) which is
  290. ;    using this feature.
  291. ;
  292. GOODBYE:    RET
  293. ;.....
  294. ;
  295. ;
  296. ; You can use this area for any special initialization or setup you may
  297. ; wish to include.  Each must stop with a RET. You can check the other
  298. ; available overlays for ideas how to write your own routines if that
  299. ; may be of some help.
  300. ;
  301. INITMOD:     RET
  302. ;
  303. SETUPR:        ;Allow baud rate change w SET cmd
  304.         LXI    D,BAUDBUF
  305.         CALL    JMP$ILPRT
  306.         DB    'Input baud rate (110, 300, 600, 1200)',CR,LF
  307.         DB    '                (2400,4800,9600,19200):',0
  308.         CALL    JMP$INBUF
  309.         LXI    D,BAUDBUF+2
  310.         CALL    JMP$INLNCOMP    ;Compare BAUDBUF+2 w char's
  311.         DB    '110',0
  312.         MVI    L,3        ;Code from MODEBAUD.LIB
  313.         JNC    BAUDMATCH
  314. ;
  315.         CALL    JMP$INLNCOMP
  316.         DB    '300',0
  317.         MVI    L,6
  318.         JNC    BAUDMATCH
  319. ;
  320.         CALL    JMP$INLNCOMP
  321.         DB    '600',0
  322.         MVI    L,7
  323.         JNC    BAUDMATCH
  324. ;
  325.         CALL    JMP$INLNCOMP
  326.         DB    '1200',0
  327.         MVI    L,8
  328.         JNC    BAUDMATCH
  329. ;
  330.         CALL    JMP$INLNCOMP
  331.         DB    '2400',0
  332.         MVI    L,10
  333.         JNC    BAUDMATCH
  334. ;
  335.         CALL    JMP$INLNCOMP
  336.         DB    '4800',0
  337.         MVI    L,12
  338.         JNC    BAUDMATCH
  339. ;
  340.         CALL    JMP$INLNCOMP
  341.         DB    '9600',0
  342.         MVI    L,14
  343.         JNC    BAUDMATCH
  344. ;
  345.         CALL    JMP$INLNCOMP
  346.         DB    '19200',0
  347.         MVI    L,15
  348.         JC    SETUPR
  349. ;
  350. BAUDMATCH:    CALL    SET$BAUDRATE
  351.         CALL    MSPEED$INIT
  352.         CALL    AACCOR        ;Allow all Control Char on Recv?
  353.         RET            ; (* SETUP *)
  354. ;
  355. SET$BAUDRATE:    PUSH    H        ;Save baud code
  356.         MVI    C,32H        ;Function: direct bios call.
  357.         LXI    D,BIOSPB    ;BIOS parameter block
  358.         CALL    5
  359.         LXI    D,8+7        ;Index to BAUD rate in 2nd
  360.         DAD    D        ; entry. (i.e. MODEM)
  361.         POP    D        ;Get new code back.
  362.         MOV    A,M        ;Best not to change high
  363.         ANI    0F0H        ; nibble, whatever it is.
  364.         ORA    E        ;Put new code in table.
  365.         MOV    M,A
  366. ;
  367.         MVI    C,32H        ;Function: direct bios call.
  368.         LXI    D,BIOSPB1    ;Initialize device means to
  369.         CALL    5        ; set BAUD rate to PMC.
  370.         RET
  371. ;
  372. ; M712PM.ASM 10/09/83 by Jim Warner, modified by Bill Wells 01/13/84
  373. AACCOR:        CALL    JMP$ILPRT
  374.         DB    'Allow ALL control characters on receive?',CR,LF
  375.         DB    'Answer "Y" to permit control of local',CR,LF
  376.         DB    '  console from remote system.',CR,LF
  377.         DB    'Answer "Y" to use vi on Unix (Y/N): ',0
  378.         LXI    D,BAUDBUF
  379.         CALL    JMP$INBUF
  380.         LXI    D,BAUDBUF+2
  381.         LDAX    D    ; Force input to upper case for compare
  382.         ANI    5FH    ; Added by Gregg Small UCB 1/13/84
  383.         STAX    D    ;
  384.         CALL    JMP$INLNCOMP
  385.         DB    'Y',0
  386.         MVI    A,0FFH
  387.         JC    YES$CNTRL
  388.         INR    A
  389. YES$CNTRL:    STA    IGNORCTL
  390.         RET
  391. ;
  392. ; M712PM.ASM 10/09/83 by Jim Warner
  393. MSPEED$INIT:    IN    P$GETBAUD    ;Read serial speeds.
  394.         ANI    0FH        ;Mask to modem port speed.
  395.         MOV    L,A
  396.         MVI    H,0
  397.         LXI    D,STABLE
  398.         DAD    D
  399.         MOV    A,M        ;Get local speed code
  400.         STA    MSPEED        ; and tell MDM712.
  401.         RET 
  402. ;
  403. BIOSPB        DB    20    ;BIOS fcn: return devtbl address
  404.         DB    0    ;A-reg contents
  405.         DW    0    ;BC-reg contents
  406.         DW    0    ;DE-reg contents
  407.         DW    0    ;HL-reg contents
  408. ;
  409. BIOSPB1        DB    21    ;BIOS fcn: initialize device in c-reg
  410.         DB    0    ;A-reg contents
  411.         DB    1    ;C-reg=1 for MODEM
  412.         DB    0    ;B-reg
  413.         DW    0    ;DE-reg
  414.         DW    0    ;HL-reg
  415. ;
  416. ;This table is used to translate baud rate values as read from
  417. ; the hardware latch into their more restrictive MODEM712
  418. ; equivalents.
  419. ;
  420. ;           MDM712 BAUD                  hardware BAUD 
  421. ;            rate code                    rate code
  422. STABLE        DB    0    ;Really 50 baud, use 110    0
  423.         DB    0    ;Really 75 baud, use 110    1
  424.         DB    0    ;110 baud            2
  425.         DB    0    ;Really 134.5 baud, use 110    3
  426.         DB    0    ;Really 150 baud, use 110    4
  427.         DB    1    ;300 baud            5
  428.         DB    3    ;600 baud            6
  429.         DB    5    ;1200 baud            7
  430.         DB    5    ;Really 1800 baud, use 1200    8
  431.         DB    6    ;Really 2000 baud, use 2400    9
  432.         DB    6    ;2400 baud            A
  433.         DB    6    ;Really 3600 baud, use 2400    B
  434.         DB    7    ;4800 baud            C
  435.         DB    7    ;Really 7200 baud, use 4800    D
  436.         DB    8    ;9600 baud            E
  437.         DB    9    ;19.2k                F
  438. ;
  439. SPCLMENU:    RET
  440. ;.....
  441. ;
  442. ;    
  443. ;
  444. BAUDBUF:    DB    10,0
  445.         DS    10
  446. ;-----------------------------------------------------------------------
  447. ; M7GP-1.ASM 11/11/83:
  448.  
  449. ;
  450. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  451. ;                 0C00H (without Smartmodem)
  452. ;.....
  453. ;
  454.       END
  455. ;
  456.