home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / hd64180a.lbr / IOAD.AZM / IOAD.ASM
Assembly Source File  |  1991-08-04  |  7KB  |  299 lines
  1. ;----------------------------------------------------------------
  2. ;      This module reads the I/O Bus Driven A-To-D card
  3. ;
  4. ; Written     By Richard Holmes        06-12-86
  5. ; Last Update By Richard Holmes        06-12-86
  6. ;----------------------------------------------------------------
  7. ;
  8.     maclib    z80
  9.     maclib    core
  10. ;
  11.     public    ini$ad,rd$ad
  12.     public    scan$ad
  13. ;
  14.     extrn    cie,coe,cst,pdde,ptxt
  15.     extrn    phde,crlf
  16. ;
  17. ;----------------------------------------------------------------
  18. ;     ---- A to D equates ----
  19. ;
  20. ; Note that all the signals are LOW going to that to generate the actual
  21. ; bit image ANDs and not or's must be used.
  22. ; 
  23. cs$bar    equ    0000$1110b        ; Chip select
  24. rd$bar    equ    0000$1101b        ; Read from ADC-1205
  25. wr$bar    equ    0000$1011b        ; Write to DC-1205
  26. ss$bar    equ    0000$0101b        ; Status from ADC-1205
  27. ;
  28. ; Setup what the bits mean
  29. ;
  30. sars    equ    6            ;bit 6 = Conversion in progress
  31. byst    equ    2            ;    2 = 0 for high byte, 1 for low
  32. eoc    equ    1            ;    1 = 1 for end of conversion
  33. int    equ    0            ;    0 = 1 for data ready to be read
  34. ;
  35. ; Setup the port addresses
  36. ;
  37. data    equ    @gp3a            ; General purpose port 3
  38. cntl    equ    data + 1
  39. mode    equ    data + 3        ; 8255 mode
  40. ;
  41. ; 8255 modes of operation
  42. ;
  43. rd$mod    equ    090h            ; B = outputs, A = inputs
  44. wr$mod    equ    080h            ; B = outputs, A = outputs
  45. ;
  46. ;----------------------------------------------------------------
  47. ;    Initialize the A to D chip by disabling all its inputs
  48. ;
  49. ;----------------------------------------------------------------
  50. ;
  51. ini$ad:
  52.     mvi    a,rd$mod
  53.     out    mode
  54.     mvi    a,cs$bar and wr$bar and ss$bar    ; Chip reset
  55.     out    cntl
  56.     mvi    a,0ffh
  57.     out    cntl            ; All inputs high = dead effectively
  58.     ret
  59. ;
  60. ;----------------------------------------------------------------
  61. ;       Read the A-D channel. Return data in HL.
  62. ;
  63. ; On entry
  64. ;   A = channel
  65. ;
  66. ; On Exit
  67. ;  HL = data
  68. ;  All registers except A and HL preserved
  69. ;  A to D error sets HL to 
  70. ;                         FFFF for converter busy on entry
  71. ;                         FFFE for cannot begin conversion
  72. ;              FFFD for cannot complete conversion
  73. ;----------------------------------------------------------------
  74. ;
  75. rd$ad:
  76.     push    d
  77.     push    b
  78. ; Select read status mode
  79.     mvi    a,rd$mod
  80.     out    mode            ; 8255 reading data port
  81. ;
  82. ; Status is on the data port now
  83. ;
  84.     mvi    b,50            ; Tries
  85. wait$ready:
  86.     mvi    a,cs$bar and ss$bar
  87.     out    cntl            ; Read status to see whats going on
  88.     in    data
  89. ; 
  90.     push    psw
  91.     mvi    a,0ffh
  92.     out    cntl
  93.     pop    psw
  94. ;
  95.     bit    sars,a            ; Are we converting ?
  96.     jrz    start$conversion
  97.     djnz    wait$ready
  98.     lxi    h,0ffffh        ; Converter busy on entry
  99.     jr    ioad$end
  100. ;
  101. ; Here we can start the conversion.
  102. ;
  103. start$conversion:
  104.     mvi    a,cs$bar and wr$bar    ; Selects a write = start conversion
  105.     out    cntl
  106.     nop
  107.     mvi    a,0ffh
  108.     out    cntl            ; Let it work a little
  109. ; A small delay and see if conversion started
  110.     nop
  111.     nop
  112.     nop
  113.     nop
  114.     mvi    a,cs$bar and ss$bar    ; Status read, SARS must be high
  115.     out    cntl
  116.     in    data            ; Read the status now from the chip
  117. ; Save data, de-select A-D, restore data
  118.     push    psw
  119.     mvi    a,0ffh
  120.     out    cntl            ; Turn off the logic again;
  121.     pop    psw
  122. ;
  123.     bit    sars,a            ; SARS high = converting
  124.     jrnz    ad$started
  125.     mvi    a,0fffeh        ; Cannot start flag
  126.     jr    ioad$end
  127. ;
  128. ; Here the A-D started. We wait a little the try to read the data
  129. ;
  130. ad$started:
  131.     mvi    b,35            ; this is ~ 90uS
  132. ad$wait:
  133.     nop
  134.     djnz    ad$wait
  135. ;
  136. ;Load a re-try counter now to get data back from converter
  137. ;
  138.     mvi    b,20            ; Retry counter to ensure conversion
  139. ad$read:
  140.     mvi    a,cs$bar and ss$bar    ; Select a status read only
  141.     out    cntl            ; Read mode now, real quick
  142.     in    data
  143. ; Save data, de-select A-D, restore data
  144.     push    psw
  145.     mvi    a,0ffh
  146.     out    cntl            ; Turn off the logic again;
  147.     pop    psw
  148. ; Test for end of conversion.
  149.     bit    int,a            ; 1 = end of conversion, read the data
  150.     jrnz    get$data
  151.     djnz    ad$read
  152. ; Here, the converter timed out. Signal it.
  153.     mvi    a,0fffdh
  154.     jr    ioad$end
  155. ;
  156. ; Here, A = the status with end of conversion indicated.
  157. ; We now see if it is the high byte and if so, read data.
  158. ;
  159. get$data:
  160.     bit    byst,a
  161.     jrz    get$data$high        ; byst low = high byte in latches
  162. ; Here we got a low byte
  163.     mvi    a,cs$bar and rd$bar
  164.     out    cntl            ; Read the first (high byte);
  165.     nop
  166.     mvi    a,0ffh
  167.     out    cntl
  168.     nop
  169. ;
  170. get$data$high:
  171.     lxi    d,0            ; Compare
  172.     mvi    b,10
  173. ;
  174. ; Loop here to get data and make sure stable
  175. ;
  176. get$data$loop:
  177.     mvi    a,cs$bar and rd$bar
  178.     out    cntl            ; Read the first (high byte);
  179.     nop
  180.     nop                ; Allow cables to settle ?
  181.     nop
  182.     in    data            ; Read chip
  183.     ani    0001$1111b        ; 12 bit A-D remember. 13th = sign
  184.     mov    h,a
  185.     mvi    a,0ffh
  186.     out    cntl            ; This clock second byte into latches
  187.     nop
  188.     nop
  189.     mvi    a,cs$bar and rd$bar
  190.     out    cntl            ; Read the first (high byte);
  191.     nop
  192.     in    data            ; Read chip
  193.     mov    l,a
  194.     mvi    a,0ffh
  195.     out    cntl            ; This clock second byte into latches
  196. ;
  197. ; See if data stable
  198. ;
  199.     mov    a,l
  200.     cmp    e            ; L = E ?
  201.     jrnz    not$same
  202.     mov    a,h
  203.     cmp    d
  204.     jrz    ioad$end
  205. ;
  206. not$same:
  207.     xchg                ; Hl -> DE looking for a match
  208.     djnz    get$data$loop
  209.     lxi    h,0
  210. ;
  211. ioad$end:
  212.     pop    b
  213.     pop    d
  214.     ret
  215. ;
  216. ;----------------------------------------------------------------
  217. ; Scan the A-D converter and display the values as they change.
  218. ; Indicate any error and any change in the error status.
  219. ;
  220. ; On Exit
  221. ;  All registers presumed lost
  222. ;----------------------------------------------------------------
  223. ;
  224. scan$ad:
  225.     call    ini$ad            ; Initialize converter
  226.     call    rd$ad
  227.     jr    new$ad
  228. ;
  229. ; Now, read and display any changes.
  230. ; Exit when any key is pressed.
  231. ;
  232. scan$loop:
  233.     call    cst
  234.     jnz    scan$end
  235.     call    rd$ad            ; Read converter
  236.     lda    old$ad            ; Compare to previous values
  237.     cmp    l            ; Same ?
  238.     jrnz    new$ad
  239.     lda    old$ad + 1
  240.     cmp    h            ; Same here = both the same. No change
  241.     jrz    scan$loop
  242. new$ad:
  243.     shld    old$ad
  244.     call    crlf
  245. ; Is it an Error ?
  246.     mov    a,h
  247.     cpi    0ffh            ; Error flag
  248.     jrz    ad$error
  249. ; Else display the value
  250.     xchg
  251.     call    pdde
  252.     jmp    scan$loop
  253. ;
  254. ad$error:
  255.     xchg
  256.     call    phde
  257.     lxi    d,error0
  258. ; 
  259.     mov    a,e            ; E = the sub-code of the error
  260.     cpi    0ffh            ; Converter busy at start
  261.     jrz    ad$msg
  262. ;
  263.     lxi    d,error1
  264.     cpi    0feh            ; Cannot start conversion
  265.     jrz    ad$msg
  266. ;
  267.     lxi    d,error2
  268.     cpi    0fdh
  269.     jrz    ad$msg
  270. ; Else a silly error
  271.     lxi    d,errorN
  272. ad$msg:
  273.     call    ptxt
  274.     jmp    scan$loop
  275. ;
  276. scan$end:
  277.     call    cie
  278.     ret
  279. ;
  280. error0:    db    ' Cannot start - Converter busy$'
  281. error1:    db    ' Cannot start - Converter wont start$'
  282. error2:    db    ' Cannot complete conversion - Stuck$'
  283. errorN:    db    ' Un-Recognized A-D error$'
  284. ;
  285. ; ---- Data ----
  286. ;
  287.     dseg
  288. old$ad    ds    2
  289. ;
  290. ; ------------------------------
  291. ; ----                      ----
  292. ; ---- End of program - Bye ----
  293. ; ----                      ----
  294. ; ------------------------------
  295. ;
  296.     end
  297. ;
  298. ;
  299.