home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug054.ark / STARS.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  1.6 KB  |  59 lines
  1. 100 PRINT "STARS - A NUMBER GUESSING GAME"
  2. 110 PRINT
  3. 120 RANDOMIZE
  4. 130 REM *** A IS LIMIT ON NUMBER, M IS NUMBER OF GUESSES
  5. 140 LET A=100
  6. 150 LET M=7
  7. 160 PRINT "DO YOU WANT INSTRUCTIONS (1=YES 0=NO)";
  8. 170 INPUT Z
  9. 180 IF Z=0 THEN 270
  10. 190 REM *** INSTRUCTIONS ON HOW TO PLAY
  11. 200 PRINT "I AM THINKING OF A WHOLE NUMBER FROM 1 TO";A
  12. 210 PRINT "TRY TO GUESS MY NUMBER. AFTER YOU GUESS, I"
  13. 220 PRINT "WILL TYPE ONE OR MORE STARS (*). THE MORE"
  14. 230 PRINT "STARS I TYPE, THE CLOSER YOU ARE TO MY NUMBER."
  15. 240 PRINT "ONE STAR (*) MEANS FAR AWAY. SEVEN STARS (*******)"
  16. 250 PRINT "MEANS REALY CLOSE. YOU GET";M;"GUESES."
  17. 260 REM *** COMPUTER 'THINKS' OF A NUMBER
  18. 270 PRINT:PRINT
  19. 280 LET X=INT(A*RND(1))+1
  20. 290 PRINT "OK, I AM THINKING OF A NUMBER. START GUESSING."
  21. 300 LET E=E+1
  22. 310 REM *** GUESSING BEGINS. HUMAN GETS M GUESSES
  23. 320 FOR K=1 TO M
  24. 330 PRINT
  25. 340 PRINT "YOUR GUESS";
  26. 350 INPUT G
  27. 360 IF G=X THEN 590
  28. 370 LET D=ABS(X-G)
  29. 380 IF D>= 64 THEN 500
  30. 390 IF D>= 32 THEN 490
  31. 400 IF D>= 16 THEN 480
  32. 410 IF D>= 8 THEN 470
  33. 420 IF D>= 4 THEN 460
  34. 430 IF D>= 2 THEN 450
  35. 440 PRINT "*";
  36. 450 PRINT "*";
  37. 460 PRINT "*";
  38. 470 PRINT "*";
  39. 480 PRINT "*";
  40. 490 PRINT "*";
  41. 500 PRINT "*";
  42. 510 PRINT
  43. 520 NEXT K
  44. 530 REM *** DID NOT GUESS NUMBER IN M GUESSES
  45. 540 PRINT
  46. 550 PRINT "SORRY, THAT'S";M;"GUESSES. NUMBER WAS";X
  47. 560 LET Y=Y+7
  48. 570 GOTO 270
  49. 580 REM *** WE HAVE A WINNER
  50. 590 FOR N=1 TO 50
  51. 600 PRINT "*";
  52. 610 NEXT N
  53. 620 PRINT "!!!"
  54. 630 PRINT "YOU GOT IT IN ";K;"GUESSES !!!!!"
  55. 640 LET Y=Y+K
  56. 650 PRINT "AVERAGE IS :"Y/E "     LET'S PLAY AGAIN..."
  57. 660 GOTO 270
  58. 670 END
  59.