home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / cpm / utils / dirutl / edir.lbr / EDIR.AZM / EDIR.ASM
Assembly Source File  |  1987-12-24  |  5KB  |  177 lines
  1.  
  2. ;EDIR AS OF 11/28/87
  3. ;COPYRIGHT (C) 1987 BY ROBERT GREENLEE, P.O. BOX 23286, SAN DIEGO CA 92123
  4. ;PHONE VOICE 619-268-0112
  5. ;      MODEM 619-569-8613.
  6. ;
  7. ;THIS PROGRAM LOGS YOU INTO THE ERASED FILE DIRECTORY ON A CP/M 2.2
  8. ; COMPUTER DISK AND CHANGES THE CP/M ERA COMMAND SO THAT IT UNERASES FILES 
  9. ; AND CAUSES THE REN COMMAND TO RENAME JUST ONE DUPLICATE FILE 
  10. ; INSTEAD OF ALL FILES HAVING THE SAME NAME.   YOU CAN USE
  11. ; THE CP/M DIR COMMAND TO SEE WHICH FILES ON A DISK ARE ERASED.
  12. ;
  13. ;THE NAME EDIR STANDS FOR FOR "ERASED DIRECTORY" WHICH IS SHORT FOR
  14. ; "ERASED FILE DIRECTORY."
  15. ;
  16. ;ON MOST COMPUTERS THE PROGRAM ONLY LASTS UNTIL THE NEXT WARM BOOT.  
  17. ;
  18. ;TO CREATE THE EDIR.COM FILE FROM THIS SOURCE USE ASM.COM AND LOAD.COM
  19. ; LIKE SO:
  20. ;
  21. ;     A>ASM EDIR
  22. ;     A>LOAD EDIR
  23. ;
  24. ; 
  25.  
  26. ORG 0100H
  27.  
  28. JMP START
  29.  
  30. MESSAGE:
  31. DB 0DH,0AH
  32. DB 'EDIR v1.0 (C) 1987 by Robert Greenlee, P.O. Box 23286,',0DH,0AH
  33. DB 'San Diego CA 92123. 619-268-0112 Voice, Modem 619-569-8613.',0DH,0AH
  34. DB 'Please send for free CP/M & MSDOS product listings.',0DH,0AH
  35. DB 0DH,0AH
  36. DB 'You are now logged into the mystical Erased File Directory.',0DH,0AH
  37. DB 'While in this directory the ERA command will unerase files.',0DH,0AH
  38. DB 'To see which files are erased on this disk you can use DIR.',0DH,0AH
  39. DB 'You may also use the TYPE command to view the erased files.',0DH,0AH
  40. DB 'From here REN can change duplicate filenames one at a time.',0DH,0AH
  41. DB 'Refer to EDIR.DOC for more information.',0DH,0AH
  42. DB 0DH,0AH
  43. DB 'On most computers you can usually exit back to normal space',0DH,0AH  
  44. DB 'by typing Control-C to cause a Warm Boot.  Good luck.',0DH,0AH
  45. DB '$'
  46.  
  47. SAYOOPS:
  48. DB 0DH,0AH
  49. DB 'Oh darn nothing happened!  It seems you''re not using the real',0DH,0AH
  50. DB 'CP/M 2.2 BDOS which EDIR v1.0 needs in order for it to work.',0DH,0AH
  51. DB '$'
  52.  
  53. START:
  54. LHLD 1          ;GET START OF BIOS (EG.'S BELOW ASSUME EA00)
  55. DCR H           ;GO DOWN INTO BDOS
  56. DCR H
  57. MVI L,7FH       ;POINT TO CP/M 2.2 VERSION NUMBER, 22H (EG. E87F)
  58. MVI A,22H
  59. CMP M
  60.  
  61. MVI C,9        ;IF NOT CP/M 2.2 BDOS THEN SAY SO AND ABORT.
  62. LXI D,SAYOOPS
  63. JNZ 5
  64.  
  65. ; NOW UPDATE CODE LISTS BELOW WITH REAL MSB OF BDOS MEMORY LOCATIONS 
  66. MOV A,H
  67. STA LIST2A      ;EG. E8
  68. SUI 4
  69. STA LIST1A      ;EG. E4
  70. DCR A
  71.  
  72. ;;;STA LIST1B   ;EG. E3.  DON'T INCLUDE THIS IF YOU WANT TO BE 
  73.         ;           ABLE TO unERA AMBIGUOUS FILENAMES (LIKE ERA *.*).
  74.  
  75. STA LIST1D
  76. SUI 2           ;EG. E1 
  77. PUSH PSW
  78. SUI 2           ;EG. DF
  79. STA LIST1C      ;MSB OF ADDR OF USERNO IN BDOS
  80. ;
  81. MVI L,59H       ;EG. HL=E859    
  82. LXI D,LIST1
  83. MVI B,LIST2-LIST1
  84. CALL BMOVEL
  85.  
  86. POP PSW
  87. MOV H,A
  88. MVI L,48H       ;EG. HL=E148    
  89. ;;;LXI D,LIST2    ;DON'T NEED THIS SINCE DE ALREADY POINTS TO LIST2
  90. MVI B,LIST3-LIST2
  91.  
  92. CALL BMOVEL
  93.  
  94. MVI C,9
  95. LXI D,MESSAGE
  96. JMP 5        ;DISPLAY SIGNON MESSAGE AND RETURN TO CCP
  97.  
  98.  
  99. BMOVEL:
  100. LDAX D
  101. MOV M,A
  102. INX D
  103. INX H
  104. DCR B
  105. JNZ BMOVEL
  106. RET
  107.  
  108.  
  109.  
  110. ;ROUTINE IN LIST1 REPLACES AUTOSEL ROUTINE 
  111. ;EG. E859
  112. LIST1:
  113. MVI M,0E5H      ;SET USERS FCB BYTE 0 TO E5H FOR ERASED FILES ONLY
  114.  
  115. DB 3AH          ;LDA USERNO (GET CURRENT USER NUMBER INTO A).
  116. DB 41H
  117. LIST1C: DB 0    ;EG. DF41
  118.  
  119. DB 32H          ;STA.  MAKES ERA ROUTINE USE CUR. USER NUMBER INSTEAD OF E5.
  120. DB 0AFH         
  121. LIST1D: DB 0    ;EG. E3AF 
  122.  
  123. ;;
  124. ;RESET THE "JUST ONE FILE PLEASE" TRICK IN ERA/REN ROUTINES 
  125. MVI A,0C8H
  126. DB 01H          ;OPCODE FOR LXI B
  127.  
  128. ;IF ENTRY IS MADE AT POKEC9 THEN "JUST ONE" TRICK GOES INTO EFFECT 
  129. POKEC9:
  130. MVI A,0C9H
  131.  
  132. POKEC:
  133. DB 32H
  134. DB 2AH          ;CAUSES RENAME COMMAND TO STOP AFTER ONE FILE 
  135. LIST1A: DB 0    ;EG. E42A
  136.  
  137. ;;;DB 32H    ;CAUSES ERA COMMAND TO STOP AFTER ONE FILE
  138. ;;;DB 0A7H    ; WHICH ALSO MEANS NO ERA *.* ETC. ALLOWED. 
  139. ;;;LIST1B: DB 0 ;EG. E3A7
  140. RET
  141.  
  142. ;;;
  143.  
  144. ;ROUTINE IN LIST2 REPLACES "CHECK FOR READ ONLY FILE ROUTINE" 
  145. ; WHICH IS CALLED BEFORE DIRECTORY WRITE TAKES PLACE
  146. ;EG. E148
  147. LIST2:
  148. DB 0FH          ;LOOK AT 16TH BYTE IN DIRECTORY
  149. DB 0
  150. DAD D
  151. MOV A,M
  152. DCR A           ;DECREMENT IT (IF E5H IT WILL GO TO E4H)
  153. RPE             ;RETURNS ONLY IF ACCUMULATOR WAS 80H PRIOR TO DCR A
  154.  
  155. ;IF ACC WAS E5H THEN THAT'S THE END OF DIRECTORY 
  156. ;IF ACC WAS NOT E5H OR 80H THEN ALLOW THIS DIRECTORY
  157. ; ENTRY TO BE RENAMED/UNERASED BUT CAUSE THIS TO BE THE LAST
  158. ; DIRECTORY ENTRY FOR THIS FILE BY POKING RETURN OPCODES INTO 
  159. ; REN AND ERA ROUTINES USING OUR POKEC9 ROUTINE 
  160. CPI 0E5H-1
  161. DB 0C2H         ;OPCODE FOR JNZ (JUMPS IF NEITHER 80H OR E5H) 
  162. DB POKEC9-LIST1+59H
  163. LIST2A: DB 0    ;EG. E864
  164.  
  165. ;OK IT WAS E5H SO PREVENT ANYTHING FROM HAPPENING TO THIS DIRECTORY
  166. ; ENTRY BY TERMINATING ERA/REN ROUTINES NOW.
  167. POP PSW         ;TAKE RETURN OFF STACK AND TERMINATE ERA/REN ROUTINE
  168.         ; (ACTUALLY ONLY ERA COULD EVER BE TERMINATED SINCE
  169.         ;  REN DOESN'T ACCEPT AMBIGUOUS FILENAMES).
  170. RET
  171.  
  172. LIST3 EQU $
  173.  
  174.  
  175.  END
  176.  
  177.