home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug054.ark / DEFUSE.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  2.0 KB  |  42 lines
  1. 5 REM *** WRITTEN BY TOM KARZES, CURTIS JR HS, SUDBURY, MA
  2. 6 REM *** MODIFIED BY DAVE AHL, DIGITAL
  3. 10 PRINT "YOU ARE IN A LARGE, NEW GOVERNMENT BUILDING WITH 1,000,000"
  4. 20 PRINT "ROOMS IN IT.  THE BUILDING IS 100 ROOMS LONG (0-99), 100"
  5. 30 PRINT "ROOMS WIDE (0-99), AND 100 FLOORS HIGH (0-99).":PRINT 
  6. 40 PRINT "A MAD BOMBER HAS HIDDEN A BOMB IN ONE OF THE ROOMS AND"
  7. 50 PRINT "HAS JUST PHONED A THREAT THAT THE BOMB IS SET TO GO"
  8. 60 PRINT "OFF IN 200 SECONDS.  FORTUNATELY, YOU HAPPEN TO HAVE A BOMB-"
  9. 70 PRINT "TRACKER THAT SENDS OUT SIGNALS THAT GET STRONGER AS YOU"
  10. 80 PRINT "GET CLOSER TO THE BOMB.  YOU ARE STARTING IN ROOM 0,0,0"
  11. 90 PRINT "AND IT TAKES 10 SECONDS TO MOVE TO ANY OTHER ROOM.":PRINT 
  12. 100 RANDOMIZE:A=INT(100*RND):B=INT(100*RND):C=INT(100*RND)
  13. 110 IF A=0 AND B=0 AND C=0 THEN 100
  14. 120 P1=A/100+B+C*100:D=0:E=0:F=0:G=0:P=0
  15. 125 PRINT "SIGNAL","CURRENT ROOM","SEC. INTO","COORDINATES FOR"
  16. 130 PRINT "STRENGTH","L , W , H","MISSION","SEARCH (L,W,H)"
  17. 132 B$=" ####.##      ##  ##  ##     ###           "
  18. 135 PRINT USING B$;10000-ABS(P1-P),D,E,F,G;
  19. 140 INPUT D,E,F:G=G+10:P=D/100+E+F*100
  20. 142 IF P=P1 THEN 170
  21. 145 IF G=200 THEN GOTO 150 ELSE GOTO 180
  22. 150 PRINT "BOOOOOOOMMM!!!":PRINT "YOU BLEW IT.  THE BUILDING BLEW UP."
  23. 152     PRINT "The bomb coordinates were:";A;",";B;",";C
  24. 155 PRINT :INPUT "WANT TO PLAY AGAIN (YES OR NO)";A$
  25. 160 IF A$="NO" THEN GOTO 999 ELSE PRINT :PRINT :GOTO 100
  26. 170 PRINT "BOMB DEACTIVATED AT";G;"SECONDS!!!":PRINT :GOTO 155
  27. 180 IF D>99 OR D<0 OR E>99 OR E<0 THEN 200
  28. 190 IF F>99 THEN GOTO 220
  29. 195 IF F<0 THEN GOTO 230 ELSE GOTO 135
  30. 200 PRINT "YOU WALKED OUT A WINDOW ON THE";
  31. 201 IF F<4 THEN 240
  32. 205 PRINT  F;"TH FLOOR!!!"
  33. 210 PRINT "YOU WERE KILLED AND";200-G;"SECONDS LATER THE BUILDING"
  34. 215 PRINT "BLEW UP!!!":PRINT :GOTO 155
  35. 220 PRINT "YOU ARE NOW";F*9;"FEET IN THE AIR!!!":GOTO 210
  36. 230 PRINT "YOU ARE NOW -";F*9;"FEET UNDERGROUND!!!":GOTO 210
  37. 240 ON F GOTO 250,260,270
  38. 250 PRINT " 1ST FLOOR!!!":GOTO 210
  39. 260 PRINT " 2ND FLOOR!!!":GOTO 210
  40. 270 PRINT " 3RD FLOOR!!!":GOTO 210
  41. 999 END
  42.