home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug035.ark / DISTPLUS.ASM < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  10.6 KB  |  318 lines
  1. ; 30 AUG; FIXED EAST-SIDE ERROR IN 'DIST'.. MOSHELL.
  2. ;
  3. * WHERE * TYE SHULTZ /  3 FEB 79  /  VERSION 2.1
  4. *
  5. * 'WHERE' RETURNS VIA 'OUTPARM' THE X,Y LOCATION OF THE 
  6. ; CENTER  OF  GRAVITY OF THE OBJECT NAMED BY FIRST PARAM.THE
  7. * PIXEL COORDINATES ARE PLACED IN THE NEXT TWO PARAMETERS BY 'OUTPAR'.
  8. * 
  9. * SYSTEM SUBROUTINES: INPARM, OBJR, OUTPARM.
  10. *
  11. * ALL REGISTERS ARE RESTORED.
  12. *
  13. CTRGRAVX EQU    2
  14. INPARM    EQU    5030H
  15. OUTPARM    EQU    5033H
  16. OBJR    EQU    5006H
  17. *
  18.     ORG    2E50H
  19. WHERE:    MVI    H,0    ;
  20.     CALL    INPARM    ; GET OBJECT # INTO D.
  21.     MOV    D,E
  22.     MVI    E,CTRGRAVX    ; POINT E AT  CTR.OF GRAV. X COORD.
  23.     CALL    OBJR    ; GET FIRST X INTO A.
  24.     XCHG
  25.     MOV    E,A
  26.     CALL    OUTPARM    ; PUT X INTO SECOND PARAMETER.
  27.     XCHG
  28.     INR    E    ; POINT  E AT FIRST  PIXEL Y COORD.
  29.     CALL    OBJR    ; GET Y INTO A.
  30.     XCHG
  31.     MOV    E,A
  32.     CALL    OUTPARM    ; PUT IT IN THE THIRD PARAMETER.
  33.     RET
  34. ***********************************************************************
  35. *                                                                     *
  36. *                   DISTANCE OPERATOR                                 *
  37. *                   VERSION 1.1                                       *
  38. *                   MAR. 26, 1979                                     *
  39. *                   TYE SHULTZ                                        *
  40. *                                      *
  41. *    THIS ROUTINE FINDS THE DISTANCE BETWEEN THE TWO OBJECTS          *
  42. *    SPECIFIED IN THE FIRST TWO PARAMETERS FOLLOWING THE OPCODE.      *
  43. *    THE DISTANCE FOUND IS PLACED IN THE THIRD PARAMETER.             *
  44. *                                          *
  45. *    THERE ARE TWO MAJOR PHASES TO THIS ROUTINE:              *
  46. *      1) FIND THE MINIMUM AND MAXIMUM X COORDINATE AND Y COORD       *
  47. *         IN EACH OF THE OBJECTS AND SAVE THEM IN 8 CONSECUTIVE       *
  48. *         BYTES.                              *
  49. *      2) USING THE MINIMUMS AND MAXIMUMS FOUND IN PHASE I, FIND      *
  50. *         THE DISTANCE BETWEEN THE TWO OBJECTS AND PLACE IT IN        *
  51. *         THE THIRD PARAMETER.  THE ALGORITHM FOR THIS IS DESCRIBED   *
  52. *         BELOW (SEE PHASE II).                             *
  53. *                                      *
  54. *    SUBROUTINES CALLED --                          *
  55. *      INPARM - RETURNS THE NEXT PARAMETER IN THE PROGRAM QUEUE     *
  56. *                 IN REGISTERS D AND E (16 BIT PARAMS) OR IN E (8     *
  57. *                 BIT PARAMS).                          *
  58. *        OUTPARM - PLACES THE 16 BIT VALUE IN D,E OR THE 8 BIT VALUE  *
  59. *               IN E INTO THE NEXT PARAMETER IN THE PROGRAM        *
  60. *              QUEUE. IF THE VALUE IS IN E ONLY, D MUST          *
  61. *           BE ZERO.                          *
  62. *        OBJR - RETURNS A BYTE FROM AN OBJECT IN REGISTER A. THE      *
  63. *        NUMBER OF THE DESIRED OBJECT MEST BE IN D AND THE     *
  64. *               NUMBER OF THE DESIRED BYTE MUST BE IN E.          *
  65. *     OBJW - PUTS THE CONTENTS OF REGISTER A INTO A BYTE OF    *
  66. *               OF AN OBJECT. REGISTERS ARE AS IN OBJR.                 *
  67. *     SCANNER - SCANS THE PIXELS BYTES OF AN OBJECT AND          *
  68. *            RETURNS THE MINIMUM AND MAXIMUM X AND Y           *
  69. *           COORDINATES IN THE OBJECT. WHEN SCANNER IS       *
  70. *            CALLED, REGISTERS D AND E MUST HAVE THE OBJECT     *
  71. *           NUMBER AND THE NUMBER OF THE BYTE WHICH CONTAINS   *
  72. *           THE Y COORD OF THE FIRST PIXEL (CURRENTLY THE    *
  73. *           5TH BYTE OF THE OBJECT). REGISTERS BC AND HL          *
  74. *           MUST HAVE THE X,Y COORDS OF THE FIRST PIXEL.          *
  75. *                                      *
  76. ***********************************************************************
  77. *
  78. INPARM    EQU    5030H
  79. OUTPARM EQU    5033H
  80. OBJR    EQU    5006H
  81. PIXEL1X EQU    4
  82. ;
  83. ;
  84.     ORG    2E70H
  85. DIST:    MVI    A,1    ;SET OBJECT FLAG TO 1 INITIALLY. WHEN AN OBJECT
  86.     STA    OBJFLAG    ;HAS BEEN SCANNED, OBJFLAG IS DECREMENTD BY 1. IF
  87.             ;IT IS THEN NON-NEGATIVE, THE NEXT OBJECT IS
  88.             ;SCANNED. OTHERWISE, PHASE II BEGINS.
  89.     LXI    H,OBJ1XMAX    ;GET THE ADDRESS OF THE FIRST OF THE 8
  90.     PUSH    H        ;BYTES THAT WILL HOLD THE MIN AND MAX X AND
  91.                 ;Y COORDS.
  92. ;
  93. ;
  94. ************
  95. *
  96. *    PHASE I -- GET THE NUMBER OF THE OBJECT SPECIFIED BY THE NEXT
  97. *             PARAMETER IN THE QUEUE AND INITIALIZE THE MINS AND MAXIMUMS
  98. *        FOR THAT OBJECT. CALL THE SCANNER TO RETURN THE ACTUAL
  99. *        MINIMUMS AND MAXIMUMS AND SAVE THEM. THEN CHECK IF ANOTHER
  100. *        OBJECT REMAINS TO BE SCANNED. IF ONE DOES REMAIN, CONTINUE
  101. *        PHASE I AT THE TOP; OTHERWISE GO ON TO PHASE II.
  102. ;
  103. ;
  104. PHASE1:    CALL    INPARM        ;GET THE NUMBER OF THE NEXT OBJECT INTO D
  105.     MOV    D,E        ;AND THE BYTE NUMBER OF THE FIRST PIXEL X
  106.     MVI    E,PIXEL1X    ;COORD INTO E.
  107.     CALL    OBJR        ;GET THE VALUE OF THE FIRST PIXEL X COORD INTO
  108.     MOV    B,A        ;REGISTERS B AND H (INITIAL MIN AND MAX).
  109.     MOV    H,A        ;THEN POINT REGISTER E AT THE FIRST PIXEL Y
  110.     INR    E        ;COORD, GET THE Y VALUE, AND INITIALIZE THE
  111.     CALL    OBJR        ;MINIMUM AND MAXIMUM Y COORD
  112.     MOV    C,A        ;REGISTER C AND L.
  113.     MOV    L,A
  114.     CALL    SCANNER        ;SCAN THE OBJECT FOR THE ACTUAL MINIMUM AND
  115.                 ;MAXIMUM X AND Y (X MIN IN B, MAX IN H - Y
  116.                 ;MIN IN C AND MAX IN L).
  117. ;
  118. ;    SAVE THE MINIMUM AND MAXIMUM VALUES FOR THE CURRENT OBJECT.
  119. ;
  120.     XCHG            ;SAVE THE MAX X AND Y IN DE. THEN GET THE ADDRESS
  121.     POP    H        ;OF THE FIRST OF THE FOUR BYTES WHICH WILL
  122.     MOV    M,D        ;HOLD THE MINS AND MAXES. SAVE THE MAX X.
  123.     INX    H        ;
  124.     MOV    M,B        ;SAVE THE MIN X.
  125.     INX    H
  126.     MOV    M,E        ;SAVE THE MAX Y.
  127.     INX    H        ;
  128.     MOV    M,C        ;SAVE THE MIN Y.
  129.     INX    H        ;LEAVE HL POINTING AT THE NEXT BYTE TO HOLD
  130.                 ;A MAX X (IF THERE IS ANOTHER OBJECT TO BE
  131.                 ;SCANNED).
  132. ;
  133. ;    CHECK IF ANOTHER OBJECT NEEDS TO BE SCANNED. IF ONE DOES, GO BACK
  134. ;    TO THE START OF PHASE I. OTHERWISE, GO ON TO PHASE II.
  135. ;
  136.     LDA    OBJFLAG        ;GET THE END OF PHASE I FLAG AND DECREMENT IT.
  137.     DCR    A        ;IF THE RESULT IS NEGATIVE, BOTH OBJECTS HAVE
  138.     JM    PHASE2        ;BEEN SCANNED --> GO TO PHASE II. OTHERWISE, 
  139.     STA    OBJFLAG        ;SAVE THE FLAG AND THE ADDRESS OF THE BYTE
  140.     PUSH    H        ;BYTE WHICH WILL RECEIVE THE MAX X OF THE
  141.     JMP    PHASE1        ;SECOND OBJECT AND CONTINUE PHASE I.
  142. ;
  143. ;
  144. *****************
  145. *
  146. *    PHASE II -- THIS PHASE DETERMINES THE DISTANCE BETWEEN THE TWO
  147. *         OBJECTS AND PLACES THAT DISTANCE IN THE NEXT PARAMETER
  148. *         IN THE QUEUE. TO DETERMINE THE DISTANCE BETWEEN THE TWO
  149. *         OBJECTS, THIS VERSION FIRST FINDS THE DISPLACEMENTS
  150. *         BETWEEN THE OBJECTS IN THE X AND Y DIRECTIONS. IF THE
  151. *         OBJECTS OVERLAP IN EITHER (OR BOTH) DIRECTIONS, A
  152. *         DISPLACEMENT OF -1 IS ASSIGNED IN THAT DIRECTION. THE
  153. *         LARGER OF THE TWO DISPLACEMENTS IS THEN CHOSEN AS THE
  154. *         DISTANCE BETWEEN THE OBJECTS. IF BOTH DISPLACEMENTS ARE
  155. *         -1, A DISTANCE OF 0 IS CHOSEN.
  156. *
  157. *****************
  158. ;
  159. ;
  160. *
  161. *    THIS SECTION DETERMINES THE DISPLACEMENT OF THE TWO OBJECTS IN THE X
  162. *    DIRECTION AND EXITS WITH THAT DISPLACEMENT IN REGISTER H.
  163. *
  164. ;
  165. PHASE2:    LDA    OBJ1XMAX    ;CHECK IF THE MAXIMUM X OF THE FIRST OBJECT
  166.     MOV    B,A        ;IS <= THE MINIMUM X OF THE SECOND OBJECT.
  167.     LDA    OBJ2XMIN    ;IF IT IS, GET THE X DISPLACEMENT INTO A AND
  168.     SUB    B        ;JUMP TO THE END OF THIS SECTION. OTHERWISE,
  169.     JM    XTEST2        ;JUMP TO THE NEXT TEST.
  170.     JMP    SECTEND
  171. ;
  172. XTEST2:    LDA    OBJ2XMAX    ;CHECK IF THE MAX X OF THE SECOND OBJECT IS
  173.     MOV    B,A        ; <= THE MINIMUM X OF THE FIRST OBJECT.
  174.     LDA    OBJ1XMIN    ;IF IT IS, GET THE X DISPLACEMENT INTO A AND
  175.     SUB    B
  176.     JP    SECTEND        ;JUMP TO THE END OF THIS SECTION. OTHERWISE,
  177.     XRA    A        ;THE OBJECTS OVERLAP AND A DISPLACEMENT OF
  178.     DCR    A        ; -1 IS SAVED.
  179. SECTEND:    MOV    H,A    ;SAVE THE DISPLACEMENT FOUND FOR USE IN THE THIRD
  180.                 ;SECTION.
  181. ;
  182. ;
  183. *
  184. *    THIS SECTION DETERMINES THE DISPLACEMENT OF THE TWO OBJECTS IN THE Y
  185. *    DIRECTION AND EXITS WITH THE DISPLACEMENT FOUND IN REGISTER A.
  186. *
  187. ;
  188. ;
  189.     LDA    OBJ1YMAX    ;LOGIC IS THE SAME AS THE LAST SECTION.
  190.     MOV    B,A
  191.     LDA    OBJ2YMIN
  192.     SUB    B
  193.     JP    GETDIST
  194. ;
  195.     LDA    OBJ2YMAX
  196.     MOV    B,A
  197.     LDA    OBJ1YMIN
  198.     SUB    B
  199.     JP    GETDIST
  200. ;
  201.     XRA    A
  202.     DCR    A
  203. ;
  204. ;
  205. ;
  206. *
  207. *    THIS SECTION CHOOSES THE LARGER OF THE TWO DISPLACEMENTS FOUND PREVIOUSLY
  208. *    AND SETS THE NEXT PARAMETER IN THE QUEUE TO THIS DISTANCE. IF
  209. *    BOTH DISPLACEMENTS = -1, THE DISTANCE BETWEEN THE TWO
  210. *    OBJECTS IS ZERO.
  211. *
  212. ;
  213. GETDIST:    CMP    H    ;IF THE TWO DISPLACEMENTS ARE EQUAL, GO CHECK
  214.     JZ    TSTOUCH        ;IF THEY ARE BOTH = -1. IF THE Y DISPLACEMENT
  215.     JP    SAVYDIST    ;(IN A) IS GREATER, GO SAVE IT.
  216.     MOV    E,H        ;ELSE SAVE THE X DISPLACEMENT AND GO EXIT
  217.     JMP    ENDIST        ;THIS SECTION.
  218. ;
  219. TSTOUCH:    ANA    A    ;CHECK IF THE Y DISPLACEMENT IS -1. IF NOT,
  220.     JP    SAVYDIST    ;GO SAVE IT AS THE DISTANCE. IF IT IS, 
  221.     XRA    A        ;SET IT TO 0 AND FALL THROUGH.
  222. SAVYDIST:    MOV    E,A    ;SAVE THE Y DISPLACEMENT (OR A ZERO IF 
  223.                 ;BOTH DISPLACEMENTS WERE -1.
  224. ENDIST:    XRA    A        ;MOVE A ZERO INTO D AND PUT THE DISTANCE INTO
  225.     MOV    D,A    ;THE NEXT PARAMETER.THEN RETURN CONTROL TO EXEC.
  226.     PUSH    D
  227.     CALL    OUTPARM
  228.     POP    D
  229. ;
  230. ; SET THE ZERO FLAG IF DISTANCE IS ZERO.CLEAR IT OTHERWISE.
  231. ZFLAG    EQU    40H
  232. NOZFLAG    EQU    0BFH
  233. FLAGS    EQU    114H
  234. ;
  235.     XRA    A
  236.     CMP    E    ;IF E IS ZERO,
  237.     JZ    YESZERO
  238. NOZERO:    LDA    FLAGS
  239.     ANI    NOZFLAG
  240.     STA    FLAGS
  241.     RET
  242. YESZERO:LDA    FLAGS
  243.     ORI    ZFLAG
  244.     STA    FLAGS
  245.     RET
  246. ;
  247. ;
  248. ;
  249. *************************************************************************
  250. *                                    *
  251. *    SCANNER -- THIS ROUTINE SCANS THROUGH THE OBJECT, COMPARING EACH    *
  252. *            X AND Y COORD TO THE MINIMUM AND MAXIMUM X AND Y FOUND    *
  253. *        SO FAR. ON ENTRY, BC AND HL MUST HAVE THE X,Y OF THE     *
  254. *        FIRST PIXEL. DE MUST HAVE THE NUMBER OF THE OBJECT    *
  255. *        TO BE SCANNED AND THE NUMBER OF THE BYTE WHICH HAS    *
  256. *        THE Y OF THE FIRST PIXEL.                *
  257. *                                    *
  258. *************************************************************************
  259. ;
  260. ;
  261. SPECODE    EQU    0FFH
  262. ENDFLAG    EQU    80H
  263. ;
  264. SCANNER:    INR    E    ;CHECK IF THE NEXT BYTE OF THE OBJECT IS A
  265.     CALL    OBJR        ;IS A SPECIAL CODE (HEX FF). IF IT IS,
  266.     CPI    SPECODE        ;JUMP TO A ROUTINE TO CHECK IF THE END
  267.     JZ    TESTEND        ;OF THE OBJECT HAS BEEN REACHED. THIS ROUTINE
  268.                 ;BUMPS REG E TO THE NEXT PIXEL AND RETURNS
  269.                 ;TO THE TOP OF THE SCANNER IF THE END WASN'T
  270.                 ;REACHED.
  271.     CMP    B        ;CHECK IF THE NEX X IS A NEW MIN OR MAX.
  272.     JM    NEWXMIN        ;IF IT'S A NEW MIN, GO SAVE IT AND CHECK FOR
  273.     CMP    H        ;A NEW Y MIN OR MAX. ELSE DO THE SAME FOR A NEW
  274.     JM    CHECKY        ;X MAX. IF IT'S NOT A NEW MIN OR MAX X,
  275.                 ;GO CHECK THE NEXT Y.
  276. NEWXMAX:MOV    H,A
  277.     JMP    CHECKY
  278. NEWXMIN:MOV    B,A    ;SAVE THE NEW MINIMUM X.
  279. CHECKY:    INR    E        ;POINT E AT THE NEXT BYTE (A Y COORD).
  280.     CALL    OBJR
  281.     CMP    C
  282.     JM    NEWYMIN
  283.     CMP    L
  284.     JM    SCANNER
  285.     MOV    L,A        ;SAVE A NEW Y MAX.
  286.     JMP    SCANNER
  287. NEWYMIN:    MOV    C,A    ;SAVE A NEW Y MIN.
  288.         JMP    SCANNER
  289. ;
  290. ;
  291. ;    THIS ROUTINE CHECKS IF THE BYTE FOLLOWING A SPECIAL CODE BYTE IS AN
  292. ;    END OF OBJECT FLAG (HEX 80). IF IT IS, A RETURN FROM THE SCANNER
  293. ;    IS EXECUTED. IF NOT, CONTROL RETURNS TO THE TOP OF THE SCANNER.
  294. ;
  295. TESTEND:    INR    E
  296.         CALL    OBJR
  297.         CPI    ENDFLAG
  298.         JNZ    SCANNER
  299.         RET
  300. ;
  301. ;
  302. *********************************************************************
  303. *
  304. *    DATA AREA FOR DISTANCE OPERATOR.
  305. *
  306. *********************************************************************
  307. ;
  308. ;
  309. OBJ1XMAX    DB    0H
  310. OBJ1XMIN    DB    0H
  311. OBJ1YMAX    DB    0H
  312. OBJ1YMIN    DB    0H
  313. OBJ2XMAX    DB    0H
  314. OBJ2XMIN    DB    0H
  315. OBJ2YMAX    DB    0H
  316. OBJ2YMIN    DB    0H
  317. OBJFLAG        DB    1
  318.