home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug003.ark / LOAN.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  2.5 KB  |  89 lines
  1. REM   LOAN AMORTIZATION PROGRAM
  2. REM   WRITTEN BY BOB SIMPSON , CARDIFF CA. 
  3. PRINT "* * * * LOAN AMORTIZATION PROGRAM * * * * "
  4. PRINT
  5. PRINT "TO USE THIS PROGRAM, ENTER THE LOAN DATA AS EACH FACTOR"
  6. PRINT "IS REQUESTED. THE COMPUTER WILL REPEAT THE PERTINANT"
  7. PRINT "INFORMATION AND GIVE THE PERIODIC PAYMENT.  YOU WILL THEN BE ASKED"
  8. PRINT "IF YOU WANT THE PAYMENT SCHEDULE.  A 'Y' ANSWER WILL PRINT THE FULL"
  9. PRINT "TABULATION, PAYMENT BY PAYMENT WITH ALL PERIODIC AND CUMULATIVE TOTALS"
  10. PRINT
  11. PRINT "YOU WILL THEN BE GIVEN A CHANCE TO MODIFY PARAMETERS.  IF YOU WANT"
  12. PRINT "TO RECALCULATE A LOAN CHANGING ONLY THE INTEREST RATE, TYPE"
  13. PRINT "'I'.  AFTER ENTERING THE NEW INTEREST RATE, ANSWER 'C' TO CONTINUE."
  14. PRINT "IF OTHER PARAMETERS NEED CHANGING, SPECIFY THEM BEFORE THE 'C'."
  15. PRINT "IF 'N' IS ANSWERED TO THE 'CHANGE PARAMETERS?' PROMPT, THE PROGRAM"
  16. PRINT "WILL START FROM THE BEGINNING."
  17. PRINT
  18. PRINT
  19. REM
  20. 10 GOSUB 700
  21. 20 GOSUB 750
  22. 28 GOSUB 800
  23. 30 GOSUB 850
  24. 40 D=N*Y
  25. 50 R=R1/(100*N)
  26. 52 IF R<>0 THEN 60
  27. 55 A1=P/D
  28. 57 GOTO 70
  29. 60 A1=(R/(1-(1+R)^(-D)))*P
  30. 70 A=INT(A1*100+.5)/100
  31. 100 PRINT "PAYMENT IS $";A;","; N;"TIMES PER YEAR FOR ";Y;"YEARS"
  32. 110 PRINT "FOR A LOAN OF $";P;"AT ";R1;"% INTEREST"
  33. 120 PRINT
  34. 130 PRINT "PAYMENT SCHEDULE";
  35. 140 INPUT Q$
  36. 150 IF Q$="Y" THEN 900
  37. 160 PRINT
  38. 200 PRINT "CHANGE PARAMETER  N(O), I(NT), Y(EARS), P(AYMENTS), L(OAN), OR C(ONTINUE)"
  39. 210 INPUT Q$
  40. 220 IF Q$="N" THEN 10
  41. 270 IF Q$="I" THEN 350
  42. 280 IF Q$="P" THEN 400
  43. 290 IF Q$="Y" THEN 500
  44. 300 IF Q$="L" THEN 600
  45. 310 GOTO 40
  46. 350 GOSUB 700
  47. 360 GOTO 200
  48. 400 GOSUB 750
  49. 410 GOTO 200
  50. 500 GOSUB 800
  51. 510 GOTO 200
  52. 600 GOSUB 850
  53. 610 GOTO 200
  54. 700 PRINT "INTEREST RATE IN %";
  55. 710 INPUT R1
  56. 730 RETURN
  57. 750 PRINT "NUMBER OF PAYMENTS PER YEAR";
  58. 760 INPUT N
  59. 770 RETURN
  60. 800 PRINT "HOW MANY YEARS";
  61. 810 INPUT Y
  62. 820 RETURN
  63. 850 PRINT "LOAN IN $";
  64. 860 INPUT P
  65. 870 RETURN
  66. 900 B=P
  67. 905 P1=0:P2=0
  68. 906 I1=0:I2=0
  69. 907 PRINT "PMNT   YR  PER    PMNT       TOTAL    PMNT       TOTAL";
  70. 908 PRINT "     BAL"
  71. 909 PRINT " NO.";TAB(19);"INT         INT     PRIN       PRIN      DUE"
  72. 910 PRINT "-----------------------------------------------------------";
  73. 911 PRINT "------"
  74. 913 FOR T=1 TO D
  75. 914 IF T=0 THEN 940
  76. 915 I1=INT(R*B*100+.5)/100
  77. 920 I2=I2+I1
  78. 925 P1=A-I1
  79. 930 P2=P2+P1
  80. 935 B=B-P1
  81. 940 Y1=INT(T/N)
  82. 945 T1=T-Y1*N
  83. 950 PRINT T;TAB(8);Y1;TAB(13);T1;TAB(19);I1;TAB(29);I2;TAB(39);P1;
  84. 953 PRINT TAB(49);P2;TAB(59);B
  85. 955 NEXT T
  86. 956 PRINT "PAYMENTS TOTAL $";D*A
  87. 960 GOTO 160
  88. 999 END
  89.