home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug054.ark / GUNNER.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  1.9 KB  |  59 lines
  1. 10 REM *** MODIFIED AND CONVERTED TO RSTS/E BY DAVID AHL, DIGITAL
  2. 90 RANDOMIZE
  3. 100 PRINT "THIS COMPUTER DEMONSTRATION SIMULATES THE"
  4. 110 PRINT"RESULTS OF FIRING A FIELD ARTILLERY WEAPON."
  5. 120 PRINT
  6. 130 PRINT"YOU ARE THE OFFICER-IN-CHARGE, GIVING ORDERS TO THE GUN"
  7. 140 PRINT"CREW, TELLING THEM THE DEGREES OF ELEVATION YOU ESTIMATE"
  8. 150 PRINT"WILL PLACE THE PROJECTILE ON TARGET.  A HIT WITHIN 100 YARDS"
  9. 160 PRINT "OF THE TARGET WILL DESTROY IT.  TAKE MORE THAN 5 SHOTS,"
  10. 170 PRINT "AND THE ENEMY WILL DESTROY YOU!":PRINT
  11. 180 PRINT"MAXIMUM RANGE OF YOUR GUN IS 46500 YARDS."
  12. 185 Z=0
  13. 190 PRINT
  14. 195 S1=0
  15. 200 LET T=43000-30000*RND(X)
  16. 210 LET S=0
  17. 220 GOTO 370
  18. 230 PRINT"MINIMUM ELEVATION OF GUN IS ONE DEGREE."
  19. 240 GOTO 390
  20. 250 PRINT"MAXIMUM ELEVATION OF GUN IS 89 DEGREES."
  21. 260 GOTO 390
  22. 270 PRINT"OVER TARGET BY";ABS(E);"YARDS."
  23. 280 GOTO 390
  24. 290 PRINT "SHORT OF TARGET BY";ABS(E);"YARDS."
  25. 300 GOTO 390
  26. 310 GOTO 320
  27. 320 PRINT"***TARGET DESTROYED***   ";S;"ROUNDS OF AMMUNITION EXPENDED"
  28. 322 GOSUB 600
  29. 325 S1=S1+S
  30. 330 IF Z=4 THEN 490
  31. 340 Z=Z+1
  32. 345 PRINT
  33. 350 PRINT"THE FORWARD OBSERVER HAS SIGHTED MORE ENEMY ACTIVITY."
  34. 360 GOTO 200
  35. 370 PRINT"     DISTANCE TO THE TARGET IS";INT(T);"YARDS....."
  36. 380 PRINT
  37. 390 PRINT
  38. 400 PRINT"ELEVATION:";
  39. 410 INPUT B
  40. 420 IF B>89 THEN 250
  41. 430 IF B<1 THEN 230
  42. 440 LET S=S+1
  43. 442 IF S<6 THEN 450
  44. 444 PRINT:PRINT "BOOM !!!  YOU HAVE JUST BEEN DESTROYED ";
  45. 445 GOSUB 600
  46. 446 PRINT "BY THE ENEMY":PRINT:PRINT:GOTO 495
  47. 450 LET B2=2*B/57.3:LET I=46500*SIN(B2):LET X=T-I:LET E=INT(X)
  48. 460 IF ABS(E)<100 THEN 310
  49. 470 IF E>100 THEN 290
  50. 480 IF E<-100 THEN 270
  51. 490 PRINT:PRINT:PRINT "TOTAL ROUNDS EXPENDED WERE";S1
  52. 491 IF S1>15 THEN 495 ELSE PRINT "NICE SHOOTING !!":GOSUB 600:GOTO 500
  53. 495 PRINT "BETTER GO BACK TO FORT SILL FOR REFRESHER TRAINING!"
  54. 500 PRINT:PRINT "THANK YOU FOR PLAYING!"
  55. 505 PRINT:PRINT "TRY AGAIN.....":PRINT:GOTO 180
  56. 600 FOR N=1 TO 10:PRINT CHR$(7);:NEXT N
  57. 610 RETURN
  58. 999 END
  59.