home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / freset.asm < prev    next >
Assembly Source File  |  1994-07-13  |  3KB  |  123 lines
  1. ; Routine:    FRESET -- fast drive reset and login
  2. ; Author:    Bridger Mitchell (Plu*Perfect Systems)
  3. ; CPU:        Z80-compatible
  4. ; Date:        December 27, 1987
  5. ; 
  6. ; This routine (fast-)resets and logs in the cp/m drive in register
  7. ; (A).  When possible, it uses BDOS function 37 (logoff drives). 
  8. ; In most cases FRESET is significantly faster than using function 13
  9. ; (reset all drives) to do a general reset.
  10. ; 
  11. ; FRESET functions correctly with Digital Research's CP/M 2.2 bdos,
  12. ; which contains a bug that does not allow the logged-in drive to
  13. ; be reset with function 37.
  14. ; 
  15. ; Some CP/M bdos emulators (such as ZRDOS, PZDOS, ...) have changed
  16. ; the operation of the general-reset function 13, in order to speed
  17. ; up warm-boots and disk-resets on systems with hard-drives. In this
  18. ; case, a non-removable drive (hard disk, ram disk), after it
  19. ; has been initially logged in, remains logged in after a general
  20. ; reset.
  21. ; 
  22. ; On such systems it is **essential** that any program that uses
  23. ; BIOS disk functions to write to a non-removable drive also cause
  24. ; the disk's allocation map to be rebuilt before any BDOS disk
  25. ; functions are used.  DU (DU3) and UNERASE are probably the most
  26. ; common examples of such programs; they modify the disk directory.
  27. ; For these systems, the drive must first be logged off with
  28. ; function 37 and then logged in.  Calling FRESET within such
  29. ; programs will ensure that the disk's allocation map is recomputed.
  30. ; 
  31. ; The FRESET algorithm:
  32. ;
  33. ;   if requested_drive is logged in
  34. ;     if a second drive is logged in
  35. ;         log in the second drive
  36. ;         logoff requested drive (fn.37)
  37. ;     else
  38. ;         do general reset (fn. 13)    
  39. ;   log in requested drive
  40. ; 
  41. ;
  42. xbdos    equ    5
  43.  
  44. ;    Fast-reset drive (A)
  45. ;    A = 0 ... 15  for  A: ... P:
  46. ;    
  47. CSEG
  48. freset:
  49.     ld    (reqdrv),a    ; save requested drive
  50.     push    af
  51.     ld    c,24        ; get logged-in drives vector
  52.     call    xbdos
  53.     pop    af        ; (recover requested drive)
  54.     push    hl        ; save logged-in vector
  55.     call    fshftr        ; shift requested drive's bit to bit 0
  56.     bit    0,l        ; is requested drive logged in?
  57.     pop    hl        ;  (recover (unshifted) logged vector)
  58.     jr    z,flogit    ; ..z - no, just log it in
  59.     ld    b,0        ;  initialize drive index/count
  60.     jr    frese2
  61. ;
  62. frese1:    ld    a,1        ; shift vector right 1 bit
  63.     call    fshftr
  64. frese2:    bit    0,l        ; if drive is logged in
  65.     jr    z,frese3    ;
  66.     ld    a,(reqdrv)    ; .. and it is not requested drive
  67.     cp    b
  68.     jr    nz,fnd2nd    ; .. have found 2nd logged in drive
  69. frese3:    inc    b        ; else increment drive count
  70.     ld    a,b        ;   and continue for 16 drives 
  71.     cp    16
  72.     jr    c,frese1    ;
  73.     ld    c,13        ; no other drive is logged in, so..
  74.     jr    flogit0        ; ..do general reset, then (re)log requested
  75. ;
  76. ;    have a second logged-in drive, so switch to it
  77. ;
  78. fnd2nd:    ld    e,b        ; select b'th drive
  79.     call    fslctit
  80.     ld    a,(reqdrv)    ; set up bit to log out drive
  81.     ld    hl,1
  82.     call    fshftl
  83.     ex    de,hl
  84.     ld    c,37        ; log out drive in DE vector
  85. ;
  86. flogit0:call    xbdos
  87. ;
  88. ;    login requested drive
  89. ;
  90. flogit:    ld    a,(reqdrv)
  91.     ld    e,a
  92. fslctit:ld    c,14        ; select bdos drive
  93.     jp    xbdos    
  94. ;
  95. ;
  96. ; shift hl right (a) bits
  97. ;
  98. fshftr:
  99.     inc    a
  100. shftr1:    dec    a
  101.     ret    z
  102.     srl    h
  103.     rr    l    
  104.     jr    shftr1
  105. ;
  106. ;
  107. ; shift hl left (a) bits
  108. ;
  109. fshftl:
  110.     inc    a
  111. shftl1:    dec    a
  112.     ret    z
  113.     add    hl,hl
  114.     jr    shftl1    
  115.  
  116. ;--------------------
  117. DSEG
  118. reqdrv:    ds    1
  119.  
  120.     end
  121. t
  122.     call    fshftr
  123. frese2:    bit    0,l        ; i