home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug054.ark / BULCOW.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  2.0 KB  |  64 lines
  1. 5 GOSUB500
  2. 10 DIMD(10,4),B(10),C(10),G(10)
  3. 15 RANDOMIZE:PRINT
  4. 17 PRINT"       BULL = CORRECT DIGIT IN THE CORRECT POSITION"
  5. 18 PRINT"       COW  = CORRECT DIGIT BUT IN THE WRONG POSITION"
  6. 20 LETA=0:GOTO200
  7. 30 PRINT:PRINT:PRINT"           THINK OF A 5 DIGIT NUMBER AND I WILL TRY TO"
  8. 32 PRINT"           GUESS IT WHILE YOU TRY TO GUESS MY NUMBER !!"
  9. 35 PRINT"YOUR GUESS";:INPUTN:LETN=(N+.1)/100000
  10. 40 FORI=0TO4:LETG(I)=INT(10*N):LETN=10*N-INT(10*N)
  11. 41 FORK=0TOI-1:IFG(I)=G(K)GOTO170
  12. 42 NEXTK
  13. 43 NEXTI
  14. 45 LETP=4:LETA=0:GOSUB300
  15. 50 PRINTV"BULL";:IFV<>1THENPRINT"S";
  16. 55 IFV=5THENPRINT" - YOU WIN":GOTO20
  17. 60 PRINTW-V"COW";:IFW<>V+1THENPRINT"S";
  18. 65 IFJ=0THENLETA=1:GOTO200
  19. 68 GOSUB400
  20. 70 PRINT" - MY GUESS IS ";
  21. 75 FORI=0TO4:PRINTCHR$(D(J,I)+48);:NEXTI
  22. 80 PRINT" MY SCORE";:INPUTB(J),C(J):LETC(J)=C(J)+B(J)
  23. 81 IFB(J)>-1THENIFB(J)<6THENIFC(J)<6THENIFC(J)-B(J)>-1GOTO83
  24. 82 PRINT" - RIDICULOUS!!";:GOTO70
  25. 83 IFB(J)=4THENIFC(J)=5GOTO82
  26. 85 IFB(J)=5THENPRINT" - I WIN - MY NUMBER WAS ";:GOTO100
  27. 90 GOTO 35
  28. 100 FORI=0TO4:PRINTCHR$(D(0,I)+48);:NEXTI
  29. 110 GOTO20
  30. 150 PRINT:PRINT"YOU HAVE GIVEN ME IMPOSSIBLE SCORES - GAME SPOILED": GOTO10
  31. 170 PRINT"REPEATED DIGITS NOT ALLOWED":GOTO35
  32. 200 FORP=0TO4
  33. 210 LETD(A,P)=INT(10*RND(1))
  34. 220 FORI=0TOP-1:IFD(A,I)=D(A,P)GOTO210
  35. 230 NEXTI
  36. 240 NEXTP
  37. 250 IFA=0GOTO30
  38. 260 LETJ=1:GOTO70
  39. 300 LETV=0:LETW=0
  40. 310 FORI=0TOP:IFD(A,I)=G(I)THENLETV=V+1
  41. 320 FORK=0TO4:IFD(A,K)=G(I)THENLETW=W+1
  42. 330 NEXTK
  43. 340 NEXTI
  44. 350 RETURN
  45. 400 LETP=0
  46. 405 LETG(P)=D(J,P)
  47. 410 FORI=0TOP-1:IFG(I)=G(P)GOTO430
  48. 415 NEXTI
  49. 420 FORA=1TOJ:GOSUB300
  50. 425 IFV<=B(A)THENIFW<=C(A)THENIF4-P>=C(A)-WTHENIF4-P>=B(A)-VGOTO448
  51. 430 LETG(P)=G(P)+3:IFG(P)>9THENLETG(P)=G(P)-10
  52. 432 IFP=0THENIFG(P)=D(1,0)GOTO150
  53. 435 IFG(P)<>D(J,P)GOTO410
  54. 440 LETP=P-1:IFP<0THENGOTO150
  55. 445 GOTO430
  56. 448 NEXTA
  57. 450 LETP=P+1:IFP<5GOTO405
  58. 455 LETJ=J+1
  59. 460 FORI=0TO4:LETD(J,I)=G(I):NEXTI
  60. 465 RETURN
  61. 500 PRINT:PRINT:PRINT"           BRADFORD UNIVERSITY BULLS AND COWS GAME"
  62. 510 GOTO10
  63. 999 END
  64.