home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / asmlib.lbr / SBCMPC.AZM / SBCMPC.ASM
Assembly Source File  |  1991-06-25  |  8KB  |  315 lines
  1. ;****************************************************************
  2. ;*        This is a module in ASMLIB            *
  3. ;*                                *
  4. ;* This is the MPC-6  and SBC-800 console I/O super          *
  5. ;* re-directable I/O driver module for ASMLIB and the MPC-6.    *
  6. ;* This module is linked into  ASMLIB  in-place of the      *
  7. ;* original COE, CIE, CST drivers.                *         
  8. ;*                                *
  9. ;* This module supports the following devices and is selected   *
  10. ;* by sending the following codes to the console driver COE     *
  11. ;* which intercepts the code and directs the output to the     *
  12. ;* following devices.                        *
  13. ;*                                *
  14. ;*   Code        --- Device ---                *
  15. ;*    F8    SBC-800 standard I/O drivers. Standard default. *
  16. ;*                                    *
  17. ;*    F9    MPC-6 Channel 0                    *
  18. ;*    FA              1                    *
  19. ;*    FB              2                    *
  20. ;*    FC              3                    *
  21. ;*    FD              4                    *
  22. ;*    FE              5                    *
  23. ;*                                *
  24. ;* When the above codes are sent to the COE routine, they are   *
  25. ;* intercepted and used to SWITCH all further I/O to the     *
  26. ;* selected device from this point on.                *
  27. ;* This is extremely handy for having multiple I/O devices in a *
  28. ;* program selected chain.                    *
  29. ;*                                *
  30. ;*            Written        R.C.H.      14/11/83    *
  31. ;*            Last Update    R.C.H.       14/12/83    *
  32. ;****************************************************************
  33. ;
  34.     name    'SBCMPC'
  35.     public    coe,cie,cst,loe,lst,ionum
  36. ;
  37.     maclib    z80
  38. ;
  39. ;
  40. ; Equates for SBC-800 I/O addresses and device masks
  41. ;
  42. rxmsk    equ    1        ; For DART chips this applies
  43. txmsk    equ    4
  44. codat    equ    88h        ; Console ports on sbc800
  45. costat    equ    89h
  46. sestat    equ    8bh        ; Serial status port on SBC800
  47. serdat    equ    8ah        ; Serial data port on SBC800
  48. ; 
  49. ; Equates for MPC-6 Card.
  50. ;
  51. mpcdat    equ    00        ; MPC-6 data port
  52. txstat    equ    01        ; MPC-6 transmitter status port
  53. rxstat    equ    02        ; MPC-6 receiver status port
  54. command    equ    txstat        ; MPC-6 command port
  55. reset    equ    03        ; MPC-6 reset port
  56. send    equ    010h        ; Opcode for sending a byte to MPC
  57. receive    equ    00        ; Opcode for receiving a byte from MPC
  58. ;
  59. num    equ    04        ; 0 = cpmio,2=sbc800io,3=cpmmpc,4=sbcmpc
  60. ;
  61. ionum:
  62.     mvi    l,num
  63.     ret
  64. ;
  65. ;----------------------------------------------------------------
  66. ; Get the status of the currently selected I/O device
  67. ;
  68. ; Channel = 0 then SBC-800
  69. ; Channel = 1 to 6 then MPC-6
  70. ;----------------------------------------------------------------
  71. ;
  72. cst:
  73.     lda    channel
  74.     ora    a            ; Channel 00 ?
  75.     jz    const            ; Get SBC-800 console status
  76. ; Here we get the status of the MPC-6 receiver stored in A.
  77.     dcr    a            ; make in the range 0..5
  78.     jr    mpcstat            ; Do the job and return to user
  79. ;
  80. ;----------------------------------------------------------------
  81. ;        Read A character
  82. ;        ----------------
  83. ;
  84. ; Use the channel number to select either the MPC-6 or the SBC-800 
  85. ; Channel allocations as before.
  86. ;----------------------------------------------------------------
  87. ;
  88. cie:
  89.     lda    channel
  90.     ora    a
  91.     jz    conin
  92.     dcr    a            ; make the channel number in range
  93.     jr    mpcread
  94. ;
  95. ;----------------------------------------------------------------
  96. ;        Output a character in A 
  97. ;        -----------------------
  98. ;
  99. ; Test if the character is a channel selector byte 
  100. ; Write character in A to MPC-6 or SBC-800, again depending on 
  101. ; selected channel number.
  102. ; Before writing, we test if it is a channel selector byte as
  103. ; defined previously.
  104. ;----------------------------------------------------------------
  105. ;
  106. coe:
  107.     push    psw            ; save the character
  108.     ani    0f8h            ;
  109.     cpi    0f8h            ; Mask to test top 5 bits
  110.     jrnz    coe2
  111. ; Here the byte is a channel selector
  112.     pop    psw            ; restore the byte
  113.     ani    07h            ; leave only the channel number there
  114.     cpi    07
  115.     rz                ; Ignore out of range value
  116.     sta    channel            ; Save the number
  117.     ret
  118. ;
  119. ; Here and it is not a channel selector, but a valid ascii byte < 0f8h
  120. ;
  121. coe2:    ; Do the channel test and jump
  122.     lda    channel
  123.     ora    a
  124.     jz    conout            ; do the job via SBC-800
  125. ;
  126.     jr    mpcsend            ; send it and return via MPC i/o driver
  127. ;
  128. ;----------------------------------------------------------------
  129. ;                     Get the MPC-6 status
  130. ;              --------------------
  131. ;
  132. ; Channel number is in the CHANNEL byte
  133. ; Return A = 00 = no character there all else = character there
  134. ;----------------------------------------------------------------
  135. ;
  136. mpcstat:
  137.     push    d
  138.     call    bitset            ; Get a channel mask into E
  139.     in    rxstat
  140. rdy:
  141.     ana    e            ; the desired channel ??
  142.     pop    d            ; restore register
  143.     rz
  144.     mvi    a,0ffh            ; load with 0ffh if not
  145.     ret
  146. ;
  147. ;----------------------------------------------------------------
  148. ;         Read an MPC-6 channel. 
  149. ;        ----------------------
  150. ;
  151. ; Channel number is in the CHANNEL byte
  152. ;----------------------------------------------------------------
  153. ;
  154. mpcread:
  155.     push    d
  156. ; Generate a channel mask in E 
  157.     call    bitset
  158. ; 
  159. cari0:
  160.     in    txstat
  161.     ani    080h        ; we are truly busy, wait, if bit set
  162.     jrnz    cari0
  163. ;
  164. ; Wait till MPC-6 is ready with data for this channel
  165.     in    rxstat        ; channel mask
  166.     ana    e
  167.     jrz    cari0
  168. ;
  169.     in    txstat
  170.     ani    080h
  171.     jrnz    cari0
  172. ; Mask in the receive byte with the MPC-6 channel number
  173.     lda    channel        ; get the channel number
  174.     dcr    a        ; make it in range 0..5
  175.     ori    receive        ; Mask in the channel selected by the user
  176.     out    command
  177. cari1:
  178.     in    txstat
  179.     ani    080h
  180.     jrz    cari1
  181.     in    MPCDAT
  182. ; character is in A and ready for action
  183.     ani    07fh            ; mask off parity
  184. ;
  185.     pop    d            ; restore the register
  186.     ret
  187. ;
  188. ;----------------------------------------------------------------
  189. ;         Send data to the MPC-6 
  190. ;        ----------------------
  191. ;
  192. ; Data at stack TOP
  193. ; The channel number is saved in the CHANNEL byte and bitset uses
  194. ; this to generate channel mask bytes.
  195. ;----------------------------------------------------------------
  196. ;
  197. mpcsend:
  198.     pop    psw            ; get the character
  199.     push    b            ; save all user registers
  200.     push    d
  201. ;
  202.     mov    c,a            ; save the character for later
  203.     out    mpcdat            ; send the character to MPC-6
  204. caro0:
  205.     in    txstat
  206.     ani    080h
  207.     jrnz    caro0
  208. ; Get a channel mask into E
  209. ;
  210.     call    bitset
  211. ; Read status till MPC-6 accepts the character (mask in E)
  212. ;
  213. caro1:
  214.     in    txstat
  215.     ana    e
  216.     jrz    caro1
  217. ;
  218. ; Load the channel number, mask in the send command byte then send to MPC
  219. ;
  220.     lda    channel
  221.     dcr    a            ; make it in range 0..5
  222.     ori    send            ; tell MPC-6 we are sending data to it
  223.     out    command            ; send to command port
  224. ;
  225. ; A little delay for the MPC is done here to make sure it reads the byte
  226. ;
  227. delay:
  228.     mvi    a,030h
  229. del1:
  230.     dcr    a
  231.     jrnz    del1
  232. ; Restore the users character then his registers.
  233.     mov    a,c            ; restore the character
  234.     pop    d
  235.     pop    b
  236.     ret
  237. ;
  238. ;        ----------------
  239. ; Set bits to suit a selected MPC-6 channel.
  240. ; This is done by reading the channel byte to set a single bit
  241. ; in the byte returned in A
  242. ;        ----------------
  243. ;
  244. bitset:
  245.     push    b            ; save this
  246.     lda    channel            ; get channel number 1..6
  247.     mov    b,a            ; load into counter
  248.     xra    a            ; clear seed
  249.     stc                ; set carry
  250. ;
  251. ; Rotate the carry up the A register to generate a bit pattern
  252. ; for the required channel. Channel 0 -> 01, channel 4 -> 08 etc.
  253. ;
  254. bit0:
  255.     ral                ; rotate arith left thru carry
  256.     djnz    bit0            ; do for all bits
  257.     mov    e,a
  258.     pop    b            ; restore register
  259.     ret
  260. ;
  261. ;****************************************************************
  262. ;     SBC-800 i/o drivers. Used when channel = 00        *
  263. ;****************************************************************
  264. ;
  265. const:    in    costat            ; sbc status port
  266.     ani    rxmsk
  267.     rz
  268.     mvi    a,0ffh
  269.     ret                ; exit valid
  270. ;
  271. conin:    call    const
  272.     jrz    conin            
  273.     in    codat            ; character available
  274.     ani    7fh
  275.     ret
  276. ;
  277. conout: in    costat
  278.     ani    txmsk
  279.     jrz    conout
  280.     pop    psw            ; restore the character
  281.     out    codat            ; data port for SBC400
  282.     ret
  283. ;
  284. ; The line printer is assumed here to be the SBC-800 second
  285. ; serial port.
  286. ;
  287. loe:
  288.     push    psw
  289. loe1:
  290.            in    sestat
  291.     ani    txmsk
  292.     jrz    loe1
  293.     pop    psw
  294.     out    serdat            ; data port for SBC400
  295.     ret
  296. ;
  297. ; Get the serial output status.
  298. ;
  299. lst:
  300.           in    sestat            ; sbc status port
  301.     ani    txmsk
  302.     rz
  303.     mvi    a,0ffh
  304.     ret                ; exit valid
  305. ;
  306. ; Data storage is required to save the channel selection byte
  307. ; which is selected when the byte is sent to the COE driver
  308. ;
  309.     dseg
  310. channel    db    00            ; Holds the logged in channel number
  311.     end
  312.  
  313.  
  314.  
  315.