home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / programs / spell / spell20.mac < prev    next >
Text File  |  1994-07-13  |  56KB  |  2,255 lines
  1. ;
  2. ; SPELL version 2.0        December 22, 1982
  3. ;
  4. ;    written by Michael C. Adler
  5. ;
  6. ;    History of SPELL's dictionary:
  7. ;    The first SPELL using this dictionary was probably written
  8. ;    by Ralph Gorin at Stanford.  It was transported to MIT by
  9. ;    Wayne Mattson.  Both the program at MIT and the dictionary
  10. ;    were most recently revised by William Ackerman.
  11. ;
  12. ;        Thanks to all for the effort spent desigining
  13. ;        the dictionary!
  14. ;                        -Michael
  15. ;
  16. ; 
  17.     .Z80
  18.     TITLE    SPELL
  19. ;    JMP    START    <--Include this line if assembled under anything
  20. ;                but M80.
  21.  
  22.     DB    '(C) 1982 Michael C. Adler. '
  23.     DB    'This program has been released into the public domain '
  24.     DB    'by the author.  It may neither be sold for profit nor '
  25.     DB    'included in a sold software package without permission '
  26.     DB    'of the author.'
  27. ;
  28. ;    SPELL will compare words in a document to a dictionary
  29. ; and mark any words that are not found.  It is intended for use
  30. ; with WordStar's ^QL (Find Misspelling) command.  Words are marked
  31. ; with a preceding null if they are not found.
  32. ;
  33. ;    WARNING:  SPELL requires a Z80 processor.
  34. ;
  35. ;    MODIFICATION HISTORY:
  36. ;
  37. ;    2.0 - December 22, 1982  Michael Adler
  38. ;          -Bug fix:  modified to rename files correctly at end of
  39. ;           run if output drive is different from input drive.
  40. ;          -Bug fix:  modified to recognize hyphenated words in indented
  41. ;           text.
  42. ;          -Enhanced to allow user specified dictionaries on command
  43. ;           line.
  44. ;    1.3 - October 10, 1982  Michael Adler
  45. ;          -Bug fix:  crashed if number of unique words was multiple
  46. ;           of 256.
  47. ;    1.2 - October 8, 1982  Michael Adler
  48. ;          -Modified MEMWRD routine to store words backwards in
  49. ;           memory starting just below the BDOS.  Thus, maximum
  50. ;           memory is utilized since pointers to words and the words
  51. ;           grow toward each other.
  52. ;          -FILE.UDC is now deleted if it is empty.
  53. ;          -Added messages displaying number of words, number of
  54. ;           unique words, and number of words not found.
  55. ;    1.1 - August 28, 1982  Michael Adler
  56. ;          -Crashed if file.ADD had a zero length word.  Fixed.
  57. ;          -Fixed bug in AUXDIC:  stopped reading from .ADD file
  58. ;           when 0 encountered.
  59. ;          -Fixed compatability with WS R(un program).  WS initializes
  60. ;           byte at 6CH with default drive instead of 0.  Caused output
  61. ;           to be directed to wrong drive sometimes.
  62. ;          -Set SPELL to ignore lines starting with . because WS can't
  63. ;           handle misspelling markers in dot command lines.
  64. ;          -SPELL did not find hyphenated words if LF had parity bit
  65. ;           set.  Fixed.
  66. ;
  67. ;    1.0 - August 16, 1982  Michael Adler
  68. ;          -Released
  69. ;
  70.  
  71.  
  72.     INCLUDE    SPELL0.MAC
  73.  
  74. ERRCHR    EQU    0            ;THIS IS THE CHARACTER THAT MARKS
  75.                     ;UNFOUND WORDS.  FOR WordStar, IT
  76.                     ;MUST BE 0.  IF YOU ARE USING ANOTHER
  77.                     ;EDITOR, SET ERRCHR TO THE ASCII
  78.                     ;EQUIVALENT OF THE CHARACTER THAT
  79.                     ;SHOULD MARK MISSPELLED WORDS.
  80.  
  81.  
  82. BOOT    EQU    0000H
  83. BDOS    EQU    BOOT+0005H
  84. IFCB    EQU    BOOT+005CH
  85. TPA    EQU    BOOT+0100H
  86. CONOUT    EQU    2
  87. STROUT    EQU    9
  88. OPEN    EQU    15
  89. CLOSE    EQU    16
  90. DELETE    EQU    19
  91. READ    EQU    20
  92. WRITE    EQU    21
  93. MAKE    EQU    22
  94. RENAME    EQU    23
  95. CURDSK    EQU    25
  96. SETDMA    EQU    26            ;SET DMA ADDRESS
  97. RANREA    EQU    33            ;READ RANDOM
  98.  
  99. LF    EQU    10
  100. CR    EQU    13
  101. EOF    EQU    01AH            ;END OF FILE CHARACTER
  102. ;
  103. ;    The following are bit flags for the dictionary
  104. ;
  105. ZFLAG    EQU    1
  106. YFLAG    EQU    2
  107. RFLAG    EQU    4
  108. GFLAG    EQU    8
  109. DFLAG    EQU    16
  110. MFLAG    EQU    32
  111. SFLAG    EQU    64
  112. HFLAG    EQU    256
  113. VFLAG    EQU    512
  114. JFLAG    EQU    1024
  115. XFLAG    EQU    2048
  116. TFLAG    EQU    4096
  117. NFLAG    EQU    8192
  118. PFLAG    EQU    16384
  119.  
  120. ;
  121. ;    Macros
  122. ;
  123. JISIT    MACRO    CHAR, JMPLOC        ;JUMP TO JMPLOC IF (HL) .EQ. CHAR
  124.     LD    A,CHAR
  125.     CP    (HL)
  126.     JP    Z,JMPLOC
  127.     ENDM
  128.  
  129. QISIT    MACRO    CHAR, JMPLOC        ;QUICK FORM OF JISIT.  CHARACTER
  130.                     ;TO COMPARE IS ALREADY IN A
  131.     CP    CHAR
  132.     JP    Z,JMPLOC
  133.     ENDM
  134.  
  135. ISIT    MACRO    CHAR            ;JUMP TO WRDNOT IF (HL) .NE. CHAR
  136.     LD    A,CHAR
  137.     CP    (HL)
  138.     JP    NZ,WRDNOT
  139.     ENDM
  140.  
  141.  
  142. START:    LD    SP,STACK        ;CREATE A STACK
  143.     LD    A,0C9H            ;RETURN INSTRUCTION
  144.     LD    (TPA),A            ;DON'T ALLOW SECOND RUN OF PROGRAM
  145.     LD    DE,WELCOM        ;PRINT SIGNON MESSAGE
  146.     LD    C,STROUT
  147.     CALL    BDOS
  148.     JR    START0
  149. WELCOM:    DB    'SPELL V2.0 -- December 22, 1982',CR,LF
  150.     DB    '(C) 1982 Michael C. Adler',CR,LF,'$'
  151.     
  152. START0:    LD    A,(BOOT+6CH)        ;GET OUTPUT DRIVE
  153.     PUSH    PSW            ;SAVE IT
  154.     LD    C,OPEN            ;OPEN THE DICTIONARY FILE
  155.     LD    DE,DICFCB
  156.     CALL    BDOS
  157.     CP    0FFH            ;FOUND?
  158.     JP    NZ,SETUP        ;JUMP IF FOUND
  159.     LD    A,1            ;TRY DRIVE A IF NOT ON DEFAULT DRIVE
  160.     LD    (DICFCB),A
  161.     LD    C,OPEN
  162.     LD    DE,DICFCB
  163.     CALL    BDOS
  164.     CP    0FFH            ;FOUND?
  165.     JP    NZ,SETUP
  166.     LD    C,STROUT        ;OUTPUT:  "CAN'T FIND DICTIONARY..."
  167.     LD    DE,DICERR
  168.     CALL    BDOS
  169.     CALL    0
  170. DICERR:    DB    'Can''t find dictionary file DICT.DIC',CR,LF,'$'
  171.  
  172. SETUP:    LD    DE,OFCB            ;COPY INPUT FILENAME TO OUTPUT
  173.     LD    HL,IFCB
  174.     LD    BC,9
  175.     LDIR
  176.     LD    DE,P2FCB        ;COPY INPUT FILENAME TO PASS 2 FCB
  177.     LD    HL,IFCB            ; (THIS FCB IS FOR INPUT ON PASS 2)
  178.     LD    BC,12
  179.     LDIR
  180.     LD    DE,FILDIC        ;COPY INPUT FILENAME TO FILE.DIC FCB
  181.     LD    HL,IFCB
  182.     LD    BC,9
  183.     LDIR
  184.     LD    DE,FILADD        ;COPY INPUT FILENAME TO FILE.ADD FCB
  185.     LD    HL,IFCB
  186.     LD    BC,9
  187.     LDIR
  188.     LD    DE,FILD$$        ;COPY INPUT FILENAME TO FILE.D$$ FCB
  189.     LD    HL,IFCB
  190.     LD    BC,9
  191.     LDIR
  192.     POP    PSW            ;GET OUTPUT DRIVE, IF SPECIFIED (FROM
  193.                     ;6CH)
  194.     CP    0
  195.     JR    Z,NODRV
  196.     LD    HL,BOOT+81H        ;SEARCH FOR DRIVE SPECIFICATION IN
  197.                     ;COMMAND LINE
  198.     LD    A,(BOOT+80H)        ;NUMBER OF CHARACTERS IN COMMAND LINE
  199.     LD    B,0
  200.     LD    C,A            ;COUNTER
  201.     ADD    HL,BC            ;HL POINTS TO LAST CHARACTER
  202.     DEC    BC            ;DON'T TEST FIRST BYTE OF INPUT
  203.     LD    A,':'            ;SEARCHING FOR ":"
  204.     CPDR
  205.     JR    NZ,NODRV        ;IF NO DRIVE SPECIFIED, THEN USE
  206.                     ;DEFAULT
  207.     LD    A,(HL)            ;GET DRIVE NAME
  208.     AND    5FH            ;MAKE UPPER CASE
  209.     SUB    40H            ;MAKE A=1
  210.     LD    (OFCB),A        ;MAKE OUTPUT FILES ON OUTPUT DRIVE
  211.     LD    (FILD$$),A
  212. NODRV:    LD    C,OPEN            ;OPEN THE INPUT FILE
  213.     LD    DE,IFCB
  214.     CALL    BDOS
  215.     LD    C,OPEN            ;WITH PASS 1 AND PASS 2 FCB'S
  216.     LD    DE,P2FCB
  217.     CALL    BDOS
  218.     CP    0FFH
  219.     JP    NZ,SETUP0        ;JUMP IF FOUND
  220.     LD    C,STROUT        ;OUTPUT:  "CAN'T FIND INPUT FILE"
  221.     LD    DE,NOINPT
  222.     CALL    BDOS
  223.     CALL    BOOT
  224. NOINPT:    DB    'Can''t find input file',CR,LF,'$'
  225.  
  226. SETUP0:    LD    C,DELETE        ;DELETE OUTPUT FILE (FILE.$$$)
  227.     LD    DE,OFCB
  228.     CALL    BDOS
  229.     LD    C,MAKE            ;MAKE A NEW OUTPUT FILE
  230.     LD    DE,OFCB
  231.     CALL    BDOS
  232.     CP    0FFH
  233.     JP    NZ,SETUP1        ;JUMP IF SUCCESSFUL
  234.     LD    C,STROUT        ;OUTPUT:  "DIRECTORY FULL"
  235.     LD    DE,NODIR
  236.     CALL    BDOS
  237.     CALL    BOOT
  238. NODIR:    DB    'Directory full',CR,LF,'$'
  239.  
  240. SETUP1:    CALL    CTRLZ            ;FILL OUTPUT BUFFER WITH EOF
  241.     LD    A,EOF            ;MARK END OF OUTPUT BUFFER
  242.     LD    (OBUFF+512),A
  243.     LD    A,0            ;MARK END OF DICTIONARY BUFFER
  244.     LD    (DICBUF+256),A
  245.     LD    (DICBUF+257),A
  246.     LD    A,(PUTCHR)        ;GET THE NORMAL FIRST INSTRUCTION
  247.                     ;AT PUTCHR
  248.     LD    (SAVPUT),A        ;STORE IT FOR LATER
  249.     LD    A,0C9H            ;RETURN INSTRUCTION
  250.     LD    (PUTCHR),A        ;DISABLE OUTPUT
  251.     CALL    AUXDIC            ;LOAD "SPELL.DIC", FILE.DIC AND
  252.                     ; FILE.ADD
  253.     LD    HL,IFCB            ;INPUT FILE FCB
  254.     LD    (FILPAT),HL        ;PATCH GETWRD: TO READ FROM IT
  255.  
  256.  
  257. ;
  258. ; SRTFIL -- Sort the file in memory, alphabetically.  Duplicate words are
  259. ;    discarded.  This will save a lot of time during dictionary lookups
  260. ;    since the words will have to be located only once.
  261.  
  262. SRTFIL:    CALL    GETWRD            ;GET A WORD INTO SRCWRD:
  263.     JP    Z,CHECK            ;IF EOF THEN START CHECKING
  264.     LD    HL,(TOTWRD)        ;KEEP TRACK OF TOTAL # OF WORDS
  265.     INC    HL
  266.     LD    (TOTWRD),HL
  267.     CALL    CREWRD            ;CREATE WORD FROM SRCWRD:
  268.     LD    A,0            ;IS IT AT LEAST 2 CHARS LONG?
  269.     CP    C
  270.     JR    Z,SRTFIL        ;FORGET IT IF NOT
  271.     LD    A,41            ;IF LONGER THAN 40, ALSO FORGET IT
  272.     CP    C
  273.     JR    Z,SRTFIL
  274.     CALL    MEMWRD            ;PUT WORD IN MEMORY
  275.     AND    A            ;FULL?
  276.     JR    Z,SRTFIL        ;GET ANOTHER WORD IF NOT
  277.     LD    HL,(INPTR)        ;GET OLD INPUT BUFFER POINTER
  278.     LD    (OLDPTR),HL        ;SAVE IT
  279.     LD    A,1            ;MARK PASS 1 INCOMPLETE
  280.     LD    (STOPED),A
  281.     LD    (MLTPAS),A        ;RECORD PERMANENTLY THAT >1 PASS
  282.     LD    C,36            ;GET RECORD NUMBER OF INPUT FILE
  283.     LD    DE,IFCB
  284.     CALL    BDOS
  285.  
  286.  
  287. ;
  288. ; CHECK -- Compare the entries in the sorted table to the dictionary.
  289. ;    Words that are found are marked.
  290. ;
  291. CHECK:    LD    A,(STOPED)        ;IS READ OF SOURCE COMPLETE?
  292.     CP    0
  293.     JR    NZ,CHEC01        ;IF NOT, NO MESSAGE
  294.     LD    DE,TOTMSG        ;OUTPUT: "TOTAL # OF WORDS"
  295.     LD    C,STROUT
  296.     CALL    BDOS
  297.     LD    HL,(TOTWRD)        ;PRINT NUMBER
  298.     CALL    DECOUT
  299. CHEC01:    LD    HL,(SRTTOP)        ;TOP ENTRY IN POINTER TABLE
  300.     LD    DE,(SRTBOT)        ;BOTTOM
  301.     XOR    A            ;CLEAR CARRY
  302.     DEC    HL            ;POINT TO TRUE END, NOT DUMMY RECORD
  303.     DEC    HL
  304.     SBC    HL,DE            ;HL=NUMBER OF WORDS TIMES 2
  305.     JP    Z,MAIN            ;IF EMPTY, WRITE OUT FILE
  306.     RRC    L            ;DIVIDE HL BY 2
  307.     LD    A,L
  308.     AND    07FH
  309.     LD    L,A
  310.     LD    A,0
  311.     RRC    H
  312.     ADC    A,0
  313.     RRC    A
  314.     OR    L
  315.     LD    L,A
  316.     LD    A,H
  317.     AND    07FH
  318.     LD    H,A
  319.     LD    B,H            ;PUT COUNTER IN BC
  320.     LD    C,L
  321.     INC    B            ;MAKE B WORD WITH DEC B AND JNZ
  322.                     ;COMBINATION
  323.     LD    A,0
  324.     CP    C            ;IF C 0?
  325.     JR    NZ,CHEC02
  326.     DEC    B            ;IF C=0 THEN READJUST B BECAUSE
  327.                     ;IT WOULD LOOP 256 TOO MANY TIMES
  328. CHEC02:    LD    HL,(SRTBOT)        ;GET ADDRESS OF FIRST ENTRY
  329.     INC    HL            ;BYPASS DUMMY ENTRY AT BEGINNING
  330.     INC    HL
  331. CHECK0:    LD    E,(HL)            ;GET ADDRESS OF WORD IN MEMORY
  332.     INC    HL
  333.     LD    D,(HL)
  334.     INC    HL
  335.     PUSH    BC
  336.     PUSH    HL
  337.     LD    HL,WORD
  338.     LD    C,0FEH            ;CHARACTER COUNTER
  339.                     ;AT THE END, C=CHARS-1.  START OF WITH
  340.                     ;-2 SO THAT 0 AND 1 CHARACTER NOT
  341.                     ;COUNTED
  342. CHECK1:    LD    A,(DE)            ;GET A CHARACTER
  343.     LD    (HL),A            ;PUT IT IN WORD:
  344.     INC    C
  345.     DEC    DE
  346.     INC    HL
  347.     CP    0            ;END OF WORD?
  348.     JR    NZ,CHECK1        ;LOOP UNTIL END
  349.     LD    A,C
  350.     LD    (LASTC),A        ;NUMBER OF CHARACTERS
  351.     LD    HL,(UNQWRD)        ;RECORD # OF UNIQUE WORDS
  352.     INC    HL
  353.     LD    (UNQWRD),HL
  354.     CALL    WRDTST            ;SEARCH DICTIONARY FOR WORD
  355.     CP    1            ;FOUND?
  356.     JR    NZ,CHECK2        ;LEAVE UNMARKED IF NOT FOUND
  357.     INC    DE            ;POINT TO END MARKER OF WORD
  358.     LD    A,080H
  359.     LD    (DE),A            ;MARK WORD AS FOUND
  360.     JR    CHECK3
  361. CHECK2:    LD    HL,(MISWRD)        ;INCREMENT MISSED WORDS COUNTER
  362.     INC    HL
  363.     LD    (MISWRD),HL
  364. CHECK3:    POP    HL
  365.     POP    BC
  366.     DEC    C
  367.     JP    NZ,CHECK0        ;LOOP
  368.     DEC    B
  369.     JP    NZ,CHECK0        ;16 BIT LOOP INDEX
  370.     LD    HL,P2FCB        ;SET TO INPUT FROM PASS 2 FCB
  371.     LD    (FILPAT),HL
  372.     LD    HL,(P2OPTR)        ;SET PASS 2 INPUT POINTER
  373.     LD    (INPTR),HL
  374.     LD    A,(SAVPUT)        ;GET THE NORMAL FIRST INSTRUCTION
  375.                     ;AT PUTCHR
  376.     LD    (PUTCHR),A        ;PATCH IT INTO THE WRITE ROUTINE
  377.     LD    HL,P2BUF+512        ;PATCH NEW BUFFER INTO GETCHR
  378.     LD    (BUFPAT),HL
  379.     LD    HL,P2BUF
  380.     LD    (BUFPA0),HL
  381.     LD    (BUFPA1),HL
  382.     INC    HL
  383.     LD    (BUFPA2),HL
  384.     LD    A,(LASTCH)        ;SAVE LAST CHARACTER READ
  385.     LD    B,A
  386.     LD    A,(OLSTCH)        ;PUT OLD LASTCH BACK
  387.     LD    (LASTCH),A
  388.     LD    A,B
  389.     LD    (OLSTCH),A        ;SAVE CURRENT LASTCH
  390.     JR    MAIN
  391. TOTMSG:    DB    CR,LF,LF,'Total number of words in document:    $'
  392.  
  393. ;
  394. ; MAIN -- Do a second pass through the input file.  Compare each word to
  395. ;    the memory buffer to determine whether the words were found.
  396. ;    If a word was not found, mark it with the ERRCHR.
  397.  
  398. MAIN:    CALL    GETWRD            ;GET A WORD INTO SRCWRD:
  399.     JP    Z,DONE            ;IF EOF THEN STOP
  400.     CALL    CREWRD            ;CREATE WORD FROM SRCWRD:
  401.     LD    A,0            ;IS WORD AT LEAST 2 CHARS LONG?
  402.     CP    C
  403.     JR    Z,MAIN0            ;ACCEPT IF NOT
  404.     LD    A,41            ;IF LONGER THAN 40, ALSO ACCEPT
  405.     CP    C
  406.     JR    Z,MAIN0
  407.     CALL    MEMWRD            ;SEARCH FOR WORD IN MEMORY
  408.     LD    A,(DE)            ;GET MARKER FOR WORD
  409.     CP    080H            ;WORD SPELLED CORRECTLY?
  410.     JR    Z,MAIN0
  411.     LD    A,ERRCHR        ;IF NOT, MARK WORD
  412.     CALL    PUTCHR
  413. MAIN0:    LD    HL,SRCWRD        ;OUTPUT THE ORIGINAL WORD
  414. MAIN1:    LD    A,(HL)
  415.     CP    0            ;END OF WORD?
  416.     JR    Z,MAIN2
  417.     CALL    PUTCHR            ;OUTPUT CHARACTER
  418.     INC    HL            ;POINT TO NEXT CHARACTER
  419.     JR    MAIN1            ;LOOP
  420. MAIN2:    LD    A,(STOPED)        ;WAS PASS 1 INCOMPLETE
  421.     AND    A
  422.     JR    Z,MAIN            ;GET NEXT WORD IF NOT
  423.     LD    DE,P2FCB        ;COMPUTE CURRENT RECORD NUMBER
  424.     LD    C,36
  425.     CALL    BDOS
  426.     LD    DE,(P2FCB+21H)
  427.     LD    HL,(IFCB+21H)        ;COMPARE STOPPED RECORD NUMBER TO
  428.                     ;CURRENT
  429.     XOR    A            ;CLEAR CARRY
  430.     SBC    HL,DE
  431.     JP    NZ,MAIN            ;GET NEXT WORD IF NOT THE SAME
  432.     LD    HL,(OLDPTR)        ;GET POSITION IN RECORD
  433.     LD    DE,P2BUF-INBUF        ;OFFSET IT TO COMPARE WITH PASS 2 BUFF
  434.     ADD    HL,DE
  435.     LD    DE,(INPTR)
  436.     XOR    A
  437.     SBC    HL,DE            ;COMPARE STOPPED POS TO CURRENT
  438.     JP    NZ,MAIN            ;GET NEXT WORD IF NOT THE SAME
  439.     LD    A,0            ;UNMARK PASS 1 INCOMPLETE
  440.     LD    (STOPED),A
  441.     LD    HL,(INPTR)        ;SAVE PASS 2 INPUT POINTER
  442.     LD    (P2OPTR),HL
  443.     LD    HL,(OLDPTR)        ;GET OLD POINTER TO BUFFER
  444.     LD    (INPTR),HL        ;RESET BUFFER POINTER
  445.     LD    HL,IFCB            ;PATCH GETCHR: ROUTINE TO READ FROM
  446.                     ;PASS 1 FCB
  447.     LD    (FILPAT),HL
  448.     LD    HL,INBUF+512        ;PATCH THE CORRECT BUFFER INTO GETCHR
  449.     LD    (BUFPAT),HL
  450.     LD    HL,INBUF
  451.     LD    (BUFPA0),HL
  452.     LD    (BUFPA1),HL
  453.     INC    HL
  454.     LD    (BUFPA2),HL
  455.     LD    A,0C9H            ;MAKE PUTCHR NOT WORK
  456.     LD    (PUTCHR),A
  457.     LD    HL,(SRTBOT)        ;RESET MEMORY BUFFER POINTERS
  458.     INC    HL
  459.     INC    HL
  460.     LD    (SRTTOP),HL
  461.     LD    HL,(BDOS+1)        ;GET BDOS VECTOR
  462.     DEC    HL            ;POINT TO FREE MEMORY
  463.     LD    (FREE),HL        ;POINTER TO FREE MEMORY
  464.     LD    A,(LASTCH)        ;SAVE LAST CHARACTER READ
  465.     LD    B,A
  466.     LD    A,(OLSTCH)        ;PUT OLD LASTCH BACK
  467.     LD    (LASTCH),A
  468.     LD    A,B
  469.     LD    (OLSTCH),A        ;SAVE CURRENT LASTCH
  470.     JP    SRTFIL            ;FILL BUFFER AGAIN
  471.  
  472. ;
  473. ; DONE -- Write out the rest of the output buffer and then close and rename
  474. ;    output files.
  475.  
  476. DONE:    LD    HL,OBUFF        ;WRITE OUT REMAINING DATA IN BUFFER
  477.     LD    DE,128
  478. DONE1:    LD    A,EOF            ;DONE?
  479.     CP    (HL)
  480.     JR    Z,DONE3
  481.     PUSH    DE
  482.     PUSH    HL
  483.     LD    D,H            ;SET UP DMA ADDRESS
  484.     LD    E,L
  485.     LD    C,SETDMA
  486.     CALL    BDOS
  487.     LD    DE,OFCB            ;WRITE 128 BYTES TO FILE
  488.     LD    C,WRITE
  489.     CALL    BDOS
  490.     POP    HL
  491.     POP    DE
  492.     CP    0            ;ERROR?
  493.     JR    NZ,DONE2        ;DISK FULL --> BRANCH
  494.     ADD    HL,DE            ;POINT TO NEXT RECORD
  495.     JR    DONE1
  496. DONE2:    LD    C,STROUT        ;DISK FULL
  497.     LD    DE,DSKFUL        ;DISK FULL MESSAGE (SEE PUTCHR)
  498.     CALL    BDOS
  499.     CALL    BOOT
  500.  
  501. DONE3:    LD    DE,OFCB            ;CLOSE OUTPUT FILE
  502.     LD    C,CLOSE
  503.     CALL    BDOS
  504.     LD    A,'B'
  505.     LD    (OFCB+9),A
  506.     LD    A,'A'
  507.     LD    (OFCB+10),A
  508.     LD    A,'K'
  509.     LD    (OFCB+11),A
  510.     LD    A,(OFCB)        ;REMEMBER OUTPUT DRIVE NAME
  511.     PUSH    PSW
  512.     LD    A,(IFCB)        ;GET THE DRIVE ON WHICH INPUT WAS DONE
  513.     LD    (OFCB),A        ;TRY TO DELETE .BAK ON IT ONLY
  514.     LD    DE,OFCB
  515.     LD    C,DELETE
  516.     CALL    BDOS
  517.     LD    DE,IFCB+16        ;RENAME SOURCE TO SOURCE.BAK
  518.     LD    HL,OFCB
  519.     LD    BC,12            ;COPY FILENAME FOR RENAME
  520.     LDIR
  521.     LD    DE,IFCB
  522.     LD    C,RENAME
  523.     CALL    BDOS
  524.     LD    HL,IFCB+9        ;RENAME .$$$ TO SOURCE
  525.     LD    DE,IFCB+25
  526.     LD    BC,3
  527.     LDIR
  528.     LD    A,'$'
  529.     LD    (IFCB+9),A
  530.     LD    (IFCB+10),A
  531.     LD    (IFCB+11),A
  532.     POP    PSW            ;RESTORE OUTPUT DRIVE NAME
  533.     LD    (IFCB),A        ;AND PUT IT IN FCB
  534.     LD    DE,IFCB
  535.     LD    C,RENAME
  536.     CALL    BDOS
  537.                     ;NOW TAKE CARE OF USER DICTIONARIES
  538.     LD    DE,FILADD        ;DELETE FILE.ADD
  539.     LD    C,DELETE
  540.     CALL    BDOS
  541.     LD    DE,FILDIC        ;DELETE FILE.UDC
  542.     LD    C,DELETE
  543.     CALL    BDOS
  544.     LD    A,(MLTPAS)        ;WAS MORE THAN 1 PASS REQUIRED?
  545.     CP    0
  546.     JR    Z,DONE30        ;NO MESSAGE IF NOT
  547.     LD    DE,NOTOUT        ;OUTPUT: NO TOTALS PRINTED
  548.     LD    C,STROUT
  549.     CALL    BDOS
  550.     JR    DONE31
  551. DONE30:    LD    DE,UNQMSG        ;OUTPUT: # OF UNIQUE WORDS
  552.     LD    C,STROUT
  553.     CALL    BDOS
  554.     LD    HL,(UNQWRD)        ;PRINT # OF WORDS
  555.     CALL    DECOUT
  556.     LD    DE,MISMSG        ;OUTPUT: # OF "MISSPELLED" WORDS
  557.     LD    C,STROUT
  558.     CALL    BDOS
  559.     LD    HL,(MISWRD)        ;PRINT #
  560.     CALL    DECOUT
  561. DONE31:    LD    HL,(FILUDC)        ;DELETE FILE.D$$ IF IT HAS NO WORDS
  562.     LD    A,0
  563.     CP    H
  564.     JR    NZ,DONE4        ;RENAME IT TO FILE.UDC IF >0 WORDS
  565.     CP    L
  566.     JR    NZ,DONE4
  567.     LD    DE,FILD$$        ;DELETE IT
  568.     LD    C,DELETE
  569.     CALL    BDOS
  570.     CALL    BOOT
  571.  
  572. DONE4:    LD    HL,FILDIC        ;RENAME FILE.D$$ TO FILE.UDC
  573.     LD    DE,FILD$$+16
  574.     LD    BC,12
  575.     LDIR
  576.     LD    DE,FILD$$
  577.     LD    C,RENAME
  578.     CALL    BDOS
  579.     CALL    BOOT
  580. NOTOUT:    DB    CR,LF,'No subtotals available due to size of document.$'
  581. UNQMSG:    DB    CR,LF,'    Number of unique words:        $'
  582. MISMSG:    DB    CR,LF,'    Unique "misspelled" words:    $'
  583.  
  584. ;
  585. ; GETWRD -- Read a word from an input file.  Words are any series of
  586. ;    alphabetic characters (with or without parity set) and
  587. ;    apostrophes.
  588. ;
  589. ;        Returns:  C <-- number of characters in word
  590. ;              Z flag set if EOF
  591.  
  592. GETWRD:    CALL    GETCHR            ;GET A CHARACTER
  593.     CP    EOF            ;END OF FILE?
  594.     RET    Z
  595.     CALL    LEGAL            ;TEST IF LEGAL
  596.     LD    (LASTCH),A        ;SAVE LAST CHARACTER
  597.     JR    Z,KILPER        ;EXIT LOOP IF LEGAL
  598.     CALL    PUTCHR            ;SEND CHARACTER DIRECTLY OUT
  599.     JR    GETWRD            ;LOOP UNTIL LEGAL
  600. KILPER:    LD    C,A
  601.     AND    07FH            ;MASK PARITY
  602.     CP    '.'            ;IS IT A DOT COMMAND?
  603.     LD    A,C
  604.     JR    NZ,GETWR0        ;GET WORD IF NOT
  605.     CALL    PUTCHR
  606. KILPE0:    CALL    GETCHR            ;ERADICATE THIS LINE
  607.     CP    EOF            ;END OF FILE?
  608.     RET    Z
  609.     CALL    PUTCHR            ;OUTPUT IT
  610.     LD    (LASTCH),A
  611.     AND    07FH            ;MASK PARITY
  612.     CP    LF            ;IS IT A LINE TERMINATOR?
  613.     JR    NZ,KILPE0        ;LOOP THROUGH WHOLE LINE
  614.     JR    GETWRD            ;GET A TEXT WORD NOW
  615. GETWR0:    LD    C,1            ;ZERO CHARACTER COUNTER
  616.     LD    HL,SRCWRD+1        ;INITIALIZE POINTER TO SRCWRD:
  617.     LD    (SRCWRD),A        ;STORE FIRST CHARACTER
  618. GETWR1:    CALL    GETCHR
  619. HYPTST:    CP    1FH            ;SOFT HYPHEN?
  620.     JP    Z,ISHYP
  621.     CP    1EH            ;UNUSED SOFT HYPHEN?
  622.     JP    NZ,NOTHYP
  623. ISHYP:    LD    (LASTCH),A        ;UPDATE LAST CHARACTER POINTER
  624.     LD    (HL),A            ;STORE HYPHEN
  625.     INC    HL
  626.     INC    C
  627.     CALL    GETCHR
  628. ISHYP0:    CP    CR OR 80H        ;SOFT RETURN AFTER HYPHEN?
  629.     JR    NZ,HYPTST        ;TEST FOR ANOTHER HYPHEN
  630.     LD    (LASTCH),A        ;UPDATE LAST CHARACTER POINTER
  631.     LD    (HL),A            ;STORE RETURN
  632.     INC    HL
  633.     INC    C
  634.     CALL    GETCHR
  635.     LD    B,A            ;SAVE THE CHAR
  636.     AND    07FH            ;KILL PARITY BIT
  637.     CP    LF            ;SOFT LINE FEED?
  638.     LD    A,B            ;RESTORE CHAR
  639.     JR    NZ,HYPTST        ;TEST FOR ANOTHER HYPHEN
  640.     LD    (LASTCH),A        ;UPDATE LAST CHARACTER POINTER
  641.     LD    (HL),A            ;STORE LF
  642.     INC    HL
  643.     INC    C
  644.     CALL    GETCHR
  645. ISHYP1:    CP    ' ' OR 80H        ;ELIMINATE SOFT SPACES AT START OF LINE
  646.     JR    NZ,ISHYP0        ;TEST FOR REST OF WORD
  647.     LD    (LASTCH),A        ;UPDATE LAST CHARACTER POINTER
  648.     LD    (HL),A            ;STORE SPACE
  649.     INC    HL
  650.     INC    C
  651.     CALL    GETCHR
  652.     JR    ISHYP1            ;TEST FOR MORE SPACES    
  653. NOTHYP:    CALL    LEGAL
  654.     JR    NZ,GETWR2        ;EXIT LOOP WHEN NOT WORD CHARACTER
  655.     LD    (LASTCH),A
  656.     LD    (HL),A
  657.     INC    HL
  658.     INC    C
  659.     JR    GETWR1
  660. GETWR2:    LD    (HL),0            ;MARK END OF WORD
  661.     LD    HL,(INPTR)        ;DECREMENT POINT FOR INPUT BUFFER
  662.                     ;SO FIRST CHAR AFTER WORD IS KEPT
  663.     DEC    HL
  664.     LD    (INPTR),HL
  665.     RET
  666.  
  667. ;
  668. ; LEGAL -- Determines whether character is alphabetic, an apostrophe,
  669. ;    or period for a dot command.
  670. ;
  671. ;        Returns:  Z flag set <-- characters was one of the above
  672. ;              Z flag clear <-- was not one of the above
  673.  
  674. LEGAL:    LD    B,A
  675.     AND    05FH            ;KILL PARITY AND LOWER CASE
  676.     CP    'A'            ;MUST BE GREATER THAN "A"
  677.     JP    C,LEGAL0
  678.     CP    'Z'+1            ;GREATER THAN "Z"
  679.     JP    NC,LEGAL0
  680.     LD    A,B
  681.     CP    A            ;SET ZERO FLAG
  682.     RET
  683. LEGAL0:    LD    A,B
  684.     AND    07FH            ;KILL ONLY PARITY
  685.     CP    27H            ;"'"
  686.     JR    Z,LEGAL1
  687.     LD    A,(LASTCH)        ;WAS LAST CHARACTER A LF?
  688.     AND    7FH            ;MASK PARITY
  689.     CP    LF
  690.     JR    NZ,LEGAL1
  691.     LD    A,B
  692.     CP    '.'            ;ACCEPT PERIODS SO DOT COMMAND ACCEPTED
  693. LEGAL1:    LD    A,B
  694.     RET
  695.  
  696. ;
  697. ; GETCHR -- Read a character from an input file into a buffer.  This routine
  698. ;    is used for a number of different purposes.  The file from which
  699. ;    to read is patched into FILPAT.  The buffer to which writes should
  700. ;    occur is patched into BUFPAT-BUFPA2.
  701. ;
  702. ;        Returns:  A  <-- next character from input file
  703.  
  704. GETCHR:    PUSH    BC
  705.     PUSH    DE
  706.     PUSH    HL
  707.     LD    HL,(INPTR)        ;POINTER FOR INPUT
  708.     LD    DE,INBUF+512        ;END OF INPUT BUFFER
  709. BUFPAT    EQU    $-2            ;PATCH FOR INPUT BUFFER
  710.     XOR    A            ;CLEAR CARRY
  711.     PUSH    HL
  712.     SBC    HL,DE            ;AT END OF BUFFER?
  713.     POP    HL
  714.     JP    Z,GETCH0        ;REFILL BUFFER
  715.     LD    A,(HL)            ;GET THE CHARACTER
  716.     INC    HL            ;INCREMENTED POINTER
  717.     LD    (INPTR),HL
  718. GETRET:    POP    HL
  719.     POP    DE
  720.     POP    BC
  721.     RET
  722. GETCH0:    LD    HL,INBUF
  723. BUFPA0    EQU    $-2            ;PATCH FOR INPUT BUFFER
  724.     LD    DE,128
  725.     LD    C,4
  726. GETCH2:    PUSH    BC
  727.     PUSH    DE
  728.     PUSH    HL
  729.     LD    A,EOF            ;MARK WITH EOF IN CASE NO RECORD
  730.     LD    (HL),A
  731.     LD    D,H            ;SET UP DMA ADDRESS FOR READ
  732.     LD    E,L
  733.     LD    C,SETDMA
  734.     CALL    BDOS            ;SET DMA ADDRESS
  735.     LD    DE,IFCB
  736. FILPAT    EQU    $-2            ;FCB PATCH ADDRESS
  737.     LD    C,READ            ;READ 128 BYTES OF INPUT FILE
  738.     CALL    BDOS
  739.     POP    HL
  740.     POP    DE
  741.     POP    BC
  742.     CP    0            ;SUCCESS?
  743.     JR    NZ,GETCH3        ;JUMP IF EOF
  744.     ADD    HL,DE            ;POINT TO NEXT RECORD ADDRESS
  745.     DEC    C
  746.     JP    NZ,GETCH2        ;LOOP FOR 4 RECORDS
  747. GETCH3:    LD    A,(INBUF)        ;GET FIRST CHARACTER
  748. BUFPA1    EQU    $-2            ;ANOTHER BUFFER PATCH
  749.     LD    (HL),EOF        ;PUT EOF AT BEGINNING OF FIRST UNUSED
  750.                     ;RECORD IN MEMORY
  751.     LD    HL,INBUF+1
  752. BUFPA2    EQU    $-2            ;AND YET ANOTHER BUFFER PATCH
  753.     LD    (INPTR),HL        ;SET UP POINTER TO RECORDS
  754.     JP    GETRET
  755.  
  756. ;
  757. ; CREWRD -- Converts the word in SRCWRD to a word in WORD.  Parity bits
  758. ;    are cleared, lower case is converted to upper case, and apostrophes
  759. ;    that are not imbedded in words are discarded.
  760.  
  761. CREWRD:    LD    HL,WORD            ;POINTER TO DESINATION BUFFER
  762.     LD    DE,SRCWRD        ;SOURCE BUFFER
  763.     LD    C,0
  764. CREWR0:    LD    A,(DE)            ;GET A CHARACTER
  765.     CP    0            ;END OF WORD?
  766.     JP    Z,CREWR2
  767.     AND    07FH            ;MASK PARITY
  768.     CP    027H            ;"'" CHARACTER?
  769.     JR    Z,CREWR3
  770.     AND    05FH            ;MASK PARITY AND CONVERT TO UPPER CASE
  771.     CP    'A'            ;IS IT ONLY A HYPHEN?
  772.     JR    C,CREWR1        ;IF SO, SKIP IT
  773. CREADD:    INC    C
  774.     LD    (HL),A            ;PUT CHARACTER IN WORD BUFFER
  775.     LD    A,41            ;MAXIMUM OF 40 CHARACTERS IN WORD
  776.     CP    C
  777.     RET    Z            ;WORD TOO LONG.  ACCEPT IT
  778.     INC    HL
  779. CREWR1:    INC    DE
  780.     JP    CREWR0
  781. CREWR2:    LD    (HL),0            ;MARK END OF WORD
  782.     LD    HL,LASTC        ;PUT NUMBER OF CHARACTERS IN LASTC
  783.     DEC    C            ;C=NUMBER OF CHARACTERS - 1
  784.     JP    P,CREWS2        ;JUMP IF C WASN'T ALREADY 0
  785.     INC    C
  786. CREWS2:    LD    (HL),C
  787.     RET
  788. CREWR3:    LD    A,0            ;IF FIRST CHARACTER IN WORD, IGNORE
  789.                     ;"'"
  790.     CP    C
  791.     JR    Z,CREWR1
  792.     INC    DE
  793.     LD    A,(DE)            ;IF LAST CHAR IN WORD, IGNORE
  794.     CP    0
  795.     DEC    DE
  796.     JR    Z,CREWR1
  797.     LD    A,27H            ;OTHERWISE, KEEP "'"
  798.     JR    CREADD
  799.  
  800. ;
  801. ; PUTCHR -- write a character to output file
  802. ;
  803. ;        Input:  A --> character to output
  804.  
  805. PUTCHR:    PUSH    PSW
  806.     PUSH    BC
  807.     PUSH    DE
  808.     PUSH    HL
  809.     LD    HL,(OPOSS)        ;GET CURRENT POSITION IN OBUFF
  810.     LD    (HL),A            ;PUT CHARACTER IN BUFFER
  811.     INC    HL
  812.     LD    (OPOSS),HL        ;UPDATE POINTER
  813.     LD    DE,OBUFF+512        ;AT END OF BUFFER?
  814.     XOR    A            ;CLEAR CARRY
  815.     SBC    HL,DE
  816.     JR    Z,PUTCH0        ;WRITE OUT DATA IF END OF BUFFER
  817. PUTRET:    POP    HL
  818.     POP    DE
  819.     POP    BC
  820.     POP    PSW
  821.     RET
  822. PUTCH0:    LD    C,4            ;LOOP COUNTER
  823.     LD    HL,OBUFF        ;ADDRESS OF DATA
  824.     LD    DE,128            ;LENGTH OF EACH RECORD
  825. PUTCH1:    PUSH    BC
  826.     PUSH    DE
  827.     PUSH    HL
  828.     LD    D,H            ;SET UP DMA ADDRESS
  829.     LD    E,L
  830.     LD    C,SETDMA
  831.     CALL    BDOS
  832.     LD    DE,OFCB            ;WRITE RECORD TO OUTPUT FILE
  833. OUTPAT    EQU    $-2            ;PATCH ADDRESS FOR OUTPUT FILE FCB
  834.     LD    C,WRITE
  835.     CALL    BDOS
  836.     CP    0            ;SUCCESS?
  837.     JR    NZ,PUTCH2        ;JUMP IF DISK FULL
  838.     POP    HL
  839.     POP    DE
  840.     POP    BC
  841.     ADD    HL,DE            ;POINT TO NEXT RECORD
  842.     DEC    C
  843.     JP    NZ,PUTCH1        ;LOOP FOR 512 BYTE BUFFER
  844.     LD    HL,OBUFF        ;RESET POINTER
  845.     LD    (OPOSS),HL
  846.     CALL    CTRLZ            ;FILL BUFFER WITH EOF CHARACTER
  847.     JP    PUTRET            ;RETURN
  848. PUTCH2:    LD    C,STROUT        ;DISK FULL ERROR
  849.     LD    DE,DSKFUL
  850.     CALL    BDOS
  851.     CALL    BOOT            ;GIVE UP
  852. DSKFUL:    DB    CR,LF,'Disk full -- aborting',CR,LF,'$'
  853.  
  854. ;
  855. ; CTRLZ -- Fill the output buffer with EOF characters to prepare it for
  856. ;    writing
  857.  
  858. CTRLZ:    LD    HL,OBUFF        ;BUFFER ADDRESS
  859.     LD    B,2            ;LOOP 256 BYTES 2 TIMES
  860.     LD    C,0
  861. CTRLZ0:    LD    (HL),EOF        ;PUT EOF IN BUFFER
  862.     INC    HL
  863.     DEC    C            ;FAST COUNTER
  864.     JR    NZ,CTRLZ0
  865.     DEC    B            ;SLOW COUNTER
  866.     JR    NZ,CTRLZ0
  867.     RET
  868.  
  869. ;
  870. ; MEMWRD -- put word in WORD into memory.  If word already exists in memory
  871. ;    then its the address of its status byte is returned in DE.  If the
  872. ;    word is not found, the word is placed in memory and the pointers
  873. ;    that alphabetize the words are updated.  If memory is full, a
  874. ;    1 is returned in A.  Otherwise 0 is returned in A.
  875.  
  876. MEMWRD:    LD    BC,(SRTBOT)        ;GET ADDRESS OF BOTTOM OF WORD POINTER
  877.     LD    DE,(SRTTOP)        ;TOP OF WORD POINTER
  878.     JR    MEMSKP
  879. MEMWR0:    POP    HL
  880.     POP    DE
  881.     POP    BC
  882.     JP    M,MEMW00
  883.     LD    D,H            ;MOVE HIGH POINTER DOWN
  884.     LD    E,L
  885.     JR    MEMSKP
  886. MEMW00:    LD    B,H            ;MOVE LOW POINTER UP
  887.     LD    C,L
  888. MEMSKP:    LD    H,D            ;HL IS POINTER TO RECORD BETWEEN DE AND
  889.     LD    L,E            ;BC
  890.     XOR    A            ;CLEAR CARRY
  891.     SBC    HL,BC
  892.     LD    A,0            ;IS BC+1=HL?
  893.     CP    H
  894.     JP    NZ,MEMWR1
  895.     LD    A,2
  896.     CP    L
  897.     JP    NZ,MEMWR1
  898.     LD    HL,(SRTTOP)        ;UPDATE SRTTOP=SRTTOP+2
  899.     INC    HL
  900.     INC    HL
  901.     LD    (SRTTOP),HL
  902.     XOR    A            ;CLEAR CARRY
  903.     PUSH    HL
  904.     SBC    HL,DE            ;NUMBER OF BYTES IN TABLE TO MOVE
  905.     LD    B,H            ;PUT NUMBER OF COUNTER FOR LDDR
  906.     LD    C,L
  907.     POP    HL
  908.     PUSH    DE            ;SAVE THE ADDRESS FOR NEW WORD
  909.     LD    D,H            ;PUT DESTINATION ADDRESS IN DE
  910.     LD    E,L
  911.     DEC    HL            ;SOURCE IN HL
  912.     DEC    HL
  913.     LDDR                ;PUT A SPACE FOR NEW POINTER IN TABLE
  914.     POP    DE
  915.     LD    HL,(FREE)        ;ADDRESS TO STORE NEW WORD
  916.     EX    DE,HL
  917.     LD    (HL),E            ;STORE ADDRESS OF WORD IN TABLE
  918.     INC    HL
  919.     LD    (HL),D
  920.     LD    HL,WORD
  921.     LD    A,(LASTC)        ;GET NUMBER OF CHARACTERS
  922.     LD    B,A
  923.     INC    B            ;B = NUMBER OF CHARACTERS IN WORD + 1
  924.     INC    B
  925. MEMW01:    LD    A,(HL)            ;GET A CHARACTER
  926.     LD    (DE),A            ;PUT IT IN MEMORY
  927.     DEC    DE            ;STORE WORD BACKWARDS
  928.     INC    HL            ;NEXT CHAR IN WORD
  929.     DJNZ    MEMW01    
  930.     LD    (FREE),DE        ;UPDATE FREE MEMORY POINTER
  931.     EX    DE,HL
  932.     LD    DE,45            ;ALLOW ROOM FOR ANOTHER WORD
  933.     XOR    A            ;CLEAR CARRY
  934.     SBC    HL,DE
  935.     LD    DE,(SRTTOP)        ;POINTER TO TOP OF POINTER TABLE
  936.     XOR    A
  937.     SBC    HL,DE            ;IS ANY MEMORY LEFT?
  938.     JR    C,MEMFUL        ;IF NOT, NO MORE MEMORY
  939.     LD    A,0            ;INDICATE MEMORY LEFT
  940.     RET
  941. MEMFUL:    LD    A,1            ;NO MEMORY LEFT
  942.     RET
  943. MEMWR1:    RRC    L            ;DIVIDE HL BY 2
  944.     LD    A,L
  945.     AND    07EH            ;MAKE IT EVEN
  946.     LD    L,A
  947.     LD    A,0
  948.     RRC    H
  949.     ADC    A,0            ;IF BIT 0 OF H SET, THEN C SET
  950.     RRC    A
  951.     OR    L
  952.     LD    L,A
  953.     LD    A,H
  954.     AND    07FH
  955.     LD    H,A
  956.     ADD    HL,BC            ;HL POINTS TO RECORD BETWEEN BC AND
  957.                     ;DE
  958.     PUSH    BC
  959.     PUSH    DE
  960.     PUSH    HL
  961.     LD    E,(HL)            ;DE= ADDRESS OF COMPARISON WORD IN BUFF
  962.     INC    HL
  963.     LD    D,(HL)
  964.     LD    HL,WORD            ;HL= ADDRESS OF NEW WORD BUFFER
  965. MEMWR2:    LD    A,(DE)            ;GET A CHARACTER
  966.     AND    07FH            ;KILL CARRY (FOR 0 BYTE OF CORRECTED
  967.                     ;WORDS)
  968.     CP    (HL)            ;COMPARE THEM
  969.     JP    NZ,MEMWR0        ;IF .NE. THEN TRY ANOTHER WORD
  970.     LD    A,0
  971.     CP    (HL)            ;END OF WORD?
  972.     DEC    DE            ;DECREMENT WORD TABLE POINTER (WORDS
  973.                     ;ARE STORED BACKWARDS
  974.     INC    HL            ;INCREMENT POINTER (DON'T AFFECT
  975.                     ;FLAGS)
  976.     JR    NZ,MEMWR2
  977.     POP    HL
  978.     POP    BC            ;TRASH OLD DE
  979.     POP    BC
  980.     INC    DE            ;POINT TO 0 OR 080H AT END OF WORD
  981.                     ; (80H IS CORRECTED AND WORD FOUND)
  982.     RET                ;DON'T BOTHER TO BUFFER THE SAME WORD
  983.  
  984. ;
  985. ; AUXDIC -- Open SPELL.DIC and load it into memory.  Open FILE.UDC and load
  986. ;    it as well.  If FILE.ADD exists (wordstar dictionary addition file),
  987. ;    load it and put its contents in FILE.UDC.
  988.  
  989. AUXDIC:    LD    HL,NEXT            ;ZERO THE MEMORY DICTIONARY
  990.     LD    A,0
  991.     LD    (HL),A
  992.  
  993. AUXDI2:    LD    DE,FILD$$        ;MAKE TEMPORARY .DIC OUTPUT FILE
  994.     LD    C,DELETE
  995.     CALL    BDOS
  996.     LD    DE,FILD$$
  997.     LD    C,MAKE
  998.     CALL    BDOS
  999.     LD    HL,FILD$$        ;PATCH THIS FCB INTO OUTPUT ROUTINE
  1000.     LD    (OUTPAT),HL
  1001.     LD    A,(SAVPUT)        ;MAKE PUTCHR: WRITE TO A FILE
  1002.     LD    (PUTCHR),A
  1003.     LD    DE,FILDIC        ;TRY TO OPEN FILE.UDC
  1004.     LD    C,OPEN
  1005.     CALL    BDOS
  1006.     CP    0FFH            ;FOUND?
  1007.     JP    Z,AUXDI4        ;JUMP IF NOT
  1008.     LD    HL,FILDIC        ;PATCH GETCHR: TO READ FROM THIS FILE
  1009.     LD    (FILPAT),HL
  1010.     LD    HL,INBUF+512        ;PATCH INPTR TO READ ON FIRST CALL
  1011.     LD    (INPTR),HL
  1012. AUXDI3:    CALL    GETWRD            ;GET A WORD INTO SRCWRD:
  1013.     JP    Z,AUXDI4        ;IF EOF THEN START CHECKING
  1014.     CALL    CREWRD            ;CREATE WORD FROM SRCWRD:
  1015.     LD    A,0            ;IS IT AT LEAST 2 CHARS LONG?
  1016.     CP    C
  1017.     JR    Z,AUXDI3        ;FORGET IT IF NOT
  1018.     LD    A,41            ;IF LONGER THAN 40, ALSO FORGET IT
  1019.     CP    C
  1020.     JR    Z,AUXDI3
  1021.     PUSH    HL
  1022.     LD    HL,(FILUDC)        ;INCREMENT COUNTER FOR WORDS OUTPUT
  1023.     INC    HL            ;  TO FILE.UDC
  1024.     LD    (FILUDC),HL
  1025.     POP    HL
  1026.     CALL    SAVWRD            ;PUT WORD IN MEMORY
  1027.     LD    HL,WORD            ;PUT WORD IN OUTPUT FILE
  1028. AUXDH3:    LD    A,(HL)            ;GET A CHARACTER
  1029.     CP    0            ;END OF WORD?
  1030.     JR    Z,AUXDI3        ;QUIT OUTPUT IF END
  1031.     CALL    PUTCHR            ;OUTPUT CHARACTER
  1032.     INC    HL
  1033.     JR    AUXDH3
  1034.  
  1035. AUXDI4:    LD    DE,FILADD        ;TRY TO OPEN FILE.ADD
  1036.     LD    C,OPEN
  1037.     CALL    BDOS
  1038.     CP    0FFH            ;FOUND?
  1039.     JP    Z,AUXDI7        ;RETURN IF NOT
  1040.     LD    HL,FILADD        ;PATCH GETCHR: TO READ FROM FILE.ADD
  1041.     LD    (FILPAT),HL
  1042.     LD    HL,INBUF+512        ;SET INPTR TO READ ON FIRST CALL
  1043.     LD    (INPTR),HL
  1044.     LD    A,CR            ;PUT CR LF IN OUTPUT FILE
  1045.     CALL    PUTCHR
  1046.     LD    A,LF
  1047.     CALL    PUTCHR
  1048. AUXDI5:    CALL    GETCHR            ;GET A CHARACTER FROM FILE.ADD
  1049.                     ;IGNORE ALL WORD TYPES EXCEPT 0FFH
  1050.                     ;(EOF)
  1051.     CP    0FFH            ;END OF WORDS IN CURRENT RECORD?
  1052.     JR    Z,AUXDI5        ;IF YES, LOOP THROUGH RECORD
  1053.     CP    0            ;ZERO USED AS FILLER CHARACTER?
  1054.     JP    Z,AUXDI5
  1055.     CP    EOF            ;EOF?
  1056.     JP    Z,AUXDI7
  1057.     CALL    GETCHR            ;THIS CHARACTER IS LENGTH OF WORD
  1058.     CP    0            ;NO CHARACTERS?
  1059.     JR    Z,AUXDI5
  1060.     LD    B,A
  1061.     LD    HL,WORD            ;BUFFER IT IN WORD
  1062. AUXDI6:    CALL    GETCHR            ;GET A CHARACTER
  1063.     LD    (HL),A            ;SAVE IT IN WORD:
  1064.     INC    HL
  1065.     DJNZ    AUXDI6            ;GET WHOLE WORD
  1066.     LD    A,0            ;MARK END OF WORD
  1067.     LD    (HL),A
  1068.     CALL    SAVWRD            ;PUT WORD IN MEMORY
  1069.     JP    Z,AUXDI5        ;IF WORD ALREADY IN MEMORY THEN DON'T
  1070.                     ;OUTPUT TO FILE.UDC
  1071.     PUSH    HL
  1072.     LD    HL,(FILUDC)        ;INCREMENT COUNTER FOR WORDS OUTPUT
  1073.     INC    HL            ;  TO FILE.UDC
  1074.     LD    (FILUDC),HL
  1075.     POP    HL
  1076.     LD    HL,WORD            ;OUTPUT WORD
  1077. AUXDH6:    LD    A,(HL)            ;GET A CHARACTER
  1078.     INC    HL
  1079.     CP    0            ;END?
  1080.     JR    Z,AUXDK6
  1081.     CALL    PUTCHR
  1082.     JR    AUXDH6
  1083. AUXDK6:    LD    A,CR            ;PUT CR LF IN OUTPUT FILE
  1084.     CALL    PUTCHR
  1085.     LD    A,LF
  1086.     CALL    PUTCHR
  1087.     JP    AUXDI5            ;GET ANOTHER CHARACTER
  1088.  
  1089. AUXDI7:    LD    HL,OBUFF        ;WRITE OUT REMAINING DATA IN BUFFER
  1090.     LD    DE,128
  1091. AUXDI8:    LD    A,EOF            ;DONE?
  1092.     CP    (HL)
  1093.     JR    Z,AUXDJ0
  1094.     PUSH    DE
  1095.     PUSH    HL
  1096.     LD    D,H            ;SET UP DMA ADDRESS
  1097.     LD    E,L
  1098.     LD    C,SETDMA
  1099.     CALL    BDOS
  1100.     LD    DE,FILD$$        ;WRITE 128 BYTES TO FILE
  1101.     LD    C,WRITE
  1102.     CALL    BDOS
  1103.     POP    HL
  1104.     POP    DE
  1105.     CP    0            ;ERROR?
  1106.     JR    NZ,AUXDI9        ;DISK FULL --> BRANCH
  1107.     ADD    HL,DE            ;POINT TO NEXT RECORD
  1108.     JR    AUXDI8
  1109. AUXDI9:    LD    C,STROUT        ;DISK FULL
  1110.     LD    DE,DSKFUL        ;DISK FULL MESSAGE (SEE PUTCHR)
  1111.     CALL    BDOS
  1112.     CALL    BOOT
  1113.  
  1114. AUXDJ0:    CALL    RDICT            ;READ SPELL.DIC
  1115.     LD    HL,BOOT+81H        ;POINT TO INPUT LINE BUFFER
  1116.     LD    A,(BOOT+80H)        ;NUMBER OF CHARACTERS
  1117.     LD    B,A
  1118.     LD    A,' '            ;LOOK FOR A SPACE TO INDICATE END OF
  1119.                     ;INPUT FILE NAME
  1120. AUXDJ1:    CP    (HL)
  1121.     JR    Z,AUXDJ2        ;EXIT LOOP IF SPACE
  1122.     INC    HL            ;NEXT CHARACTER
  1123.     DJNZ    AUXDJ1            ;LOOP WHILE CHARACTERS LEFT
  1124.     JR    AUXRET            ;NOTHING AFTER FILE.  JUST RETURN.
  1125. AUXDJ2:    LD    A,'$'            ;NOW LOOK FOR $ TO INDICATE MORE DICTS.
  1126. AUXDJ3:    CP    (HL)
  1127.     JR    Z,AUXDJ4        ;EXIT LOOP IF FOUND
  1128.     INC    HL
  1129.     DJNZ    AUXDJ3            ;CONTINUE WHILE CHARACTERS LEFT
  1130.     JR    AUXRET            ;NOT FOUND
  1131. AUXDJ4:    LD    A,' '            ;ELMINATE SPACES
  1132.     INC    HL            ;SKIP '$'
  1133.     DJNZ    AUXDJ5            ;CONTINUE IF CHAR LEFT
  1134.     JR    AUXRET
  1135. AUXDJ5:    CP    (HL)
  1136.     JR    NZ,AUXDJ6        ;STOP IF NOT SPACE
  1137.     INC    HL
  1138.     DJNZ    AUXDJ5
  1139.     JR    AUXRET            ;DONE IF JUST SPACES
  1140. AUXDJ6:    LD    A,0
  1141.     LD    (SPLDIC),A        ;USE DEFAULT DRIVE
  1142.     LD    DE,SPLDIC+1        ;FCB BUFFER TO USE
  1143.     LD    A,' '            ;NULL FILE NAME (SPACES)
  1144.     PUSH    BC
  1145.     LD    B,8            ;FIRST DO FILENAME, NOT EXTENSION
  1146. AUXDJ7:    LD    (DE),A
  1147.     INC    DE            ;CLEAR ENTIRE FILENAME
  1148.     DJNZ    AUXDJ7
  1149.     LD    DE,SPLDIC+12        ;GET REST OF FCB
  1150.     LD    B,24
  1151.     LD    A,0            ;ZERO REST OF FCB
  1152. AUXDJ8:    LD    (DE),A
  1153.     INC    DE
  1154.     DJNZ    AUXDJ8
  1155.     POP    BC
  1156.     LD    DE,SPLDIC+1        ;POINT TO FCB
  1157.     LD    C,0            ;NO CHARACTERS WRITTEN TO FCB YET
  1158.     LD    A,2            ;ARE AT LEAST 3 CHAR LEFT?
  1159.     CP    B
  1160.     JP    NC,AUXDJ9        ;IF NOT, CAN'T BE A DRIVE SPECIFIED
  1161.     INC    HL
  1162.     LD    A,(HL)            ;SEE IF NEXT CHAR IS A ':'
  1163.     DEC    HL
  1164.     CP    ':'
  1165.     JR    NZ,AUXDJ9        ;JUMP IF NO DRIVE SPECIFIED
  1166.     LD    A,(HL)            ;GET THE DRIVE
  1167.     INC    HL            ;POINT TO NEXT CHAR AFTER :
  1168.     INC    HL
  1169.     DEC    B
  1170.     DEC    B
  1171.     AND    11011111B        ;MAKE SURE IT'S UPPER CASE
  1172.     SUB    'A'-1            ;MAKE DRIVE NUMBER BASED AT 0
  1173.     LD    (SPLDIC),A        ;STORE IT IN FCB
  1174. AUXDJ9:    LD    A,(HL)            ;GET A CHARACTER
  1175.     CP    ' '            ;END OF FILENAME?
  1176.     JR    Z,AUXDK2        ;READ THE FILE
  1177.     CP    '.'            ;PERIOD?  DISCARD EXTENSION IF YES.
  1178.     JR    Z,AUXDK0
  1179.     LD    (DE),A            ;FCB IT
  1180.     INC    DE
  1181.     INC    C
  1182.     LD    A,8            ;8 CHARACTERS WRITTEN YET?
  1183.     CP    C
  1184.     JR    Z,AUXDK0
  1185.     INC    HL
  1186.     DJNZ    AUXDJ9
  1187.     JR    AUXDK2            ;READ THE FILE
  1188. AUXDK0:    LD    A,' '            ;SEARCH FOR SPACE TO END FILENAME
  1189.                     ;DISCARD EXTRA CHARACTERS
  1190. AUXDK1:    CP    (HL)
  1191.     JR    Z,AUXDK2
  1192.     INC    HL            ;TRY NEXT CHAR
  1193.     DJNZ    AUXDK1
  1194. AUXDK2:    DEC    HL            ;POINT TO CHAR BEFORE END OR SPACE
  1195.     INC    B            ;1 MORE LEFT NOW
  1196.     CALL    RDICT            ;READ FROM THE DICTIONARY
  1197.     JP    AUXDJ4            ;TRY FOR ANOTHER DICTIONARY
  1198.  
  1199. AUXRET:    LD    DE,FILD$$        ;CLOSE TEMPORARY FILE
  1200.     LD    C,CLOSE
  1201.     CALL    BDOS
  1202.     LD    HL,OFCB            ;PATCH PUTCHR: TO OUTPUT TO FILE.$$$
  1203.     LD    (OUTPAT),HL
  1204.     LD    A,0C9H            ;RETURN OPCODE
  1205.     LD    (PUTCHR),A        ;MAKE PUTCHR: DO NOT OUTPUT
  1206.     CALL    CTRLZ            ;CLEAR OUTPUT BUFFER
  1207.     LD    HL,OBUFF        ;CLEAR OUTPUT BUFFER POSITION
  1208.     LD    (OPOSS),HL
  1209.     LD    HL,(FREE)        ;GET ADDRESS OF NEXT FREE BYTE
  1210.     INC    HL
  1211.     LD    (SRTBOT),HL        ;POINT TO TABLE FOR INPUT FILE INDEX
  1212.     INC    HL
  1213.     INC    HL
  1214.     LD    (SRTTOP),HL        ;TOP OF TABLE
  1215.     LD    HL,(BDOS+1)        ;GET ADDRESS OF BDOS
  1216.     DEC    HL            ;POINT TO FREE MEMORY
  1217.     LD    (FREE),HL
  1218.     LD    HL,INBUF+512
  1219.     LD    (INPTR),HL        ;SET INPUT FILE POINTER TO READ RECORD
  1220.                     ;ON NEXT GETCHR: CALL
  1221.     CALL    CTRLZ            ;CLEAN OUTPUT FILE BUFFER
  1222.     LD    A,LF            ;RESET LASTCH FOR INPUT
  1223.     LD    (LASTCH),A
  1224.     LD    DE,UDCMSG        ;OUTPUT: "Words read from...FILE.UDC"
  1225.     LD    C,STROUT
  1226.     CALL    BDOS
  1227.     LD    HL,(FILUDC)        ;NUMBER OF WORDS WRITTEN
  1228.     LD    B,H            ;GOES IN BC
  1229.     LD    C,L
  1230.     LD    HL,FILD$$        ;FCB ADDRESS IN HL
  1231.     LD    A,'U'            ;CHANGE 'FILENAME.D$$' TO '.UDC'
  1232.     LD    (FILD$$+9),A
  1233.     LD    A,'D'
  1234.     LD    (FILD$$+10),A
  1235.     LD    A,'C'
  1236.     LD    (FILD$$+11),A
  1237.     CALL    TYPFIL            ;WRITE FILENAME AND # TO CONSOLE
  1238.     LD    A,'D'            ;CHANGE IT BACK TO '.D$$'
  1239.     LD    (FILD$$+9),A
  1240.     LD    A,'$'
  1241.     LD    (FILD$$+10),A
  1242.     LD    (FILD$$+11),A
  1243.     RET
  1244. UDCMSG:    DB    CR,LF,'Words written to dictionary $'
  1245.  
  1246. ;
  1247. ; RDICT - Read dictionary in SPLDIC FCB
  1248. ;
  1249. RDICT:    PUSH    PSW
  1250.     PUSH    BC
  1251.     PUSH    DE
  1252.     PUSH    HL
  1253.     LD    HL,INBUF+512
  1254.     LD    (INPTR),HL        ;SET INPUT FILE POINTER TO READ RECORD
  1255.                     ;ON NEXT GETCHR CALL
  1256.     LD    HL,0
  1257.     LD    (SPLDC),HL        ;RESET # WORDS READ
  1258.     LD    DE,SPLDIC        ;FCB FOR SPELL.DIC
  1259.     LD    C,OPEN
  1260.     CALL    BDOS
  1261.     PUSH    PSW
  1262.     LD    C,CURDSK        ;GET THE DEFAULT DRIVE BEFORE ITS
  1263.     CALL    BDOS            ;    TOO LATE
  1264.     INC    A
  1265.     LD    (DEFDRV),A
  1266.     POP    PSW
  1267.     CP    0FFH            ;FOUND?
  1268.     JR    NZ,RDICT0        ;YES, READ FROM IT
  1269.     LD    A,(SPLDIC)        ;WAS DEFAULT DRIVE TESTED?
  1270.     CP    0
  1271.     JR    NZ,RDICT2        ;IF SPECIFIC DRIVE TESTED AND NOT
  1272.                     ;FOUND THEN GIVE UP
  1273.     LD    A,1            ;TRY DRIVE "A"
  1274.     LD    (SPLDIC),A
  1275.     LD    DE,SPLDIC
  1276.     LD    C,OPEN
  1277.     CALL    BDOS
  1278.     CP    0FFH            ;FOUND?
  1279.     JP    Z,RDICT2        ;IF NOT, GIVE UP
  1280. RDICT0:    LD    HL,SPLDIC        ;PATCH FCB ADDRESS INTO GETWRD
  1281.     LD    (FILPAT),HL
  1282. RDICT1:    CALL    GETWRD            ;GET A WORD INTO SRCWRD:
  1283.     JP    Z,RDICT3        ;IF EOF THEN START CHECKING
  1284.     CALL    CREWRD            ;CREATE WORD FROM SRCWRD:
  1285.     LD    A,0            ;IS IT AT LEAST 2 CHARS LONG?
  1286.     CP    C
  1287.     JR    Z,RDICT1        ;FORGET IT IF NOT
  1288.     LD    A,41            ;IF LONGER THAN 40, ALSO FORGET IT
  1289.     CP    C
  1290.     JR    Z,RDICT1
  1291.     PUSH    HL
  1292.     LD    HL,(SPLDC)        ;INCREMENT COUNTER FOR WORDS IN
  1293.     INC    HL            ;   SPELL.DIC
  1294.     LD    (SPLDC),HL
  1295.     POP    HL
  1296.     CALL    SAVWRD            ;PUT WORD IN MEMORY
  1297.     JR    RDICT1
  1298.  
  1299. RDICT2:    LD    DE,RNT            ;PRINT CR,LF
  1300.     LD    C,STROUT
  1301.     CALL    BDOS
  1302.     LD    A,(SPLDIC)            ;DEFAULT DRIVE USED?
  1303.     CP    0
  1304.     JR    NZ,RDICU0        ;JUMP IF NOT
  1305.     LD    A,(DEFDRV)        ;GET DEFAULT DRIVE
  1306.     LD    (SPLDIC),A        ;AND PUT IT IN FCB
  1307. RDICU0:    LD    A,(SPLDIC)        ;GET DRIVE
  1308.     ADD    A,'A'-1            ;MAKE IT A LETTER
  1309.     LD    C,CONOUT
  1310.     LD    E,A
  1311.     CALL    BDOS            ;PRINT DRIVE NAME
  1312.     LD    E,':'
  1313.     LD    C,CONOUT
  1314.     CALL    BDOS            ;AND A COLON
  1315.     LD    DE,SPLDIC+1        ;POINT TO FILENAME
  1316.     LD    HL,SPLDIC+12        ;POINT TO FIRST BYTE AFTER NAME
  1317.     LD    A,'$'
  1318.     LD    (SPLDIC+12),A        ;MARK END FOR OUPTUT
  1319.     LD    C,STROUT
  1320.     CALL    BDOS            ;PRINT THE FILE NAME
  1321.  
  1322.     LD    DE,RNT0            ;PRINT NOT FOUND
  1323.     LD    C,STROUT
  1324.     CALL    BDOS
  1325.     JR    RDICTR
  1326. RNT:    DB    CR,LF,'$'
  1327. RNT0:    DB    ' not found$'
  1328.  
  1329. RDICT3:    LD    DE,RDIWRD        ;FOUND MESSAGE
  1330.     LD    C,STROUT
  1331.     CALL    BDOS
  1332.     LD    HL,(SPLDC)        ;STORE # WORDS READ IN BC
  1333.     LD    B,H
  1334.     LD    C,L
  1335.     LD    HL,SPLDIC        ;FCB ADDRESS
  1336.     CALL    TYPFIL            ;TYPE FILE NAME AND # WORDS IN IT
  1337.     JR    RDICTR
  1338. RDIWRD:    DB    CR,LF,'Words read from dictionary  $'
  1339.  
  1340. RDICTR:    POP    HL
  1341.     POP    DE
  1342.     POP    BC
  1343.     POP    PSW
  1344.     RET
  1345.  
  1346. ;
  1347. ; TYPFIL -- print name of dictionary file being read and words found in it
  1348. ;
  1349. ;    Input:  BC -->  Number of words found in file
  1350. ;        HL -->  Address of file's FCB
  1351. ;
  1352. TYPFIL:    PUSH    PSW
  1353.     PUSH    BC
  1354.     PUSH    DE
  1355.     PUSH    HL
  1356.     LD    A,(HL)            ;DEFAULT DRIVE USED?
  1357.     CP    0
  1358.     JR    NZ,TYPFI0        ;JUMP IF NOT
  1359.     LD    A,(DEFDRV)        ;GET DEFAULT DRIVE
  1360.     LD    (HL),A            ;AND PUT IT IN FCB
  1361. TYPFI0:    LD    A,(HL)            ;GET DRIVE
  1362.     ADD    A,'A'-1            ;MAKE IT A LETTER
  1363.     PUSH    BC
  1364.     PUSH    HL
  1365.     LD    C,CONOUT
  1366.     LD    E,A
  1367.     CALL    BDOS            ;PRINT DRIVE NAME
  1368.     LD    E,':'
  1369.     LD    C,CONOUT
  1370.     CALL    BDOS            ;AND A COLON
  1371.     POP    HL
  1372.     LD    D,H
  1373.     LD    E,L
  1374.     INC    DE            ;POINT TO FILENAME
  1375.     LD    BC,12
  1376.     ADD    HL,BC            ;HL POINTS TO END OF FILENAME
  1377.     LD    A,'$'
  1378.     LD    (HL),A            ;MARK END FOR OUPTUT
  1379.     LD    C,STROUT
  1380.     CALL    BDOS            ;PRINT THE FILE NAME
  1381.     LD    DE,TYPSPA        ;PRINT SPACES AFTER NAME
  1382.     LD    C,STROUT
  1383.     CALL    BDOS
  1384.     POP    BC
  1385.     LD    H,B            ;NUMBER OF WORDS FOUND
  1386.     LD    L,C
  1387.     CALL    DECOUT            ;PRINT NUMBER
  1388.     POP    HL
  1389.     POP    DE
  1390.     POP    BC
  1391.     POP    PSW
  1392.     RET
  1393. TYPSPA:    DB    ':    $'
  1394.  
  1395. ;
  1396. ; SAVWRD -- put WORD in memory dictionary
  1397. ;
  1398.  
  1399. SAVWRD:    CALL    USRTST            ;WAS WORD ALREADY MARKED?
  1400.     CP    1
  1401.     RET    Z            ;RETURN WITH Z SET IF ALREADY MARKED
  1402.     LD    HL,(FREE)        ;GET NEXT AVAILABLE BYTE
  1403.     LD    DE,WORD            ;POINT TO WORD
  1404. SAVWR0:    LD    A,(DE)            ;GET A CHARACTER
  1405.     LD    (HL),A            ;STORE IT IN BUFFER
  1406.     INC    DE            ;INCREMENT POINTERS
  1407.     INC    HL
  1408.     CP    0            ;END OF WORD?
  1409.     JR    NZ,SAVWR0
  1410.     LD    (HL),A            ;MARK END OF TABLE WITH 0
  1411.     LD    (FREE),HL        ;UPDATE FREE MEMORY POINTER
  1412.     LD    A,1
  1413.     AND    A            ;MAKE FOR Z NOT SET
  1414.     RET
  1415.  
  1416. ;
  1417. ; WRDTST -- Search for WORD in dictionary.  If it is not found, try
  1418. ;    stripping of suffixes and looking for new word with a flag set.
  1419. ;
  1420. ;        Returns in A:  0 <-- WORD not found
  1421. ;                   1 <-- WORD found
  1422. ;                   2 <-- root word found but necessary
  1423. ;                     suffix flag not set.  Returned
  1424. ;                     only if suffixes were stripped.
  1425.  
  1426. WRDTST:    PUSH    BC
  1427.     PUSH    DE
  1428.     PUSH    HL
  1429.     LD    HL,0
  1430.     LD    (FLAG),HL        ;NO FLAGS FOR FIRST LOOKUP
  1431.     CALL    FINDIT            ;LOOK FOR WORD IN DICTIONARY
  1432.     PUSH    PSW
  1433.     LD    A,1            ;ASSUME THAT WORD WAS FOUND AND
  1434.                     ;INDICATE WORKING IN ALPHABETICAL ORDER
  1435.                     ;STILL (DECODING OF CURRENT RECORD
  1436.                     ;BY LOOKUP ROUTINE CAN CONTINUE FROM
  1437.                     ;CURRENT POSITION)
  1438.     LD    (ALPHA),A
  1439.     POP    PSW
  1440.     CP    0            ;NOT FOUND?
  1441.     JP    Z,WRDTS0        ;KEEP TRYING IF NOT FOUND
  1442. WRDRET:    POP    HL
  1443.     POP    DE
  1444.     POP    BC
  1445.     RET
  1446.  
  1447. WRDTS0:    CALL    USRTST            ;TEST USER DICTIONARY
  1448.     CP    1            ;FOUND?
  1449.     JP    Z,WRDRET
  1450.     LD    A,0            ;NOT WORKING IN ALPHABETICAL ORDER
  1451.                     ;ANY MORE
  1452.     LD    (ALPHA),A
  1453.     LD    HL,LASTC        ;PUT NUMBER OF CHARACTERS -1 IN C
  1454.     LD    C,(HL)
  1455.     LD    B,0            ;MAKE BC AN OFFSET TO LAST CHAR
  1456.     LD    HL,WORD            ;POINT TO WORD
  1457.     ADD    HL,BC            ;POINT TO LAST CHARACTER IN WORD
  1458.     LD    A,(HL)
  1459.     QISIT    'E',FLGV        ;WORD ENDS IN "E"
  1460.     QISIT    'H',FLGH        ;"H"
  1461.     QISIT    'Y',FLGY        ;"LY"
  1462.     QISIT    'G',FLGG        ;"ING"
  1463.     QISIT    'N',FLGN        ;"TION, "EN"
  1464.     QISIT    'D',FLGD        ;"ED", "IED"
  1465.     QISIT    'T',FLGT        ;"EST", "IEST"
  1466.     QISIT    'R',FLGR        ;"ER", "IER"
  1467.     QISIT    'S',FLGS        ;LOTS OF WORDS ENDING IN "S"
  1468.     LD    A,0
  1469.     JP    WRDRET            ;NO FLAGS FIT
  1470.  
  1471. FLGV:    LD    A,2            ;WORD MUST BE 4 CHARS LONG
  1472.     CP    C
  1473.     JP    P,WRDNOT        ;NOT FOUND IF TOO SHORT
  1474.     LD    DE,VFLAG        ;LOOKING FOR V FLAG
  1475.     LD    (FLAG),DE
  1476.     DEC    HL            ;CHARACTER BEFORE
  1477.     ISIT    'V'
  1478.     DEC    HL
  1479.     ISIT    'I'
  1480.     LD    (HL),'E'        ;GET "CREATIVE"
  1481.     INC    HL
  1482.     LD    (HL),0
  1483.     CALL    FINDIT
  1484.     CP    0            ;FOUND?
  1485.     JP    NZ,WRDRET        ;BRANCH IF FOUND
  1486.     DEC    HL            ;POINT TO CHAR BEFORE NEW "E"
  1487.     DEC    HL
  1488.     JISIT    'E',WRDNOT        ;KILL "CREATEIVE"
  1489.     INC    HL
  1490.     LD    (HL),0
  1491.     CALL    FINDIT
  1492.     JP    WRDRET
  1493.  
  1494. FLGH:    LD    A,2            ;MUST BE 4 CHARS LONG
  1495.     CP    C
  1496.     JP    P,WRDNOT
  1497.     LD    DE,HFLAG        ;SEEKING WORD WITH H FLAG SET
  1498.     LD    (FLAG),DE
  1499.     DEC    HL
  1500.     ISIT    'T'
  1501.     DEC    HL
  1502.     JISIT    'Y',WRDNOT        ;KILL "TWENTYTH"
  1503.     INC    HL
  1504.     LD    (HL),0            ;NEW END OF WORD
  1505.     CALL    FINDIT            ;GET "HUNDREDTH"
  1506.     CP    0            ;FOUND?
  1507.     JP    NZ,WRDRET        ;RETURN IS FOUND
  1508.     LD    A,4            ;WORDS WITH "IETH" MUST BE 6 CHARS LONG
  1509.     CP    C
  1510.     JP    P,WRDNOT
  1511.     DEC    HL
  1512.     ISIT    'E'
  1513.     DEC    HL
  1514.     ISIT    'I'
  1515.     LD    (HL),'Y'        ;MODIFY WORD TO END IN "Y"
  1516.     INC    HL
  1517.     LD    (HL),0
  1518.     CALL    FINDIT            ;GET "TWENTIETH"
  1519.     JP    WRDRET
  1520.  
  1521. FLGY:    LD    A,2            ;MUST BE 4 CHARACTERS LONG (AT LEAST)
  1522.     CP    C
  1523.     JP    P,WRDNOT
  1524.     LD    DE,YFLAG        ;WORDS MUST HAVE Y FLAG SET
  1525.     LD    (FLAG),DE
  1526.     DEC    HL
  1527.     ISIT    'L'
  1528.     LD    (HL),0            ;MARK NEW END OF WORD
  1529.     CALL    FINDIT            ;GET "QUICKLY"
  1530.     JP    WRDRET
  1531.  
  1532. FLGG:    LD    A,2            ;MUST BE AT LEAST 4 CHARS LONG
  1533.     CP    C
  1534.     JP    P,WRDNOT
  1535.     LD    DE,GFLAG        ;SET G FLAG
  1536.     LD    (FLAG),DE
  1537. FLGGE:    DEC    HL
  1538.     ISIT    'N'
  1539.     DEC    HL
  1540.     ISIT    'I'
  1541.     LD    (HL),'E'
  1542.     INC    HL
  1543.     LD    (HL),0
  1544.     CALL    FINDIT            ;GET "FILING"
  1545.     CP    0
  1546.     JP    NZ,WRDRET        ;RETURN IF FOUND
  1547.     DEC    HL
  1548.     DEC    HL
  1549.     JISIT    'E',WRDNOT        ;KILL "FILEING"
  1550.     INC    HL
  1551.     LD    (HL),0
  1552.     CALL    FINDIT            ;GET "CROSSING"
  1553.     JP    WRDRET
  1554.  
  1555. FLGN:    LD    A,2            ;MUST BE 4 CHARS LONG
  1556.     CP    C
  1557.     JP    P,WRDNOT
  1558.     LD    DE,NFLAG        ;SET N FLAG
  1559.     LD    (FLAG),DE
  1560. FLGNEE:    DEC    HL
  1561.     JISIT    'O',FLGNO        ;WORD WITH "TION"
  1562.     ISIT    'E'            ;IF .EQ. "TION" THEN .EQ. "EN"
  1563.     DEC    HL
  1564.     JISIT    'E',WRDNOT        ;KILL "CREATEEN"
  1565.     JISIT    'Y',WRDNOT        ;KILL "MULTIPLYEN"
  1566.     INC    HL
  1567.     LD    (HL),0
  1568.     CALL    FINDIT            ;GET "FALLEN"
  1569.     JP    WRDRET
  1570. FLGNO:    LD    A,3            ;MUST BE 4 CHARS LONG
  1571.     CP    C
  1572.     JP    P,WRDNOT
  1573.     DEC    HL
  1574.     ISIT    'I'
  1575.     LD    (HL),'E'
  1576.     INC    HL
  1577.     LD    (HL),0
  1578.     CALL    FINDIT            ;GET "CREATION"
  1579.     CP    0
  1580.     JP    NZ,WRDRET        ;RETURN IF FOUND
  1581.     LD    A,7            ;MUST BE AT LEAST 9 CHARS LONG
  1582.     CP    C
  1583.     JP    P,WRDNOT
  1584.     DEC    HL
  1585.     DEC    HL
  1586.     ISIT    'T'
  1587.     DEC    HL
  1588.     ISIT    'A'
  1589.     DEC    HL
  1590.     ISIT    'C'
  1591.     DEC    HL
  1592.     ISIT    'I'
  1593.     LD    (HL),'Y'
  1594.     INC    HL
  1595.     LD    (HL),0
  1596.     CALL    FINDIT
  1597.     JP    WRDRET
  1598.  
  1599. FLGD:    LD    A,2            ;MUST BE 4 CHARACTERS LONG
  1600.     CP    C
  1601.     JP    P,WRDRET
  1602.     LD    DE,DFLAG        ;SET D FLAG
  1603.     LD    (FLAG),DE
  1604. FLGDE:    DEC    HL
  1605.     ISIT    'E'
  1606.     INC    HL
  1607.     LD    (HL),0
  1608.     CALL    FINDIT            ;GET "CREATED"
  1609.     CP    0
  1610.     JP    NZ,WRDRET
  1611.     DEC    HL
  1612.     DEC    HL
  1613.     JISIT    'E',WRDNOT        ;KILL "CREATEED"
  1614.     LD    A,(HL)
  1615.     CP    'Y'            ;IF .NE. "Y" TRY OTHER SUFFIXES
  1616.     JP    NZ,FLGD5
  1617.     DEC    HL
  1618.     CALL    VOWEL            ;VOWEL MUST BE BEFORE "Y"
  1619.     JP    NZ,WRDNOT
  1620.     INC    HL
  1621.     INC    HL
  1622.     LD    (HL),0
  1623.     CALL    FINDIT            ;GET "CONVEYED"
  1624.     JP    WRDRET
  1625. FLGD5:    INC    HL
  1626.     LD    (HL),0
  1627.     CALL    FINDIT            ;GET "CROSSED"
  1628.     CP    0
  1629.     JP    NZ,WRDRET        ;RETURN IF FOUND
  1630.     DEC    HL
  1631.     ISIT    'I'
  1632.     DEC    HL
  1633.     CALL    VOWEL            ;CAN'T BE A VOWEL
  1634.     JP    Z,WRDNOT
  1635.     INC    HL
  1636.     LD    (HL),'Y'
  1637.     INC    HL
  1638.     LD    (HL),0
  1639.     CALL    FINDIT            ;GET "IMPLIED"
  1640.     JP    WRDRET
  1641.  
  1642. FLGT:    LD    A,2            ;MUST BE AT LEAST 4 CHARS LONG
  1643.     CP    C
  1644.     JP    P,WRDNOT
  1645.     LD    DE,TFLAG        ;T FLAG MUST BE SET
  1646.     LD    (FLAG),DE
  1647.     DEC    HL
  1648.     JISIT    'S',FLGDE        ;SAME RULES AS 'D' FLAG IF ENDS
  1649.                     ;IN "ST"
  1650.     JP    WRDNOT            ;NOT FOUND IF NOT "ST"
  1651.  
  1652. FLGR:    LD    A,2            ;MUST BE AT LEAST 4 CHARS LONG
  1653.     CP    C
  1654.     JP    P,WRDNOT
  1655.     LD    DE,RFLAG        ;SET R FLAG
  1656.     LD    (FLAG),DE
  1657. FLGRE:    JP    FLGDE            ;SAME RULES AS D FLAG
  1658.  
  1659. FLGS:    LD    A,2            ;MUST BE 4 CHARS LONG
  1660.     CP    C
  1661.     JP    P,WRDNOT
  1662.     LD    DE,SFLAG        ;TRY PURE "S" FLAG FIRST
  1663.     LD    (FLAG),DE
  1664.     DEC    HL
  1665.     JISIT    'S',FLGP        ;"NESS", "INESS"
  1666.     JISIT    27H,FLGM        ;"'S"
  1667.     CALL    SXZH            ;IS IT S, X, Z OR H?
  1668.     JP    Z,WRDNOT        ;IF YES, THEN ILLEGAL WORD
  1669.     LD    A,(HL)            ;PURE "S" LEGAL IF .NE. "Y"
  1670.     CP    'Y'
  1671.     JR    NZ,FLGS2
  1672.     DEC    HL
  1673.     CALL    VOWEL
  1674.     JP    NZ,WRDNOT        ;ILLEGAL WORD IF NOT A VOWEL
  1675.     INC    HL
  1676. FLGS2:    INC    HL
  1677.     LD    (HL),0
  1678.     CALL    FINDIT            ;GET "CONVEYS", "BATS"
  1679.     CP    0
  1680.     JP    NZ,WRDRET        ;RETURN IF FOUND
  1681.     DEC    HL
  1682.     LD    A,(HL)
  1683.     QISIT    'R',FLGZ        ;"ERS", "IERS"
  1684.     QISIT    'N',FLGX        ;"IONS", "ICATIONS", "ENS"
  1685.     QISIT    'G',FLGJ        ;"INGS"
  1686.     ISIT    'E'
  1687.     DEC    HL
  1688.     CALL    SXZH
  1689.     JP    NZ,FLGS5        ;IF LETTER NOT S,X,Z OR H TRY "IES"
  1690.     INC    HL
  1691.     LD    (HL),0
  1692.     CALL    FINDIT            ;GET "FIXES"
  1693.     JP    WRDRET
  1694. FLGS5:    ISIT    'I'
  1695.     DEC    HL
  1696.     CALL    VOWEL
  1697.     JP    Z,WRDNOT        ;CAN'T BE A VOWEL
  1698.     INC    HL
  1699.     LD    (HL),'Y'
  1700.     INC    HL
  1701.     LD    (HL),0
  1702.     CALL    FINDIT            ;GET "IMPLIES"
  1703.     JP    WRDRET
  1704.  
  1705. FLGX:    LD    DE,XFLAG        ;SET X FLAG
  1706.     LD    (FLAG),DE
  1707.     JP    FLGNEE            ;SAVE AS "N" FLAG NOW
  1708.  
  1709. FLGJ:    LD    DE,JFLAG        ;SET J FLAG
  1710.     LD    (FLAG),DE
  1711.     JP    FLGGE            ;SAVE AS "G" FLAG NOW
  1712.  
  1713. FLGZ:    LD    DE,ZFLAG        ;SET Z FLAG
  1714.     LD    (FLAG),DE
  1715.     JP    FLGRE            ;SAVE AS "R" FLAG NOW
  1716.  
  1717. FLGP:    LD    A,3            ;MUST BE 5 CHARS LONG
  1718.     CP    C
  1719.     JP    P,WRDNOT
  1720.     LD    DE,PFLAG        ;SET P FLAG
  1721.     LD    (FLAG),DE
  1722.     DEC    HL
  1723.     ISIT    'E'
  1724.     DEC    HL
  1725.     ISIT    'N'
  1726.     DEC    HL
  1727.     LD    A,(HL)
  1728.     CP    'Y'
  1729.     JP    NZ,FLGP4        ;LEGAL IF .NE. "Y"
  1730.     DEC    HL
  1731.     CALL    VOWEL
  1732.     JP    NZ,WRDNOT        ;ILLEGAL IF "Y" AND NO VOWEL
  1733.     INC    HL
  1734. FLGP4:    INC    HL
  1735.     LD    (HL),0
  1736.     CALL    FINDIT            ;GET "LATENESS", "GRAYNESS"
  1737.     CP    0
  1738.     JP    NZ,WRDRET        ;RETURN IF FOUND
  1739.     DEC    HL
  1740.     ISIT    'I'
  1741.     DEC    HL
  1742.     CALL    VOWEL
  1743.     JP    Z,WRDNOT        ;CAN'T BE A VOWEL
  1744.     INC    HL
  1745.     LD    (HL),'Y'
  1746.     INC    HL
  1747.     LD    (HL),0
  1748.     CALL    FINDIT            ;GET "CLOUDINESS"
  1749.     JP    WRDRET
  1750.  
  1751. FLGM:    LD    DE,MFLAG        ;SET M FLAG
  1752.     LD    (FLAG),DE
  1753.     LD    (HL),0
  1754.     CALL    FINDIT            ;GET "DOG'S"
  1755.     JP    WRDRET
  1756.  
  1757. WRDNOT:    LD    A,0            ;NOT FOUND
  1758.     JP    WRDRET
  1759. ;
  1760. ; VOWEL -- determine whether character in (HL) is a vowel.
  1761. ;
  1762. ;        Returns:  Z flag SET <-- is a vowel
  1763. ;              Z flag CLEAR <-- is not a vowel
  1764.  
  1765. VOWEL:    PUSH    BC
  1766.     PUSH    HL
  1767.     LD    A,(HL)            ;GET CHARACTER
  1768.     LD    HL,VOWELS        ;POINTER TO VOWELS
  1769.     LD    BC,5            ;5 VOWELS
  1770.     CPIR                ;TEST AGAINST ALL VOWELS
  1771.                     ;SET STATUS BITS TO BE USED AFTER RET
  1772.     POP    HL
  1773.     POP    BC
  1774.     RET
  1775. VOWELS:    DB    'AEIOU'
  1776.  
  1777. ;
  1778. ; SXZH -- same as VOWEL put for the characters S, X, Z and H
  1779.  
  1780. SXZH:    PUSH    BC
  1781.     PUSH    HL
  1782.     LD    A,(HL)            ;GET CHARACTER
  1783.     LD    HL,SXZH0        ;POINTER TO CHARACTER LIST
  1784.     LD    BC,4            ;4 POTENTIAL MATCHES
  1785.     CPIR                ;TEST AGAINST S, X, Z, H
  1786.     POP    HL
  1787.     POP    BC
  1788.     RET
  1789. SXZH0:    DB    'SXZH'
  1790.  
  1791. ;
  1792. ; Determine which record of dictionary would contain WORD.  Puts record in
  1793. ;    BC
  1794.  
  1795. FINDIT:    PUSH    BC
  1796.     PUSH    DE
  1797.     PUSH    HL
  1798.     LD    A,(ALPHA)        ;STILL IN ALPHABETICAL ORDER?
  1799.     AND    A
  1800.     JP    NZ,FINLO5        ;DON'T DECREMENT POINTERS IF YES
  1801.  
  1802.     LD    HL,(LSTADR)        ;GET ADDRESS OF LAST DICTIONARY POINTER
  1803.                     ;USED
  1804. FINLOW:    LD    DE,WORD
  1805.     EX    DE,HL
  1806.     LD    BC,4
  1807. FINLO1:    LD    A,(DE)            ;MAKE SURE THAT CURRENT RECORD IS
  1808.                     ;BEFORE WORD
  1809.     INC    DE
  1810.     CPI
  1811.     JP    M,FINLO5        ;IF EARLIER, JUMP
  1812.     JR    NZ,FINLO2        ;IF LATER, THEN DECREMENT
  1813.     JP    PE,FINLO1        ;LOOP WHILE BC-1 .NE. 0
  1814. FINLO2:    LD    BC,(LSTREC)        ;DECREMENT THE POINTERS
  1815.     DEC    BC
  1816.     LD    HL,0            ;IS IT TOO LOW?
  1817.     XOR    A
  1818.     SBC    HL,BC
  1819.     JR    Z,FINLO5        ;IF SO, THEN FORGET IT
  1820.     LD    (LSTREC),BC
  1821.     LD    HL,(LSTADR)
  1822.     LD    DE,4
  1823.     XOR    A            ;CLEAR CARRY
  1824.     SBC    HL,DE
  1825.     LD    (LSTADR),HL
  1826.     JP    FINLOW            ;TRY AGAIN
  1827.  
  1828. FINLO5:    LD    BC,(LSTREC)        ;GET LAST RECORD NUMBER READ
  1829.     LD    HL,(LSTADR)        ;GET ADDRESS OF LAST DICTIONARY POINTER
  1830.                     ;USED
  1831. FINDI0:    PUSH    BC
  1832.     PUSH    HL
  1833.     LD    DE,WORD
  1834.     EX    DE,HL
  1835.     LD    BC,4            ;COMPARING UP TO 4 CHARACTERS
  1836. FINDI1:    LD    A,(DE)            ;GET A CHARACTER FROM POINTER TABLE
  1837.     INC    DE
  1838.     CPI                ;COMPARE TO WORD:
  1839.     JR    NZ,FINDI2        ;JUMP IF DIFFERENT
  1840.     JP    PO,FINDI3        ;JUMP IF ALL 4 CHARACTERS EQUAL
  1841.     JR    FINDI1            ;TRY ANOTHER
  1842. FINDI2:    JP    P,FINDI3        ;TOO FAR IN DICTIONARY
  1843.     LD    DE,4
  1844.     POP    HL
  1845.     POP    BC
  1846.     ADD    HL,DE            ;POINT TO NEXT RECORD INDEX
  1847.     INC    BC
  1848.     JP    FINDI0
  1849. FINDI3:    POP    HL
  1850.     POP    BC
  1851. FINDI4:    DEC    BC
  1852.     LD    DE,4
  1853.     XOR    A            ;CLEAR CARRY
  1854.     SBC    HL,DE
  1855.     LD    (LSTREC),BC        ;UPDATE POINTERS
  1856.     LD    (LSTADR),HL
  1857.  
  1858. ;
  1859. ; LOOKUP -- loop through as many records as it takes to be sure that word is
  1860. ;    not in dictionary
  1861.  
  1862. LOOKUP:    CALL    DICFND
  1863.     CP    0FFH            ;IF RETURN STATUS=0FFH THEN WORD COULD
  1864.                     ;BE IN NEXT RECORD
  1865.     JR    NZ,LOOKU0        ;RETURN IF NOT IN NEXT RECORD
  1866.     INC    BC
  1867.     LD    HL,0+(TABBOT-TABTOP)/4    ;MAKE SURE NOT PAST LAST RECORD
  1868.     XOR    A            ;CLEAR THE CARRY BIT
  1869.     SBC    HL,BC
  1870.     JR    NZ,LOOKUP        ;TRY NEXT RECORD IF NOT AT END
  1871.     LD    A,0
  1872. LOOKU0:    POP    HL            ;RESTORE THE STACK
  1873.     POP    DE
  1874.     POP    BC
  1875.     RET
  1876.  
  1877. ;
  1878. ; DICFND  -- read record in BC from dictionary.  Determine whether WORD is
  1879. ;    in it.
  1880. ;
  1881. ;        Returns in A:  0 <-- word not found
  1882. ;                   1 <-- word found
  1883. ;                   2 <-- word found but flag not set
  1884. ;                 0FFH<-- word not found but it may be in next
  1885. ;                     record
  1886.  
  1887. DICFND:    PUSH    HL
  1888.     PUSH    DE
  1889.     PUSH    BC
  1890.     RLC    B            ;MULTIPLY BC BY 2 SO IT POINTS TO
  1891.                     ;256 BYTE RECORD
  1892.     RLC    C
  1893.     LD    A,0
  1894.     ADC    A,B            ;GET THE CARRY FROM RLC C
  1895.     LD    B,A
  1896.     LD    A,C
  1897.     AND    0FEH            ;KILL BIT 0
  1898.     LD    C,A
  1899.     LD    HL,(DICREC)        ;GET THE CURRENT RECORD IN RAM
  1900.     DEC    HL            ;POINT TO FIRST 128 BYTES OF 256
  1901.                     ;BYTE DICTIONARY RECORDS
  1902.     XOR    A            ;CLEAR CARRY BIT
  1903.     SBC    HL,BC            ;ATTEMPT TO READ THE SAME RECORD?
  1904.     JR    NZ,DICDSK        ;IF NO, READ FROM DISK
  1905.     LD    A,(ALPHA)        ;WORKING IN APHABETICAL ORDER?
  1906.     AND    A
  1907.     JP    NZ,DICFO1        ;JUST GET ANOTHER WORD IF YES
  1908.     LD    A,(CURBIT)        ;ROTATE CURRENT BYTE SO IT IS THE RIGHT
  1909.                     ;POSITION IN CASE SAME RECORD USED
  1910.     AND    0111B            ;IS IT ON CORRECT ROTATION NOW?
  1911.     JR    Z,DICFN0
  1912.     LD    HL,(CURBYT)        ;ADDRESS OF CURRENT BYTE
  1913.     LD    B,A
  1914.     LD    A,8            ;MUST COMPLETE 8 ROTATIONS, TOTAL
  1915.     SUB    B            ;SUBTRACT NUMBER ALREADY DONE
  1916.     LD    B,A
  1917. ROTATE:    RLC    (HL)
  1918.     DJNZ    ROTATE
  1919.     JP    DICFN0            ;START TESTING WORDS
  1920. DICDSK:    PUSH    BC
  1921.     LD    (DICREC),BC        ;NEW RECORD TO READ
  1922.     LD    C,SETDMA        ;SET DMA TO DICTIONARY BUFFER
  1923.     LD    DE,DICBUF        ;DICIONARY BUFFER IN RAM
  1924.     CALL    BDOS
  1925.     LD    C,RANREA        ;BDOS RANDOM READ CODE
  1926.     LD    DE,DICFCB        ;FCB OF DICTIONARY
  1927.     CALL    BDOS
  1928.     POP    BC
  1929.     INC    BC            ;GET 256 BYTES
  1930.     LD    (DICREC),BC        ;NEXT RECORD NUMBER
  1931.     LD    C,SETDMA        ;DMA ADDRESS 256 BYTES HIGHER
  1932.     LD    DE,DICBUF+128
  1933.     CALL    BDOS
  1934.     LD    C,RANREA
  1935.     LD    DE,DICFCB
  1936.     CALL    BDOS            ;READ NEXT RECORD
  1937.  
  1938. DICFN0:    LD    HL,DICBUF-1        ;INITIALIZE POINTER TO DICTIONARY
  1939.                     ;BUFFER
  1940.     LD    (CURBYT),HL
  1941.     LD    A,0            ;CURRENT BIT=0
  1942.     LD    (CURBIT),A
  1943. DICFN1:    CALL    MOVWRD            ;GET A WORD
  1944. DICFO1:    LD    HL,WORD            ;POINT TO WORD
  1945.     LD    BC,DICWRD        ;POINTER TO DICTIONARY WORD
  1946. DICFN2:    LD    A,(BC)            ;GET A LETTER FROM DICTIONARY WORD
  1947.     CP    (HL)            ;THE SAME?
  1948.     INC    HL            ;POINT TO NEXT CHARACTER
  1949.     INC    BC
  1950.     JR    NZ,DICFN4        ;IF NOT, TRY SOME MORE OR END
  1951.     CP    0            ;END OF WORD?
  1952.     JR    NZ,DICFN2        ;TRY ANOTHER CHARACTER
  1953.     LD    C,1            ;INDICATE WORD FOUND
  1954.     LD    HL,(DICFL)
  1955.     LD    A,(FLAG)        ;GET FIRST FLAG
  1956.     CP    0            ;NO FLAG WANTED?
  1957.     JR    Z,DICFN3        ;TRY NEXT BYTE OF FLAG IF NONE
  1958.     AND    L
  1959.     CP    0            ;INDICATE WORD FOUND IF .NE. 0
  1960.     JR    NZ,DICRET
  1961.     LD    C,2            ;INDICATE MAIN WORD FOUND/NO FLAG
  1962.     JR    DICRET
  1963. DICFN3:    LD    A,(FLAG+1)        ;TRY NEXT FLAG BYTE
  1964.     CP    0            ;NO FLAG WANTED?
  1965.     JR    Z,DICRET        ;IF NONE WANTED THEN WORD FOUND
  1966.     AND    H
  1967.     CP    0            ;FOUND IF .NE. 0
  1968.     JR    NZ,DICRET
  1969.     LD    C,2            ;INDICATE MAIN WORD FOUND/NO FLAG
  1970.     JR    DICRET
  1971.  
  1972. DICFN4:    JP    M,DICFN1        ;IF TEST WORD IS EARLIER IN ALPHABET,
  1973.                     ;TRY NEXT DICTIONARY WORD
  1974.     LD    C,0            ;NOT FOUND
  1975. ;    JP    DICRET
  1976.  
  1977. DICRET:    LD    A,C            ;PUT STATUS BYTE IN A
  1978.     POP    BC
  1979.     POP    DE
  1980.     POP    HL
  1981.     RET
  1982.  
  1983. ;
  1984. ; MOVWRD -- read a word from the dictionary by decoding the flags.
  1985. ;
  1986. ;        Returns:  DICWRD <-- word from dictionary
  1987.  
  1988. MOVWRD:    LD    A,0
  1989.     LD    B,4
  1990.     CALL    GETBIT            ;GET 4 BITS INTO A
  1991.     LD    HL,DICWRD        ;POINT TO DICTIONARY WORD BUFFER
  1992.     LD    B,0
  1993.     LD    C,A            ;NUMBER OF CHARACTERS TO KEEP
  1994.     ADD    HL,BC
  1995. MOVWR1:    LD    A,0
  1996.     LD    B,3            ;GET FIRST 3 OF 5 BITS FOR CHARACTER
  1997.     CALL    GETBIT            ;BITS IN A
  1998.     CP    0111B            ;IS IT AN END OF WORD MARK?
  1999.     JR    Z,GETFLG        ;GET THE FLAGS NOW
  2000.     LD    B,2            ;GET REMAINING 2 BITS
  2001.     CALL    GETBIT
  2002.     CP    0            ;IF ZERO THEN END OF RECORD
  2003.     JP    Z,MOVMOR        ;INDICATE MAY BE IN NEXT RECORD
  2004.     ADD    A,40H            ;MAKE IT ASCII
  2005.     CP    'Z'+1            ;IS IT AN ENCODED "'"?
  2006.     JR    NZ,MOVWR4        ;JUMP IF NOT
  2007.     LD    A,027H            ;MAKE IT A "'"
  2008. MOVWR4:    LD    (HL),A            ;BUFFER THE CHARACTER
  2009.     INC    HL
  2010.     JR    MOVWR1            ;GET ANOTHER CHARACTER
  2011. MOVMOR:    LD    C,0FFH            ;INDICATE MAY BE IN NEXT RECORD
  2012.     POP    DE            ;GET USELESS RETURN WORD
  2013.     JP    DICRET            ;RETURN
  2014.  
  2015. ;
  2016. ; GETFLG -- read suffix flags from buffer.
  2017. ;
  2018. ;        Returns:  DICFL <-- 16 byte flag word
  2019.  
  2020. GETFLG:    LD    A,0
  2021.     LD    (HL),A            ;MARK THE END OF THE WORD
  2022.     LD    B,4            ;GET 4 BITS FOR NUMBER OF FLAGS VALUE
  2023.     CALL    GETBIT
  2024.     LD    B,A            ;NUMBER OF BITS IN B
  2025.     LD    HL,0
  2026.     CP    0            ;ARE ANY BITS THERE TO COPY?
  2027.     JP    Z,GETFL8        ;RETURN IF NONE
  2028.     PUSH    BC
  2029.     CP    8            ;MORE THAN 8 BITS?
  2030.     JP    M,GETFL1        ;JUMP IF NOT
  2031.     LD    B,7            ;GET 7 BITS FOR FIRST BYTE
  2032. GETFL1:    LD    A,0
  2033.     CALL    GETBIT
  2034.     POP    BC
  2035.     LD    L,A            ;THIS IS THE LOW BYTE OF FLAGS
  2036.     LD    A,B
  2037.     CP    8            ;GET MORE IF GREATER THAN 8 BITS
  2038.     JP    P,GETFL4
  2039.     LD    A,7            ;COMPUTE NUMBER OF ROTATIONS NECESSARY
  2040.                     ;TO PUT IT IN THE RIGHT PLACE
  2041.     SUB    B
  2042.     JP    Z,GETFL8        ;IF EXACTLY 7 THEN DONE
  2043.     LD    B,A            ;COUNTER
  2044. GETFL3:    RLC    L
  2045.     DJNZ    GETFL3
  2046.     JP    GETFL8            ;NO RETURN
  2047. GETFL4:    SUB    7            ;GET NUMBER OF BITS NEEDED FOR BYTE 2
  2048.     LD    B,A
  2049.     LD    A,0
  2050.     PUSH    BC
  2051.     CALL    GETBIT            ;GET BIT FOR HIGH BYTE OF STATUS FLAG
  2052.     POP    BC
  2053.     LD    H,A            ;SAVE HIGH BYTE
  2054.     LD    A,7            ;COMPUTE NUMBER OF ROTATIONS LEFT
  2055.     SUB    B
  2056.     JR    Z,GETFL8        ;RETURN IF NONE
  2057.     LD    B,A
  2058. GETFL6:    RLC    H
  2059.     DJNZ    GETFL6
  2060. GETFL8:    LD    (DICFL),HL        ;SAVE THE FLAG
  2061.     RET
  2062.  
  2063. ;
  2064. ; GETBIT -- read number of bits in B from dictionary buffer.
  2065. ;
  2066. ;        Returns:  A <-- byte value of B bits
  2067.  
  2068. GETBIT:    PUSH    DE
  2069.     PUSH    HL
  2070.     EX    AF,AF'            ;A HOLDS DESIRED DECODED BYTE.
  2071.                     ;A' HOLD CURRENT BIT VALUE
  2072.  
  2073.     LD    A,(CURBIT)
  2074.     LD    HL,(CURBYT)        ;ADDRESS OF CURRENT BYTE FOR OUTPUT
  2075.     LD    D,(HL)            ;D = CURRENT BYTE VALUE
  2076.     EX    AF,AF'
  2077. GETBI0:    EX    AF,AF'            ;GET CURRENT BIT VALUE
  2078.     AND    0111B            ;MASK 1ST THREE BITS
  2079.     JR    NZ,GETBI1        ;IF .NE. 0 THEN NOT TIME TO INC CURBYT
  2080.     LD    (HL),D            ;RESTORE OLD BYTE TO ORIGINAL VALUE
  2081.     INC    HL
  2082.     LD    (CURBYT),HL
  2083.     LD    D,(HL)            ;UPDATE D = CURRENT BYTE VALUE
  2084. GETBI1:    INC    A
  2085.     EX    AF,AF'            ;BACK TO DECODED BYTE
  2086.     RLC    D            ;MOVE BYTE SO NEXT BIT IN RIGHT PLACE
  2087.     RLC    A            ;MAKE A READY TO RECEIVE
  2088.     BIT    0,D            ;IS THE BIT ON?
  2089.     JR    Z,GETBI2        ;DON'T SET A IF IT ISN'T
  2090.     OR    1            ;SET BIT 1 OF A
  2091. GETBI2:    DJNZ    GETBI0            ;LOOP THROUGH DESIRED NUMBER OF BITS
  2092.     EX    AF,AF'            ;GET CURRENT BIT
  2093.     LD    (CURBIT),A        ;UPDATE IT
  2094.     EX    AF,AF'
  2095.     LD    (HL),D            ;UPDATE BYTE FOR NEXT CALL
  2096.     POP    HL
  2097.     POP    DE
  2098.     RET
  2099.  
  2100. ;
  2101. ; USRTST -- test user dictionary in memory for WORD.
  2102. ;
  2103. ;        Returns in A:  0 <-- word not found
  2104. ;                   1 <-- word found
  2105.  
  2106. USRTST:    LD    HL,NEXT            ;BEGINNING OF USER DICTIONARY BUFFER
  2107.     LD    A,0
  2108.     CP    (HL)            ;DOES ONE EXIST?
  2109.     RET    Z            ;CAN'T FIND ELEMENT OF AN EMPTY SET!
  2110.     LD    DE,WORD            ;ADDRESS OF WORD FOR COMPARING
  2111. USRTS1:    LD    A,(DE)            ;GET A CHARACTER
  2112.     CP    (HL)            ;ARE THEY THE SAME?
  2113.     JR    NZ,USRTS2        ;IF NOT SAME, TRY ANOTHER WORD
  2114.     INC    DE
  2115.     INC    HL
  2116.     CP    0            ;END OF WORD?
  2117.     JR    NZ,USRTS1        ;LOOP THROUGH WHOLE WORD
  2118.     LD    A,1            ;FOUND IT!
  2119.     RET
  2120. USRTS2:    LD    A,0
  2121. USRTS3:    CP    (HL)            ;LOOK FOR END OF WORD
  2122.     INC    HL
  2123.     JR    NZ,USRTS3
  2124.     CP    (HL)            ;IF NEXT BYTE ALSO 0 THEN END OF TABLE
  2125.     RET    Z
  2126.     LD    DE,WORD
  2127.     JR    USRTS1            ;TEST ANOTHER WORD
  2128.  
  2129. ;
  2130. ;  DECOUT - Output number in HL to console in decimal
  2131. ;
  2132.  
  2133. DECOUT:    PUSH    PSW
  2134.     PUSH    BC
  2135.     PUSH    DE
  2136.     PUSH    HL
  2137.     LD    B,0            ;B WILL BE 1 ONCE NON-ZERO CHAR OUTPUT
  2138.     LD    DE,10000        ;START BY TRYING 10,000'S
  2139.     CALL    NUMOUT            ;OUTPUT A NUMBER
  2140.     LD    DE,1000            ;1000'S
  2141.     CALL    NUMOUT
  2142.     LD    DE,100
  2143.     CALL    NUMOUT
  2144.     LD    DE,10
  2145.     CALL    NUMOUT
  2146.     LD    B,1            ;GUARANTEE THAT 0 WILL PRINT
  2147.     LD    DE,1
  2148.     CALL    NUMOUT
  2149.     POP    HL
  2150.     POP    DE
  2151.     POP    BC
  2152.     POP    PSW
  2153.     RET
  2154.  
  2155. NUMOUT:    LD    C,0            ;COUNTER FOR NUMBER OF SUBTRACTIONS
  2156. NUMOU0:    INC    C            ;COUNT LOOPS THROUGH SUBTRACTION
  2157.     XOR    A            ;CLEAR CARRY
  2158.     SBC    HL,DE            ;SUBTRACT UNITS UNTIL CARRY
  2159.     JP    NC,NUMOU0
  2160.     ADD    HL,DE            ;RESET TO LAST POSITIVE VALUE
  2161.     DEC    C            ;DON'T COUNT LAST SUBRTRACTION
  2162.     JR    NZ,NUMOU1        ;IF NOT ZERO, THEN OUTPUT
  2163.     CP    B            ;ANYTHING OUTPUT YET?
  2164.     RET    Z            ;IF NOT, THEN DON'T PRINT A 0
  2165. NUMOU1:    LD    B,1            ;INDICATE OUTPUT SENT
  2166.     LD    A,C
  2167.     ADD    A,'0'            ;CONVERT TO ASCII
  2168.     LD    E,A            ;OUTPUT TO CONSOLE
  2169.     LD    C,CONOUT        ;CONSOLE OUTPUT CODE
  2170.     PUSH    BC
  2171.     PUSH    HL
  2172.     CALL    BDOS
  2173.     POP    HL
  2174.     POP    BC
  2175.     RET
  2176.  
  2177.  
  2178.  
  2179. INPTR:    DW    INBUF+512        ;POINTER TO CURRENT BYTE IN INPUT BUFF
  2180. OPOSS:    DW    OBUFF            ;POINTER TO CURRENT BYTE IN OUTPUT BUFF
  2181. SRTBOT:    DW    NEXT            ;POINTER TO BEGINNING OF MEMORY POINTER
  2182.                     ;TABLE OF ALPHABETIZED WORDS FROM INPUT
  2183.                     ;FILE
  2184. SRTTOP:    DW    NEXT+2            ;POINTER TO TOP OF MEMORY POINTER TABLE
  2185. FREE:    DW    NEXT            ;POINTER TO NEXT FREE BYTE IN TPA
  2186. LASTCH:    DB    LF            ;LAST CHARACTER INDICATOR
  2187. OLSTCH:    DB    LF            ;BUFFER FOR OLD LAST CHARACTER WHEN
  2188.                     ;MULTIPLE INPUT FCB'S IN USE
  2189. SAVPUT:    DS    1            ;BUFFER FOR NORMAL FIRST INSTRUCTION
  2190.                     ;AT PUTCHR.  USED WHILE OUTPUT IS
  2191.                     ;DISABLED
  2192. DICFL:    DW    0            ;DICTIONARY FLAG FOR COMPARE
  2193. CURBYT:    DW    DICBUF-1        ;CURRENT BYTE OF DICBUF (FOR GETBIT)
  2194. CURBIT:    DB    0            ;CURRENT BIT OF BYTE (FOR GETBIT)
  2195. ALPHA:    DB    0            ;0 IF NOT WORKING IN ALPHABETICAL
  2196.                     ;ORDER (DID FLAG SEEK).  1 IF IN ORDER
  2197. LSTREC:    DW    1            ;RECORD NUMBER OF LAST DICTIONARY
  2198.                     ;RECORD READ
  2199. LSTADR:    DW    TABTOP+4        ;POINTER TO TABLE WHERE FIRST 4 BYTES
  2200.                     ;OF LAST RECORD READ ARE FOUND
  2201. OLDPTR:    DW    0            ;POINTER FOR PASS 1 OF INPUT FILE IS
  2202.                     ;SAVED HERE DURING PASS 2 IF ALL OF
  2203.                     ;FILE DID NOT FIT IN MEMORY
  2204. P2OPTR:    DW    P2BUF+512        ;POINTER FOR PASS2 OF INPUT FILE IS
  2205.                     ;SAVED HERE DURING PASS 1 IF ALL OF
  2206.                     ;FILE DID NOT FIT IN MEMORY
  2207. STOPED:    DB    0            ;IS 1 IF ALL OF FILE DID NOT FIT IN
  2208.                     ;MEMORY
  2209. MLTPAS:    DB    0            ;SAME AS STOPED BUT NEVER RESET ONCE
  2210.                     ;SET
  2211. DEFDRV:    DB    0            ;RECEIVES DEFAULT DRIVE VALUE
  2212. SPLDC:    DW    0            ;STORES NUMBER OF WORDS IN SPELL.DIC
  2213. FILUDC:    DW    0            ;STORES NUMBER OF WORDS WRITTEN TO
  2214.                     ;FILE.UDC
  2215. TOTWRD:    DW    0            ;RECORDS TOTAL NUMBER OF WORDS IN DOC
  2216. UNQWRD:    DW    0            ;NUMBER OF UNIQUE WORDS IN DOC
  2217. MISWRD:    DW    0            ;NUMBER OF MISSPELLED WORDS
  2218.  
  2219. OFCB:    DB    0,'        $$$'        ;FCB FOR OUTPUT FILE
  2220.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2221.     DB    0,0,0,0,0,0,0,0,0,0,0
  2222. P2FCB:    DB    0,'           '        ;FCB FOR PASS 2 OF INPUT FILE
  2223.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2224.     DB    0,0,0,0,0,0,0,0,0,0,0
  2225. FILDIC:    DB    0,'        UDC'        ;FCB FILE FILE.UDC
  2226.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2227.     DB    0,0,0,0,0,0,0,0,0,0,0
  2228. FILADD:    DB    0,'        ADD'        ;FCB FOR FILE.ADD
  2229.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2230.     DB    0,0,0,0,0,0,0,0,0,0,0
  2231. FILD$$:    DB    0,'        D$$'        ;FCB FOR TEMPORARY FILE FILE.D$$
  2232.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2233.     DB    0,0,0,0,0,0,0,0,0,0,0
  2234. SPLDIC:    DB    0,'SPELL   DIC'        ;FCB FOR SPELL.DIC
  2235.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2236.     DB    0,0,0,0,0,0,0,0,0,0,0
  2237. DICFCB:    DB    0,'DICT    DIC'        ;FCB FOR DICTIONARY FILE
  2238.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2239.     DB    0,0,0,0,0,0,0,0
  2240. DICREC:    DB    0,0,0            ;RECORD NUMBER FOR RANDOM READ
  2241.                     ;(STILL PART OF FCB)
  2242.  
  2243. STACK    EQU    $+50            ;STACK
  2244. SRCWRD    EQU    STACK            ;BUFFER FOR UNFIXED WORD
  2245. WORD    EQU    SRCWRD+100        ;BUFFER FOR FIXED WORD
  2246. DICWRD    EQU    WORD+41            ;BUFFER FOR WORDS READ FROM DICTIONARY
  2247. FLAG    EQU    DICWRD+41        ;BUFFER FOR DESIRED DICTIONARY FLAG
  2248. LASTC    EQU    FLAG+2            ;BUFFER FOR LAST CHARACTER READ
  2249. DICBUF    EQU    LASTC+1            ;BUFFER FOR DICTIONARY RECORD
  2250. INBUF    EQU    DICBUF+258        ;INPUT BUFFER FOR PASS 1
  2251. P2BUF    EQU    INBUF+513        ;INPUT BUFFER FOR PASS 2
  2252. OBUFF    EQU    P2BUF+513        ;OUTPUT BUFFER
  2253. NEXT    EQU    OBUFF+513        ;ADDRESS OF NEXT FREE BYTE
  2254.     END    START
  2255.