home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / enterprs / cpm / terms / qtpatch.arc / QT-JOYCE.ASM < prev    next >
Assembly Source File  |  1989-09-08  |  4KB  |  179 lines
  1. ; This is a patch for QTERM and the Joyce/PCW8256 with serial
  2. ; interface CPS8256.  It is developed out of other patches and by digging
  3. ; into the OS routines, since I don't have the proper documentation. As
  4. ; far as I know this information isn't available at bookstores etc.
  5. ; I even had to guess the right SIO and timer type...
  6. ; 
  7. ; It seems to work fine, altough I can't promise it will work on every
  8. ; Joyce with every configuration. The only problem is that the the
  9. ; program and/or the computer are a bit too slow for speeds above 1200
  10. ; baud. After a clear-screen the emulator misses some characters, and
  11. ; sometimes after a return it misses one character.  On Unix systems this
  12. ; is no problem, since pading can be properly specified. But on a lot of
  13. ; systems padding is unknown, so if someone knows the answer to this
  14. ; problems I'd like to hear. Also if there are bugs, missing features
  15. ; or other terrible shortcommings please contact me.
  16. ;
  17. ; Greetings, Otto Moerbeek
  18.  
  19. TRUE    equ 0ffh
  20. FALSE    equ 0
  21. ESC    equ '['-40h
  22. scrout    equ 109h    ; Address of routine to put a char on screen
  23. siod    equ 0e0h    ; Data port
  24. sioc    equ port+1    ; Control port
  25. siobs    equ 0e4h    ; Send baudrate port
  26. siobr    equ siobs+1    ; Receive baudrate port
  27. siot    equ 0e7h    ; Timer port
  28.  
  29. modist    org 110h    ; Check input status
  30.     in sioc
  31.     ani 1        ; Bit 0 is 'char available' bit
  32.     ret
  33. modin    org 120h    ; Get char
  34.     in siod
  35.     ret
  36. modost    org 130h    ; Check output status
  37.     in sioc
  38.     ani 4        ; Bit 2 is 'ready to send' bit
  39.     ret
  40. modout    org 140h    ; Put char
  41.     out siod
  42.     ret
  43. sbreak    org 150h    ; Set break bit
  44.     mvi a,5        ; Break bit is controlled by register 5
  45.     out sioc
  46.     lda r5        ; Get old value
  47.     ori 10h        ; Set bit 4
  48.     out sioc
  49.     ret
  50. ebreak    org 160h    ; Restore old situation
  51.     mvi a,5
  52.     out sioc
  53.     lda r5
  54.     out sioc
  55.     ret
  56. dtroff    org 170h    ; Drop DTR
  57.     mvi a,5
  58.     out sioc
  59.     lda r5        ; Get old value
  60.     ani 7fh        ; Clear bit 7
  61.     out sioc
  62.     ret
  63. dtron    org 180h
  64.     jmp ebreak
  65. setbd    org 190h    ; Set baudrate
  66.     call compbaud    ; First get right value in bc
  67.     mov a,b        ; Low byte to send-baudrate port
  68.     out siobs
  69.     mov a,c        ; And high byte
  70.     out siobs
  71.     mov a,b        ; Same for receive-baudrate port
  72.     out siobr
  73.     mov a,c
  74.     out siobr
  75.     ret
  76.             
  77. brtab    org 1a0h     ; offsets into table
  78.     db 0,FALSE,0,FALSE,0,TRUE,2,TRUE,4,TRUE,6,TRUE,8,TRUE,10,TRUE
  79. setmod    org 1b0h
  80.     jmp domod
  81. r5      db 0aah        ; Save value for reg 5
  82. modtab    org 1c0h
  83.     db 00h,0c0h,08h,0c8h,03h,0c3h,0bh,0cbh,01h,0c1h,09h,0c9h
  84. xfersz    org 1cdh
  85.     db 8
  86. speed    org 1ceh
  87.     db 4
  88. escape    org 1cfh
  89.     db '\'-40h
  90. signon    org 1d0h
  91.     db 'Joyce',0
  92.  
  93. clrscr    org 1f0h
  94.     db ESC,'H',ESC,'E',0
  95. moveto    org 200h
  96.     push h
  97.     mvi c,ESC
  98.     call scrout
  99.     mvi c,'Y'
  100.     call scrout
  101.     pop h
  102.     push h
  103.     mov a,h
  104.     call poff
  105.     pop h
  106.     mov a,l
  107. poff    adi ' '
  108.     mov c,a
  109.     jmp scrout
  110. baudtab    dw 13,26,52,104,208,416 ; Here some space remained for
  111.                 ; baudrate table
  112.  
  113. tcbits    org 22fh
  114.     db 0dfh        ; We miss insert char
  115. brites    org 230h    ; Various string for screen
  116.     db ESC,'q',0
  117. dims    org 238h
  118.     db ESC,'p',0
  119. dlstr    org 240h
  120.     db ESC,'M',0
  121. ilstr    org 248h
  122.     db ESC,'L',0
  123. dcstr    org 250h
  124.     db ESC,'N',0
  125. icstr    org 258h
  126.     db 0
  127. ceol    org 260h
  128.     db ESC,'K',0
  129. ceos    org 268h
  130.     db ESC,'J',0
  131.  
  132. entry    org 270h
  133.     jmp init
  134. exit    org 273h
  135.     ret
  136. patch    org 276h
  137. init    mvi a,0        ; Reset SIO
  138.     out sioc
  139.     mvi a,18h
  140.     out sioc
  141.     mvi a,0c0h    ; Init on 8 bits, no parity and 1 stop bit
  142.     call domod
  143.     mvi a,6        ; 1200 baud
  144.     call setbd
  145.     ret
  146. compbaud        ; Compute offset into baudrate table
  147.     mov e,a
  148.     mvi a,36h    ; But first init timer
  149.     out siot
  150.     lxi h,baudtab
  151.     mvi d,0
  152.     dad d
  153.     mov b,m        ; Move offset to bc
  154.     inx h
  155.     mov c,m
  156.     ret
  157.  
  158. domod    mov c,a        ; Do mode change, save code in c
  159.     mvi a,3        ; Firts reg 3
  160.     out sioc
  161.     mov a,c        ; Retrieve code
  162.     ani 80h        ; Only bit for receive bits/char
  163.     ori 41h        ; Rest stays 41h
  164.     out sioc
  165.     mvi a,4        ; Now reg 4
  166.     out sioc
  167.     mov a,c        ; Retrieve code
  168.     ani 0bh        ; We only wants bits 0,1 and 3 to be
  169.     ori 44h        ; changed, rest stays 44h
  170.     out sioc
  171.     mvi a,5        ; Reg 5
  172.     out sioc
  173.     mov a,c        ; Restrieve code
  174.     ani 40h        ; Only send bits/char
  175.     ori 0aah    ; Rest of bits stay 0aah
  176.     sta r5        ; Store value for break and DTR routines
  177.     out sioc
  178.     ret
  179.