home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / cpmug / cpmug054.ark / TRAP.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  1.4 KB  |  49 lines
  1. 1 REM*******COPYRIGHT 1972 PEOPLE'S COMPUTER COMPANY***
  2. 2 REM *** MENLO PARK
  3. 5 RANDOMIZE
  4. 10 LET G=6
  5. 20 LET N=100
  6. 30 REM-TRAP
  7. 40 REM-STEVE ULLMAN, 8-1-72
  8. 50 PRINT "WANT INSTRUCTIONS (1 FOR YES)";
  9. 60 INPUT Z
  10. 70 IF Z<>1 THEN 180
  11. 80 PRINT "I AM THINKING OF A NUMBER BETWEEN 1 AND";N
  12. 90 PRINT "TRY TO GUESS MY NUMBER. ON EACH GUESS,"
  13. 100 PRINT "YOU ARE TO ENTER 2 NUMBERS, TRYING TO TRAP"
  14. 110 PRINT "MY NUMBER BETWEEN THE TWO NUMBERS. I WILL"
  15. 120 PRINT "TELL YOU IF YOU HAVE TRAPPED MY NUMBER, IF MY"
  16. 130 PRINT "NUMBER IS LARGER THAN YOUR TWO NUMBERS, OR IF"
  17. 140 PRINT "MY NUMBER IS SMALLER THAN YOUR TWO NUMBERS."
  18. 150 PRINT "IF YOU WANT TO GUESS ONE SINGLE NUMBER, TYPE"
  19. 160 PRINT "YOUR GUESS FOR BOTH YOUR TRAP NUMBERS."
  20. 170 PRINT "YOU GET";G;"GUESSES TO GET MY NUMBER."
  21. 180 LET X=INT(N*RND(1))+1
  22. 190 FOR Q=1 TO G
  23. 200 PRINT
  24. 210 PRINT "GUESS #";Q;
  25. 220 INPUT A,B
  26. 230 IF A<>B THEN 240
  27. 235 IF X=A THEN 400
  28. 240 IF A <= B THEN 260
  29. 250 GOTO 360
  30. 260 IF A>X THEN 270
  31. 265 IF X<=B THEN 320
  32. 270 IF X<A THEN 300
  33. 280 PRINT "MY NUMBER IS LARGER THAN YOUR TRAP NUMBERS."
  34. 290 GOTO 330
  35. 300 PRINT "MY NUMBER IS SMALLER THAN YOUR TRAP NUMBERS."
  36. 310 GOTO 330
  37. 320 PRINT "YOU HAVE TRAPPED MY NUMBER."
  38. 330 NEXT Q
  39. 340 PRINT "SORRY, THAT'S";G;"GUESSES. NUMBER WAS";X
  40. 350 GOTO 410
  41. 360 PRINT "NUMBERS MUST BE IN INCREASING ORDER"
  42. 370 GOTO 210
  43. 400 PRINT "YOU GOT IT!!!"
  44. 410 PRINT
  45. 420 PRINT "TRY AGAIN."
  46. 430 PRINT
  47. 440 GOTO 180
  48. 450 END
  49.