home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / asmutl / hd64180a.lbr / IOLCD440.AZM / IOLCD440.ASM
Assembly Source File  |  1991-08-04  |  15KB  |  652 lines
  1.     title    'CORE Board LCD Drivers - 4 by 40 Char version'
  2. ;----------------------------------------------------------------
  3. ;         LCD Drivers for CORE Board
  4. ;
  5. ; This module provides all the LCD Support for CORE-BOARD
  6. ; and is separate to the I/O driver main module because
  7. ; different LCDs' will definately require different
  8. ; I/O drivers.
  9. ;
  10. ; Written     by      Richard Holmes       17-12-86
  11. ; Last Update by      Richard Holmes       11-08-87
  12. ;----------------------------------------------------------------
  13. ;        Routines in this module
  14. ;
  15. ; ini$lcd    Initialize the LCD display
  16. ; clr$lcd    Clear LCD and home cursor
  17. ; hom$lcd    Home cursor to top L.H. corner
  18. ; cur$lcd    Cursor address lcd. D = X, E = Y
  19. ; eol$lcd    Clear LCD to end of line.
  20. ; put$lcd    Write character in A to LCD.
  21. ; str$lcd    Print string at DE to LCD till a null or $
  22. ;----------------------------------------------------------------
  23. ; This version suits the HanDok 4016H. It is a 40 character by 4 
  24. ; line display.
  25. ; PA 0..7 are data bits into the chip
  26. ;
  27. ; PB 0 = Enable 1. For controller 1
  28. ;    1 = Enable 2. For controller 2
  29. ;    1 = R/W-.               1 = write to LCD
  30. ;    2 = Register select     1 = Data, 0 = control register
  31. ;----------------------------------------------------------------
  32. ;
  33.     maclib    z80
  34.     maclib    core
  35. ;
  36.     public    ini$lcd,hom$lcd,clr$lcd
  37.     public    put$lcd,cur$lcd,eol$lcd
  38.     public    str$lcd
  39. ;
  40. ; ---- Smart LCD I/O ----
  41. ;
  42.     public    xyi$lcd,xyp$lcd,pmu$lcd
  43. ;
  44.     extrn    coe
  45.     extrn    ori$led            ; Restore LED status
  46.     extrn    clrwdt            ; Stop watchdog
  47. ;
  48. ; Equates
  49. ;
  50. data    equ    044h        ; Data port of LCD
  51. cntl    equ    045h        ; Control port of LCD
  52. mode    equ    047h        ; Mode port
  53. ;
  54. idle    equ    0        ; Idle display controllers
  55. wr$cmd2    equ    1        ; Write command 1
  56. wr$cmd1    equ    2        ; Write command 2
  57. ;
  58. wr$dat2    equ    9        ; Write data 1
  59. wr$dat1    equ    0ah        ; Write data 2
  60. ;
  61. rd$st2    equ    5        ; Read status 1
  62. rd$st1    equ    6        ; Read status 2
  63. ;
  64. bs    equ    8        ; Backspace
  65. ;
  66. ;----------------------------------------------------------------
  67. ; Return LCD Status. This is tricky as it must re-initialize
  68. ; the LCD control port and read the LCD status flag BF. It
  69. ; will return a 00 if idling or an FF if busy. NOTE the
  70. ; need to re-load the CS2 line to the ram chip and clock
  71. ; and LED return when finished.
  72. ;----------------------------------------------------------------
  73. ;
  74. lcd$status:    
  75.     push    h        ; Save register to use as a scratch pad
  76. ;
  77. ; Generate the LCD enable signals
  78.     lda    lcd$cmd        ; Command to be used
  79.     ani    0000$0011b    ; Get the controller bits
  80.     ori    0000$0100b    ; Or in the status reading function
  81.     mov    l,a        ; L = device image.
  82. ;
  83.     di            ; STOP interrupts when checking LCD status
  84.     mvi    a,090h        ; Port A inputs
  85.     out    @ledmd        ; LED mode port
  86.     mvi    a,0c0h
  87.     out    @ledd        ; Re-assert ram as soon as possible
  88. ;
  89.     nop
  90.     nop
  91.     nop
  92.     nop            ; Settling time
  93. ;
  94. ;       OK, Port A inputs, B and C outputs. 
  95. ; Note the need to set R/W pin high for a time before the E pin (bit 0).
  96. ;
  97.     mvi    a,0000$0100b    ; Send the Read bit out.
  98.     out    cntl        ; To the control port
  99.     mov    a,l
  100.     out    cntl        ; Send "E" bits also
  101. ;
  102. ; This requires a 40uS delay as per the data sheet
  103. ;
  104.     mvi    a,15        ; Plenty of time 
  105. st$dly:
  106.     dcr    a
  107.     jnz    st$dly
  108. ;
  109.     in    data        ; Read the LCD data
  110.     mov    l,a        ; Save here. Can't see stack can we....
  111. ;
  112. ; Restore 8255 mode
  113.     mvi    a,080h        ; ALL outputs
  114.     out    @ledmd        ; LED mode port
  115. ; Re-load ram control signals
  116.     mvi    a,0C0h        ; Bit 6 and 7 for ram and clock on
  117.     out    @ledd        ; Sends to led port to turn on ram again.
  118. ;
  119.     nop
  120.     nop
  121.     nop
  122.     nop
  123.     xra    a
  124.     out    cntl        ; Clear the port
  125. ;
  126.     ei            ; Restore interrupts after LCD write
  127. ;
  128.     call    ori$led        ; Restore previous LED status
  129. ;
  130.     mov    a,l        ; Restore data
  131.     pop    h        ; Restore register
  132. ;Now. Determine basic state of 00 = idle or FF = busy.
  133.     ani    1000$0000b    ; Leave busy flag
  134.     rz
  135.     mvi    a,0ffh        ; Else load an FF for very busy still.
  136.     ret
  137. ;
  138. ;------------------------------------------------
  139. ; Latch the command in lcd$cmd  and the
  140. ; data in lcd$dat into the LCD.
  141. ;------------------------------------------------
  142. ;
  143. lch$lcd:
  144.     push    h
  145.     push    psw        ; Save registers
  146. ;
  147. ; Now setup timeout counter in HL and look for LCD idle
  148.     lxi    h,400        ; Big delay
  149. lch$cmd$loop:
  150.     call    clrwdt
  151.     call    lcd$status    ; Get LCD status
  152.     ora    a
  153.     jrz    lch$cmd$ok
  154.     dcx    h
  155.     mov    a,l
  156.     ora    h        ; Done ?
  157.     jrnz    lch$cmd$loop    ; Loop on till IDLE (busy flag = 0)
  158. ; ERROR here
  159. ;
  160.     pop    psw
  161.     pop    h
  162.     stc            ; Carry flag = error
  163.     ret
  164. ;
  165. ; Restore registers and do job
  166. ;
  167. lch$cmd$ok:
  168.     pop    psw
  169.     push    psw
  170. ;
  171.     out    data
  172.     lda    lcd$cmd
  173.     out    cntl
  174.     xra    a
  175.     out    cntl
  176. ;
  177.     pop    psw
  178.     pop    h
  179.     ret
  180. ;
  181.     page
  182. ;----------------------------------------------------------------
  183. ;         Initialize the LCD.
  184. ;
  185. ; 1. Data path 8 bits, 2 line display
  186. ; 2. Enable cursor. Blink. Enable display
  187. ; 4. Clear and home cursor.
  188. ; 3. Display stationary, auto increment, right
  189. ;----------------------------------------------------------------
  190. ;
  191. ini$lcd:
  192.     push    psw
  193. ;
  194. ; Select the first controller, command latching.
  195.     mvi    a,wr$cmd1    ; Command for controller 1
  196.     sta    lcd$cmd        ; Save in command port.
  197.     call    ini$cntrlr    ; Initialize the controller
  198. ;
  199.     mvi    a,wr$cmd2    ; Controller 2
  200.     sta    lcd$cmd
  201.     call    ini$cntrlr
  202. ;
  203.     xra    a
  204.     sta    lcd$x
  205.     sta    lcd$y        ; Setup X and Y addresses
  206.     call    cof$lcd        ; Turn off all cursors
  207.     call    con$lcd        ; Turn cursor on.
  208. ;
  209.     pop    psw
  210.     ret
  211. ;
  212. ;----------------------------------------------------------------
  213. ;     ---- Initialize the contoller. ----
  214. ;----------------------------------------------------------------
  215. ;
  216. ini$cntrlr:
  217. ;
  218. ; 1. Enable 8 bit bus, 2 line display
  219.     mvi    a,038h
  220.     call    lch$lcd        ; Latch 8 bit, 2 line display
  221. ;
  222. ; 2. Enable display on, cursor on, blink
  223.     mvi    a,0eh
  224.     call    lch$lcd
  225. ;
  226.     mvi    a,08
  227.     call    lch$lcd
  228. ;
  229. ;
  230. ; 3. Display stationary, Right cursor
  231. ;
  232.     mvi    a,2
  233.     call    lch$lcd
  234. ;
  235.     mvi    a,1
  236.     call    lch$lcd
  237. ;
  238. ; Done.
  239.     ret
  240. ;
  241. ;----------------------------------------------------------------
  242. ;             Clear LCD and home cursor.
  243. ;----------------------------------------------------------------
  244. ;
  245. clr$lcd:
  246.     push    psw
  247. ; Clear controller 1
  248.     mvi    a,wr$cmd1
  249.     sta    lcd$cmd            ; Select a clear command controller 1
  250.     mvi    a,1            ; Clear display totally
  251.     call    lch$lcd
  252. ;
  253. ; Clear controller 2
  254.     mvi    a,wr$cmd2
  255.     sta    lcd$cmd            ; Select a clear command controller 1
  256.     mvi    a,1            ; Clear display totally
  257.     call    lch$lcd
  258. ;
  259.     xra    a            ; Clear cursor address
  260.     sta    lcd$x
  261.     sta    lcd$y
  262.     call    hom$lcd
  263. ;
  264.     pop    psw
  265.     ret
  266. ;
  267. ;----------------------------------------------------------------
  268. ;         Home the cursor
  269. ;----------------------------------------------------------------
  270. ;
  271. hom$lcd:
  272.     push    d
  273.     push    psw
  274. ;
  275.     lxi    d,0            ; Top left hand corner of screen
  276.     call    cur$lcd            ; Home to the top lh lcd corner
  277. ;
  278.     pop    psw
  279.     pop    d
  280.     ret
  281. ;
  282. ;----------------------------------------------------------------
  283. ;     Turn all cursors off.
  284. ;----------------------------------------------------------------
  285. ;
  286. cof$lcd:
  287.     push    psw
  288.     mvi    a,wr$cmd1
  289.     sta    lcd$cmd
  290.     mvi    a,0000$1100b    ; Display on, cursor off
  291.     call    lch$lcd        ; Latch the command and data in.
  292. ;
  293.     mvi    a,wr$cmd2
  294.     sta    lcd$cmd
  295.     mvi    a,0000$1100b    ; Display on, cursor off
  296.     call    lch$lcd        ; Latch the command and data in.
  297.     pop    psw
  298.     ret
  299. ;
  300. ;----------------------------------------------------------------
  301. ;     Turn the current cursor at lcd$x and lcd$y on.
  302. ;
  303. ; This is decided by the current cursor address of the lcd.
  304. ;----------------------------------------------------------------
  305. ;
  306. con$lcd:
  307.     push    b
  308.     push    psw
  309. ;
  310. ; Select the controller and load the write command control word
  311.     mvi    c,wr$cmd1    ; Default to controller 1
  312.     lda    lcd$y        ; Line number
  313.     cpi    2
  314.     jc    con$do        ; Line 0 and 1 user controller 1
  315. ;
  316.     mvi    c,wr$cmd2    ; Controller 2 if line 2 or 3
  317. con$do:
  318.     mov    a,c        ; get
  319.     sta    lcd$cmd        ; Load the command
  320.     mvi    a,0fh        ; cursor on
  321.     call    lch$lcd        ; And do it.
  322. ;
  323.     pop    psw
  324.     pop    b
  325.     ret
  326. ;
  327.     page
  328. ;----------------------------------------------------------------
  329. ; Cursor address.
  330. ;
  331. ; On Entry D = X in the range 0..38  (characters per line)
  332. ;          E = Y in the range 0..3   (lines)
  333. ;
  334. ; If out of range, no change is made.
  335. ; All registers preserved
  336. ;----------------------------------------------------------------
  337. ;
  338. cur$lcd:
  339.     push    b
  340.     push    psw
  341. ;
  342. ; Check if X > possible range.
  343.     mov    a,d
  344.     cpi    40        ; Error if > 16
  345.     jrnc    cur$err
  346. ; Check Line number
  347.     mov    a,e
  348.     cpi    4
  349.     jrnc    cur$err        ; Error if > 3
  350. ;
  351.     sta    lcd$y
  352. ;
  353. ; Turn off cursor(s)
  354.     call    cof$lcd        ; All cursors off. Sets up lcd$cmd also.
  355. ;
  356. ; Now generate the ram address for the LCD
  357.     mvi    c,080h        ; Top bit = cursor address
  358.     mov    a,e        ; Get the line number back
  359.     ani    0000$0001b    ; Do a modulus 2
  360.     jrz    cur$not$1    ; Top row is address 80h..8fh
  361.     mvi    c,0C0h        ; If second row the offset is 0C0h
  362. ;
  363. cur$not$1:
  364.     mov    a,c        ; Address
  365.     add    d        ; Add in the X address
  366.     call    lch$lcd        ; Command in A built up
  367. ; Save the X address also
  368.     mov    a,d        ; X
  369.     sta    lcd$x
  370. ; 
  371. ; Turn on the cusor
  372.     call    con$lcd
  373. ;
  374. cur$err:
  375.     pop    psw
  376.     pop    b
  377.     ret
  378. ;
  379. ;----------------------------------------------------------------
  380. ;                Clear LCD to end of line
  381. ;----------------------------------------------------------------
  382. ;
  383. eol$lcd:
  384.     push    b
  385.     push    d
  386.     push    psw
  387. ; Get the current cursor address.
  388.     lda    lcd$y
  389.     mov    e,a
  390.     lda    lcd$x
  391.     mov    d,a        ; Save X
  392. ;
  393. ; A = column number. Send spaces to end of line now.
  394. ;
  395. eol$loop:
  396.     push    psw        ; Save current column number
  397.     mvi    a,' '        ; Erase with a space.
  398.     call    put$lcd        ; Send the character to the LCD
  399.     pop    psw        ; Restore column
  400. ;
  401.     cpi    39        ; Did we just do the last column ?
  402.     jrz    eol$done
  403.     inr    a
  404.     jr    eol$loop
  405. ;
  406. ;
  407. eol$done:
  408.     call    cur$lcd        ; Cursor address to previous row/col position
  409. ;
  410.     pop    psw
  411.     pop    d
  412.     pop    b
  413.     ret
  414. ;
  415.     page
  416. ;----------------------------------------------------------------
  417. ;
  418. ;          Send character in A to the LCD
  419. ;
  420. ; We must decide which controller by checking the lcd$y address
  421. ; and use Y = 0,1 for controller 1, and 2,3 for controller 2.
  422. ;----------------------------------------------------------------
  423. ;
  424. put$lcd:
  425.     push    psw
  426.     push    b
  427. ;
  428. ; Carriage return ?
  429.     cpi    0dh
  430.     jz    put$cr
  431.     cpi    lf
  432.     jz    put$lf
  433.     cpi    bs            ; Back space ?
  434.     jz    put$bs
  435. ;
  436. ; None of these. Bump the column number.
  437.     lda    lcd$x
  438.     inr    a
  439.     sta    lcd$x
  440.     cpi    40            ; End of line ?
  441.     jc    put$lcd1        ; If not, continue.
  442.     xra    a            ; Start of next line
  443.     sta    lcd$x
  444. ;
  445. ; Bump the row now. We must also cusor position.
  446. ; This is used as the line feed entry point so that the
  447. ; line number is advaced without advancing any columns.
  448. ;
  449.     lda    lcd$y
  450.     inr    a
  451.     sta    lcd$y
  452.     cpi    4            ; Only allowed rows 0..3
  453.     jc    put$lcd$xy        ; Not last row and all ok
  454. ;
  455. ; Past last row. Start at top again.
  456.     xra    a
  457.     sta    lcd$y
  458. ;
  459. put$lcd$xy:
  460.     push    d
  461.     lda    lcd$x
  462.     mov    d,a
  463.     lda    lcd$y
  464.     mov    e,a
  465.     call    cur$lcd            ; Setup cursor at end of line to "wrap"
  466.     pop    d
  467. ;
  468. ; Now select the controller to be used (written to).
  469. ;
  470. put$lcd1:
  471.     mvi    c,wr$dat1        ; Default to controller 1
  472.     lda    lcd$y
  473.     cpi    2
  474.     jc    put$lcd$do
  475.     mvi    c,wr$dat2
  476. ;
  477. put$lcd$do:
  478.     mov    a,c
  479.     sta    lcd$cmd
  480. ;
  481.     pop    b
  482.     pop    psw
  483.     jmp    lch$lcd
  484. ;
  485. ; Carriage return = home cursor to left hand column
  486. ;
  487. put$cr:
  488.     xra    a
  489.     sta    lcd$x
  490. ;
  491. ; Cursor address now - Also used by the CR handler
  492. ;
  493. put$lf$cur:
  494.     push    d
  495.     lda    lcd$x
  496.     mov    d,a            ; D = X
  497.     lda    lcd$y
  498.     mov    e,a            ; E = Y
  499.     call    cur$lcd
  500.     pop    d
  501. ;
  502. ;
  503. put$end:
  504.     pop    b            ; Saved at routine start.
  505.     pop    psw
  506.     ret
  507. ;
  508. ; Process a line feed by incrementing the line number by 1
  509. ;
  510. put$lf:
  511.     lda    lcd$y            ; Line number
  512.     inr    a
  513.     sta    lcd$y
  514.     cpi    4
  515.     jc    put$lf$cur        ; Carry = not past end line
  516.     xra    a
  517.     sta    lcd$y
  518.     jmp    put$lf$cur
  519. ;
  520. ; Send a backspace to the LCD by decrementing the current column by 
  521. ; one. NOTE that the backspacing will stop at left hand margin.
  522. ;
  523. put$bs:
  524.     lda    lcd$x
  525.     ora    a            ; At zero ?
  526.     jrz    put$end
  527.     dcr    a
  528.     sta    lcd$x            ; Save the new decremented column
  529.     jmp    put$lf$cur        ; Cursor address now.
  530. ;
  531.     page
  532. ;----------------------------------------------------------------
  533. ; Print the menu at the address in DE into the LCD.
  534. ;----------------------------------------------------------------
  535. ;
  536. pmu$lcd:
  537.     push    d            ; save all
  538.     push    psw
  539. ;
  540. pmenu2:
  541.     call    clrwdt            ; Reset watchdog
  542.     call    xyp$lcd            ; Print the string following to the lcd
  543.     ldax    d            ; is the next character a dollar ?
  544.     cpi    0ffh            ; end of menu ??
  545.     jrnz    pmenu2
  546. ;
  547.     pop    psw
  548.     pop    d
  549.     ret
  550. ;
  551. ;----------------------------------------------------------------
  552. ; Print the following X-Y addressed message to the LCD. The return
  553. ; address has the text in it preceeded by an X-Y address.
  554. ;----------------------------------------------------------------
  555. ;
  556. xyi$lcd:
  557.     xthl            ; HL -> string, old hl in stack
  558.     xchg            ; now DE --> string
  559.     call    setxy        ; set it up
  560.     xchg            ; now hl --> string start again
  561.     call    print
  562.     xthl            ; hl = original value, stack = return address
  563.     ret
  564. ;
  565. ;----------------------------------------------------------------
  566. ; Print the string --> by DE. Use the two bytes at the start of it
  567. ; as a screen address.
  568. ;----------------------------------------------------------------
  569. ;
  570. xyp$lcd:
  571.     push    h
  572.     call    setxy            ; set up screen
  573.     xchg                ; now hl --> string start
  574.     call    print
  575.     xchg                ; Restore DE --> past end of string
  576.     pop    h
  577.     ret
  578. ;
  579. ;       ---- Utility to print a string till a $. ----
  580. ; On return HL -> to next byte after the string (code maybe)
  581. ;
  582. print:
  583.     push    psw
  584.     inx    h
  585.     inx    h        ; skip over cursor address
  586. print2:
  587.     mov    a,m
  588.     inx    h        ; Point to next character
  589.     ora    a        ; null is allowed to end a string
  590.     jz    print3
  591.     cpi    '$'        ; End of string ?
  592.     jz    print3
  593.     call    put$lcd        ; Print the character
  594.     jr    print2
  595. print3:
  596.     pop    psw
  597.     ret
  598. ;
  599. ;----------------------------------------------------------------
  600. ; Set the cursor up according to two bytes in ram which contain
  601. ; the X and Y addresses in them. The bytes --> by DE.
  602. ;----------------------------------------------------------------
  603. ;
  604. setxy:
  605.     push    d            ; save 
  606.     push    h
  607.     xchg                ; HL --> bytes
  608.     mov    d,m            ; load X value
  609.     inx    h
  610.     mov    e,m
  611.     call    cur$lcd            ; Set it up
  612.     pop    h            ; restore all now
  613.     pop    d
  614.     ret
  615. ;
  616. ;
  617. ;----------------------------------------------------------------
  618. ;          Print string till null or $
  619. ;----------------------------------------------------------------
  620. ;
  621. str$lcd:
  622.     push    psw
  623. str$loop:
  624.     call    clrwdt
  625.     ldax    d
  626.     cpi    '$'        ; $ = end
  627.     jrz    str$end
  628.     ora    a        ; 00 = end
  629.     jrz    str$end
  630.     call    put$lcd        ; Send
  631.     inx    d        ; -> next
  632.     jr    str$loop
  633. ;
  634. ;
  635. str$end:
  636.     pop    psw
  637.     ret
  638. ;
  639. ;    ----oooo----
  640. ;
  641.     dseg
  642. ;
  643. lcd$cmd: ds    1        ; Command to write to LCD
  644. ;
  645. ;
  646. lcd$x:    ds    1
  647. lcd$y:    ds    1
  648.     end
  649. ;
  650. ; -- End of module --
  651. ;
  652.