home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / submit / subgen12.lbr / SUBGEN12.AQM / SUBGEN12.ASM
Assembly Source File  |  1985-12-03  |  19KB  |  898 lines
  1. ;=================================================================
  2. ;
  3. ;           SUBGEN.ASM Version 1.2
  4. ;               (Original - Feb/82)
  5. ;
  6. ;          Submit File Generator Program
  7. ;
  8. ;           By Steve Pritchard
  9. ;
  10. ;        of Solutions Canada Inc.
  11. ;           83 Cummer Ave,
  12. ;           Willowdale, Ontario
  13. ;           M2M 2E6   (416)-223-7549
  14. ; 
  15. ;
  16. ;
  17. ;         Copyrighted(1982) by Steve Pritchard
  18. ;
  19. ; PERMISSION IS GIVEN FOR USE AND FOR DISTRIBUTION OF THESE ROUTINES
  20. ;
  21. ;       BUT THEY ARE NOT TO BE SOLD FOR PROFIT.
  22. ;
  23. ;
  24. ;=================================================================
  25. ;
  26. ; Fixes/Updates in reverse order.
  27. ;
  28. ; Feb/26/82 - Fix telephone number.  Fix a couple of comments.
  29. ;          Suggest 'M' option. (Steve Pritchard)
  30. ;          Added msg on how to get help.    
  31. ;
  32. ; Feb/24/82 - Remove attribute flags from match testing, remove
  33. ;          limit on file capacity (W. Earnest)
  34. ;
  35. ; Feb/12/82 - Original. Lifted mostly from FMAP by WARD CHRISTENSEN
  36. ;
  37. ;-----------------------------------------------------------------
  38. ;
  39. ;Possible Extensions
  40. ;
  41. ;(1) -     Multiple disk drives. Would need expanded sort capability and
  42. ;    probably drive substitute character.
  43. ;
  44. ;(2) -    Since the file match logic is in SUBGEN in can be expanded
  45. ;    beyond CP/Ms wildcard approach.
  46. ;
  47. ;(3) -  Multiple file search capability by 'M' option to cause prompt
  48. ;    for more than one search argument.  Thus could do *.ASM and 
  49. ;    *.PLI in one pass.
  50. ;
  51. ;=================================================================
  52. ;
  53. ;
  54. ;        ---  PGM Generation Options ---
  55. ;
  56. FALSE    EQU    0
  57. TRUE    EQU    NOT FALSE
  58. ;
  59. RMAC    EQU    FALSE
  60. FNFTMRK    EQU    '@'        ;char used to signal fn.ft substitute point
  61. ;
  62. DEFP    EQU    FALSE        ;default Prompt option
  63. DEFH    EQU    FALSE        ;     header option
  64. DEFT    EQU    FALSE        ;     trailer option
  65. DEFNOT    EQU    FALSE        ;     not (invert) option
  66. DEFLOG    EQU    TRUE        ;     log option
  67. ;
  68. ;=================================================================
  69. ;
  70. ;         LET WORK BEGIN ........
  71. ;
  72.     IF    RMAC
  73.     ASEG            ; FOR RMAC
  74.     ENDIF
  75. ;
  76. ;        -----     EQUATES   -------
  77. ;
  78. ;
  79. FCB    EQU    5CH        ;SYSTEM FCB
  80. CR    EQU    13
  81. LF    EQU    10
  82. ELEN    EQU    8+3        ;length of entry
  83. ;
  84. ; BDOS EQUATES
  85. ;
  86. RDCHR    EQU    1        ;READ CHAR FROM CONSOLE
  87. WRCHR    EQU    2        ;WRITE CHR TO CONSOLE
  88. PRINT    EQU    9        ;PRINT CONSOLE BUFF
  89. RCBUF    EQU    10        ;READ CONSOLE BUFFER
  90. CONST    EQU    11        ;CHECK CONS STAT
  91. FOPEN    EQU    15        ;0FFH=NOT FOUND
  92. FCLOSE    EQU    16        ;   "    "
  93. FSRCHF    EQU    17        ;   "    "
  94. FSRCHN    EQU    18        ;   "    "
  95. ERASE    EQU    19        ;NO RET CODE
  96. FREAD    EQU    20        ;0=OK, 1=EOF
  97. FWRTE    EQU    21        ;0=OK, 1=ERR, 2=?, 255=NO DIR SPC
  98. FMAKE    EQU    22        ;255=BAD
  99. FREN    EQU    23        ;255=BAD
  100. FDMA    EQU    26
  101. BDOS    EQU    5
  102. REBOOT    EQU    0
  103. ;
  104. ;
  105. ;
  106. ;        ------  MAINLINE  --------
  107. ;
  108. ;
  109. ;        PROGRAM INITIATION
  110. ;
  111.  
  112.     ORG    100H
  113.     JMP    START
  114. VERSION    DB          'SUBGEN - February 26/82 Ver 1.2' 
  115.     DB    CR,LF,'Copyright(1982) Steve Pritchard'
  116.     DB    CR,LF
  117.     DB    CR,LF,'use    SUBGEN ?   for help info'
  118.     DB    CR,LF
  119.     DB    '$'    
  120. HELP    DB    CR,LF,'Command format:SUBGEN [d:afn.ft] [options]'
  121.     DB    CR,LF
  122.     DB    CR,LF,'It will generate SUBGEN.SUB from d:afn.ft file match'
  123.     DB    CR,LF,'under control of skeleton obtained from prompt'
  124.     DB    CR,LF,'and will substitute fn.ft where ever it finds the'
  125.     DB    CR,LF,'character '
  126.     DB    FNFTMRK,' (Try a . suffix and prefix too)'
  127.     DB    CR,LF
  128.     DB    CR,LF,'Options are:-'
  129.     DB    CR,LF,'P = prompt on each file for n, y or CR'
  130.     DB    CR,LF,'H = generate header(s) before body'
  131.     DB    CR,LF,'T = generate trailer(s) after body'
  132.     DB    CR,LF,'- = invert select logic'
  133.     DB    CR,LF,'L = invert default logging option'
  134.     DB    CR,LF,'$'
  135. START    LXI    H,0
  136.     DAD    SP
  137.     SHLD    STACK
  138.     LXI    SP,STACK
  139. ;
  140. ;        MAIN PROGRAM FLOW
  141. ;
  142.     CALL    INIT        ;initialize
  143.     CALL    DIRLOAD        ;load directory into memory
  144.     CALL    OPENFILE    ;open output file
  145.     CALL    TYPEHIT        ;type number of hits
  146.     LHLD    COUNT        ;check number found
  147.     MOV    A,H
  148.     ORA    L
  149.     JZ    EXIT        ;return no work
  150.     CALL    SORTDIR        ;sort dir entries
  151.     CALL    FORMBUF        ;form pretty buffer
  152.     CALL    WHEADER        ;write file header(s) if reqd
  153.     CALL    SKELIN        ;read standard format line(s)
  154.     CALL    WFILE        ;write body of file
  155.     CALL    WTRAIL        ;write file trailer(s) if reqd
  156. EXIT    CALL    CLSEFILE    ;close output file
  157.     NOP    ! NOP ! NOP    ;JMP 0 FOR DDT
  158.     LHLD    STACK
  159.     SPHL
  160.     RET
  161. ;============================================================
  162. ;               1ST LEVEL ROUTINES
  163. ;============================================================
  164. ;
  165. ;        INITIALIZE
  166. ;
  167. INIT    LXI    D,VERSION    ;T/ON help if ? in FCB1 pos 1
  168.     LDA    FCB+1
  169.     CPI    '?'
  170.     JNZ    INIT03
  171.     LDA    FCB+2        ;check if just ?
  172.     CPI    ' '
  173.     JNZ    INIT03        ;must be CP/M *.*
  174.     LXI    D,HELP        ;yes - so print and quit
  175.     CALL    WRCON
  176.     JMP    EXIT        ;out in a hurry
  177. INIT03    CALL    WRCON
  178.     CALL    SAVEOPT        ;save options
  179.     LXI    H,FCB+1        ;format FCB to ????????.???
  180.     MVI    B,ELEN        ;FN+FT count
  181. QLOOP    MVI    M,'?'        ;store '?' in FCB
  182.     INX    H
  183.     DCR    B
  184.     JNZ    QLOOP
  185.     RET
  186. ;
  187. ;        LOAD THE DIRECTORY (SELECTED) INTO MEMORY
  188. ;
  189. DIRLOAD    MVI    C,FSRCHF     ;search first
  190. DIRL10    LXI    D,FCB
  191.     CALL    BDOS        ;read first
  192.     INR    A        ;some?
  193.     RZ            ;jmp no to done
  194.     CALL    SELENT        ;select entry
  195.     MVI    C,FSRCHN    ;search next
  196.     JMP    DIRL10        ;repeat
  197. ;
  198. ;        OPEN OUTPUT FILE
  199. ;
  200. OPENFILE
  201.     LXI    D,MYFCB        ;open file
  202.     MVI    C,ERASE
  203.     CALL    BDOS
  204.     LXI    D,MYFCB
  205.     MVI    C,FMAKE
  206.     CALL    BDOS
  207.     INR    A
  208.     RNZ
  209.     CALL    ERXIT        ;abort type error
  210.     DB    '>> File MAKE error'
  211.     DB    CR,LF,'$'
  212.  
  213. ;
  214. ;        SORT THE SAVED ENTRIES
  215. ;
  216. SORTDIR    LHLD    COUNT        ;init the order table
  217.     PUSH    H        ;file count on stack
  218.     XCHG
  219.     LHLD    NEXTT
  220.     SHLD    AORDER        ;pointer table start
  221.     PUSH    H
  222.     DAD    D        ;2 bytes per file
  223.     DAD    D
  224.     SHLD    NEXTT        ;new table limit
  225.     POP    H
  226.     LXI    D,TABLE
  227.     LXI    B,ELEN        ;entry length
  228. ;
  229. BLDORD    MOV    M,E        ;save lo ord addr
  230.     INX    H
  231.     MOV    M,D        ;save hi ord addr
  232.     INX    H
  233.     XCHG            ;table addr in HL
  234.     DAD    B        ;point to next entry
  235.     XCHG
  236.     XTHL            ;count from stack
  237.     DCX    H
  238.     MOV    A,H
  239.     ORA    L        ;test cpunt
  240.     XTHL            ;back to stack
  241.     JNZ    BLDORD        ;..yes
  242.     POP    H        ;clean up stack of count
  243.     LHLD    COUNT        ;get count
  244.     SHLD    SCOUNT        ;save as # to sort
  245.     DCX    H        ;only 1 entry?
  246.     MOV    A,H
  247.     ORA    L
  248.     JZ    SORTDONE    ;..yes, so skip sort
  249. ;
  250. SORT    XRA    A        ;get a zero
  251.     STA    SWITCH        ;show none switched
  252.     LHLD    SCOUNT        ;get count
  253.     DCX    H        ;use 1 less
  254.     SHLD    TEMP        ;save # to compare
  255.     SHLD    SCOUNT        ;save highest entry
  256.     MOV    A,H
  257.     ORA    L
  258.     JZ    SORTDONE    ;exit if no more
  259.     LHLD    AORDER     ;point to order table
  260. ;
  261. SORTLP    MVI    A,ELEN        ;length of compare
  262.     CALL    COMPR        ;compare 2 entries
  263.     CM    SWAP        ;swap if not in order
  264.     INX    H        ;bump order
  265.     INX    H        ;..table pointer
  266.     PUSH    H
  267.     LHLD    TEMP        ;get count
  268.     DCX    H
  269.     SHLD    TEMP
  270.     MOV    A,H
  271.     ORA    L
  272.     POP    H    
  273.     JNZ    SORTLP        ;continue
  274. ;
  275. ;ONE PASS OF SORT DONE
  276.     LDA    SWITCH        ;any swaps done?
  277.     ORA    A
  278.     JNZ    SORT        ;jmp yes to repeat another pass
  279. ;
  280. SORTDONE
  281.     RET
  282. ;
  283. ;        TYPE NUMBER OF HITS
  284. ;
  285. TYPEHIT    LHLD    COUNT
  286.     MOV    A,H
  287.     ORA    A
  288.     JNZ    THIT02
  289.     MOV    A,L
  290.     CPI    1
  291.     JZ    THIT10
  292. THIT02    LXI    D,HITM1
  293.     CALL    WRCON
  294.     LHLD    COUNT
  295.     CALL    DECPRT
  296.     LXI    D,HITM3
  297. THIT05    CALL    WRCON
  298.     RET
  299. THIT10    LXI    D,HITM2
  300.     LXI    H,HITM4-1
  301.     MVI    M,' '
  302.     JMP    THIT05
  303. HITM1    DB    'There are $'
  304. HITM2    DB    'There is 1'
  305. HITM3    DB    ' selected files'
  306. HITM4    DB    CR,LF,'$'
  307. ;
  308. ;        WRITE HEADER RECORDS IF REQD
  309. ;
  310. WHEADER    LDA    OPTH        ;see if requested
  311.     ORA    A
  312.     RZ            ;return not
  313.     LXI    H,PRHDR        ;Header prompt
  314.     CALL    CONCOPY        ;copy console input to file
  315.     RET
  316. ;
  317. ;        INPUT SKELETON LINES
  318. ;
  319. SKELIN    LHLD    NEXTT        ;skel lines start where
  320.     SHLD    FSKEL        ;dir entries stop
  321.     SHLD    LSKEL
  322. SKEL10    LXI    D,PRSKEL    ;skeleton prompt
  323.     CALL    WRCON
  324.     LXI    D,TBUF        ;input a line from console
  325.     MVI    C,RCBUF    
  326.     CALL    BDOS
  327.     CALL    TYPECR
  328.     LDA    TBUF+1        ;check for data
  329.     ORA    A
  330.     JZ    SKEL50        ;jmp no    
  331. ;
  332.     MOV    B,A        ;move entry to save area
  333.     LXI    D,TBUF+2    ;input data
  334.     LHLD    LSKEL        ;output location
  335. SKEL30    LDAX    D        ;pick up byte
  336.     MOV    M,A        ;move it
  337.     INX    D
  338.     INX    H
  339.     DCR    B
  340.     JNZ    SKEL30        ;until done
  341.     MVI    M,CR        ;add crlf
  342.     INX    H
  343.     MVI    M,LF
  344.     INX    H
  345.     SHLD    LSKEL        ;remember where we are
  346.     JMP    SKEL10        ;try again
  347. ;
  348. SKEL50    LHLD    FSKEL        ;see if any entries
  349.     CALL    FLEND        ; .by doing a compare
  350.     JNZ    SKEL60        ;jmp there are some
  351.     LHLD    LSKEL        ;else default to FMAP output
  352.     MVI    M,FNFTMRK
  353.     INX    H
  354.     MVI    M,CR        ;and trailer
  355.     INX    H
  356.     MVI    M,LF
  357.     INX    H
  358.     SHLD    LSKEL        ;and save
  359. SKEL60    RET            ;return    
  360. ;
  361. ;        WRITE OUTPUT FILE
  362. ;
  363. WFILE    LHLD    COUNT        ;number of entries to write
  364.     MOV    C,L
  365.     MOV    B,H
  366.     LHLD    AORDER        ;first entry
  367. WFILE10    MOV    E,M        ;indirect adr
  368.     INX    H
  369.     MOV    D,M
  370.     INX    H
  371.     PUSH    H        ;save where we are
  372.     XCHG            ;now HL has entry adr
  373.     CALL    WENTRY        ;write entry
  374.     POP    H        ;ready for next
  375.     DCX    B
  376.     MOV    A,B
  377.     ORA    C
  378.     JNZ    WFILE10        ;until done
  379.     RET
  380. ;
  381. ;        WRITE TRAILERS IF REQD
  382. ;
  383. WTRAIL    LDA    OPTT        ;see if requested
  384.     ORA    A
  385.     RZ            ;return not
  386.     LXI    H,PRTRLR    ;trailr prompt
  387.     CALL    CONCOPY        ;copy console input to file
  388.     RET
  389. ;
  390. ;        CLOSE OUTPUT FILE
  391. ;
  392. CLSEFILE
  393.     MVI    A,'Z'-40H    ;write eof mark
  394.     CALL    FILCHR
  395.     CALL    WRSEC        ;and then the sector
  396.     LXI    D,MYFCB        ;close file
  397.     MVI    C,FCLOSE    ;function
  398.     CALL    BDOS
  399.     RET
  400. ;
  401. ;==========================================================
  402. ;        LEVEL 2 OR MORE ROUTINES
  403. ;==========================================================
  404. ;
  405. ;        SAVE OPTIONS AND INPUT FILE NAME
  406. ;
  407. SAVEOPT    LXI    D,FCB+1        ;move file name to FNFTMAT
  408.     LXI    H,FNFTMAT
  409.     MVI    B,8        ;FN portion
  410.     MVI    C,0        ;first loop sw
  411.     LDA    FCB+1        ;format to *.* if reqd
  412.     CPI    ' '
  413.     JNZ    SOPT20
  414.     MVI    A,'*'        ;yes - do it
  415.     STA    FCB+1
  416.     STA    FCB+1+8
  417. SOPT20    LDAX    D        ;pick up next byte
  418.     CPI    '*'        ;need expanding?
  419.     JNZ    SOPT30        ;no
  420. SOPT25    MVI    M,'?'        ;so do it
  421.     INX    H
  422.     INX    D
  423.     DCR    B
  424.     JNZ    SOPT25        ;until
  425.     JMP    SOPT40
  426. SOPT30    MOV    M,A        ;copy byte across
  427.     INX    H
  428.     INX    D
  429.     DCR    B
  430.     JNZ    SOPT20        ;until
  431. SOPT40    MOV    A,C        ;FT portion
  432.     ORA    A
  433.     MVI    B,3
  434.     MVI    C,1        ;2nd time sw
  435.     JZ    SOPT20        ;jmp only once so far
  436. ;
  437.     LXI    D,FCB+17-1    ;Pick up options section
  438. SOPT50    INX    D        ;next byte
  439.     LDAX    D        ;next option byte
  440.     CPI    ' '        ;test for end
  441.     JZ    SOPT60        ; .yes    
  442.     CPI    00H        ;DDT support
  443.     JZ    SOPT60
  444.     MVI    B,(OPTTABE-OPTTAB)/2
  445.     LXI    H,OPTTAB+1
  446. SOPT53    CMP    M        ;hit
  447.     JZ    SOPT55        ;jmp yes
  448.     INX    H        ;no - try next
  449.     INX    H
  450.     DCR    B
  451.     JNZ    SOPT53
  452.     STA    SOPTMSG-1
  453.     CALL    ERXIT        ;quit
  454.     DB    CR,LF
  455.     DB    '>> Invalid option=x'
  456. SOPTMSG    DB    '$'
  457. SOPT55    DCX    H        ;have a hit
  458.     MOV    A,M        ;invert hit flag
  459.     XRI    TRUE        ;from default selected at sysgen
  460.     MOV    M,A        ;and store back
  461.     JMP    SOPT50
  462. SOPT60    RET            ;return all options set
  463. ;
  464. ;        COMPARE HL TO LSKEL. NZ=NOT EQUAL
  465. ;
  466. FLEND    XCHG            ;do a subtract
  467.     LHLD    LSKEL
  468.     MOV    A,E
  469.     SUB    L
  470.     MOV    A,D
  471.     SBB    H
  472.     RET            ;return with carry set
  473. ;
  474. ;        SELECT ENTRY IF REQUIRED
  475. ;
  476. ;point to dir entry 
  477. SELENT    DCR    A        ;undo prev 'INR A'
  478.     ANI    3        ;make mod4
  479.     ADD    A        ;multiply...
  480.     ADD    A        ;..by 32 because
  481.     ADD    A        ;..each dir
  482.     ADD    A        ;..entry is 32
  483.     ADD    A        ;..bytes long
  484.     LXI    H,81H        ;point to buffer (first FN.FT entry)
  485.     ADD    L        ;point to entry
  486.     MOV    L,A        ;save (CAN'T CARRY TO H)
  487.     SHLD    SVEPOS        ;save position
  488.     CALL    FNFTMTC        ;match to FNFT wanted and NOT sw invert
  489.     RNZ            ;return unwanted
  490.     LDA    OPTP        ;user want ultimate overide
  491.     CPI    TRUE
  492.     JNZ    SELE30        ;no - so accept into table
  493.     CALL    CONFIRM
  494.     RNZ            ;user does not want it
  495. SELE30
  496. ;move entry to table
  497.     LHLD    SVEPOS        ;entry to save
  498.     XCHG            ;entry to DE
  499.     LHLD    NEXTT        ;next table entry to HL
  500.     MVI    B,ELEN        ;name entry length
  501. TMOVE    LDAX    D        ;get entry char
  502.     ANI    7FH        ;less attributes
  503.     MOV    M,A        ;store in table
  504.     INX    D
  505.     INX    H
  506.     DCR    B        ;more?
  507.     JNZ    TMOVE
  508.     SHLD    NEXTT        ;save updated table addr
  509.     LHLD    COUNT        ;get prev count
  510.     INX    H
  511.     SHLD    COUNT
  512.     RET
  513. ;
  514. ;        COPY CONSOLE TO DISK FILE FOR HEADER/TRAILER
  515. ;
  516. CONCOPY    PUSH    H        ;save prompt location
  517. COPC10    POP    D        ;write prompt
  518.     PUSH    D
  519.     CALL    WRCON
  520.     LXI    D,TBUF        ;read reply
  521.     MVI    C,RCBUF
  522.     CALL    BDOS
  523.     CALL    TYPECR
  524.     LDA    TBUF+1        ;length of reply
  525.     ORA    A        ;test length
  526.     JZ    COPC99        ;return null line
  527.     LXI    H,TBUF+2    ;not so write entry to file
  528.     MOV    B,A
  529. COPC20    MOV    A,M        ;this one
  530.     CALL    FILCHR        ;write it
  531.     INX    H        ;next
  532.     DCR    B        ;until
  533.     JNZ    COPC20
  534.     MVI    A,CR        ;write CRLF to file
  535.     CALL    FILCHR
  536.     MVI    A,LF
  537.     CALL    FILCHR
  538.     JMP    COPC10        ;repeat
  539. COPC99    POP    H        ;clean up stack
  540.     RET
  541. ;
  542. ;        MATCH DIR ENTRY TO FN.FT SPECIFIED 
  543. ;
  544. ;            AND POSSIBLY INVERT MATCH
  545. FNFTMTC    LHLD    SVEPOS        ;entry to check
  546.     LXI    D,FNFTMAT    ;master entry
  547.     MVI    B,ELEN        ;number bytes to compare
  548. FNFT10    MOV    A,M
  549.     ANI    7FH        ;remove flag bit
  550.     MOV    C,A        ;for compare
  551.     LDAX    D        ;next byte from master
  552.     CMP    C        ;to dir entry
  553.     JZ    FNFT30        ;jmp ok
  554.     CPI    '?'        ;master = ?
  555.     JNZ    FNFT40        ;no - match not equal
  556. FNFT30    INX    H        ;repeat for next byte
  557.     INX    D
  558.     DCR    B        ;until
  559.     JNZ    FNFT10
  560. ;                ;nz=no match, z=match
  561. FNFT40    LDA    OPTNOT        ;invert option flag
  562.     PUSH    PSW        ;save compare results
  563.     ORA    A        ;nz = invert
  564.     JZ    FNFT50        ;not so leave intact
  565.     POP    PSW        ;get back result
  566.     JNZ    FNFT45        ;was zero so make it NZ
  567.     ORI    1        ;by ORI
  568.     RET            ;and leave
  569. FNFT45    XRA    A        ;was NZ so make it Z
  570.     RET            ;and leave
  571. FNFT50    POP    PSW        ;no invert so restore
  572.     RET            ;return nz=no, z = yes
  573. ;
  574. ;        CONFIRM ENTRY REQUIRED OR NOT
  575. ; 
  576. CONFIRM    LHLD    SVEPOS
  577.     MVI    B,8    
  578.     CALL    TYPENB
  579.     MVI    A,'.'
  580.     CALL    TYPE
  581.     MVI    B,3
  582.     CALL    TYPENB
  583.     MVI    A,'?'
  584.     CALL    TYPE
  585.     MVI    C,RDCHR        ;read reply
  586.     CALL    BDOS
  587.     PUSH    A
  588.     CALL    TYPECR        ;get to newline
  589.     POP    A
  590.     CPI    CR        ;look for ans
  591.     JNZ    CONF10
  592.     MVI    A,'Y'        ;CR=YES
  593. CONF10    ORI    020H        ;make lower case
  594.     CPI    'y'        ;affirmative
  595.     RZ            ;return yes=z
  596.     CPI    'n'        ;must be n
  597.     JNZ    CONFIRM        ;not so try again
  598.     ORI    1        ;set nz = no
  599.     RET
  600. ;
  601. ;        WRITES ENTRY MAKING FN.FT SUBSTITUTION
  602. ;    
  603. WENTRY    SHLD    SVEPOS        ;save position
  604.     PUSH    B
  605.     PUSH    D
  606.     PUSH    H        ;and caller regs
  607.     LHLD    FSKEL        ;first pos of skeleton
  608. WENT10    MOV    A,M        ;process next char
  609.     CPI    FNFTMRK        ;special marker for FN.FT substitute
  610.     JZ    WENT20        ;yes - do that
  611.     CALL    FILCHR        ;no -write character to file
  612. WENT15    INX    H        ;next byte
  613.     PUSH    H        ;save status
  614.     CALL    FLEND        ;test end of skeleton
  615.     POP    H        ;and back again
  616.     JNZ    WENT10        ;there is more
  617.     JMP    WENT99        ;done
  618. WENT20    PUSH    H        ;save where we are
  619.     MVI    C,0        ;type of subst sw. 0=FN.FT, 1=FN, 2=FT
  620.     INX    H        ;see if nxt byte is .
  621.     MVI    A,'.'
  622.     CMP    M
  623.     JNZ    WENT22
  624.     MVI    C,1        ;it is so only do FN substitute
  625.     JMP    WENT25
  626. WENT22    DCX    H
  627.     DCX    H        ;try previous
  628.     CMP    M
  629.     JNZ    WENT25
  630.     MVI    C,2        ;FT only
  631. WENT25    POP    H        ;reload ptr to skeleton
  632.     PUSH    H
  633.     MOV    A,C        ;sw
  634.     CPI    2
  635.     JZ    WENT30        ;do FN
  636.     LHLD    SVEPOS
  637.     MVI    B,8
  638.     CALL    FILCHRNB    ;write FN but no blanks
  639. WENT30    MOV    A,C        ;sw again
  640.     ORA    A        ;see if need period
  641.     JNZ    WENT35        ;jmp no
  642.     MVI    A,'.'
  643.     CALL    FILCHR        ;write period
  644. WENT35    MOV    A,C        ;see if need FN.FT
  645.     CPI    1
  646.     JZ    WENT40        ;no
  647.     MVI    B,3
  648.     LHLD    SVEPOS
  649.     LXI    D,8
  650.     DAD    D
  651.     CALL    FILCHRNB    ;write filetype
  652. WENT40    POP    H        ;reload current ptr &
  653.     JMP    WENT15        ;return to mainline
  654. WENT99    POP    H        ;exit
  655.     POP    D
  656.     POP    B
  657.     RET    
  658. ;
  659. ;        TYPE CHAR IN A
  660. ;
  661. TYPE    PUSH    B
  662.     PUSH    D
  663.     PUSH    H
  664.     MOV    E,A
  665.     MVI    C,WRCHR
  666.     CALL    BDOS
  667.     POP    H
  668.     POP     D
  669.     POP    B
  670.     RET
  671. ;
  672. ;        WRITE MESSAGE ON CONSOLE
  673. ;          (D->msg $)
  674. ;
  675. WRCON    MVI    C,PRINT
  676.     JMP    BDOS
  677. ;
  678. ;        TYPE MSG HL POINTS TO, B HAS LENGTH
  679. ;
  680.  
  681. TYPEIT    MOV    A,M
  682.     CALL    TYPE
  683.     INX    H
  684.     DCR    B
  685.     JNZ    TYPEIT
  686.     RET
  687. ;
  688. ;        ERROR EXIT
  689. ;
  690. ERXIT    POP    D    ;GET MSG
  691.     MVI    C,PRINT
  692.     CALL    BDOS
  693.     JMP    EXIT
  694. ;
  695. ;        WRITE CHAR IN A TO FILE
  696. ;        (SAVES ALL REGS INCLUDING A)
  697. FILCHR    PUSH    PSW
  698.     PUSH    H
  699.     LHLD    BUFAD        ;current buffer adr
  700.     MOV    M,A
  701.     INX    H
  702.     SHLD    BUFAD
  703.     MOV    A,H        ;see if full buffer
  704.     DCR    A
  705.     CZ    WRSEC        ;yes so write sector
  706.     POP    H
  707.     LDA    OPTLOG        ;test if log chosen
  708.     ORA    A
  709.     JZ    FILC80        ;not so do not type
  710.     POP    PSW
  711.     PUSH    PSW        ;get char and type
  712.     CALL    TYPE
  713. FILC80    POP    PSW        ;restore char
  714.     RET
  715. ;
  716. ;        WRITE A SECTOR
  717. ;
  718. WRSEC    PUSH    B
  719.     PUSH    D
  720.     LXI    D,MYFCB
  721.     MVI    C,FWRTE
  722.     CALL    BDOS
  723.     ORA    A
  724.     JZ    WROK
  725.     CALL    ERXIT
  726.     DB    CR,LF
  727.     DB    '>> WRITE ERROR$'
  728. WROK    CALL    FORMBUF        ;clean up buffer
  729.     POP    D
  730.     POP    B
  731.     RET
  732. ;
  733. ;        TYPE ALL BUT SPACES
  734. ;        (HL -> msg, B has length)
  735. ;
  736. TYPENB    MOV    A,M        ;ignore spaces
  737.     CPI    ' '
  738.     JZ    TPNB10
  739.     CALL    TYPE
  740. TPNB10    INX    H
  741.     DCR    B
  742.     JNZ    TYPENB
  743.     RET
  744. ;
  745. ;        TYPE CRLF
  746. ;
  747. TYPECR    PUSH    A
  748.     MVI    A,CR
  749.     CALL     TYPE
  750.     MVI    A,LF
  751.     CALL    TYPE
  752.     POP    A
  753.     RET
  754. ;
  755. ;        WRITE ALL BUT SPACES TO FILE
  756. ;        (HL -> msg, B has length)
  757. ;
  758. FILCHRNB
  759.     MOV    A,M        ;ignore spaces
  760.     CPI    ' '
  761.     JZ    FILB10
  762.     CALL    FILCHR
  763. FILB10    INX    H
  764.      DCR    B
  765.     JNZ    FILCHRNB
  766.     RET
  767. ;
  768. ;        FORMAT A BUFFER AND SET UP CONTROL WORDS
  769. ;
  770. FORMBUF    PUSH    H
  771.     PUSH    A
  772.     LXI    H,080H        ;address of buffer
  773.     SHLD    BUFAD        ;save it
  774.     MVI    A,128
  775. FBUF10    MVI    M,'Z'-040H    ;set to EOF
  776.     INX    H
  777.     DCR    A
  778.     JNZ    FBUF10
  779.     POP    A
  780.     POP    H
  781.     RET
  782. ;
  783. ;        COMPARE ROUTINE FOR SORT
  784. ;        (A has number bytes to compare)
  785. ;
  786. COMPR    PUSH    H        ;save table addr
  787.     MOV    E,M        ;load lo
  788.     INX    H
  789.     MOV    D,M        ;load hi
  790.     INX    H
  791.     MOV    C,M
  792.     INX    H
  793.     MOV    B,M
  794. ;BC, DE now point to entries to be compared
  795.     XCHG
  796.     MOV    E,A        ;better reg
  797. CMPLP    LDAX    B
  798.     CMP    M
  799.     INX    H
  800.     INX    B
  801.     JNZ    CMPL80        ;out with not equal status
  802.     DCR    E
  803.     JNZ    CMPLP
  804.     XRA    A        ;ensure zero cc
  805. CMPL80    POP    H
  806.     RET            ;cond code tells all
  807. ;
  808. ;        SWAP ENTRIES IN THE ORDER TABLE
  809. SWAP    MVI    A,1
  810.     STA    SWITCH        ;show a swap was made
  811.     MOV    C,M
  812.     INX    H
  813.     PUSH    H        ;save table addr+1
  814.     MOV    B,M
  815.     INX    H
  816.     MOV    E,M
  817.     MOV    M,C
  818.     INX    H
  819.     MOV    D,M
  820.     MOV    M,B
  821.     POP    H
  822.     MOV    M,D
  823.     DCX    H        ;back pointer to correct position
  824.     MOV    M,E
  825.     RET
  826. ;
  827. ;         Print    HL in decimal with leading zero    suppression
  828. ;
  829. ;                 (Found in SD-41, Author unknown)
  830. ;
  831. DECPRT:    SUB    A        ;Clear leading zero flag
  832.     STA    LZFLG
  833.     LXI    D,-1000        ;Print 1000's digit
  834.     CALL    DIGIT
  835.     LXI    D,-100        ;Etc.
  836.     CALL    DIGIT
  837.     LXI    D,-10
  838.     CALL    DIGIT
  839.     MVI    A,'0'        ;Get 1's digit
  840.     ADD    L
  841.     JMP    TYPE
  842. DIGIT:    MVI    B,'0'        ;Start off with    ASCII 0
  843. DIGLP:    PUSH    H        ;Save current remainder
  844.     DAD    D        ;Subtract
  845.     JNC    DIGEX        ;Quit on overflow
  846.     POP    PSW        ;Throw away remainder
  847.     INR    B        ;Bump digit
  848.     JMP    DIGLP        ;Loop back
  849. DIGEX:    POP    H        ;Restore pointer
  850.     MOV    A,B
  851.     CPI    '0'        ;Zero digit?
  852.     JNZ    DIGNZ        ;No, type it
  853.     LDA    LZFLG        ;Leading zero?
  854.     ORA    A
  855.     MVI    A,'0'
  856.     JNZ    TYPE        ;Print digit
  857.     RET            ;no leading spaces for 0s
  858. DIGNZ:    STA    LZFLG        ;Set leading zero flag so next zero prints
  859.     JMP    TYPE        ;And print digit
  860. LZFLG    DB    0
  861. ;===================================================================
  862. ;        VARIABLES  AND   CONSTANTS
  863. ;===================================================================
  864. ;
  865. NEXTT    DW    TABLE        ;NEXT TABLE ENTRY
  866. COUNT    DW    0        ;ENTRY COUNT
  867. BUFAD    DW    80H        ;OUTPUT ADDR
  868. OPTTAB    EQU    $        ;OPTIONS-nonzero mean selected
  869. OPTP    DB    DEFP,'P'    ;prompt for selection yae/nae
  870. OPTH    DB    DEFH,'H'    ;ask for header
  871. OPTT    DB    DEFT,'T'    ;ask for trailer
  872. OPTNOT    DB    DEFNOT,'-'    ;invert selection criteria
  873. OPTLOG    DB    DEFLOG,'L'    ;log results to console
  874. OPTTABE    EQU    $
  875. ;
  876. PRSKEL    DB    'Skeleton? $'
  877. PRHDR    DB    'Header? $'
  878. PRTRLR    DB    'Trailer? $'
  879. ;
  880. FSKEL    DW    0        ;Position of first skel rec byte
  881. LSKEL    DW    0        ; last byte+1
  882. MYFCB    DB    0,'SUBGEN  SUB',0
  883.     DS    19
  884.     DB    0
  885. TBUF    DB    127    ;CONSOLE INPUT BUFFER
  886.     DS    127
  887. FNFTMAT    DS    11        ;match mask
  888. SCOUNT    DS    2        ;# TO SORT
  889. SVEPOS    DS    2        ;save position
  890. AORDER    DS    2        ;ORDER TABLE ADDRESS
  891. TEMP    DS    2    ;SAVE DIR ENTRY
  892. SWITCH    DS    1        ;SWAP SWITCH FOR SORT
  893.     DS    80    ;STACK AREA
  894. STACK    DS    2    ;SAVE OLD STACK HERE
  895. TABLE    EQU    $    ;READ ENTRIES IN HERE
  896.     END    100H
  897.  
  898. 1        ;SWAP SWITCH FOR SO