home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug054.ark / ROCKT1.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  2.6 KB  |  71 lines
  1. 5 REM **** WRITTEN BY ERIC PETERS, DIGITAL
  2. 10 REM *** CONVERTED TO RSTS/E BY DAVID AHL, DIGITAL
  3. 70 PRINT "LUNAR LANDING SIMULATION"
  4. 80 PRINT "----- ------- ----------":PRINT
  5. 100 INPUT "DO YOU WANT INSTRUCTIONS (YES OR NO)";A$
  6. 120 IF A$="NO" THEN 390
  7. 160 PRINT
  8. 200 PRINT "YOU ARE LANDING ON THE MOON AND HAVE TAKEN OVER MANUAL"
  9. 210 PRINT "CONTROL 500 FEET ABOVE A GOOD LANDING SPOT.  YOU HAVE A"
  10. 220 PRINT "DOWNWARD VELOCITY OF 50 FT/SEC.  120 UNITS OF FUEL REMAIN."
  11. 225 PRINT
  12. 230 PRINT "HERE ARE THE RULES THAT GOVERN YOUR SPACE VEHICLE:"
  13. 240 PRINT "(1) AFTER EACH SECOND, THE HEIGHT, VELOCITY, AND REMAINING"
  14. 250 PRINT "    FUEL WILL BE REPORTED."
  15. 260 PRINT "(2) AFTER THE REPORT, A '?' WILL BE TYPED.  ENTER THE"
  16. 270 PRINT "    NUMBER OF UNITS OF FUEL YOU WISH TO BURN DURING THE"
  17. 280 PRINT "    NEXT SECOND.  EACH UNIT OF FUEL WILL SLOW YOUR DESCENT"
  18. 290 PRINT "    BY 1 FT/SEC."
  19. 310 PRINT "(3) THE MAXIMUM THRUST OF YOUR ENGINE IS 30 FT/SEC/SEC OR"
  20. 320 PRINT "    30 UNITS OF FUEL PER SECOND."
  21. 330 PRINT "(4) WHEN YOU CONTACT THE LUNAR SURFACE, YOUR DESCENT ENGINE"
  22. 340 PRINT "    WILL AUTOMATICALLY CUT OFF AND YOU WILL BE GIVEN A"
  23. 350 PRINT "    REPORT OF YOUR LANDING SPEED AND REMAINING FUEL."
  24. 360 PRINT "(5) IF YOU RUN OUT OF FUEL, THE '?' WILL NO LONGER APPEAR,"
  25. 370 PRINT "    BUT YOUR SECOND BY SECOND REPORT WILL CONTINUE UNTIL"
  26. 380 PRINT "    YOU CONTACT THE LUNAR SURFACE.":PRINT
  27. 390 PRINT "BEGINNING LANDING PROCEDURE.....":PRINT
  28. 410 PRINT "G O O D   L U C K ! ! !"
  29. 420 PRINT:PRINT
  30. 440 PRINT "SEC  FEET   SPEED    FUEL      PLOT OF DISTANCE"
  31. 450 PRINT
  32. 455 T=0:H=500:V=50:F=120
  33. 490 PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(29);"I";TAB(H/12+29);"*"
  34. 500 INPUT B
  35. 510 IF B<0 THEN 650
  36. 520 IF B>30 THEN B=30
  37. 530 IF B>F THEN B=F
  38. 540 V1=V-B+5
  39. 560 F=F-B
  40. 570 H=H-.5*(V+V1)
  41. 580 IF H<=0 THEN 670
  42. 590 T=T+1
  43. 600 V=V1
  44. 610 IF F>0 THEN 490
  45. 615 IF B=0 THEN 640
  46. 620 PRINT "*** OUT OF FUEL ***"
  47. 640 PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(29);"I";TAB(H/12+29);"*"
  48. 650 B=0
  49. 660 GOTO 540
  50. 670 PRINT "*** CONTACT ***"
  51. 680 H=H+.5*(V+V1)
  52. 690 IF B=5 THEN 720
  53. 700 D=(-V+SQR(V*V+H*(10-2*B)))/(5-B)
  54. 710 GOTO 730
  55. 720 D=H/V
  56. 730 V1=V+(5-B)*D
  57. 760 PRINT "TOUCHDOWN AT";T+D;"SECONDS."
  58. 770 PRINT "LANDING VELOCITY =";V1;"FT/SEC"
  59. 780 PRINT F;"UNITS OF FUEL REMAINING."
  60. 790 IF V1<>0 THEN 810
  61. 800 PRINT "CONGRATULATIONS!!    A PERFECT LANDING!"
  62. 805 PRINT "YOUR LICENSE WILL BE RENEWED.......LATER."
  63. 810 IF ABS(V1)<2 THEN 840
  64. 820 PRINT "***** SORRY, BUT YOU BLEW IT!!!!"
  65. 830 PRINT "APPROPRIATE CONDOLENCES WILL BE SENT TO YOUR NEXT OF KIN."
  66. 840 PRINT:PRINT:PRINT
  67. 850 INPUT "ANOTHER MISSION";A$
  68. 870 IF A$="YES" THEN 390
  69. 880 PRINT:PRINT "CONTROL OUT.":PRINT
  70. 999 END
  71.