home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug003.ark / CHASE.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  2.5 KB  |  110 lines
  1. 10 PRINT "THIS IS THE GAME OF CHASE"
  2. 60 PRINT "WANT INSTRUCTIONS";
  3. 70 INPUT C$
  4. 75 RANDOMIZE
  5. 80 IF LEFT$(C$,1)="N" THEN 200
  6. 90 IF LEFT$(C$,1)<>"Y" THEN 60
  7. 100 PRINT "YOU ARE '*' IN A HIGH VOLTAGE MAZE WITH 5"
  8. 110 PRINT "SECURITY MACHINES '+' TRYING TO DESTROY YOU"
  9. 120 PRINT "YOU MUST MANEUVER THE SECURITY MACHINES INTO"
  10. 130 PRINT "THE MAZE 'X' TO SURVIVE.  GOOD LUCK !!!"
  11. 140 PRINT "MOVES ARE 7,8,9"
  12. 150 PRINT "          4,5,6"
  13. 160 PRINT "          1,2,3   0 TO END THE GAME"
  14. 170 PRINT
  15. 200 DIM A(10,20),E(21),F(21)
  16. 210 LET G=0
  17. 220 FOR B=1 TO 10
  18. 230 FOR C=1 TO 20
  19. 240 LET A(B,C)=0
  20. 250 IF B=1 THEN 285
  21. 260 IF B=10 THEN 285
  22. 270 IF C=1 THEN 285
  23. 280 IF C=20 THEN 285
  24. 283 GOTO 290
  25. 285 LET A(B,C)=1
  26. 290 NEXT C
  27. 300 NEXT B
  28. 310 FOR D=1 TO 21
  29. 320 LET B=INT(RND*8)+2
  30. 330 LET C=INT(RND*18)+2
  31. 340 IF A(B,C)<>0 THEN 320
  32. 350 LET A(B,C)=1
  33. 360 IF D<6 THEN 365
  34. 363 GOTO 370
  35. 365 LET A(B,C)=2
  36. 370 IF D=6 THEN 375
  37. 373 GOTO 380
  38. 375 LET A(B,C)=3
  39. 380 LET E(D)=B
  40. 390 LET F(D)=C
  41. 400 NEXT D
  42. 500 FOR B=1 TO 10
  43. 510 FOR C=1 TO 20
  44. 520 IF A(B,C)<>0 THEN 530
  45. 523 PRINT " ";
  46. 525 GOTO 560
  47. 530 IF A(B,C)<>1 THEN 540
  48. 533 PRINT "X";
  49. 535 GOTO 560
  50. 540 IF A(B,C)<>2 THEN 550
  51. 543 PRINT "+";
  52. 545 GOTO 560
  53. 550 IF A(B,C)<>3 THEN 560
  54. 555 PRINT "*";
  55. 560 NEXT C
  56. 570 PRINT
  57. 580 NEXT B
  58. 600 LET B=E(6)
  59. 610 LET C=F(6)
  60. 620 LET A(B,C)=0
  61. 630 INPUT Y
  62. 640 ON Y+1 GOTO 1400,680,680,680,690,800,690,660,660,660
  63. 660 LET B=B-1
  64. 670 GOTO 690
  65. 680 LET B=B+1
  66. 690 ON Y GOTO 700,800,720,700,800,720,700,800,720
  67. 700 LET C=C-1
  68. 710 GOTO 800
  69. 720 LET C=C+1
  70. 800 IF A(B,C)=1 THEN 1500
  71. 810 IF A(B,C)=2 THEN 1600
  72. 820 LET A(B,C)=3
  73. 830 LET E(6)=B
  74. 840 LET F(6)=C
  75. 850 FOR D=1 TO 5
  76. 860 IF A(E(D),F(D))<>2 THEN 960
  77. 870 LET A(E(D),F(D))=0
  78. 880 IF E(D)>=B THEN 890
  79. 883 LET E(D)=E(D)+1
  80. 885 GOTO 900
  81. 890 IF E(D)=B THEN 900
  82. 895 LET E(D)=E(D)-1
  83. 900 IF F(D)>=C THEN 910
  84. 903 LET F(D)=F(D)+1
  85. 905 GOTO 920
  86. 910 IF F(D)=C THEN 920
  87. 915 LET F(D)=F(D)-1
  88. 920 IF A(E(D),F(D))=3 THEN 1600
  89. 930 IF A(E(D),F(D))=0 THEN 940
  90. 933 LET G=G+1
  91. 935 GOTO 950
  92. 940 LET A(E(D),F(D))=2
  93. 950 IF G=5 THEN 1700
  94. 960 NEXT D
  95. 970 GOTO 500
  96. 1400 PRINT "SORRY TO SEE YOU QUIT"
  97. 1410 GOTO 1710
  98. 1500 PRINT "ZAP!!! YOU TOUCHED THE FENCE !!!!!"
  99. 1510 GOTO 1710
  100. 1600 PRINT "** YOU HAVE BEEN DESTROYED BY A LUCKY COMPUTER **"
  101. 1610 GOTO 1710
  102. 1700 PRINT "YOU ARE LUCKY **YOU DESTROYED ALL THE ENEMY**"
  103. 1710 PRINT "WANT TO PLAY AGAIN";
  104. 1720 INPUT C$
  105. 1730 IF LEFT$(C$,1)="Y" THEN 210
  106. 1735 IF LEFT$(C$,1)<>"N" THEN 1710
  107. 1740 PRINT "HOPE YOU DON'T FEEL FENCED IN."
  108. 1750 PRINT "TRY AGAIN SOMETIME"
  109. 2000 END
  110.