home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug020.ark / CIVILW.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  8.0 KB  |  241 lines
  1. 1 L=0:W=0:R1=0:P1=0
  2. 2 Q1=0:M3=0:M4=0
  3. 3 P2=0:T1=0:T2=0
  4. 5 REM ARKABLE PROGRAM BY L. CRAM , L. GOODIE , AND D. HIBBARD 
  5. 6 PRINT "DO YOU WANT DESCRIPTIONS (1=YES, 0=NO)";
  6. 7 INPUT Z
  7. 8 REM ARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
  8. 9 FOR U=1 TO 6 
  9. 10 PRINT
  10. 11 NEXT U 
  11. 13 IF Z=0 THEN 100
  12. 15 PRINT "THIS IS A CIVIL WAR SIMULATION."
  13. 20 PRINT "TO PLAY, TYPE A RESPONSE WHEN THE COMPUTER ASKS." 
  14. 30 PRINT "REMEMBER THAT ALL FACTORS ARE INTERRELATED AND THAT YOUR" 
  15. 35 PRINT "RESPONSES COULD CHANGE HISTORY. FACTS AND FIGURES USED ARE" 
  16. 40 PRINT "BASED ON THE ACTUAL OCCURENCE. MOST BATTLES TEND TO RESULT" 
  17. 45 PRINT "AS THEY DID IN THE CIVIL WAR, BUT IT ALL DEPENDS ON YOU!!"
  18. 50 PRINT
  19. 51 PRINT "THE OBJECT OF THE GAME IS TO WIN AS MANY BATTLES AS POSSIBLE" 
  20. 52 PRINT
  21. 55 PRINT "YOUR CHOICES FOR DEFENSIVE STRATEGY ARE:" 
  22. 60 PRINT "       (1) ARTILLERY ATTACK"
  23. 65 PRINT "       (2) FORTIFICATION AGAINST FRONTAL ATTACK"
  24. 70 PRINT "       (3) FORTIFICATION AGAINST FLANKING MANUEVERS"
  25. 75 PRINT "       (4) FALLING BACK"
  26. 80 PRINT "YOUR CHOICES FOR OFFENSIVE STRATEGY ARE:" 
  27. 85 PRINT "       (1) ARTILLERY ATTACK"
  28. 90 PRINT "       (2) FRONTAL ATTACK"
  29. 95 PRINT "       (3) FLANKING MANUEVERS"
  30. 96 PRINT "       (4) ENCIRCLEMENT"
  31. 97 PRINT "YOU MAY SURRENDER BY TYPING A '5' FOR YOUR STRATEGY." 
  32. 98 PRINT
  33. 99 PRINT "YOU ARE THE CONFEDERACY.       GOOD LUCK!"
  34. 100 READ M1,M2,C1,C2,M,A,U 
  35. 101 LET I1=10+(L-W)*2
  36. 102 LET I2=10+(W-L)*2
  37. 103 LET D1=100*INT((M1*(100-I1)/2000)*(1+(R1-Q1)/(R1+1))+0.5)
  38. 104 LET D2=100*INT(M2*(100-I2)/2000+0.5) 
  39. 105 LET F1=5*M1/6
  40. 106 LET A1=Z 
  41. 107 FOR U=1 TO 4 
  42. 108 PRINT
  43. 109 NEXT U 
  44. 110 PRINT "THIS IS THE BATTLE OF ";
  45. 115 GOSUB 800
  46. 120 PRINT " ","CONFEDERACY","  UNION"
  47. 130 PRINT "MEN"," ";INT(M1*(1+(P1-T1)/(M3+1)))," ";
  48. 131 PRINT INT(M2*(1+(P2-T2)/(M4+1))) 
  49. 140 PRINT "MONEY","$";D1,"$";D2
  50. 150 PRINT "INFLATION"," ";I1+15;"%"," ";I2;"%" 
  51. 160 PRINT
  52. 170 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR FOOD";
  53. 180 INPUT F
  54. 185 IF F<0 THEN 750
  55. 190 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR SALARIES";
  56. 200 INPUT S
  57. 205 IF S<0 THEN 750
  58. 210 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR AMMUNITION";
  59. 220 INPUT B
  60. 221 IF B<0 THEN 750
  61. 222 PRINT
  62. 224 IF F+S+B<=D1 THEN 230
  63. 226 PRINT "THINK AGAIN!  YOU HAVE ONLY $";D1
  64. 228 GOTO 160 
  65. 230 LET O=((2*F^2+S^2)/F1^2+1) 
  66. 235 IF O<10 THEN 260 
  67. 240 PRINT "MORALE IS HIGH" 
  68. 250 GOTO 300 
  69. 260 IF O<5 THEN 290
  70. 270 PRINT "MORALE IS FAIR" 
  71. 280 GOTO 300 
  72. 290 PRINT "MORALE IS POOR" 
  73. 300 IF M<>3 THEN 330 
  74. 310 PRINT "YOU ARE ON THE OFFENSIVE" 
  75. 320 GOTO 370 
  76. 330 IF M<>1 THEN 360 
  77. 340 PRINT "YOU ARE ON THE DEFENSIVE" 
  78. 350 GOTO 370 
  79. 360 PRINT "BOTH SIDES ARE ON THE OFFENSIVE"
  80. 370 PRINT
  81. 380 PRINT "YOUR STRATEGY";
  82. 390 INPUT Y
  83. 391 IF Y=5 THEN 1487 
  84. 392 IF ABS(Y-3)<3 THEN 395 
  85. 393 PRINT "YOU JERK!  USE THE OTHER SET OF STRATEGIES!!" 
  86. 394 GOTO 370 
  87. 395 PRINT
  88. 400 PRINT " ","CONFEDERACY","UNION"
  89. 410 LET C5=(2*C1/5)*(1+1/(2*(ABS(INT(4*RND+1)-Y)+1))) 
  90. 412 LET C5=INT(C5*(1+1/O)*(1.28+F1/(B+1))+0.5) 
  91. 414 IF C5+100/O<M1*(1+(P1-T1)/(M3+1)) THEN 424 
  92. 416 LET C5=INT(13*M1/20*(1+(P1-T1)/(M3+1)))
  93. 418 LET E=7*C5/13
  94. 420 LET U=1
  95. 422 GOTO 426 
  96. 424 LET E=100/O
  97. 426 PRINT "CASUALTIES",C5,INT(17*C2*C1/(C5*20)+0.5)
  98. 430 PRINT "DESERTIONS",INT(E),INT(5*O) 
  99. 432 PRINT
  100. 433 IF C5-C1>=0 THEN 439 
  101. 435 PRINT "YOUR CASUALTIES WERE ";INT(100*(C1-C5)/C1+0.5);"% LESS THAN "
  102. 437 GOTO 441 
  103. 439 PRINT "YOUR CASUALTIES WERE ";INT(100*(C5-C1)/C1+0.5);"% MORE THAN "
  104. 441 PRINT "THE ACTUAL CASUALITIES AT ";
  105. 443 LET A1=1 
  106. 445 GOSUB 800
  107. 450 IF U=1 THEN 470
  108. 460 IF C5+E<17*C2*C1/(C5*20)+5*O THEN 490
  109. 470 PRINT "YOU LOSE "; 
  110. 471 LET L=L+1
  111. 480 GOTO 555 
  112. 490 PRINT "YOU WIN ";
  113. 491 LET W=W+1
  114. 555 GOSUB 800
  115. 556 IF W=8 THEN 1490 
  116. 580 LET T1=T1+C5+E 
  117. 590 LET T2=T2+17*C2*C1/(C5*20)+5*O 
  118. 600 LET P1=P1+C1 
  119. 610 LET P2=P2+C2 
  120. 620 LET Q1=Q1+(F+S+B)
  121. 630 LET R1=R1+M1*(100-I1)/20 
  122. 635 LET M3=M3+M1
  123. 637 LET M4=M4+M2 
  124. 650 IF A=14 THEN 1500
  125. 660 GOTO 100 
  126. 670 DATA 18000,18500,1967,2708,1,1,0 
  127. 672 DATA 40000,44894,10699,13047,3,2,0 
  128. 674 DATA 95000,115000,20614,15849,3,3,0
  129. 676 DATA 54000,63000,10000,14000,2,4,0 
  130. 678 DATA 40000,50000,10000,12000,3,5,0 
  131. 680 DATA 75000,120000,5377,12653,1,6,0 
  132. 682 DATA 38000,45000,11000,12000,1,7,0 
  133. 684 DATA 32000,90000,13000,17197,2,8,0 
  134. 686 DATA 50000,70000,12000,19000,1,9,0 
  135. 688 DATA 72500,85000,20000,23000,3,10,0
  136. 690 DATA 66000,60000,18000,16000,2,11,0
  137. 692 DATA 37000,60000,6700,5800,2,12,0
  138. 694 DATA 62000,110000,17723,18000,2,13,0 
  139. 696 DATA 65000,100000,8500,3700,1,14,0 
  140. 750 PRINT "GO TO JAIL."
  141. 752 PRINT "GO DIRECTLY TO JAIL." 
  142. 754 PRINT "DO NOT PASS GO."
  143. 756 PRINT "DO NOT COLLECT $200"
  144. 758 GOTO 107 
  145. 800 IF A<>1 THEN 850 
  146. 810 PRINT "BULL RUN" 
  147. 820 IF A1=1 THEN 1480
  148. 830 PRINT"JULY 21,1861    GEN. BEAUREGARD COMMANDING THE SOUTH MET THE" 
  149. 832 PRINT"UNION FORCES WITH GEN MCDOWELL IN A PREMATURE BATTLE AT BULL" 
  150. 834 PRINT"RUN.  GEN. JACKSON HELPED PUSH BACK THE UNION ATTACK."
  151. 840 GO TO 1480 
  152. 850 IF A<>2 THEN 900 
  153. 860 PRINT "SHILOH" 
  154. 870 IF A1=1 THEN 1480
  155. 880 PRINT"APRIL 6-7,1862    THE CONFEDERATE SURPRISE ATTACK AT SHILOH"
  156. 882 PRINT"FAILED DUE TO POOR ORGANIZATION." 
  157. 890 GO TO 1480 
  158. 900 IF A<>3 THEN 950 
  159. 910 PRINT "SEVEN DAYS" 
  160. 920 IF A1=1 THEN 1480
  161. 930 PRINT"JUNE 25-JULY 1,1862    GENERAL LEE (CSA) UPHELD THE OFFENSIVE"
  162. 932 PRINT"THROUGHOUT THE BATTLE AND FORCED GEN. MCCLELLAN AND THE UNION"
  163. 934 PRINT"FORCES AWAY FROM RICHMOND." 
  164. 940 GO TO 1480 
  165. 950 IF A<>4 THEN 1000
  166. 960 PRINT "THE SECOND BULL RUN"
  167. 970 IF A1=1 THEN 1480
  168. 980 PRINT"AUG 29-30,1862    THE COMBINED CONFEDERATE FORCES UNDER LEE AND"
  169. 982 PRINT"JACKSON DROVE THE UNION FORCES BACK INTO WASHINGTON." 
  170. 990 GO TO 1480 
  171. 1000 IF A<>5 THEN 1050
  172. 1010 PRINT "ANTIETAM" 
  173. 1020 IF A1=1 THEN 1480
  174. 1030 PRINT"SEPT 17,1862    THE SOUTH FAILED TO INCORPORATE MARYLAND INTO"
  175. 1032 PRINT"THE CONFEDERACY." 
  176. 1040 GO TO 1480 
  177. 1050 IF A<>6 THEN 1100
  178. 1060 PRINT "FREDERICKSBURG" 
  179. 1070 IF A1=1 THEN 1480
  180. 1080 PRINT"DEC 13,1862 THE CONFEDERACY UNDER LEE SUCESSFULLY REPULSED" 
  181. 1082 PRINT"AN ATTACK BY THE UNION UNDER GEN. BURNSIDE."
  182. 1090 GOTO 1480
  183. 1100 IF A <>7 THEN 1150 
  184. 1110 PRINT "MURFREESBORO" 
  185. 1120 IF A1=1 THEN 1480
  186. 1130 PRINT"DEC 31,1862    THE SOUTH UNDER GEN. BRAGG WON A CLOSE BATTLE" 
  187. 1140 GOTO 1480
  188. 1150 IF A<>8 THEN 1200
  189. 1160 PRINT "CHANCELLORSVILLE" 
  190. 1170 IF A1=1 THEN 1480
  191. 1180 PRINT"MAY 1-6,1863    THE SOUTH HAD A COSTLY VICTORY AND LOST ONE"
  192. 1182 PRINT"OF THEIR OUTSTANDING GENERALS, 'STONEWALL' JACKSON."
  193. 1190 GOTO 1480
  194. 1200 IF A<>9 THEN 1250
  195. 1210 PRINT "VICKSBURG"
  196. 1220 IF A1=1 THEN 1480
  197. 1230 PRINT"JULY 4,1863    VICKSBURG WAS A COSTLY DEFEAT FOR THE SOUTH" 
  198. 1232 PRINT"BECAUSE IT GAVE THE UNION ACCESS TO THE MISSISSIPPI." 
  199. 1240 GOTO 1480
  200. 1250 IF A<>10 THEN 1300 
  201. 1260 PRINT "GETTYSBURG" 
  202. 1270 IF A1=1 THEN 1480
  203. 1280 PRINT"JUNE 30,1863    A SOUTHERN MISTAKE BY GEN. LEE AT GETTYSBURG" 
  204. 1282 PRINT"COST THEM ONE OF THE MOST CRUCIAL BATTLES OF THR WAR."
  205. 1290 GOTO 1480
  206. 1300 IF A<>11 THEN 1350 
  207. 1310 PRINT "CHICKAMAUGA"
  208. 1320 IF A1=1 THEN 1480
  209. 1330 PRINT"NOV 25,1863    AFTER THE SOUTH HAD SIEGED GEN. ROSENCRANS'" 
  210. 1332 PRINT"ARMY FOR THREE MONTHS, GEN. GRANT BROKE THE SIEGE." 
  211. 1340 GOTO 1480
  212. 1350 IF A<>12 THEN 1400 
  213. 1360 PRINT "CHATTANOOGA"
  214. 1370 IF A1=1 THEN 1480
  215. 1380 PRINT"SEPT 15,1863    CONFUSION IN A FOREST NEAR CHICKAMAUGA LED" 
  216. 1382 PRINT"TO A COSTLY SOUTHERN VICTORY."
  217. 1390 GOTO 1480
  218. 1400 IF A<>13 THEN 1450 
  219. 1410 PRINT "SPOTSYLVANIA" 
  220. 1420 IF A1=1 THEN 1480
  221. 1430 PRINT"MAY 5,1864    GRANT'S PLAN TO KEEP LEE ISOLATED BEGAN TO FAIL"
  222. 1432 PRINT"HERE, AND CONTINUED AT COLD HARBOR AND PETERSBURG." 
  223. 1440 GOTO 1480
  224. 1450 PRINT "ATLANTA"
  225. 1460 IF A1=1 THEN 1480
  226. 1470 PRINT"AUGUST, 1864   SHERMAN AND THREE VETERAN ARMIES CONVERGED ON" 
  227. 1472 PRINT"ATLANTA AND DEALT THE DEATH BLOW TO THE CONFEDERACY." 
  228. 1480 PRINT
  229. 1485 RETURN 
  230. 1487 PRINT "THE CONFEDERACY HAS SURRENDERED"
  231. 1488 GOTO 1500
  232. 1490 PRINT "THE UNION HAS SURRENDERED"
  233. 1500 PRINT
  234. 1510 PRINT "YOU HAVE WON ";W;"BATTLES AND LOST ";L;"BATTLES."
  235. 1515 IF Y=5 THEN 1550 
  236. 1520 IF W<=L THEN 1550
  237. 1530 PRINT "THE CONFIDERACY HAS WON THE WAR"
  238. 1540 STOP
  239. 1550 PRINT "THE UNION HAS WON THE WAR"
  240. 1560 END
  241.