home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug018.ark / FLTARITH.ASM < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  38.4 KB  |  1,313 lines
  1. ; 8008 BINARY FLOATING POINT SYSTEM
  2. ; 
  3. ; THE 8008 BINARY FLOATING POINT SYSTEM CONSISTS OF A 
  4. ; SET OF SUBROUTINES DESIGNED TO PERFORM  ARITHMETIC
  5. ; OPERATIONS ON NUMERIC QUANTITIES REPRESENTED IN
  6. ; MEMORY.
  7. ; 
  8. ; EACH NUMERIC QUANTITY OCCUPIES FOUR CONSECUTIVE WORDS
  9. ; (32 BITS) OF MEMORY.  THE LARGEST MAGNITUDE THAT CAN
  10. ; BE REPRESENTED IS APPROXIMATELY 3.6 TIMES TEN TO THE
  11. ; 38TH POWER.  THE SMALLEST NON-ZERO MAGNITUDE THAT
  12. ; CAN BE REPRESENTED IS APPROXIMATELY 2.7 TIMES TEN TO 
  13. ; THE MINUS 39TH POWER.  EACH NUMERIC QUANTITY IS
  14. ; REPRESENTED WITH A PRECISION OF ONE PART IN
  15. ; APPROXIMATELY  16,00Q,00Q.
  16. ; 
  17. ; THE SOFTWARE CONSTITUTING THE  FLOATING POINT SYSTEM
  18. ; IS DIVIDED INTO TWO SECTIONS, EACH OF WHICH OCCUPIES
  19. ; 3 BANKS OF ROM OR RAM.  SECTION 1 IS INDEPENDENT OF 
  20. ; OTHER SOFTWARE.  SECTION 2 IS OPERABLE ONLY WHEN 
  21. ; SECTION 1 IS AVAILABLE IN MEMORY.  IN ADDITION TO
  22. ; MEMORY FOR PROGRAM, 63 WORDS OF RAM ARE USED AS SCRATCHPAD.
  23. ; 
  24. ; SOFTWARE SECTION 1 CONTAINS  THE FOLLOWING SUBROUTINES:
  25. ;     LOD - LOAD SPECIFIED DATA INTO THE FLOATING POINT
  26. ;           ACCUMULATOR.
  27. ;     ADD - ADD SPECIFIED DATA TO THE FLOATING POINT 
  28. ;           ACCUMULATOR.
  29. ;     SUB - SUBTRACT SPECIFIED DATA FROM THE FLOATING
  30. ;           POINT ACCUMULATOR.
  31. ;     MUL - MULTIPLY THE FLOATING POINT ACCUMULATOR
  32. ;           BY THE SPECIFIED DATA.
  33. ;     DIV - DIVIDE THE FLOATING POINT ACCUMULATOR
  34. ;           BY THE SPECIFIED DATA
  35. ;     TST - SET CONTROL BITS TO INDICATE ATTRIBUTES
  36. ;           OF THE CONTENTS OF THE FLOATING POINT ACCUMULATOR
  37. ;     CHS - CHANGE THE SIGN OF THE FLOATING POINT ACCUMULATOR.
  38. ;     ABS - SET THE SIGN OF THE FLOATING POINT ACCUMULATOR
  39. ;           POSITIVE.
  40. ;     STR - STORE IN SPECIFIED MEMORY THE VALUE IN THE 
  41. ;           REGISTERS AS RETURNED BY OTHER SUBROUTINES.
  42. ;     INIT - MOVE CODE FROM ROM TO RAM IN PREPARATION
  43. ;            FOR EXECUTION OF THE MUL AND DIV SUBROUTINES.
  44. ; 
  45. ; SOFTWARE SECTION 2 CONTAINS SUBROUTINES WHICH ARE
  46. ; USED TO CONVERT DATA BETWEEN THE BINARY  FLOATING
  47. ; POINT FORMAT AND A DECIMAL FORMAT SUITABLE FOR
  48. ; ENTRY OR DISPLAY IN INPUT/OUTPUT EQUIPMENT.  THE
  49. ; DECIMAL FORMAT IS STORED IN MEMORY AS A SERIES
  50. ; OF CHARACTERS.  RELATIVELY SIMPLE INPUT/OUTPUT
  51. ; ROUTINES MAY BE USED TO INTERFACE THE MEMORY-
  52. ; RESIDENT CHARACTER STRINGS WITH ANY TYPE OF PHYSICAL
  53. ; I/O DEVICE.  THE CONVERSION ROUTINES ARE MORE FULLY
  54. ; EXPLAINED IN TEXT IMMEDIATELY PRECEEDING THE ROUTINES.
  55. ; 
  56. ; THE 8008  BINARY FLOATING POINT SYSTEM CONSISTS OF A SET
  57. ; OF SUBROUTINES DESIGNED TO PERFORM OPERATIONS ON NUMERIC
  58. ; QUANTITIES REPRESENTED IN A SPECIFIC NOTATION.  SUBROUTINES
  59. ; ARE PROVIDED TO PERFORM A VARIETY OF ARITHMETIC AND RELATED
  60. ; OPERATIONS.
  61. ; 
  62. ; THE SUBROUTINES ARE DESIGNED TO BE STORED AND EXECUTED IN
  63. ; READ-ONLY-MEMORY (ROM) AND REQUIRE THE FIRST PORTION OF A
  64. ; BANK OF READ-WRITE MEMORY (RAM, FROM 'RANDOM ACCESS MEMORY')
  65. ; FOR SCRATCHPAD MEMORY.   THE SUBROUTINES ARE SEPARATED INTO
  66. ; A NUMBER OF PACKAGES, EACH CONTAINING SUBROUTINES FOR A GROUP
  67. ; OF RELATED OPERATIONS.  THE AMOUNT OF MEMORY (ROM AND RAM)
  68. ; REQUIRED FOR INSTALLATION OF THE SYSTEM IS DEPENDENT UPON
  69. ; THE COMBINATION OF PACKAGES TO BE USED.  SCRATCHPAD MEMORY
  70. ; IS INITIALIZED BY A UTILITY SUBROUTINE WHICH MUST BE EXECUTED
  71. ; BEFORE OTHER SUBROUTINES ARE EXECUTED THE FIRST TIME.
  72. ; 
  73. ; IN GENERAL, THE SUBROUTINES HAVE SIMILAR ENTRY AND EXIT
  74. ; CONDITIONS.  UNLESS SPECIFIED DIFFERENTLY IN THE DESCRIPTION
  75. ; OF A SUBROUTINE, THE SUBROUTINES HAVE THE FOLLOWING CHARACTERISTICS.
  76. ; 
  77. ; SUBROUTINES REQUIRING ONE OPERAND TAKE IT FROM AN INTERNAL
  78. ; FLOATING POINT ACCUMULATOR.  SUBROUTINES REQUIRING TWO OPERANDS
  79. ; TAKE ONE FROM THE ACCUMULATOR AND THE OTHER FROM THE MEMORY
  80. ; LOCATION INDICATED BY THE CONTENTS OF THE H AND L REGISTERS
  81. ; UPON ENTRY.  THE NUMERIC RESULT OF EACH OPERATION IS STORED
  82. ; IN THE ACCUMULATOR AND IS RETURNED TO THE CALLING ROUTINE
  83. ; IN THE A, B, C, AND D REGISTERS.
  84. ; 
  85. ; UPON EXIT FROM THE ARITHMETIC SUBROUTINES, THE PROPERTIES
  86. ; OF THE RESULT ARE INDICATED BY THE SETTINGS OF THE CONTROL
  87. ; BITS.
  88. ;      CARRY BIT = 1   THE RESULT EXCEEDS THE CAPACITY OF THE 
  89. ;                      ACCUMULATOR.  THE OTHER CONTROL BITS, THE
  90. ;                      CONTENTS OF THE HARDWARE REGISTERS, AND
  91. ;                      THE CONTENTS OF THE ACCUMULATOR ARE
  92. ;                      MEANINGLESS.  THIS SITUATION IS ALSO
  93. ;                      INDICATED BY A NON-ZERO QUANTITY BEING
  94. ;                      STORED IN A FLAG WORD.
  95. ;      CARRY BIT = 0   THE RESULT IS IN RANGE.  THE ZERO AND 
  96. ;                      SIGN BITS ARE PROPERLY SET, AND THE A, B,
  97. ;                      C, AND D REGISTERS CONTAIN THE FOUR PARTS
  98. ;                      OF THE ACCUMULATOR.
  99. ;      ZERO BIT = 1    THE RESULT OF THE OPERATION IS ZERO OR
  100. ;                      A QUANTITY TOO SMALL TO BE REPRESENTED.
  101. ;      ZERO BIT = 0    THE RESULT IS NON-ZERO.
  102. ;      SIGN BIT = 1    THE RESULT IS NEGATIVE.
  103. ;      SIGN BIT = 0    THE RESULT IS POSITIVE.
  104. ; DATA ARE REPRESENTED IN A NOTATION WHICH RECORDS EIGHT BITS
  105. ; OF EXPONENT, ONE BIT OF SIGN, AND TWENTY-FOUR BITS OF FRACTION.
  106. ; THE LARGEST MAGNITUDE THAT CAN BE REPRESENTED IS APPROXIMATELY
  107. ; 3.6 * 10 ** 38.  THE SMALLEST NON-ZERO MAGNITUDE IS 
  108. ; APPROXIMATELY 2.7 * 10 ** -39.  THE RESOLUTION OF THE NOTATION
  109. ; IS APPROXIMATELY 6.2 * 10 ** -8; I.E., BETTER THAN SEVEN 
  110. ; DECIMAL DIGIT PRECISION.
  111. ; 
  112. ; DATA VALUES ARE REPRESENTED IN FOUR CONSECUTIVE MEMORY WORDS
  113. ; WHICH MUST BE IN THE SAME BANK OF MEMORY.  THE INTERPRETATION
  114. ; OF THESE WORDS IS SHOWN BELOW.
  115. ;      WORD 1           IF NON-ZERO, THIS WORD CONTAINS THE
  116. ;                       EXPONENT PLUS A BIAS OF 200 OCTAL.  THE
  117. ;                       EXPONENT INDICATES THE POWER OF 2 BY
  118. ;                       WHICH THE FRACTION IS TO BE MULTIPLIED TO
  119. ;                       OBTAIN THE REPRESENTED VALUE.  IF THIS
  120. ;                       WORD IS ZERO, THE REPRESENTED VALUE IS ZERO
  121. ;                       AND WORDS 2, 3, AND 4 ARE MEANINGLESS.
  122. ;      WORD 2, BIT 7    THIS BIT INDICATES THE SIGN OF THE VALUE:
  123. ;                       0 IF POSITIVE, 1 IF NEGATIVE.
  124. ;      WORD 2, BITS 6-0 THESE BITS PLUS AN ASSUMED 1 IN BIT 7 POSITION
  125. ;                       ARE THE MOST SIGNIFICANT BITS OF THE FRACTION.
  126. ;                       THE FRACTION IS STORED IN ABSOLUTE FORM 
  127. ;                       (UNSIGNED) WITH THE RADIX POINT POSITIONED TO
  128. ;                       THE LEFT OF BIT 7.  THE VALUE OF THE FRACTION
  129. ;                       IS THUS LESS  1.0 AND EQUAL TO OR GREATER THAN
  130. ;                       THAN 0.5.
  131. ;      WORD 3           THIS WORD CONTAINS THE SECOND MOST SIGNIFICANT
  132. ;                       EIGHT BITS OF THE FRACTION.
  133. ;      WORD 4           THIS WORD CONTAINS THE EIGHT LEAST SIGNIFICANT
  134. ;                       BITS OF THE FRACTION.
  135. ; 
  136. ;                  EXAMPLES OF DATA NOTATION
  137. ;          VALUE    WORD1  WORD2  WORD3  WORD4
  138. ;           0.0      00Q    XXX    XXX    XXX     X = DON'T CARE
  139. ;          +1.0      201    00Q    00Q    00Q
  140. ;          -1.0      201    200    00Q    00Q
  141. ;          +0.1      175    114    314    314
  142. ;        -100.0      207    310    63Q    63Q
  143. ; 
  144. ; 
  145. ; FLOATING POINT ACCUMULATOR.
  146. ; 
  147. ; THE FLOATING POINT ACCUMULATOR CONSISTS OF 5 SCRATCHPAD WORDS
  148. ; CONTAINING RESPECTIVELY THE ACCUMULATOR EXPONENT, THE 
  149. ; ACCUMULATOR SIGN, AND THREE WORDS OF ACCUMULATOR FRACTION.
  150. ; THE EXPONENT IS RECORDED WITH A BIAL OF 200 OCTAL.  AN
  151. ; EXPONENT WORD OF ZERO INDICATES THAT THE VALUE IN THE 
  152. ; ACCUMULATOR IS ZERO AND THE REMAINING WORDS OF THE ACCUMULATOR
  153. ; ARE MEANINGLESS.  THE SIGN WORD HOLDS 00Q IF THE ACCUMULATOR
  154. ; IS NEGATIVE, 200 OCTAL IF POSITIVE.  THE FRACTION IS RECORDED
  155. ; AS A NORMALIZED POSITIVE VALUE WITH THE RADIX POINT TO THE 
  156. ; LEFT OF THE MOST SIGNIFICANT BIT OF THE FIRST FRACTION WORD.
  157. ; OVERFLOW FLAG
  158. ; 
  159. ; THE OVERFLOW FLAG WORD IS PROVIDED AS A CONVENIENCE TO THE 
  160. ; USER OF THE FLOATING POINT SYSTEM.  THE WORD IS INITIALLY SET
  161. ; TO ZERO AND MAY BE RESET TO ZERO BY THE USER AT ANY TIME.
  162. ; WHEN ANY OF THE SYSTEM ROUTINES DETECTS AN OVERFLOW CONDITION,
  163. ; THE OVERFLOW FLAG IS SET NON-ZERO.  THUS THE USER MAY CLEAR
  164. ; THE FLAG, PERFORM A SEQUENCE OF FLOATING POINT OPERATIONS, AND
  165. ; CHECK THE FLAG TO DETERMINE IF AN OVERFLOW OCCURRED DURING THE
  166. ; SEQUENCE.
  167. ; 
  168. ; SIGNIFICANCE INDEX.
  169. ; 
  170. ; THE FLOATING POINT ADD AND SUBTRACT SUBROUTINES RETURN A
  171. ; SIGNIFICANCE INDEX TO THE USER WHEN  THE RESULT OF THE
  172. ; OPERATION IS NOT ZERO.  THIS INDEX GIVES AN INDICATION OF THE
  173. ; CHANGE IN THE VALUE OF THE ACCUMULATOR EXPONENT AS A RESULT
  174. ; OF THE ARITHMETIC OPERATION PERFORMED.  IT IS USED PRIMARILY
  175. ; FOR COMPARISON OF TWO VALUES WHICH ARE EXPECTED TO BE EQUAL,
  176. ; BUT WHICH MAY DIFFER BY A SMALL AMOUNT DUE TO MEASUREMENT OR
  177. ; ROUND-OFF ERRORS.  AS AN EXAMPLE, A SIGNIFICANCE INDEX OF
  178. ; 354 OCTAL (-20 DECIMAL) INDICATES THAT THE RESULT OF THE
  179. ; OPERATION IS SMALLER THAN THE OPERANDS BY A FACTOR OF 
  180. ; APPROXIMATELY ONE MILLION (2 ** 20).
  181. ; THE FLOATING POINT TEST, COMPLEMENT AND ABSOLUTE SUBROUTINES
  182. ; RETURN THE SIGNIFICANCE INDEX FROM AN IMMEDIATELY PRECEEDING
  183. ; ADD OR SUBTRACT OPERATION.
  184. ; 
  185. ; 
  186. ; ARITHMETIC AND UTILITY PACKAGE
  187. ; 
  188. ; THE ARITHMETIC AND UTILITY SUBROUTINE PACKAGE OF THE 8008
  189. ; BINARY FLOATING POINT SYSTEM CONTAINS SUBROUTINES FOR
  190. ; PERFORMING THE BASIC ARITHMETIC AND UTILITY OPERATIONS 
  191. ; AVAILABLE IN THE SYSTEM.
  192. ; 
  193. ; THE ARITHMETIC AND UTILITY PACKAGE IS CONTAINED IN 768
  194. ; CONSECUTIVE WORDS OF MEMORY (3 BANKS OF ROM) AND DOES NOT
  195. ; REQUIRE THAT ANY OTHER SOFTWARE BE PRESENT IN MEMORY.  THIS
  196. ; PACKAGE USES THE FIRST 54 WORDS OF A BANK OF RAM AS
  197. ; SCRATCHPAD MEMORY.
  198. ; 
  199. ; THE INDIVIDUAL SUBROUTINES INCLUDED IN THE ARITHMETIC AND 
  200. ; UTILITY PACKAGE ARE DESCRIBED BELOW.
  201. ; 
  202. ; FLOATING POINT INITIALIZE SUBROUTINE
  203. ; 
  204. ; THE FLOATING POINT INITIALIZE SUBROUTINE MOVES A SECTION OF
  205. ; CODE FROM ROM MEMORY TO SCRATCHPAD RAM MEMORY IN PREPARATION
  206. ; FOR EXECUTION OF THE FLOATING POINT MULTIPLY AND DIVIDE
  207. ; SUBROUTINES.  THE OVERFLOW FLAG IS ALSO SET TO ZERO.
  208. ; 
  209. ;      ENTRY POINT
  210. ;             INIT
  211. ; 
  212. ;      ENTRY CONDITIONS
  213. ;             NONE
  214. ; 
  215. ;      EXIT CONDITIONS
  216. ;             SCRATCHPAD RAM INITIALIZED
  217. ; 
  218. ;      REGISTERS ALTERED
  219. ;             E, H, L
  220. ; 
  221. ;      MAXIMUM SUBROUTINE LEVELS USED
  222. ;             0
  223. ; 
  224. ; 
  225. ; STORE REGISTERS SUBROUTINE
  226. ; 
  227. ; THE STORE REGISTERS SUBROUTINE STORES  THE CONTENTS OF THE
  228. ; A,B,C,AND D  REGISTERS IN  FOUR CONSECUTIVE MEMORY LOCATIONS  
  229. ; (IN THE SAME BANK OF RAM).  THE ADDRESS WHERE THE FIRST WORD
  230. ; WILL BE STORED IS INDICATED BY THE CONTENTS OF THE H AND L
  231. ; REGISTERS.
  232. ; 
  233. ; ENTRY POINT
  234. ;     STR
  235. ; 
  236. ; ENTRY  CONDITIONS
  237. ;      A REGISTER = 1ST WORD TO BE STORED
  238. ;      B REGISTER = 2ND WORD TO BE STORED
  239. ;      C REGISTER = 3RD WORD TO BE STORED
  240. ;      D REGISTER = 4TH WORD TO BE STORED
  241. ;      H REGISTER = MS 6 BITS OF MEMORY ADDRESS
  242. ;      L REGISTER = LS 8 BITS OF MEMORY ADDRESS
  243. ; 
  244. ; EXIT  CONDITIONS
  245. ;      THE CONTENTS OF THE REGISTERS ARE STORED IN THE SPECIFIED
  246. ;      MEMORY LOCATION
  247. ; 
  248. ; REGISTERS ALTERED
  249. ;      L
  250. ; 
  251. ; MAXIMUM SUBROUTINE LEVELS USED
  252. ;      0
  253. ; 
  254. ; 
  255. ; FLOATING POINT LOAD ROUTINE
  256. ; 
  257. ; THE FLOATING POINT LOAD SUBROUTINE  PLACES THE SPECIFIED
  258. ; FLOATING  POINT  OPERAND IN THE FLOATING POINT ACCUMULATOR
  259. ; 
  260. ; ENTRY POINT 
  261. ;      LOD
  262. ; 
  263. ; ENTRY CONDITIONS
  264. ;      H REGISTER = MS 6 BITS OF OPERAND ADDRESS
  265. ;      L REGISTER = LS 8 BITS OF OPERAND ADDRESS
  266. ; 
  267. ; EXIT CONDITIONS
  268. ;      CONTROL  BITS SET AS DEFINED FOR THE SYSTEM
  269. ;      A REGISTER = ACCUMULATOR EXPONENT
  270. ;      B REGISTER = ACCUMULATOR SIGN AND 1ST FRACTION
  271. ;      C REGISTER = ACCUMULATOR 2ND FRACTION
  272. ;      D REGISTER = ACCUMULATOR 3RD FRACTION
  273. ; 
  274. ; REGISTERS ALTERED
  275. ;      ALL
  276. ; 
  277. ; MAXIMUM SUBROUTINE  LEVELS USED
  278. ;      1
  279. ; 
  280. ; 
  281. ; FLOATING POINT ADD SUBROUTINE
  282. ; 
  283. ; THE FLOATING POINT ADD SUBROUTINE ADDS  THE SPECIFIED
  284. ; FLOATING POINT OPERAND TO THE  VALUE  IN  THE FLOATING POINT
  285. ; ACCUMULATOR AND  PLACES  THE SUM IN  THE FLOATING POINT
  286. ; ACCUMULATOR.
  287. ; 
  288. ; ENTRY POINT
  289. ;       ADD
  290. ; 
  291. ; ENTRY CONDITIONS
  292. ;       H REGISTER = MS 6 BITS OF OPERAND ADDRESS
  293. ;       L REGISTER = LS 8 BITS OF OPERAND ADDRESS
  294. ; 
  295. ; EXIT CONDITIONS
  296. ;       CONTROL BITS SET AS DEFINED FOR THE SYSTEM 
  297. ;       IF OVERFLOW:
  298. ;             LOCATION <OVER> SET NON-ZERO
  299. ;       IF NO OVERFLOW:
  300. ;             A REGISTER = ACCUMULATOR  EXPONENT
  301. ;             B REGISTER = ACCUMULATOR SIGN AND 1ST FRACTION
  302. ;             C REGISTER = ACCUMULATOR 2ND FRACTION
  303. ;             D REGISTER = ACCUMULATOR 3RD FRACTION
  304. ;             E REGISTER = SIGNIFICANCE INDEX
  305. ; 
  306. ; REGISTERS ALTERED
  307. ;       ALL
  308. ; 
  309. ; MAXIMUM SUBROUTINE  LEVELS  USED
  310. ;       2
  311. ; 
  312. ; 
  313. ; 
  314. ; FLOATING POINT SUBTRACT SUBROUTINE
  315. ; 
  316. ; THE  FLOATING POINT SUBTRACT SUBROUTINE SUBTRACTS THE SPECIFIED
  317. ; FLOATING POINT OPERAND FROM THE VALUE IN THE FLOATING POINT
  318. ; ACCUMULATOR AND PLACES THE DIFFERENCE IN  THE FLOATING POINT
  319. ; ACCUMULATOR.
  320. ; 
  321. ; ENTRY POINT
  322. ;       SUB
  323. ; 
  324. ; ENTRY CONDITIONS
  325. ;       H REGISTER = MS 6 BITS OF OPERAND ADDRESS
  326. ;       L REGISTER = LS 8 BITS OF OPERAND ADDRESS
  327. ; 
  328. ; EXIT CONDITIONS
  329. ;       CONTROL BITS SET AS DEFINED  FOR THE SYSTEM
  330. ;       IF  OVERFLOW:
  331. ;           LOCATION <OVER> SET NON-ZERO
  332. ;       IF  NO OVERFLOW:
  333. ;           A REGISTER = ACCUMULATOR EXPONENT
  334. ;           B REGISTER = ACCUMULATOR SIGN AND 1ST FRACTION
  335. ;           C REGISTER = ACCUMULATOR 2ND FRACTION
  336. ;           D REGISTER = ACCUMULATOR 3RD FRACTION
  337. ;           E REGISTER = SIGNIFICANCE INDEX
  338. ; 
  339. ; REGISTERS ALTERED
  340. ;      ALL
  341. ; 
  342. ; MAXIMUM SUBROUTINE LEVELS USED
  343. ;      2
  344. ; 
  345. ; 
  346. ; 
  347. ; FLOATING POINT ABSOLUTE SUBROUTINE
  348. ; 
  349. ; THE FLOATING POINT ABSOLUTE SUBROUTINE SETS THE SIGN OF THE
  350. ; VALUE IN THE FLOATING POINT ACCUMULATOR POSITIVE.
  351. ; 
  352. ; ENTRY POINT
  353. ;       ABS
  354. ; 
  355. ; ENTRY CONDITIONS
  356. ;       NONE
  357. ; 
  358. ; EXIT CONDITIONS
  359. ;       CONTROL BITS SET AS DEFINED FOR THE SYSTEM
  360. ;       A REGISTER = ACCUMULATOR EXPONENT
  361. ;       B REGISTER = ACCUMULATOR SIGN AND 1ST FRACTION
  362. ;       C REGISTER = ACCUMULATOR 2ND FRACTION
  363. ;       D REGISTER = ACCUMULATOR 3RD FRACTION
  364. ;       E REGISTER = SIGNIFICANCE INDEX, IF THE PREVIOUS
  365. ;                    OPERATION WAS AN ADD OR SUBTRACT
  366. ; 
  367. ; REGISTERS ALTERED
  368. ;       ALL
  369. ; 
  370. ; MAXIMUM SUBROUTINE  LEVELS USED
  371. ;       0
  372. ; 
  373. ; 
  374. ; 
  375. ; FLOATING POINT ZERO SUBROUTINE
  376. ; 
  377. ; THE FLOATING  POINT ZERO SUBROUTINE PLACES THE VALUE ZERO IN
  378. ; THE FLOATING POINT ACCUMULATOR.
  379. ; 
  380. ; ENTRY POINT
  381. ;       ZRO
  382. ; 
  383. ; ENTRY CONDITIONS
  384. ;       NONE
  385. ; 
  386. ; EXIT CONDITIONS
  387. ;       CONTROL  BITS SET AS DEFINED FOR THE SYSTEM
  388. ;       A REGISTER = ACCUMULATOR EXPONENT
  389. ;       B REGISTER = ACCUMULATOR SIGN AND 1ST FRACTION
  390. ;       C REGISTER = ACCUMULATOR 2ND FRACTION
  391. ;       D REGISTER = ACCUMULATOR 3RD FRACTION
  392. ; 
  393. ; REGISTERS ALTERED
  394. ;       ALL
  395. ; 
  396. ; MAXIMUM SUBROUTINE  LEVELS USED
  397. ;       0
  398. ; 
  399. ; 
  400. ; 
  401. ; FLOATING POINT TEST SUBROUTINE
  402. ; 
  403. ; THE FLOATING POINT TEST SUBROUTINE LOADS THE VALUE IN THE
  404. ; FLOATING POINT ACCUMULATOR INTO THE REGISTERS AND SETS THE
  405. ; ZERO AND SIGN CONTROL BITS TO INDICATE THE CORRESPONDING
  406. ; ATTRIBUTES OF THE VALUE.
  407. ; 
  408. ; ENTRY POINT
  409. ;       TST
  410. ; 
  411. ; ENTRY CONDITIONS
  412. ;       NONE
  413. ; 
  414. ; EXIT CONDITIONS
  415. ;       CONTROL  BITS SET AS DEFINED FOR THE SYSTEM
  416. ;       A REGISTER = ACCUMULATOR EXPONENT
  417. ;       B REGISTER = ACCUMULATOR SIGN AND 1ST FRACTION
  418. ;       C REGISTER = ACCUMULATOR 2ND FRACTION
  419. ;       D REGISTER = ACCUMULATOR 3RD FRACTION
  420. ;       E REGISTER = SIGNIFICANCE INDEX, IF THE PREVIOUS 
  421. ;                    OPERATION WAS AN ADD OR SUBTRACT
  422. ; 
  423. ; REGISTERS ALTERED
  424. ;       ALL
  425. ; 
  426. ; MAXIMUM SUBROUTINE LEVELS USED
  427. ;       0
  428. ; 
  429. ; 
  430. ; 
  431. ; FLOATING POINT COMPLEMENT SUBROUTINE
  432. ; 
  433. ; THE FLOATING POINT COMPLEMENT SUBROUTINE CHANGES THE
  434. ; ARITHMETIC SIGN OF THE VALUE IN THE FLOATING POINT
  435. ; ACCUMULATOR
  436. ; 
  437. ; ENTRY POINT
  438. ;       CHS
  439. ; 
  440. ; ENTRY CONDITIONS
  441. ;       NONE
  442. ; 
  443. ; EXIT CONDITIONS
  444. ;       CONTROL BITS SET AS DEFINED FOR THE SYSTEM
  445. ;       A REGISTER = ACCUMULATOR EXPONENT
  446. ;       B REGISTER = ACCUMULATOR SIGN AND 1ST FRACTION
  447. ;       C REGISTER = ACCUMULATOR 2ND FRACTION
  448. ;       D REGISTER = ACCUMULATOR 3RD  FRACTION
  449. ;       E REGISTER = SIGNIFICANCE  INDEX, IF THE PREVIOUS
  450. ;                    OPERATION WAS AN ADD OF SUBTRACT
  451. ; 
  452. ; REGISTERS ALTERED
  453. ;       ALL
  454. ; 
  455. ; MAXIMUM SUBROUTINE LEVELS USED
  456. ;       0
  457. ; 
  458. ; 
  459. ; SAMPLE PROGRAM USING THE 8008 FLOATING POINT SYSTEM 
  460. ; 
  461. ; INVESTIGATE  THE RIGHT TRIANGLE
  462. ; 
  463. ; INITIALIZE THE FLOATING POINT  SYSTEM SCRATCHPAD
  464. ; 
  465.     ORG    1000Q
  466. BEGIN:    CALL    INIT        ;INITIALIZE THE SCRATCHPAD
  467. ; 
  468. ; SQUARE THE BASE AND STORE THE RESULT
  469. ; 
  470.     LXI    H,BASE        ;ADDRESS OF THE BASE LEG
  471.     CALL    LOD        ;LOAD THE BASE LEG INTO THE ACCUM
  472.     LXI    H,BASE        ;ADDRESS OF THE BASE LEG
  473.     CALL    MUL        ;SQUARE THE BASE    LEG
  474.     LXI    H,TEMP        ;ADDRESS OF TEMPORARY STORAGE
  475.     CALL    STR
  476. ; 
  477. ; SQUARE THE HEIGHT, ADD THE SQUARE OF THE BASE AND STORE
  478. ; 
  479.     LXI    H,HEIGHT        ;ADDRESS OF THE HEIGHT LEG
  480.     CALL    LOD        ;LOAD THE HEIGHT LEG INTO THE ACCUM
  481.     LXI    H,HEIGHT
  482.     CALL    MUL        ;SQUARE THE HEIGHT LEG
  483.     LXI    H,TEMP        ;TEMPORARY STORAGE
  484.     CALL    ADD        ;SUM THE BASE AND HEIGHT SQUARES
  485.     LXI    H,TEMP        ;TEMP STORAGE
  486.     CALL    STR        ;SAVE THE SUM OF THE SQUARES
  487. ; 
  488. ; SQUARE  THE HYPOTENUSE, SUBTRACT THE SUM OF THE SQUARES OF THE LEGS
  489. ; 
  490.     LXI    H,HYPOT        ;ADDRESS OF THE HYPOTENUSE
  491.     CALL    LOD        ;LOAD THE HYPOTENUSE INTO THE ACCUM
  492.     LXI    H,HYPOT
  493.     CALL    MUL        ;SQUARE THE HYPOT
  494.     LXI    H,TEMP        ;TEMP STORAGE
  495.     CALL    SUB        ;SUBTRACT THE SUM OF THE SQUARES OF THE LEGS
  496. ; 
  497. ;  CHECK FOR AN OVERFLOW DURING THE ABOVE OPERATIONS
  498. ; 
  499.     MVI    H,SCRB        ;ADDRESS THE SCRATCH BANK
  500.     MVI    L,OVER        ;ADDRESS THE OVERFLOW FLAG
  501.     MOV    A,M        ;GET THE FLAG
  502.     ANA    A        ;SET THE CONTROL    BITS
  503.     JNZ    ERR3        ;JUMP IF AN OVERFLOW OCCURRED
  504.     CALL    TST        ;TEST THE ACCUMULATOR
  505.     JZ    OK        ;IF THE ACCUM IS ZERO
  506. ; 
  507. ; CHECK  FOR ROUND OFF ERROR
  508. ; 
  509.     MOV    A,E
  510.     ADI    22
  511.     JP    ERR2
  512. ; 
  513. ; PYTHAGORAS WAS ALL WET
  514. ; 
  515. ERR1:    HLT
  516. ; 
  517. ; HE WAS PRETTY CLOSE
  518. ; 
  519. ERR2:    HLT
  520. ; 
  521. ; THAT IS A BIG TRIANGLE
  522. ; 
  523. ERR3:    HLT
  524. ; 
  525. ; RIGHT ON
  526. ;   (THE PROGRAM STOPS HERE IF IT HAS BEEN KEYED IN WITHOUT ERROR,
  527. ;    AND IF THE CPU IS FUNCTIONING PROPERLY)
  528. ; 
  529. OK:    HLT
  530. ; 
  531. ; DATA STORAGE
  532. ; 
  533. BASE:    DB    202Q,300Q,0,0        ;-3
  534. HEIGHT: DB    203Q,0,0,0        ;4
  535. HYPOT:    DB    203Q,40Q,0,0        ;5
  536. TEMP:    DB    0,0,0,0        ;TEMPORARY STORAGE
  537. ;      FLOATING POINT ARITHMETIC PACKAGE
  538. ; 
  539.     ORG    1400Q        ;SET ORIGIN TO 1400 OCTAL
  540. ARTHB    EQU    3        ;BANK    NO. OF ARITH PKG
  541. ARITH    EQU    $
  542. SCR    EQU    5400Q
  543. SCRB    EQU    13Q        ;BANK NO. OF SCRATCHPAD
  544. ; 8008 BINARY FLOATING POINT SYSTEM
  545. ; ARITHMETIC AND UTILITY PACKAGE
  546. ; PROGRAMMER: CAL OHME
  547. ; DATE: 26 DECEMBER 1973
  548. ; ARITH IS THE BEGINNING ADDRESS OF THE
  549. ; ARITHMETIC AND UTILITY PACKAGE OF THE FLOATING
  550. ; POINT SYSTEM.
  551. ; SCR IS THE BEGINNING ADDRESS OF THE RAM USED AS 
  552. ; SCRATCHPAD FOR THE SYSTEM.
  553. ; THE RAM MULTIPLY AND DIVIDE SUBROUTINES
  554. ; ARE MOVED FROM  ROM TO RAM BY SUBROUTINE
  555. ; INIT AND ARE EXECUTED IN RAM ONLY.
  556. ; RAM MULTIPLY SUBROUTINE.
  557. ; 
  558. MULX4    EQU    $-ARITH+SCR
  559.     ADI    0        ;ADD OPERAND 3RD FRACTION
  560. MULP3    EQU    $-1-ARITH
  561.     MOV    E,A        ;4TH PARTIAL PROD
  562.     MOV    A,D        ;3RD PARTIAL PROD
  563.     ACI    0        ;ADD OPERAND 2ND FRACTION
  564. MULP2    EQU    $-1-ARITH
  565.     MOV    D,A        ;3RD PARTIAL PROD
  566.     MOV    A,C        ;2ND PARTIAL PROD
  567.     ACI    0        ;ADD OPERAND 1ST FRACTION
  568. MULP1    EQU    $-1-ARITH
  569.     JMP    MULX5        ;TO ROM CODE
  570. ; 
  571. ; RAM DIVIDE SUBTROUTINE
  572. ; 
  573. DIVX5    EQU    $-ARITH+SCR
  574.     SUI    0        ;SUB DIVISOR 4TH FRACTION
  575. OP4S    EQU    $-1-ARITH
  576.     MOV    A,L        ;REMAINDER 3RD FRACTION
  577.     SBI    0        ;SUBDIVISOR 3RD FRACTION
  578. OP3S    EQU    $-1-ARITH
  579.     MOV    L,A        ;REMAINDER 3RD FRACTION
  580.     MOV    A,H        ;REMAINDER 2ND FRACTION
  581.     SBI    0        ;SUB DIVISOR 2ND FRACTION
  582. OP2S    EQU    $-1-ARITH
  583.     MOV    H,A        ;REMAINDER 2ND FRACTION
  584.     MOV    A,E        ;REMAINDER 1ST FRACTION
  585.     SBI    0        ;SUB DIVISOR 1ST FRACTION
  586. OP1S    EQU    $-1-ARITH
  587.     MOV    E,A        ;REMAINDER 1ST FRACTION
  588.     MVI    A,0        ;REMAINDER 4TH FRACTION
  589. OP4A    EQU    $-1-ARITH
  590.     RET        ;RETURN TO ROM
  591. DIVX6    EQU    $-ARITH+SCR
  592.     ADI    0        ;ADD DIVISOR 3RD FRACTION
  593. OP3A    EQU    $-1-ARITH
  594.     MOV    L,A        ;REMAINDER 3RD FRACTION
  595.     MOV    A,H        ;REMAINDER 2ND FRACTION
  596.     ACI    0        ;ADD DIVISOR 2ND FRACTION
  597. OP2A    EQU    $-1-ARITH
  598.     MOV    H,A        ;REMAINDER 2ND FRACTION
  599.     MOV    A,E        ;REMAINDER 1ST FRACTION
  600.     ACI    0        ;ADD DIVISOR 1ST FRACTION
  601. OP1A    EQU    $-1-ARITH
  602.     MOV    E,A        ;REMAINDER 1ST FRACTION
  603.     MVI    A,0        ;REMAINDER 4TH FRACTION
  604. OP4X    EQU    $-1-ARITH
  605.     JMP    DIVX2        ;TO ROM CODE
  606. ; 
  607. ;  RAM  LOCATIONS USED BY  THE BINARY FLOATING POINT SYSTEM
  608. ; 
  609. OVER    EQU    $-ARITH
  610.     DB    0        ;INITIALLY CLEAR
  611. PREX    EQU    OVER+1        ;PREVIOUS EXPONENT
  612. ACCE    EQU    PREX+1        ;ACCUMULATOR EXPONENT
  613. ACCS    EQU    ACCE+1        ;ACCUMULATOR SIGN
  614. ACC1    EQU    ACCS+1        ;ACCUMULATOR 1ST FRACTION
  615. ACC2    EQU    ACC1+1        ;ACCUMULATOR 2ND FRACTION
  616. ACC3    EQU    ACC2+1        ;ACCUMULATOR 3RD FRACTION
  617. SF    EQU    ACC3+1        ;SUBTRACTION FLAG
  618. ; 
  619. ; INIT SUBROUTINE ENTRY POINT
  620. ; 
  621. INIT:    MVI    L,PREX        ;ADDRESS LAST WORD TO MOVE
  622. INIT1:    MVI    H,ARTHB        ;ADDRESS ROM COPY
  623.     MOV    E,M        ;CURRENT WORD OF ROM COPY
  624.     MVI    H,SCRB        ;ADDRESS RAM COPY
  625.     MOV    M,E        ;WRITE CURRENT WORD TO RAM
  626.     DCR    L        ;DECREMENT WORD ADDRESS
  627.     JP    INIT1        ;IF MORE TO MOVE
  628.     RET        ;RETURN TO CALLER
  629. ; 
  630. ; STR SUBROUTINE ENTRY POINT
  631. ; 
  632. STR0:    MOV    M,E        ;STORE ZEROETH WORD
  633.     INR    L        ;ADDRESS FIRST WORD
  634. STR:    MOV    M,A        ;STORE FIRST WORD
  635. STR1:    INR    L        ;ADDRESS SECOND WORD
  636.     MOV    M,B        ;STORE SECOND WORD
  637.     INR    L
  638.     MOV    M,C        ;STORE THIRD WORD
  639.     INR    L
  640.     MOV    M,D        ;STORE FOURTH WORD
  641.     RET        ;RETURN TO    CALLER
  642. ; 
  643. ; FLOATING  POINT ZRO SUBROUTINE ENTRY POINT
  644. ; 
  645. ZRO:    MVI    H,SCRB        ;ADDRESS SCRATCH BANK
  646. ZRO1:    MVI    L,ACCE        ;ADDRESS ACCUM EXPONENT
  647.     XRA    A        ;CLEAR THE A REGISTER
  648.     MOV    M,A        ;CLEAR THE ACCUM EXPONENT
  649.     RET        ;RETURN TO CALLER
  650. ; 
  651. ; FLOATING  POINT CHS SUBROUTINE ENTRY POINT
  652. ; 
  653. CHS:    MVI    A,200Q        ;MASK FOR SIGN BIT
  654.     MVI    B,0        ;MVI INST TO SKIP NEXT WORD
  655.     ORG    $-1
  656. ; 
  657. ; FLOATING POINT ABS SUBROUTINE ENTRY POINT
  658. ; 
  659. ABS:    XRA    A        ;CLEAR THE A REGISTER
  660.     MVI    H,SCRB        ;ADDRESS THE SCRATCH BANK
  661.     MVI    L,ACCS        ;ADDRESS ACCUM SIGN
  662.     ANA    M
  663.     XRI    200Q        ;COMPLEMENT THE SIGN BIT
  664.     MOV    M,A        ;PUT THE ACCUM SIGN BACK
  665. ; 
  666. ; FLOATING POINT TEST ENTRY POINT
  667. ; 
  668. TST:    MVI    H,SCRB        ;ADDRESS    SCRATCH    BANK
  669. TST1:    MVI    L,ACCE        ;ACCUM EXPONENT
  670.     MOV    A,M        ;GET THE EXPONENT
  671.     ANA    A        ;SET CONTROL BITS
  672.     JZ    ZRO        ;IF ACCUM IS ZERO
  673.     MOV    E,A        ;ACCUM EXPONENT
  674.     INR    L        ;ADDRESS THE ACCUM SIGN
  675.     MOV    A,M
  676.     INR    L        ;ADDRESS ACCUM 1ST FRACTION
  677.     XRA    M        ;XOR ACCUM SIGN AND 1ST FRACTION
  678.     INR    L        ;ADDRESS ACCUM 2ND FRACTION
  679.     MOV    C,M
  680.     INR    L        ;ADDRESS ACCUM 3RD FRACTION
  681.     MOV    D,M
  682.     JMP    ADD12        ;TO SET EXIT CONDITIONS
  683. ; 
  684. ; FLOATING POINT LOAD ENTRY POINT
  685. ; 
  686. LOD:    MOV    A,M        ;OPERAND EXPONENT
  687.     ANA    A        ;SET CONTROL BITS
  688.     JZ    ZRO        ;IF OPERAND IS ZERO
  689.     MOV    E,A        ;OPERAND EXPONENT
  690.     INR    L        ;ADDRESS OPERAND SIGN AND 1ST FRACTION
  691.     MOV    A,M
  692.     INR    L        ;ADDRESS OPERAND 2ND FRACTION
  693.     MOV    C,M
  694.     INR    L        ;ADDRESS OPERAND 3RD FRACTION
  695.     MOV    D,M
  696. ; 
  697. ; STORE THE OPERAND IN  THE ACCUM
  698. ; 
  699.     MOV    L,A        ;OPERAND SIGN AND 1ST FRACTION
  700. LOD1:    ORI    200Q        ;SET THE ASSUMED MSB IN THE FIRST    FRACTION
  701. ;                            TO A 1
  702.     MOV    B,A        ;ACCUM 1ST FRACTION
  703.     XRA    L        ;ACCUMULATOR SIGN
  704.     MVI    H,SCRB        ;ADDRESS SCRATCH BANK
  705.     MVI    L,ACCE        ;ADDRESS ACCUM EXPONENT
  706.     CALL    STR0        ;SET THE ACCUMULATOR
  707.     XRA    B        ;ACCUM SIGN AND 1ST FRACTION
  708. ; 
  709. ; SET CONTROL BITS AND EXIT
  710. ; 
  711.     MOV    B,A        ;ACCUM SIGN AND 1ST FRACTION
  712.     ORI    1        ;SET SIGN BIT FOR EXIT
  713.     MOV    A,E        ;ACCUMULATOR EXPONENT
  714.     RET        ;RETURN TO CALLER
  715. ; 
  716. ; FLOATING POINT MUL SUBROUTINE  ENTRY POINT
  717. ; 
  718. MUL:    MOV    A,M        ;OPERAND EXPONENT
  719.     ANA    A        ;SET CONTROL BITS
  720.     CNZ    MDEX        ;READ OPERAND IN NOT ZERO
  721.     JZ    ZRO        ;IF ZERO OR UNDERFLOW
  722.     JC    OVERF        ;IF OVERFLOW
  723.     CALL    MULX        ;CALL FIXED MULT SUBROUTINE
  724. ; 
  725. ; NORMALIZE IF NECESSARY
  726. ; 
  727.     MOV    A,B        ;1ST PRODUCT
  728.     ANA    A        ;SET CONTROL BITS
  729.     JM    RNDA        ;IF NO NORMALIZATION NECESSARY
  730.     MVI    L,ACCE        ;ADDRESS ACCUM EXP
  731.     MOV    A,M
  732.     SBI    1        ;DECR ACCUM EXP
  733.     MOV    M,A
  734.     RZ        ;RETURN TO CALLER IF UNDERFLOW
  735.     CALL    LSH        ;CALL LEFT SHIFT ROUTINE
  736. ; 
  737. ; ROUND IF NECESSARY
  738. ; 
  739. RNDA:    CALL    ROND        ;CALL ROUNDING SUBROUTINE
  740.     JC    OVERF        ;IF OVERFLOW
  741.     MOV    B,A        ;ACCUM SIGN AND 1ST FRACTION
  742.     ORI    1        ;GET SIGN BIT
  743.     MOV    A,E        ;ACCUM EXP
  744.     RET
  745. ; 
  746. ; FLOATING POINT DIV SUBROUTINE ENTRY POINT
  747. ; 
  748. DIV:    XRA    A        ;CLEAR A REGISTER
  749.     SUB    M        ;COMPLEMENT OF DIVISOR EXPONENT
  750.     CPI    1        ;SET CARRY IF DIVISION BY ZERO
  751.     CNC    MDEX        ;READ OPERAND IF NOT ZERO
  752.     JC    OVERF        ;IF OVERFLOW OR DIVISION BY ZERO
  753.     JZ    ZRO1        ;IF UNDERFLOW OF ZERO
  754.     MOV    C,A        ;DIVISOR 1ST FRACTION
  755.     CALL    DIVX        ;CALL FIXED DIVISION SUBROUTINE
  756.     MVI    H,SCRB        ;ADDRESS SCRATCH BANK
  757.     JC    RNDA        ;IF NO OVERFLOW
  758. ; 
  759. ; SET OVERFLOW FLAG
  760. ; 
  761. OVERF:    MVI    H,SCRB        ;ADDR SCRATCH BANK
  762.     MVI    L,OVER        ;ADDRESS OVERFLOW FLAG
  763.     MVI    A,-1        ;OVERFLOW FLAG
  764.     MOV    M,A        ;STORE OVERFLOW FLAG
  765.     RLC        ;SET CARRY BIT FOR EXIT
  766.     RET
  767.     DB    0        ;CHECK SUM WORD
  768. ; 
  769. ; FLOATING POINT SUB SUBROUTINE ENTRY POINT
  770. ; 
  771. SUB:    MVI    A,200Q        ;MASK TO CHANGE OPERAND SIGN
  772.     MVI    B,0        ;MVI INST TO SKIP NEXT WORD
  773.     ORG    $-1
  774. ; 
  775. ; FLOATING POINT ADD SUBROUTINE ENTRY POINT
  776. ; 
  777. ADD:    XRA    A        ;CLEAR THE A REGISTER
  778. ; 
  779. ; LOAD THE OPERAND
  780. ; 
  781.     MOV    E,M        ;OPERAND EXPONENT
  782.     INR    L        ;ADDRESS OPERAND SIGN, 1ST FRACTION
  783.     XRA    M
  784.     MOV    B,A        ;OPERAND SIGN AND 1ST FRACTION
  785.     INR    L        ;ADDRESS OPERAND 2ND FRACTION
  786.     MOV    C,M
  787.     INR    L        ;ADDRESS OPERAND 3RD FRACTION
  788.     MOV    D,M
  789. ; 
  790. ; SAVE INITIAL EXPONENT
  791. ; 
  792.     MVI    H,SCRB        ;ADDRESS SCRATCH BANK
  793.     MVI    L,ACCE        ;ADDRESS ACCUM EXPONENT
  794.     MOV    A,M
  795.     DCR    L        ;ADDRESS INITIAL EXPONENT
  796.     MOV    M,A        ;SAVE INITIAL EXPONENT
  797. ; 
  798. ; CHECK FOR ZERO OPERAND
  799. ; 
  800.     MOV    A,E        ;OPERAND EXP
  801.     ANA    A        ;SET CONTROL BITS
  802.     JZ    TST1        ;IF OPERAND IS ZERO
  803. ; 
  804. ; GENERATE SUBTRACTION FLAG, RESTORE SUPPRESSED FRACTION BIT
  805. ; 
  806.     MOV    L,B        ;OPERAND SIGN AND 1ST FRACTION
  807.     MOV    A,B
  808.     ORI    200Q        ;SET ASSUMED MSB
  809.     MOV    B,A        ;OPERAND 1ST FRACTION
  810.     XRA    L        ;OPERAND SIGN
  811.     MVI    L,ACCS        ;ADDRESS ACCUM SIGN
  812.     XRA    M        ;SUBTRACTION FLAG
  813.     MVI    L,SF        ;ADDRESS SUBTRACTION FLAG
  814.     MOV    M,A        ;STORE IT
  815. ; 
  816. ; DETERMINE RELATIVE MAGNITUDES OF OPERAND AND ACCUM
  817. ; 
  818.     MVI    L,ACCE        ;ADDRESS ACCUM EXP
  819.     MOV    A,M
  820.     ANA    A        ;SET CONTROL BITS
  821.     JZ    ADD17        ;IF ACCUM IS ZERO
  822.     SUB    E        ;DIFFERENCE OF EXPONENTS
  823.     JC    ADD2        ;IF ACCUM SMALLER THAN OPERAND
  824. ; 
  825. ; CHECK FOR INSIGNIFICANT OPERAND
  826. ; 
  827.     JM    TST1        ;IF OPERAND IS INSIG
  828.     CPI    25        ;COMPARE SHIFT COUNT TO 25
  829.     JC    ADD3        ;JOIN EXCHANGE PATH IF OP IS SIGNIFICANT
  830.     JMP    TST1        ;OPERAND IS INSIGNIFICANT
  831. ; 
  832. ; CHECK FOR INSIGNIFICANT  ACCUM
  833. ; 
  834. ADD2:    JP    ADD17        ;IF ACCUM IS INSIGNIFICANT
  835.     CPI    -25        ;COMPARE SHIFT COUNT TO MINUS 25
  836.     JC    ADD17        ;IF ACCUM IS INSIG
  837.     MOV    M,E        ;OPERAND EXP
  838.     MOV    E,A        ;SHIFT COUNT
  839.     MVI    L,SF        ;ADDRESS THE SUBTRACTION FLAG
  840.     MOV    A,M
  841.     MVI    L,ACCS        ;ADDRESS THE ACCUM SIGN
  842.     XRA    M        ;OPERAND SIGN
  843.     MOV    M,A        ;ACCUM SIGN
  844.     XRA    A        ;ZERO THE A REGISTER
  845.     SUB    E        ;COMPLEMENT SHIFT COUNT
  846. ; 
  847. ; EXCHANGE ACCUM AND OPERAND
  848. ; 
  849.     INR    L        ;ADDRESS ACCUM 1ST FRACTION
  850.     MOV    E,M
  851.     MOV    M,B        ;OPERAND 1ST FRACTION
  852.     MOV    B,E        ;ACCUM 1ST FRACTION
  853.     INR    L        ;ADDRESS ACCUM 2ND FRACTION
  854.     MOV    E,M
  855.     MOV    M,C        ;OPERAND 2ND FRACTION
  856.     MOV    C,E        ;ACCUM 2ND FRACTION
  857.     INR    L        ;ADDRESS ACCUM 3RD FRACTION
  858.     MOV    E,M
  859.     MOV    M,D        ;OPERAND 3RD FRACTION
  860.     MOV    D,E        ;ACCUM 3RD FRACTION
  861. ; 
  862. ; POSITION THE OPERAND
  863. ; 
  864. ADD3:    CALL    RSH        ;CALL RIGHT SHIFT 
  865.     MVI    L,SF        ;ADDRESS THE SUBTRACTION FLAG
  866.     MOV    A,M
  867.     ANA    A        ;SET CONTROL BITS
  868.     MVI    L,ACC3        ;ADDRESS ACCUM 3RD FRACTION
  869.     JM    ADD9        ;IF SUBTRACTION REQUIRED
  870. ; 
  871. ; ADD ADDEND TO  AUGEND
  872. ; 
  873.     MOV    A,M        ;AUGEND 3RD    FRACTION
  874.     ADD    D        ;ADDEND 3RD FRACTION
  875.     MOV    D,A        ;SUM 3RD FRACTION
  876.     DCR    L        ;ADDRESS AUGEND 2ND FRACTION
  877.     MOV    A,M
  878.     ADC    C        ;ADDEND 2ND FRACTION
  879.     MOV    C,A        ;SUM 2ND FRACTION
  880.     DCR    L        ;ADDRESS AUGEND 1ST FRACTION
  881.     MOV    A,M
  882.     ADC    B        ;ADDEND 1ST FRACTION
  883.     MOV    B,A        ;SUM 1ST FRACTION
  884.     JNC    ADD11        ;IF NO CARRY FROM 1ST FRACTION
  885. ; 
  886. ; RIGHT SHIFT SUM TO  NORMALIZED POSITION
  887. ; 
  888.     RAR        ;RIGHT SHIFT SUM 1ST FRACTION
  889.     MOV    B,A        ;SUM 1ST FRACTION
  890.     MOV    A,C        ;SUM 2ND FRACTION
  891.     RAR        ;RIGHT SHIFT SUM 2ND FRACTION
  892.     MOV    C,A        ;SUM 2ND FRACTION
  893.     MOV    A,D        ;SUM 3RD FRACTION
  894.     RAR        ;RIGHT SHIFT SUM 3RD FRACTION
  895.     MOV    D,A        ;SUM 3RD FRACTION
  896.     RAR        ;4TH FRACTION = LOW BIT OF 3RD
  897.     MOV    E,A        ;SUM 4TH FRACTION
  898.     MVI    L,ACCE        ;ADDRESS ACCUM EXP
  899.     MOV    A,M
  900.     ADI    1        ;INCREMENT ACCUMULATOR EXP
  901.     JC    OVERF        ;IF OVERFLOW
  902.     MOV    M,A        ;STORE ACCUM EXP
  903.     JMP    ADD11        ;TO ROUND FRACTION
  904. ; 
  905. ; SUBTRACT  SUBTRAHEND FROM MINUEND
  906. ; 
  907. ADD9:    XRA    A        ;MINUEND 4TH FRACTION IS ZERO
  908.     SUB    E        ;SUBTRAHEND 4TH FRACTION
  909.     MOV    E,A        ;DIFFERENCE 4TH FRACTION
  910.     MOV    A,M        ;MINUEND 3RD FRACTION
  911.     SBB    D        ;SUBTRA 3RD FRACTION
  912.     MOV    D,A        ;DIFF 3RD FRACTION
  913.     DCR    L        ;ADDRESS MINUEND 2ND FRACTION
  914.     MOV    A,M
  915.     SBB    C        ;SUBTRA 2ND FRACTION
  916.     MOV    C,A        ;DIFF 2ND FRACTION
  917.     DCR    L        ;ADDRESS MINUEND 1ST    FRACTION
  918.     MOV    A,M
  919.     SBB    B        ;SUBTRA 1ST FRACTION
  920.     MOV    B,A        ;DIFF 1ST FRACTION
  921. ADD10:    CC    COMP        ;COMPLEMENT IF NECESSARY
  922.     CP    NORM        ;NORMALIZE IF NECESSARY
  923.     JP    ZRO1        ;IF UNDERFLOW OR ZERO
  924. ADD11:    CALL    ROND        ;CALL ROUNDING SUBROUTINE
  925.     JC    OVERF        ;IF OVERFLOW
  926. ADD12:    MOV    B,A        ;ACCUM SIGN AND 1ST FRACTION
  927.     MVI    L,PREX        ;ADDRESS PREVIOUS EXP
  928.     MOV    A,E        ;ACCUM EXP
  929.     SUB    M        ;DIFFERENCE IN EXPONENTS
  930.     MOV    L,A
  931.     MOV    A,B        ;ACCUM SIGN AND 1ST FRACTION
  932.     ORI    1        ;SET SIGN BIT FOR EXIT
  933.     MOV    A,E        ;ACCUM EXP
  934.     MOV    E,L        ;SIGNIFICANCE INDEX
  935.     RET
  936. ; 
  937. ; LOAD THE ACCUM WITH THE OPERAND
  938. ; 
  939. ADD17:    MVI    L,SF        ;ADDRESS THE SUBTRACTION FLAG
  940.     MOV    A,M
  941.     MVI    L,ACCS        ;ADDRESS THE ACCUM SIGN
  942.     XRA    M        ;OPERAND SIGN
  943.     DCR    L        ;ADDRESS ACCUM EXP
  944.     CALL    STR0        ;SET THE ACCUM
  945.     XRA    B        ;ACCUM SIGN AND 1ST FRACTION
  946.     JMP    ADD12        ;JOIN EXIT CODE
  947.     DB    0        ;CHECH SUM WORD
  948. ; 
  949. ; SUBROUTINE TO READ THE OPERAND AND
  950. ; CHECK THE ACCUMULATOR EXPONENT
  951. ; 
  952. MDEX:    MOV    B,A        ;EXPONENT MODIFIER
  953.     INR    L        ;ADDRESS OPERAND SIGN, 1ST FRACTION
  954.     MOV    C,M
  955.     INR    L        ;ADDRESS OPERAND 2ND FRACTION
  956.     MOV    D,M
  957.     INR    L        ;ADDRESS OPERAND 3RD FRACTION
  958.     MOV    E,M
  959.     MVI    H,SCRB        ;ADDRESS SCRATCH BANK
  960.     MVI    L,ACCE        ;ADDRESS ACCUM EXP
  961.     MOV    A,M
  962.     ANA    A        ;SET CONTROL BITS
  963.     RZ        ;RETURN IF ACCUM IS ZERO
  964.     ADD    B        ;RESULT EXP PLUS BIAS
  965.     MOV    B,A
  966.     RAR        ;CARRY TO SIGN
  967.     XRA    B        ;CARRY AND SIGN MUST DIFFER
  968.     MOV    A,B        ;RESULT EXP PLUS BIAS
  969.     MVI    B,200Q        ;EXP BIAS, SIGN MASK, MOST SIG BIT
  970.     JP    OVUN        ;IF OVER OR UNDERFLOW
  971.     SUB    B        ;REMOVE EXCESS EXP BIAS
  972.     RZ        ;RETURN IF UNDERFLOW
  973.     MOV    M,A        ;RESULT EXP
  974.     INR    L        ;ADDRESS ACCUM SIGN
  975.     MOV    A,M
  976.     XRA    C        ;RESULT SIGN IN SIGN BIT
  977.     ANA    B        ;RESULT SIGN
  978.     MOV    M,A        ;STORE IT
  979.     MOV    A,C        ;OPERAND SIGN AND 1ST FRACTION
  980.     ORA    B        ;OPERAND FIRST FRACTION
  981.     RET
  982. OVUN:    RLC        ;SET CARRY BIT IF OVERFLOW
  983.     RC        ;RETURN IF OVERFLOW
  984.     XRA    A        ;CLEAR A REGISTER
  985.     RET        ;RETURN IF UNDERFLOW
  986. ; 
  987. ; SUBROUTINE TO LEFT SHIFT THE B,C,D,AND E REGISTERS ONE BIT
  988. ; 
  989. LSH:    MOV    A,E        ;ORIGINAL CONTENTS OF E
  990.     RAL        ;LEFT SHIFT E
  991.     MOV    E,A        ;RESTORE CONTENTS OF E 
  992. LSH1:    MOV    A,D        ;ORIGINAL CONTENTS OF D
  993.     RAL        ;LEFT SHIFT D
  994.     MOV    D,A        ;RESTORE D
  995.     MOV    A,C        ;ORIGINAL CONTENTS OF C
  996.     RAL        ;LEFT SHIFT C
  997.     MOV    C,A        ;RESTORE C
  998.     MOV    A,B        ;ORIGINAL CONTENTS OF B
  999.     ADC    A        ;LEFT SHIFT B
  1000.     MOV    B,A        ;RESTORE B
  1001.     RET
  1002. ; 
  1003. ; RIGHT SHIFT THE B,C,D,AND E REGISTERS
  1004. ; BY THE SHIFT COUNT IN THE A REGISTER
  1005. ; SHIFT OPERAND TO REGISTER INDICATED BY
  1006. ; SHIFT COUNT
  1007. ; 
  1008. RSH:    MVI    E,0        ;OPERAND 4TH FRACTION IS ZERO
  1009. RSH0:    MVI    L,8        ;EACH REG IS 8 BITS OF SHIFT
  1010. RSH1:    CMP    L        ;COMPARE SHIFT COUNT TO 8
  1011.     JM    RSH2        ;IF REQUIRED SHIFT LESS    THAN 8
  1012.     MOV    E,D        ;OPERAND 4TH FRACTION
  1013.     MOV    D,C        ;OPERAND 3RD FRACTION
  1014.     MOV    C,B        ;OPERAND 2ND FRACTION
  1015.     MVI    B,0        ;OPERAND 1ST FRACTION IS ZERO
  1016.     SUB    L        ;REDUCE SHIFT COUNT BY 1 REG
  1017.     JNZ    RSH1        ;IF MORE SHIFTS REQUIRED
  1018. ; 
  1019. ; SHIFT OPERAND RIGHT BY <SHIFT COUNT> BITS
  1020. ; 
  1021. RSH2:    ANA    A        ;SET CONTROL BITS
  1022.     RZ        ;RETURN IF SHIFT COMPLETE
  1023.     MOV    L,A        ;SHIFT COUNT
  1024. RSH3:    ANA    A        ;CLEAR CARRY BIT
  1025.     MOV    A,B        ;OPERAND 1ST FRACTION
  1026.     RAR        ;RIGHT SHIFT OPERAND 1ST FRACTION
  1027.     MOV    B,A        ;OP 1ST FRACTION
  1028.     MOV    A,C        ;OP 2ND FRACTION
  1029.     RAR
  1030.     MOV    C,A        ;OP 2ND FRACTION
  1031.     MOV    A,D        ;OP 3RD FRACTION
  1032.     RAR
  1033.     MOV    D,A        ;OP 3RD FRACTION
  1034.     MOV    A,E        ;OP 4TH FRACTION
  1035.     RAR
  1036.     MOV    E,A        ;OP 4TH FRACTION
  1037.     DCR    L        ;DECREMENT SHIFT COUNT
  1038.     JNZ    RSH3        ;IF MORE SHIFTS REQUIRED
  1039.     RET
  1040. ; 
  1041. ; COMPLEMENT THE B,C,D,AND E REGISTERS
  1042. ; 
  1043. COMP:    DCR    L        ;ADDRESS ACCUM SIGN
  1044.     MOV    A,M
  1045.     XRI    200Q        ;CHANGE SIGN
  1046.     MOV    M,A        ;PUT IT BACK
  1047. COMP1:    XRA    A        ;ZERO    THE A REGISTER
  1048.     MOV    L,A        ;ZERO L REG
  1049.     SUB    E        ;COMPLEMENT 4TH FRACTION
  1050.     MOV    E,A        ;4TH FRACTION
  1051.     MOV    A,L        ;ZERO A REG
  1052.     SBB    D        ;COMPLEMENT 3RD FRACTION
  1053.     MOV    D,A        ;3RD FRACTION
  1054.     MOV    A,L        ;ZERO A REG
  1055.     SBB    C        ;COMPLEMENT 2ND FRACTION
  1056.     MOV    C,A        ;2ND FRACTION
  1057.     MOV    A,L        ;ZERO A REG
  1058.     SBB    B        ;COMPLEMENT 1ST FRACTION
  1059.     MOV    B,A        ;1ST FRACTION
  1060.     RET
  1061. ; 
  1062. ; NORMALIZE THE REGISTERS
  1063. ; 
  1064. NORM:    MVI    L,32        ;MAXIMUM NORMALIZING SHIFT
  1065. NORM1:    MOV    A,B        ;1ST FRACTION
  1066.     ANA    A        ;SET CONTROL BITS
  1067.     JNZ    NORM3        ;IF 1ST FRACTION NONZERO
  1068.     MOV    B,C        ;1ST FRACTION
  1069.     MOV    C,D        ;2ND FRACTION
  1070.     MOV    D,E        ;3RD FRACTION
  1071.     MOV    E,A        ;ZERO    4TH FRACTION
  1072.     MOV    A,L        ;NORMALIZING SHIFT COUNT
  1073.     SUI    8        ;REDUCE SHIFT COUNT
  1074.     MOV    L,A        ;NORMALIZING SHIFT COUNT
  1075.     JNZ    NORM1        ;IF FRACTION NONZERO
  1076.     RET        ;IF FRACTION ZERO
  1077. NORM2:    DCR    L        ;DECREMENT SHIFT COUNT
  1078.     MOV    A,E        ;ORIGINAL CONTENTS OF    E
  1079.     RAL        ;LEFT    SHIFT E
  1080.     MOV    E,A        ;PUT E BACK
  1081.     MOV    A,D
  1082.     RAL
  1083.     MOV    D,A
  1084.     MOV    A,C
  1085.     RAL
  1086.     MOV    C,A
  1087.     MOV    A,B
  1088.     ADC    A        ;LEFT SHIFT B
  1089.     MOV    B,A        ;PUT B BACK
  1090. NORM3:    JP    NORM2        ;IF NOT NORMALIZED
  1091.     MOV    A,L        ;NORMALIZING SHIFT COUNT
  1092.     SUI    32        ;REMOVE BIAS
  1093.     MVI    L,ACCE        ;ADDRESS ACCUM EXP
  1094.     ADD    M        ;ADJUST ACCUM EXP
  1095.     MOV    M,A        ;NEW ACCUM EXP
  1096.     RZ        ;RETURN IF ZERO EXP
  1097.     RAR        ;MOVE BORROW BIT TO SIGN
  1098.     ANA    A        ;SET SIGN TO INDICATE UNDERFLOW
  1099.     RET
  1100. ; 
  1101. ; SUBROUTINE  TO ROUND THE B,C,D REGISTERS
  1102. ; 
  1103. ROND:    MVI    L,ACCE        ;ADDRESS    THE ACCUM EXP
  1104.     MOV    A,E        ;4TH FRACTION
  1105.     ANA    A        ;SET CONTROL BITS
  1106.     MOV    E,M        ;ACCUM EXP
  1107.     CM    RNDR        ;CALL 2ND LEVEL ROUNDER
  1108.     RC        ;IF OVERFLOW
  1109.     MOV    A,B        ;1ST FRACTION
  1110.     INR    L        ;ADDRESS ACCUM    SIGN
  1111.     XRA    M        ;ACCUM SIGN AND 1ST FRACTION
  1112.     JMP    STR1        ;RETURN THROUGH    STORE SUBROUTINE
  1113. ; 
  1114. ; SECOND LEVEL ROUNDING ROUTINE
  1115. ; 
  1116. RNDR:    INR    D        ;ROUND    3RD FRACTION
  1117.     RNZ        ;RETURN IF NO CARRY
  1118.     INR    C        ;CARRY TO 2ND FRACTION
  1119.     RNZ        ;RETURN IF NO CARRY
  1120.     INR    B        ;CARRY TO    1ST FRACTION
  1121.     RNZ        ;RETURN IF NO CARRY
  1122.     MOV    A,E        ;ACCUM EXP
  1123.     ADI    1        ;INCREMENT ACCUM    EXP
  1124.     MOV    E,A        ;NEW ACCUM    EXP
  1125.     MVI    B,200Q        ;NEW 1ST FRACTION
  1126.     MOV    M,A        ;NEW ACCUM EXP
  1127.     RET
  1128. ; 
  1129. ; FIXED POINT MULTIPLY SUBROUTINE
  1130. ; 
  1131. MULX:    MVI    L,MULP1        ;ADDRESS 1ST MULTIPLICAND
  1132.     MOV    M,A        ;1ST MULT
  1133.     MVI    L,MULP2        ;ADDRESS 2ND MULTIPLICAND
  1134.     MOV    M,D        ;2ND MULT
  1135.     MVI    L,MULP3        ;ADDRESS 3RD MULTIPLICAND
  1136.     MOV    M,E        ;3RD MULT
  1137.     XRA    A        ;CLEAR 6TH PRODUCT
  1138.     MOV    E,A        ;CLEAR 5TH PRODUCT
  1139.     MOV    D,A        ;CLEAR 4TH PRODUCT
  1140. ; 
  1141. ; MULTIPLY  BY EACH ACCUMULATOR FRACTION IN TURN
  1142. ; 
  1143.     MVI    L,ACC3        ;ADDRESS 3RD FRACTION
  1144.     CALL    MULX2        ;MULTIPLY BY ACCUM 3RD FRACTION
  1145.     MVI    L,ACC2        ;ADDRESS 2ND FRACTION
  1146.     CALL    MULX1        ;MULTIPLY BY ACCUM 2ND FRACTION
  1147.     MVI    L,ACC1        ;ADDRESS 1ST FRACTION
  1148. ; 
  1149. ; MULTIPLY BY ONE ACCUMULATOR WORD
  1150. ; 
  1151. MULX1:    MOV    A,D        ;5TH PARTIAL PRODUCT
  1152.     MOV    E,C        ;4TH PARTIAL PROD
  1153.     MOV    D,B        ;3RD PARTIAL PROD
  1154. MULX2:    MOV    B,M        ;MULTIPLIER
  1155.     MOV    L,A        ;5TH PARTIAL PROD
  1156.     XRA    A        ;ZERO A REGISTER
  1157.     MOV    C,A        ;2ND PARTIAL PROD
  1158.     SUB    B        ;SET CARRY BIT FOR EXIT FLAG
  1159.     JC    MULX3        ;IF MULTIPLIER IS NOT ZERO
  1160.     MOV    C,D        ;2ND PARTIAL PRODUCT
  1161.     MOV    D,E        ;3RD PARTIAL PROD
  1162.     RET        ;MULT BY ZERO COMPLETE
  1163. ; 
  1164. ; COMPLETE ADDITION OF MULTIPLICAND
  1165. ; 
  1166. MULX5:    MOV    C,A        ;2ND PARTIAL PROD
  1167.     JNC    MULX3        ;IF NO CARRY TO 1ST PROD
  1168.     INR    B        ;ADD CARRY TO 1ST PROD
  1169.     ANA    A        ;CLEAR CARRY BIT
  1170. ; 
  1171. ; LOOP FOR EACH BIT OF MULTIPLIER WORD
  1172. ; 
  1173. MULX3:    MOV    A,L        ;5TH PARTIAL PRODUCT, EXIT FLAG
  1174.     ADC    A        ;SHIFT EXIT FLAG OUT    IF DONE
  1175.     RZ        ;EXIT IF MULTIPLICATION DONE
  1176.     MOV    L,A        ;5TH PARTIAL PROD, EXIT FLAG
  1177.     MOV    A,E        ;4TH PARTIAL PROD
  1178.     RAL        ;SHIFT 4TH PARTIAL PROD
  1179.     MOV    E,A        ;4TH PARTIAL PROD
  1180.     MOV    A,D        ;3RD PARTIAL PROD
  1181.     RAL
  1182.     MOV    D,A
  1183.     MOV    A,C        ;2ND PARTIAL PROD
  1184.     RAL
  1185.     MOV    C,A
  1186.     MOV    A,B        ;1ST PARTIAL PROD AND MULTIPLIER
  1187.     RAL
  1188.     MOV    B,A
  1189.     JNC    MULX3        ;IF NO ADDITION REQUIRED
  1190. ; 
  1191. ; ADD THE MULTIPLICAND TO THE PRODUCT
  1192. ; IF THE MULTIPLIER BIT IS ONE
  1193. ; 
  1194.     MOV    A,E        ;4TH PARTIAL PROD
  1195.     JMP    MULX4        ;TO RAM CODE
  1196. ; 
  1197. ; FIXED POINT DIVIDE SUBROUTINE .
  1198. ; SUBTRACT DIVISOR FROM ACCUM TO OBTAIN 1ST REMAINDER
  1199. ; 
  1200. DIVX:    MVI    L,ACC3        ;ADDRESS ACCUM 3RD FRACTION
  1201.     MOV    A,M
  1202.     SUB    E        ;DIVISOR 3RD FRACTION
  1203.     MOV    M,A        ;REMAINDER 3RD FRACTION
  1204.     DCR    L        ;ADDRESS ACCUM 2ND FRACTION
  1205.     MOV    A,M
  1206.     SBB    D        ;DIVISOR 2ND FRACTION
  1207.     MOV    M,A        ;REMAINDER 2ND FRACTION
  1208.     DCR    L        ;ADDRESS ACCUM 1ST FRACTION
  1209.     MOV    A,M
  1210.     SBB    C        ;DIVISOR 1ST FRACTION
  1211.     MOV    M,A        ;REMAINDER 1ST FRACTION
  1212. ; 
  1213. ; HALVE THE DIVISOR AND STORE FOR ADDITION OR SUBTRACTION
  1214. ; 
  1215.     MOV    A,C        ;DIVISOR 1ST FRACTION
  1216.     RAL        ;SET CARRY BIT
  1217.     MOV    A,C        ;DIVISOR 1ST FRACTION
  1218.     RAR        ;HALF OF DIVISOR 1ST FRACTION
  1219. ;                            + 200 OCTAL TO CORRECT QUOTIENT
  1220.     MVI    L,OP1S        ;ADDRESS 1ST SUBTRACT DIVISOR
  1221.     MOV    M,A
  1222.     MVI    L,OP1A        ;ADDRESS 1ST ADD DIVISOR
  1223.     MOV    M,A
  1224.     MOV    A,D        ;DIVISOR 2ND FRACTION
  1225.     RAR        ;HALF OF DIVISOR 2ND FRACTION
  1226.     MVI    L,OP2S        ;ADDRESS 2ND SUBTRACT DIVISOR
  1227.     MOV    M,A
  1228.     MVI    L,OP2A        ;ADDRESS 2ND ADD DIVISOR
  1229.     MOV    M,A
  1230.     MOV    A,E        ;DIVISOR 3RD FRACTION
  1231.     RAR        ;HALF OF DIVISOR 3RD FRACTION
  1232.     MVI    L,OP3S        ;ADDRESS 3RD SUBTRACT DIVISOR
  1233.     MOV    M,A
  1234.     MVI    L,OP3A        ;ADDRESS 3RD ADD DIVISOR
  1235.     MOV    M,A
  1236.     MVI    B,0        ;INITIALIZE QUOTIENT 1ST FRACTION
  1237.     MOV    A,B        ;DIVISOR 4TH FRACTION IS ZERO
  1238.     RAR        ;LOW BIT OF DIVISOR 3RD FRACTION
  1239.     MVI    L,OP4S        ;ADDRESS 4TH SUBTRACT DIVISOR
  1240.     MOV    M,A        ;4TH SUBTRACT DIVISOR
  1241.     MVI    L,OP4A        ;ADDRESS 4TH ADD DIVISOR
  1242.     MOV    M,A
  1243.     MVI    L,OP4X        ;ADDRESS 4TH ADD DIVISOR
  1244.     MOV    M,A
  1245. ; 
  1246. ; LOAD 1ST REMAINDER, CHECK SIGN
  1247. ; 
  1248.     MVI    L,ACC1        ;ADDRESS REMAINDER 1ST FRACTION
  1249.     MOV    A,M
  1250.     INR    L        ;ADDRESS 2ND FRACTION
  1251.     MOV    D,M
  1252.     INR    L        ;ADDRESS 3RD FRACTION
  1253.     MOV    E,M
  1254.     ANA    A        ;SET CONTROL BITS
  1255.     JM    DIVX4        ;IF REMAINDER IS NEGATIVE
  1256. ; 
  1257. ; ADJUST EXPONENT, POSITION REMAINDER
  1258. ; AND INITIALIZE THE QUOTIENT
  1259. ; 
  1260.     MVI    L,ACCE        ;ADDRESS ACCUM EXP
  1261.     MOV    C,M        ;QUOTIENT EXP
  1262.     INR    C        ;INCREMENT QUOTIENT EXP
  1263.     RZ        ;RETURN IF OVERFLOW
  1264.     MOV    M,C        ;QUOTIENT EXP
  1265.     MOV    L,E        ;REMAINDER 3RD FRACTION
  1266.     MOV    H,D        ;REMAINDER 2ND FRACTION
  1267.     MOV    E,A        ;REMAINDER 1ST FRACTION
  1268.     MVI    D,1        ;INITIALIZE QUOTIENT 3RD FRACTION
  1269.     MOV    C,B        ;INITIALIZE QUOTIENT 2ND FRACTION
  1270. ; 
  1271. ; SUBTRACT THE DIVISOR FROM THE REMAINDER
  1272. ; IF IT IS POSITIVE
  1273. ; 
  1274. DIVX1:    XRA    A        ;REMAINDER    4TH FRACTION IS ZERO
  1275.     CALL    DIVX5        ;CALL RAM SECTION
  1276. DIVX2:    RLC        ;SHIFT REMAINDER 4TH FRACTION TO CARRY
  1277. ; 
  1278. ; SHIFT THE REMAINDER LEFT ONE BIT
  1279. ; 
  1280.     MOV    A,B        ;QUOTIENT 1ST FRACTION
  1281.     RAL        ;MSB OF QUOTIENT TO CARRY
  1282.     RC        ;IF DIVISION COMPLETE
  1283.     RAR        ;REMAINDER 4TH FRACTION TO    CARRY
  1284.     MOV    A,L        ;REMAINDER 3RD FRACTION
  1285.     RAL
  1286.     MOV    L,A
  1287.     MOV    A,H        ;REMAINDER 2ND FRACTION
  1288.     RAL
  1289.     MOV    H,A
  1290.     CALL    LSH        ;CALL LEFT SHIFT ROUTINE
  1291. ; 
  1292. ; BRANCH IF SUBTRACTION IS REQUIRED
  1293. ; 
  1294.     MOV    A,D        ;QUOTIENT 3RD FRACTION
  1295.     RRC        ;REMAINDER SIGN INDIC TO CARRY    BIT
  1296.     JC    DIVX1        ;TO SUB DIVISOR IF REMAINDER POSITIVE
  1297. ; 
  1298. ; ADD THE DIVISOR IF THE REMAINDER IS NEGATIVE
  1299. ; 
  1300. DIVX3:    MOV    A,L        ;REMAINDER 3RD FRACTION
  1301.     JMP    DIVX6        ;TO RAM CODE
  1302. ; 
  1303. ; POSITION THE REMAINDER AND INITIALIZE THE QUOTIENT
  1304. ; 
  1305. DIVX4:    MOV    L,E        ;REMAINDER 3RD FRACTION
  1306.     MOV    H,D        ;REMAINDER 2ND FRACTION
  1307.     MOV    E,A        ;REMAINDER 1ST FRACTION
  1308.     MOV    D,B        ;INITIALIZE QUOTIENT 3RD FRACTION
  1309.     MOV    C,B        ;INITIALIZE QUOTIENT 2ND FRACTION
  1310.     JMP    DIVX3        ;ADD DIVISOR IF REMAINDER IS NEGATIVE
  1311.     DB    0        ;CHECKSUM WORD
  1312.     END    
  1313.