home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug013.ark / ROCKET.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  3.1 KB  |  85 lines
  1. 5 FOR I = 1 TO 10:PRINT:NEXT I
  2. 10 PRINT TAB(18);"ROCKET 1 03:30 PM      4 MAY 1976 "
  3. 70 PRINT TAB(18);"    LUNAR LANDING SIMULATION "
  4. 80 PRINT TAB(18);"    ----- ------- ---------- "
  5. 85 FOR I = 1 TO 10:PRINT:NEXT I
  6. 100 INPUT "DO YOU WANT INSTRUCTIONS (YES OR NO) ";A$
  7. 105 IF LEFT$(A$,1)="Y" THEN 120
  8. 110 IF LEFT$(A$,1)="N" THEN 390
  9. 115 PRINT "YES OR NO":GOTO 100
  10. 120 GOSUB 160
  11. 130 INPUT "DO YOU UNDERSTAND THE INSTRUCTIONS ";A$
  12. 140 IF LEFT$(A$,1)="Y" THEN 390
  13. 145 IF LEFT$(A$,1)="N" THEN 120
  14. 150 PRINT "YES OR NO ":GOTO 130
  15. 160 PRINT
  16. 200 PRINT "YOU ARE LANDING ON THE MOON AND HAVE TAKEN OVER MANUAL"
  17. 210 PRINT "CONTROL 500 FEET ABOVE A GOOD LANDING SPOT. YOU HAVE A"
  18. 220 PRINT "DOWNWARD VELOCITY OF 50 FT/SEC. 120 UNITS OF FUEL REMAIN."
  19. 225 PRINT
  20. 230 PRINT "HERE ARE THE RULES THAT GOVERN YOUR SPACE VEHICLE:"
  21. 240 PRINT "(1) AFTER EACH SECOND, THE HEIGHT, VELOCITY, AND REMAINING"
  22. 250 PRINT "    FUEL WILL BE REPORTED. "
  23. 260 PRINT "(2) AFTER THE REPORT, A '?' WILL BE TYPED. ENTER THE"
  24. 270 PRINT "    NUMBER OF UNITS OF FUEL WOU WISH TO BURN DURING THE"
  25. 280 PRINT "    NEXT SECOND. EACH UNIT OF FUEL WILL SLOW YOUR DESCENT"
  26. 290 PRINT "    BY 1 FT/SEC. "
  27. 310 PRINT "(3) THE MAXIMUM THRUST OF YOUR ENGINE IS 30 FT/SEC/SEC OR"
  28. 320 PRINT "    30 UNITS OF FUEL PER SECOND. "
  29. 330 PRINT "(4) WHEN YOU CONTACT THE LUNAR SURFACE, YOUR DESENT ENGINE"
  30. 340 PRINT "    WILL AUTOMATICALLY CUT OFF AND YOU WILL BE GIVEN A "
  31. 350 PRINT "    REPORT OF YOUR LANDING SPEED AND REMAINING FUEL."
  32. 360 PRINT "(5) IF YOU RUN OUT OF FUEL, THE '?' WILL NO LONGER APPEAR,"
  33. 370 PRINT "    BUT YOUR SECOND BY SECOND REPORT WILL CONTINUE UNTIL"
  34. 380 PRINT "    YOU CONTACT THE LUNAR SURFACE ":PRINT
  35. 385 RETURN
  36. 390 PRINT "BEGINNING LANDING PROCEDURE.....":PRINT
  37. 410 PRINT "G O O D  L U C K ! ! ! !"
  38. 420 PRINT:PRINT
  39. 440 PRINT "SEC  FEET   SPEED    FUEL     PLOT OF DISTANCE"
  40. 450 PRINT
  41. 455 T=0:H=500:V=50:F=120
  42. 490 PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(29);"I";TAB(H/12+29);"*"
  43. 500 INPUT "UNITS OF FUEL TO USE ";B
  44. 510 IF B<0 THEN 650
  45. 520 IF B>30 THEN 525
  46. 524 GOTO 530
  47. 525 PRINT "MAXIMUM FUEL USAGE IS 30":GOTO 500
  48. 530 IF B>F THEN B=F
  49. 540 V1=V-B+5
  50. 560 F=F-B
  51. 570 H=H-.5*(V+V1)
  52. 580 IF H<=0 THEN 670
  53. 590 T=T+1
  54. 600 V=V1
  55. 610 IF F>0 THEN 490
  56. 615 IF B=0 THEN 640
  57. 620 PRINT "*** OUT OF FUEL ***"
  58. 640 PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(29);"I";TAB(H/12+29);"*"
  59. 650 B=0
  60. 660 GOTO 540
  61. 670 PRINT "*** CONTACT ***"
  62. 680 H=H+.5*(V+V1)
  63. 690 IF B=5 THEN 720
  64. 700 D=(-V+SQR(V*V+H*(10-2*B)))/(5-B)
  65. 710 GOTO 730
  66. 720 D=H/V
  67. 730 V1=V+(5-B)*D
  68. 760 PRINT "TOUCHDOWN AT ";T+D;"SECONDS."
  69. 770 PRINT "LANDING VELOCITY = ";V1;"FT/SEC"
  70. 780 PRINT F;"UNITS OF FUEL REMAINING."
  71. 790 IF V1<>0 THEN 810
  72. 800 PRINT "CONGRATULATIONS!!   A PERFECT LANDING!"
  73. 805 PRINT "YOUR LICENSE WILL BE RENEWED ........LATER "
  74. 810 IF ABS(V1)<2 THEN 840
  75. 820 PRINT "***** SORRY, BUT YOU BLEW IT !!!!!*****"
  76. 830 PRINT "APPROPRIATE CONDOLENCES WILL BE SENT TO YOU NEXT OF KIN."
  77. 840 PRINT:PRINT:PRINT
  78. 850 INPUT "ANOTHER MISSION";A$
  79. 870 IF LEFT$(A$,1)="N" THEN 880
  80. 875 IF LEFT$(A$,1)="Y" THEN 390
  81. 876 PRINT "YES OR NO":GOTO 850
  82. 880 PRINT:PRINT "CONTROL OUT.":PRINT
  83. 999 END
  84.  
  85.