home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol007 / modem926.asm < prev    next >
Assembly Source File  |  1984-04-29  |  46KB  |  1,989 lines
  1. ;
  2. ;MODEM.ASM V2.0, BY WARD CHRISTENSEN
  3. ;    (revised 9/26/80)
  4. ;
  5. ;CP/M - CP/M FILE TRANSFER PROGRAM, AND
  6. ;TERMINAL PROGRAM.
  7. ;
  8. ;NOTE: THIS FILE WILL ASSEMBLE, WITHOUT NEED FOR
  9. ;EDITING, TO WORK WITH A D.C. HAYES 80-103A MODEM
  10. ;AT *NON-STANDARD* PORT 90H WITH 4MHZ Z80 CPU.
  11. ;SEE EQUATES FOR OTHER OPTIONS INCLUDING SYSTEM CLOCK
  12. ;FREQUENCY.
  13. ;
  14. * * * * * * * * * * * * * * * * * * * * * * * * *
  15. *                        *
  16. *    THIS PROGRAM DOCUMENTED IN "MODEM.DOC"    *
  17. *                        *
  18. * * * * * * * * * * * * * * * * * * * * * * * * *
  19. * THIS PROGRAM WAS "MODEM.ASM" BUT IS         *
  20. * TEMPORARILY NAMED "MODEM926.ASM" SO PEOPLE    *
  21. * WILL REALIZE IT IS AN ENHANCEMENT OF        *
  22. * THE ORIGINAL PROGRAM "MODEM.ASM" ON CP/M    *
  23. * USER'S GROUP DISK 25.                *
  24. * * * * * * * * * * * * * * * * * * * * * * * * *
  25. ;
  26. ;PLEASE PASS ON MODS, BUGS, ETC, SO YOUR
  27. ;FIXES OR ENHANCEMENTS MAY BE SHARED BY ALL,
  28. ;         TO:
  29. ;    Ward Christensen
  30. ;    688 E. 154th St. #5D
  31. ;    Dolton, Il. 60419
  32. ;
  33. ;    (312) 849-6279
  34. ;
  35. ;You may send a self-addressed stamped postcard
  36. ;to be informed of changes/bugs as they become
  37. ;known.
  38. ;
  39. ;    --------------
  40. ;
  41. ;    09/23/77
  42. ;ORIGINALLY WRITTEN BY WARD CHRISTENSEN
  43. ;
  44. ;    04/26/79
  45. ;REWRITTEN BY WARD CHRISTENSEN TO COMBINE
  46. ;IMPROVEMENTS TO THE ORIGINAL MADE BY WARD
  47. ;AND BY KEITH PETERSEN, W8SDZ, AND SUGGESTIONS
  48. ;BY JIM BELL WHICH KEITH IMPLEMENTED.  SEE
  49. ;MODEM.DOC FOR ADDITIONAL HISTORICAL
  50. ;INFORMATION AND DOCUMENTATION.
  51. ;
  52. ;    05/09/79
  53. ;ALLOW 'T' AND 'E' SUB-OPTIONS TO GO TO TERMINAL
  54. ;OR ECHO MODEM AFTER TRANSFERRING A FILE.  (WLC)
  55. ;
  56. ;    05/22/79
  57. ;ADD FEATURE TO MAKE RECEIVE FILE ROUTINE SAY
  58. ;FILE SUCCESSFULLY OPENED, WHEN IN QUIET MODE.
  59. ;MOVE INITIAL GOBBLE GARBAGE INPUTS TO BEFORE
  60. ;COMMAND CPI'S SO ALL MODES ARE CLEARED. CHANGE
  61. ;INITIAL SEND WAIT TO 80 SECS TO ALLOW MORE TIME
  62. ;FOR RECEIVING END TO COME UP. ADD 'H' AFTER MSG
  63. ;THAT SHOWS NUMBER OF SECTORS IN EXTENT ABOUT TO
  64. ;BE SENT.  (KBP)
  65. ;
  66. ;    05/24/79
  67. ;FIX MISSING RETURN INSTRUCTION AT END OF
  68. ;INITIALIZATION ROUTINE.  (KBP)
  69. ;
  70. ;    07/01/79
  71. ;MODIFIED PROGRAM TO ALLOW FOR NON-STANDARD VERSIONS OF
  72. ;CP/M. ALL REFERENCES TO ENTRIES INTO CP/M SHOULD BE MADE
  73. ;RELATIVE TO THE VARIABLE SYMBOL CALL "BASE". FOR EXAMPLE,
  74. ;THE EQUATE TO BDOS SHOULD BE BASE+5 INSTEAD OF 5. BASE
  75. ;WILL BE SET TO 0 WHEN THE VARIABLE STDCPM IS SET TO TRUE.
  76. ;(BOB MATHIAS).
  77. ;
  78. ;    07/24/79
  79. ;MOVE INITIALIZE LOCAL STACK TO BEGINNING OF PROGRAM
  80. ;SO DEFAULT STACK IS NOT USED. ADD CONDITIONAL ASSEMBLY
  81. ;OPTION TO TERMINAL ROUTINE FOR TIMESHARE SYSTEMS.
  82. ;CORRECT ERROR IN LOCAL ABORT ROUTINE (WAS LOOKING FOR
  83. ;CONTROL E - NOW CORRECTLY LOOKS FOR CONTROL X). ADD
  84. ;REGISTER SAVES TO CONOUT, KEYIN AND AND KEYBOARD STATUS
  85. ;ROUTINES, AS SOME CBIOS ROUTINES CLOBBER THEM. (KBP)
  86. ;
  87. ;    08/05/79
  88. ;ADDED D. C. HAYES MODEM SUPPORT BY JIM BELL  (KBP)
  89. ;
  90. ;    08/06/79
  91. ;ADDED EQUATES FOR EXTERNAL MODEM (NOT S-100 PLUG-IN)
  92. ;(KBP)
  93. ;
  94. ;    12/06/79
  95. ;CORRECTED ERROR IN HELP FILE. SAID T.110, NOW SAYS
  96. ;TO.110. BY WARD CHRISTENSEN. CORRECTED RECEIVE FILE
  97. ;ROUTINE SO TERMINAL OR ECHO MODE WORKS AFTER FILE
  98. ;TRANSFER IN QUIET MODE. MOVED CHECKS FOR "H" AND
  99. ;"X" OPTIONS SO MODEM IS NOT REINITIALIZED. (KBP)
  100. ;
  101. ;    05/27/80
  102. ;ELIMINATED CONTROL-X CANCEL OF SEND FEATURE, AT
  103. ;SUGGESTION OF WARD CHRISTENSEN. A LINE GLITCH COULD
  104. ;CAUSE PREMATURE ABORT WHEN THIS FEATURE WAS ACTIVE.
  105. ;ADDED EQUATES FOR FALSE AND TRUE TO MAKE ASSEMBLY
  106. ;OPTIONS CLEARER. REMOVED H8 PORT EQUATES (THEY CAN
  107. ;BE PUT IN EXTERNAL MODEM EQUATES). (KBP)
  108. ;
  109. ;    09/26/80
  110. ;ADDED AUTO-DIAL AND AUTO-REDIAL LOGIC FOR D.C. HAYES
  111. ;CONDITIONAL ASSEMBLY.  DO I HEAR A VOLUNTEER TO ADAPT
  112. ;THIS TO PMMI? (BRUCE R. RATOFF)
  113. ;
  114. ;
  115. ;DEFINE FALSE AND TRUE
  116. ;
  117. FALSE    EQU    0
  118. TRUE    EQU    NOT FALSE
  119. ;
  120. STDCPM    EQU    TRUE    ;TRUE, IS STANDARD CP/M
  121. ALTCPM    EQU    FALSE    ;TRUE, IS ALTERNATE CP/M FOR H8 OR TRS80
  122. ;
  123.     IF    STDCPM
  124. BASE    EQU    0    ;CP/M BASE ADDRESS
  125.     ENDIF
  126. ;
  127.     IF    ALTCPM
  128. BASE    EQU    4200H    ;CP/M BASE ADDRESS FOR ALTERNATE CP/M
  129.     ENDIF
  130. ;
  131. PMMI    EQU    FALSE    ;TRUE, IS PMMI MODEM
  132. ;
  133. DCH    EQU    TRUE     ;TRUE, IS D.C. HAYES MODEM
  134. ;
  135.     IF    PMMI
  136. MODCTLP    EQU    0C0H    ;PMMI VALUES
  137. MODSNDB EQU    1    ;BIT TO TEST FOR SEND
  138. MODSNDR    EQU    1    ;VALUE WHEN READY
  139. MODRCVB EQU    2    ;BIT TO TEST FOR RECEIVE
  140. MODRCVR    EQU    2    ;VALUE WHEN READY
  141. MODDATP EQU    0C1H    ;DATA PORT
  142. BAUDRP    EQU    0C2H    ;BAUD RATE OUTPUT
  143. MODCTL2    EQU    0C3H    ;SECOND CTL PORT
  144.     ENDIF
  145. ;
  146.     IF    DCH
  147. MODCTLP    EQU    92H    ;D. C. HAYES VALUES
  148. MODSNDB EQU    2    ;BIT TO TEST FOR SEND
  149. MODSNDR    EQU    2    ;VALUE WHEN READY
  150. MODRCVB EQU    1    ;BIT TO TEST FOR RECEIVE
  151. MODRCVR    EQU    1    ;VALUE WHEN READY
  152. MODDATP EQU    90H    ;DATA PORT
  153. MODCTL2    EQU    91H    ;SECOND CTL PORT
  154.     ENDIF
  155. ;
  156.     IF    PMMI
  157. ORIGMOD    EQU    1DH    ;8 DATA, NO PARITY, ORIG
  158. ANSWMOD    EQU    1EH    ;8 DATA, NO PARITY, ANSW
  159.     ENDIF
  160. ;
  161. ;NOTE: IF DC HAYES THEN BAUD RATE DEFAULTS TO
  162. ;300 - 1 STOP BIT.  DO NOT CHANGE NEXT EQUATES
  163.     IF    DCH
  164. ORIGMOD EQU    86H    ;OFF HOOK, 110 BAUD, CAR. ON, ORIG.
  165. ANSWMOD    EQU    82H    ;OFF HOOK, 110 BAUD, CAR. ON, ANSW.
  166.     ENDIF
  167. ;
  168. ;IF YOU ARE USING AN EXTERNAL MODEM (NOT S-100 PLUG-IN)
  169. ;CHANGE THESE EQUATES FOR YOUR MODEM PORT REQUIREMENTS
  170. ;
  171. INITREQ    EQU    FALSE    ;TRUE, IF MODEM PORT INIT. REQ'D
  172. INITC1    EQU    64H    ;1ST INIT CHAR TO CTL PORT
  173. INITC2    EQU    64H    ;2ND INIT CHAR TO CTL PORT
  174. INITC3    EQU    64H    ;3RD INIT CHAR TO CTL PORT
  175. INITC4    EQU    64H    ;4TH INIT CHAR TO CTL PORT
  176. ;
  177.     IF    NOT PMMI AND NOT DCH
  178. MODCTLP    EQU    02H    ;PUT YOUR MODEM CONTROL PORT HERE
  179. MODSNDB    EQU    80H    ;YOUR BIT TO TEST FOR SEND
  180. MODSNDR    EQU    80H    ;YOUR VALUE WHEN READY
  181. MODRCVB    EQU    40H    ;YOUR BIT TO TEST FOR RECEIVE
  182. MODRCVR    EQU    40H    ;YOUR VALUE WHEN READY
  183. MODDATP    EQU    03H    ;YOUR MODEM DATA PORT
  184.     ENDIF        ;END OF EXTERNAL MODEM EQUATES
  185. ;
  186. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS
  187. EXITCHR    EQU    'E'-40H ;CTL-E EXIT FROM T OR C
  188. DISCCHR    EQU    'D'-40H    ;CTL-D DISCONNECTS MODEM T/E
  189. ;
  190. FASTCLK    EQU    TRUE     ;TRUE FOR 4 MHZ CLOCK
  191. ;
  192. ;SOME TIME-SHARE COMPUTERS REQUIRE TERMINALS TO
  193. ;HAVE BIT 7 HIGH (MARKING), SO IN THE TERMINAL
  194. ;MODE WE FORCE IT TO HIGH IF THE FOLLOWING OPTION
  195. ;IS SELECTED:
  196. ;
  197. TIMESHR    EQU    FALSE    ;TRUE TO MAKE BIT 7 HIGH
  198. ; 
  199. ;DEFINE ASCII CHARACTERS USED
  200. ;
  201. SOH    EQU    1    ;START OF HEADER
  202. EOT    EQU    4    ;END OF TRANSMISSION
  203. ACK    EQU    6    ;ACKNOWLEDGE
  204. BEL    EQU    7    ;BELL
  205. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  206. CAN    EQU    18H    ;CANCEL
  207. LF    EQU    10    ;LINEFEED
  208. CR    EQU    13    ;CARRIAGE RETURN
  209. ; 
  210.     ORG    BASE+100H
  211. ;
  212. ;INIT PRIVATE STACK
  213.     LXI    H,0    ;HL=0
  214.     DAD    SP    ;HL=STACK FROM CP/M
  215.     SHLD    STACK    ;..SAVE IT
  216.     LXI    SP,STACK ;SP=MY STACK
  217.     CALL    START    ;GO PRINT ID
  218.     DB    'MODEM PROGRAM as of '
  219.     DB    '09/26/80',CR,LF,'$'
  220. ; 
  221. START    POP    D    ;GET ID MESSAGE
  222.     MVI    C,PRINT
  223.     CALL    BDOS    ;PRINT ID MESSAGE
  224. ;
  225. ;INITIALIZE THE JMPS TO CP/M BIOS
  226. ;
  227.     CALL    INITADR
  228. ;
  229.     LDA    FCB+1    ;GET PRIMARY OPTION
  230.     CPI    'H'    ;MODEM H(ELP)?
  231.     JZ    HELP    ;..YES, GIVE HELP
  232.     CPI    'X'    ;MODEM X(AMPLES)?
  233.     JZ    EXAM    ;GIVE EXAMPLES
  234. ;
  235. ;SAVE PRIMARY OPTION, VALIDATE SECONDARY OPT.
  236. ;
  237.     CALL    PROCOPT
  238. ;
  239. ;INIT THE MODEM OR SERIAL PORT
  240. ;
  241.     CALL    INITMOD
  242. ;
  243. ;MOVE THE FILENAME FROM FCB 2 TO FCB 1
  244. ;
  245.     CALL    MOVEFCB
  246. ;
  247.     IF    DCH
  248.     CALL    DIALMOD        ; CHECK FOR PHONE # AND DIAL IT IF PRESENT
  249.     ENDIF
  250. ;
  251. ;GOBBLE UP GARBAGE CHARS FROM THE LINE
  252. ;PRIOR TO RECEIVE OR SEND
  253. ;
  254.     IN    MODDATP
  255.     IN    MODDATP
  256. ;
  257. ;JMP TO APPROPRIATE FUNCTION
  258. ;
  259.     LDA    OPTION    ;GET PRIMARY OPTION
  260. ;
  261.     CPI    'C'    ;(COMPAT W/EARLIER
  262.     JZ    TRMECHO    ;OPTION "COMPUTER")
  263. ;
  264.     CPI    'E'    ;TERMINAL IN ECHO
  265.     JZ    TRMECHO    ;..MODE?
  266. ;
  267.     CPI    'T'    ;TERMINAL..
  268.     JZ    TERM    ;..MODE?
  269. ;
  270.     CPI    'D'
  271.     JZ    DISCONN
  272. ;
  273.            CPI    'S'    ;SEND..
  274.     JZ    SENDFIL    ;..A FILE?
  275. ;
  276.     CPI    'R'    ;RECEIVE..
  277.     JZ    RCVFIL    ;..A FILE?
  278. ;
  279. ;INVALID OPTION
  280. ;
  281.     JMP    BADOPT
  282. ;
  283. * * * * * * * * * * * * * * * * * * * * *
  284. *                    *
  285. *    TERM: TERMINAL MODE        *
  286. *                    *
  287. * * * * * * * * * * * * * * * * * * * * *
  288. ;
  289. ;THIS PROGRAM SIMPLY SENDS KEYED CHARACTERS
  290. ;DOWN THE LINE, AND DISPLAYS CHARACTERS
  291. ;RECEIVED FROM THE LINE.  THIS MAKES IT
  292. ;SUITABLE FOR COMMUNICATION WITH TIME SHARING
  293. ;COMPUTERS, CBBS'S, OR ANOTHER PROGRAM
  294. ;RUNING "MODEM E" (ECHO MODE)
  295. ;
  296. ;TYPE THE "EXITCHR" (ORIGINALLY CTL-E) TO EXIT.
  297. ;OR THE "DISCCHR" (ORIGINALLY CTL-D) TO DISCONN.
  298. ;
  299. ;A FUTURE ENHANCEMENT WILL BE TO WRITE THE
  300. ;RECEIVED DATA IN MEMORY, AND ALLOW IT TO
  301. ;BE WRITTEN TO DISK
  302. ;
  303. TERM    CALL    STAT    ;LOCAL CHAR KEYED?
  304.     JZ    TERML    ;..NO, CHECK LINE
  305.     CALL    KEYIN    ;GET CHAR
  306.     CPI    EXITCHR    ;TIME TO END?
  307.     JZ    CKDIS    ;YES, CK DISCONN
  308.     CPI    DISCCHR    ;DISCONNECT REQUEST?
  309.     JZ    DISCONN    ;YES, DO IT
  310.     IF    TIMESHR
  311.     ORI    80H    ;FORCE BIT 7 TO HIGH
  312.     ENDIF        ;TIMESHR
  313.     OUT    MODDATP    ;SEND THE CHAR
  314. ;
  315. ;SEE IF CHAR FROM LINE
  316. ;
  317.     IF    NOT DCH
  318. TERML    IN    MODCTLP    ;READ STATUS
  319.     ENDIF
  320. ;
  321.     IF    DCH
  322. TERML    IN    MODCTL2    ;READ STATUS
  323.     ENDIF
  324. ;
  325.     ANI    MODRCVB    ;ISOLATE BIT
  326.     CPI    MODRCVR    ;READY?
  327.     JNZ    TERM    ;..NO, LOOP
  328.     IN    MODDATP    ;READ DATA
  329.     ANI    7FH    ;STRIP PARITY BIT
  330.     CALL    TYPE    ;TYPE IT
  331.     JMP    TERM    ;LOOP
  332. ;
  333. * * * * * * * * * * * * * * * * * * * * *
  334. *                    *
  335. *    TRMECHO: TERMINAL WITH ECHO    *
  336. *                    *
  337. * * * * * * * * * * * * * * * * * * * * *
  338. ;
  339. ;TERMINAL PROGRAM WITH ECHO - SEE NOTES
  340. ;UNDER "TERM" ABOVE
  341. ;
  342. ;C A U T I O N   DON'T RUN WITH BOTH COMPUTERS
  343. ;IN "ECHO" MODE - LINE ERRORS (OR ANY CHAR)
  344. ;WILL BE ECHOED BACK AND FORTH AD INFINITUM.
  345. ;
  346.     IF    NOT DCH
  347. TRMECHO    IN    MODCTLP    ;GET STATUS
  348.     ENDIF
  349. ;
  350.     IF    DCH
  351. TRMECHO    IN    MODCTL2    ;GET STATUS
  352.     ENDIF
  353. ;
  354.     ANI    MODRCVB    ;ISOLATE READY BIT
  355.     CPI    MODRCVR    ;ARE WE READY?
  356.     JZ    LINECHR    ;YES, READ THE CHR
  357.     CALL    STAT    ;CHECK LOCAL KB
  358.     JZ    TRMECHO    ;..NO CHAR
  359.     CALL    KEYIN    ;GET LOCAL CHAR
  360.     CPI    EXITCHR    ;END?
  361.     JZ    CKDIS    ;YES, CK DISCONN, EXIT
  362.     CPI    DISCCHR    ;DISCONN?
  363.     JZ    DISCONN    ;..YES, DO IT.
  364.     OUT    MODDATP    ;SEND CHAR
  365.     CALL    TYPE    ;ECHO IT LOCALLY
  366.     JMP    TRMECHO    ;..AND LOOP
  367. ;
  368. ;GOT CHAR FROM LINE
  369. ;
  370. LINECHR    IN    MODDATP    ;GET CHAR
  371.     OUT    MODDATP    ;ECHO IT
  372.     ANI    7FH    ;STRIP PARITY BIT
  373.     CALL    TYPE    ;TYPE IT
  374.     JMP    TRMECHO    ;LOOP
  375. ;
  376. * * * * * * * * * * * * * * * * * * * * *
  377. *                    *
  378. *    SENDFIL: SENDS A CP/M FILE    *
  379. *                    *
  380. * * * * * * * * * * * * * * * * * * * * *
  381. ;
  382. ;THE CP/M FILE SPECIFIED IN THE MODEM COMMAND
  383. ;IS TRANSFERRED OVER THE PHONE TO ANOTHER
  384. ;COMPUTER RUNNING MODEM WITH THE "R" (RECEIVE)
  385. ;OPTION.  THE DATA IS SENT ONE SECTOR AT A
  386. ;TIME WITH HEADERS AND CHECKSUMS, AND RE-
  387. ;TRANSMISSION ON ERRORS.  
  388. ;
  389. SENDFIL    CALL    OPENFIL    ;OPEN THE FILE
  390.     MVI    E,80    ;WAIT 80 SEC..
  391.     CALL    WAITNAK    ;..FOR INITIAL NAK
  392. ;
  393. SENDLP    CALL    RDSECT    ;READ A SECTOR
  394.     JC    SENDEOF    ;SEND EOF IF DONE
  395.     CALL    INCRSNO    ;BUMP SECTOR #
  396.     XRA    A    ;ZERO ERROR..
  397.     STA    ERRCT    ;..COUNT
  398. ;
  399. SENDRPT    CALL    SENDHDR    ;SEND A HEADER
  400.     CALL    SENDSEC    ;SEND DATA SECTOR
  401.     CALL    SENDCKS    ;SEND CKSUM
  402.     CALL    GETACK    ;GET THE ACK
  403.     JC    SENDRPT    ;REPEAT IF NO ACK
  404.     JMP    SENDLP    ;LOOP UNTIL EOF
  405. ;
  406. ;FILE SENT, SEND EOT'S
  407. ;
  408. SENDEOF    MVI    A,EOT    ;SEND..
  409.     CALL    SEND    ;..AN EOT
  410.     CALL    GETACK    ;GET THE ACK
  411.     JC    SENDEOF    ;LOOP IF NO ACK
  412.     JMP    DONE    ;ALL DONE
  413. ;
  414. * * * * * * * * * * * * * * * * * * * * *
  415. *                    *
  416. *    RCVFIL: RECEIVE A FILE        *
  417. *                    *
  418. * * * * * * * * * * * * * * * * * * * * *
  419. ;
  420. ;RECEIVES A FILE IN BLOCK FORMAT AS SENT
  421. ;BY ANOTHER PERSON DOING "MODEM S FN.FT".
  422. ;
  423. RCVFIL    CALL    ERASFIL    ;ERASE THE FILE
  424.     CALL    MAKEFIL    ;..THEN MAKE NEW
  425.     CALL    ILPRT    ;PRINT:
  426.     DB    'FILE OPEN, READY TO RECEIVE',CR,LF,0
  427. ;
  428. RCVLP    CALL    RCVSECT    ;GET A SECTOR
  429.     JC    RCVEOT    ;GOT EOT
  430.     CALL    WRSECT    ;WRITE THE SECTOR
  431.     CALL    INCRSNO    ;BUMP SECTOR #
  432.     CALL    SENDACK    ;ACK THE SECTOR
  433.     JMP    RCVLP    ;LOOP UNTIL EOF
  434. ;
  435. ;GOT EOT ON SECTOR - FLUSH BUFFERS, END
  436. ;
  437. RCVEOT    CALL    WRBLOCK    ;WRITE THE LAST BLOCK
  438.     CALL    SENDACK    ;ACK THE SECTOR
  439.     CALL    CLOSFIL    ;CLOSE THE FILE
  440.     JMP    DONE    ;ALL DONE
  441. ;
  442. * * * * * * * * * * * * * * * * * * * * *
  443. *                    *
  444. *        SUBROUTINES        *
  445. *                    *
  446. * * * * * * * * * * * * * * * * * * * * *
  447. ;
  448. ;
  449. ;---->    RCVSECT: RECEIVE A SECTOR
  450. ;
  451. ;RETURNS WITH CARRY SET IF EOT RECEIVED.
  452. ;
  453. RCVSECT    XRA    A    ;GET 0
  454.     STA    ERRCT    ;INIT ERROR COUNT
  455. ;
  456. RCVRPT    LDA    QFLG    ;QUIET?
  457.     ORA    A
  458.     JZ    RCVSQ    ;YES, NO STAT MSG.
  459.     CALL    ILPRT    ;PRINT:
  460.     DB    'AWAITING #',0
  461.     LDA    SECTNO    ;GET SECTOR #
  462.     INR    A    ;(REAL INR LATER)
  463.     CALL    HEXO    ;PRINT IN HEX
  464.     CALL    CRLF    ;..THEN CRLF
  465. ;
  466. RCVSQ    MVI    B,10    ;10 SEC TIMEOUT
  467.     CALL    RECV    ;GET SOH/EOT
  468.     JC    RCVSTOT    ;TIMEOUT
  469.     CPI    SOH    ;GET SOH?
  470.     JZ    RCVSOH    ;..YES
  471. ;
  472. ;EARLIER VERS. OF MODEM PROG SENT SOME NULLS -
  473. ;IGNORE THEM
  474. ;
  475.     ORA    A    ;00 FROM SPEED CHECK?
  476.     JZ    RCVSQ    ;YES, IGNORE IT
  477.     CPI    EOT    ;END OF TRANSFER?
  478.     STC        ;RETURN WITH CARRY..
  479.     RZ        ;..SET IF EOT
  480. ;
  481. ;DIDN'T GET SOH  OR EOT - 
  482. ;
  483.     MOV    B,A    ;SAVE CHAR
  484.     LDA    VSEEFLG    ;VIEWING..
  485.     ORA    A    ;..MODE?
  486.     JZ    RCVSEH    ;YES, PRT.MSG
  487.     LDA    QFLG    ;QUIET..
  488.     ORA    A    ;..MODE?
  489.     JZ    RCVSERR    ;YES, SKIP MSG
  490. RCVSEH    MOV    A,B    ;GET CHAR
  491.     CALL    HEXO    ;SHOW IN HEX
  492.     CALL    ILPRT    ;PRINT:
  493.     DB    'H RCD, NOT SOH',CR,LF,0
  494. ;
  495. ;DIDN'T GET VALID HEADER - PURGE THE LINE,
  496. ;THEN SEND NAK.
  497. ;
  498. RCVSERR    MVI    B,1    ;WAIT FOR 1 SEC..
  499.     CALL    RECV    ;..WITH NO CHARS
  500.     JNC    RCVSERR    ;LOOP UNTIL SENDER DONE
  501.     MVI    A,NAK    ;SEND..
  502.     CALL    SEND    ;..THE NAK
  503.     LDA    ERRCT    ;ABORT IF..
  504.     INR    A    ;..WE HAVE REACHED..
  505.     STA    ERRCT    ;..THE ERROR..
  506.     CPI    ERRLIM    ;..LIMIT?
  507.     JC    RCVRPT    ;..NO, TRY AGAIN
  508. ;
  509. ;10 ERRORS IN A ROW - 
  510. ;
  511.     LDA    VSEEFLG    ;VIEWING..
  512.     ORA    A    ;..FILE?
  513.     JZ    RCVCKQ    ;YES, ASK RETRY/QUIT
  514.     LDA    QFLG    ;QUIET..
  515.     ORA    A    ;..MODE?
  516.     JZ    RCVSABT    ;ABORT
  517. ;
  518. RCVCKQ    CALL    CKQUIT    ;RETRY/QUIT?
  519.     JZ    RCVSECT    ;TRY AGAIN
  520. ;
  521. RCVSABT    CALL    CLOSFIL    ;KEEP WHATEVER WE GOT
  522.     CALL    ERXIT
  523.     DB    '++UNABLE TO RECEIVE BLOCK'
  524.     DB    CR,LF,'++ABORTING++$'
  525. ;
  526. ;TIMEDOUT ON RECEIVE
  527. ;
  528. RCVSTOT    LDA    VSEEFLG    ;VIEWING..
  529.     ORA    A    ;..MODE?
  530.     JZ    RCVSPT    ;YES, PRT MSG
  531.     LDA    QFLG    ;QUIET..
  532.     ORA    A    ;..MODE?
  533.     JZ    RCVSERR    ;YES, NO MSG
  534. ;
  535. RCVSPT    CALL    ILPRT
  536.     DB    '++TIMEOUT++ ',0
  537. ;
  538. RCVPRN    LDA    ERRCT    ;PRINT ERROR..
  539.     CALL    HEXO    ;..COUNT
  540.     CALL    CRLF
  541.     JMP    RCVSERR    ;BUMP ERR CT, ETC.
  542. ;
  543. ;GOT SOH - GET BLOCK #, BLOCK # COMPLEMENTED
  544. ;
  545. RCVSOH    MVI    B,1    ;TIMEOUT = 1 SEC
  546.     CALL    RECV    ;GET SECTOR
  547.     JC    RCVSTOT    ;GOT TIMEOUT
  548.     MOV    D,A    ;D=BLK #
  549.     MVI    B,1    ;TIMEOUT = 1 SEC
  550.     CALL    RECV    ;GET CMA'D SECT #
  551.     JC    RCVSTOT    ;TIMEOUT
  552.     CMA        ;CALC COMPLEMENT
  553.     CMP    D    ;GOOD SECTOR #?
  554.     JZ    RCVDATA    ;YES, GET DATA
  555. ;
  556. ;GOT BAD SECTOR #
  557. ;
  558.     LDA    VSEEFLG    ;VIEWING..
  559.     ORA    A    ;..MODE?
  560.     JZ    RCVBSE    ;..YES, PRT MSG
  561.     LDA    QFLG    ;QUIET..
  562.     ORA    A    ;..MODE?
  563.     JZ    RCVSERR    ;..YES, NO MSG
  564. ;
  565. RCVBSE    CALL    ILPRT    ;PRINT:
  566.     DB    '++BAD SECTOR # IN HDR',CR,LF,0
  567.     JMP    RCVSERR    ;BUMP ERROR CT.
  568. ;
  569. RCVDATA    MOV    A,D    ;GET SECTOR #
  570.     STA    RCVSNO    ;SAVE IT
  571.     MVI    A,1    ;SHOW..
  572.     STA    DATAFLG    ;GETTING DATA
  573.     MVI    C,0    ;INIT CKSUM
  574.     LXI    H,BASE+80H    ;POINT TO BUFFER
  575. RCVCHR    MVI    B,1    ;1 SEC TIMEOUT
  576.     CALL    RECV    ;GET CHAR
  577.     JC    RCVSTOT    ;TIMEOUT
  578.     MOV    M,A    ;STORE CHAR
  579.     INR    L    ;DONE?
  580.     JNZ    RCVCHR    ;NO, LOOP
  581. ;
  582. ;VERIFY CHECKSUM
  583. ;
  584.     MOV    D,C    ;SAVE CHECKSUM
  585.     XRA    A    ;SHOW..
  586.     STA    DATAFLG    ;..END OF DATA
  587.     MVI    B,1    ;TIMEOUT LEN.
  588.     CALL    RECV    ;GET CHECKSUM
  589.     JC    RCVSTOT    ;TIMEOUT
  590.     CMP    D    ;CHECKSUM OK?
  591.     JNZ    RCVCERR    ;NO, ERROR
  592. ;
  593. ;GOT A SECTOR, IT'S A DUP IF = PREV,
  594. ;    OR OK IF = 1 + PREV SECTOR
  595. ;
  596.     LDA    RCVSNO    ;GET RECEIVED
  597.     MOV    B,A    ;SAVE IT
  598.     LDA    SECTNO    ;GET PREV
  599.     CMP    B    ;PREV REPEATED?
  600.     JZ    RECVACK    ;ACK TO CATCH UP
  601.     INR    A    ;CALC NEXT SECTOR #
  602.     CMP    B    ;MATCH?
  603.     JNZ    ABORT    ;NO MATCH - STOP SENDER, EXIT
  604.     RET        ;CARRY OFF - NO ERRORS
  605. ;
  606. ;GOT CKSUM
  607. ;
  608. RCVCERR    LDA    VSEEFLG    ;VIEWING..
  609.     ORA    A    ;..MODE?
  610.     JZ    RCVCPR    ;..YES, PRT MSG
  611.     LDA    QFLG    ;QUIET..
  612.     ORA    A    ;..MODE?
  613.     JZ    RCVSERR    ;YES, NO MSG
  614. ;
  615. RCVCPR    CALL    ILPRT
  616.     DB    '++CKSUM++ ',0
  617.     JMP    RCVPRN    ;PRINT ERROR #
  618. ;
  619. ;PREV SECT REPEATED, DUE TO THE LAST ACK
  620. ;BEING GARBAGED.  ACK IT SO SENDER WILL CATCH UP 
  621. ;
  622. RECVACK    CALL    SENDACK    ;SEND THE ACK,
  623.     JMP    RCVSECT    ;GET NEXT BLOCK
  624. ;
  625. ;SEND AN ACK FOR THE SECTOR
  626. ;
  627. SENDACK    MVI    A,ACK    ;GET ACK
  628.     CALL    SEND    ;..AND SEND IT
  629.     RET
  630. ;
  631. ;---->    SENDHDR: SEND THE SECTOR HEADER
  632. ;
  633. ;SEND: (SOH) (BLOCK #) (COMPLEMENTED BLOCK #)
  634. ;
  635. SENDHDR    LDA    QFLG    ;QUIET..
  636.     ORA    A    ;..MODE?
  637.     JZ    SENDHNM    ;YES, SKIP STATUS MSG.
  638.     CALL    ILPRT    ;PRINT:
  639.     DB    'SEND # ',0
  640.     LDA    SECTNO    ;PRINT..
  641.     CALL    HEXO    ;..SECT #
  642.     CALL    CRLF    ;..THEN CR/LF
  643. ;
  644. SENDHNM    MVI    A,SOH    ;SEND..
  645.     CALL    SEND    ;..SOH,
  646.     LDA    SECTNO    ;THEN SEND..
  647.     CALL    SEND    ;..SECTOR #
  648.     LDA    SECTNO    ;THEN SECTOR #
  649.     CMA        ;..COMPLEMENTED..
  650.     CALL    SEND    ;..SECTOR #
  651.     RET        ;FROM SENDHDR
  652. ;
  653. ;---->    SENDSEC: SEND THE DATA SECTOR
  654. ;
  655. ;WHILE SENDING THE SECTOR, THE "DATAFLG" IS SET
  656. ;SUCH THAT IF "V" (VIEW THE FILE) WAS REQUESTED,
  657. ;THE "SHOW" ROUTINE WILL PRINT THE DATA, BUT NOT
  658. ;THE HDR OR CKSUM, OR ANY NON-FATAL MSGS.
  659. ;
  660. SENDSEC    MVI    A,1    ;SHOW NOW AT DATA..
  661.     STA    DATAFLG    ;..FOR VIEW COMMAND
  662.     MVI    C,0    ;INIT CKSUM
  663.     LXI    H,BASE+80H    ;POINT TO BUFFER
  664. SENDC    MOV    A,M    ;GET A CHAR
  665.     CALL    SEND    ;SEND IT
  666.     INR    L    ;POINT TO NEXT CHAR
  667.     JNZ    SENDC    ;LOOP IF <100H
  668.     XRA    A    ;SHOW NOT INTO DATA..
  669.     STA    DATAFLG    ;..FOR VIEW COMMAND
  670.     RET        ;FROM SENDSEC
  671. ;
  672. ;---->    SENDCKS: SEND THE CHECKSUM
  673. ;
  674. SENDCKS    MOV    A,C    ;SEND THE..
  675.     CALL    SEND    ;..CHECKSUM
  676.     RET        ;FROM SENDCKS
  677. ;
  678. ;---->    GETACK: GET THE ACK ON THE SECTOR
  679. ;
  680. ;RETURNS WITH CARRY CLEAR IF ACK RECEIVED.
  681. ;IF AN ACK IS NOT RECEIVED, THE ERROR COUNT
  682. ;IS INCREMENTED, AND IF LESS THAN "ERRLIM",
  683. ;CARRY IS SET AND CONTROL RETURNS.  IF THE
  684. ;ERROR COUNT IS AT "ERRLIM", THE PROGRAM
  685. ;ABORTS IF IN "QUIET" MODE, OR ASKS THE
  686. ;USER FOR QUIT/RETRY IF NOT.
  687. ;
  688. GETACK    MVI    B,10    ;WAIT 10 SECONDS MAX
  689.     CALL    RECVDG    ;RECV W/GARBAGE COLLECT
  690.     JC    GETATOT    ;TIMED OUT
  691.     CPI    ACK    ;OK? (CARRY OFF IF =)
  692.     RZ        ;YES, RET FROM GETACK
  693.     MOV    B,A    ;SAVE CHAR
  694.     LDA    QFLG    ;QUIET..
  695.     ORA    A    ;..MODE?
  696.     JZ    ACKERR    ;..YES, NO MSG
  697.     MOV    A,B    ;GET CHAR
  698.     CALL    HEXO    ;PRINT IN HEX
  699.     CALL    ILPRT    ;PRINT:
  700.     DB    'H RCD, NOT ACK',CR,LF,0
  701. ;
  702. ;TIMEOUT OR ERROR ON ACK - BUMP ERROR COUNT
  703. ;
  704. ACKERR    LDA    ERRCT    ;GET COUNT
  705.     INR    A    ;BUMP IT
  706.     STA    ERRCT    ;SAVE BACK
  707.     CPI    ERRLIM    ;AT LIMIT?
  708.     RC        ;NOT AT LIMIT
  709. ;
  710. ;REACHED ERROR LIMIT
  711. ;
  712.     LDA    VSEEFLG    ;VIEWING..
  713.     ORA    A    ;..FILE?
  714.     JZ    GACKV    ;YES, ASK QUIT/RETRY
  715.     LDA    QFLG    ;QUIET..
  716.     ORA    A    ;..MODE?
  717.     JZ    CSABORT ;..YES, NO MSG
  718. ;
  719. GACKV    CALL    CKQUIT    ;SEE IF WANT TO QUIT
  720.     STC        ;TO SHOW NO ACK
  721.     RZ        ;KEEP ON TRYIN'
  722. ;
  723. CSABORT    CALL    ERXIT
  724.     DB    'CAN''T SEND SECTOR '
  725.     DB    '- ABORTING',CR,LF,'$'
  726. ;
  727. ;TIMEOUT GETTING ACK
  728. ;
  729. GETATOT    LDA    QFLG    ;QUIET..
  730.     ORA    A    ;..MODE?
  731.     JZ    ACKERR    ;YES, NO MSG
  732.     CALL    ILPRT    ;PRINT:
  733.     DB    'TIMEOUT ON ACK',CR,LF,0
  734.     JMP    ACKERR
  735. ; 
  736. ABORT    LXI    SP,STACK
  737. ;
  738. ABORTL    MVI    B,1    ;1 SEC. W/O CHARS.
  739.     CALL    RECV
  740.     JNC    ABORTL    ;LOOP UNTIL SENDER DONE
  741.     MVI    A,NAK    ;NEGATIVE ACK
  742.     CALL    SEND    ;TELL SENDING END
  743.     CALL    ILPRT    ;EXIT WITH ABORT MSG
  744.     DB    'MODEM PROGRAM CANCELLED',CR,LF,0
  745.     JMP    CKDIS    ;CHECK FOR DISCONN.
  746. ;
  747. ;---->    INCRSNO: INCREMENT SECTOR #
  748. ;
  749. INCRSNO    LDA    SECTNO    ;INCR..
  750.     INR    A    ;..SECT..
  751.     STA    SECTNO    ;..NUMBER
  752.     RET
  753. ;
  754. ;---->    ERASFIL: ERASE THE INCOMING FILE.
  755. ;
  756. ;IF IT EXISTS, ASK IF IT MAY BE ERASED.
  757. ;
  758. ERASFIL    LXI    D,FCB    ;POINT TO CTL BLOCK
  759.     MVI    C,SRCHF ;SEE IF IT..
  760.     CALL    BDOS    ;..EXISTS
  761.     INR    A    ;FOUND?
  762.     RZ        ;..NO, RETURN
  763.     CALL    ILPRT    ;PRINT:
  764.     DB    '++FILE EXISTS, TYPE Y TO ERASE: ',0
  765.     CALL    KEYIN    ;GET CHAR
  766.     PUSH    PSW
  767.     CALL    TYPE    ;ECHO
  768.     CALL    CRLF    ;BACK TO START OF LINE
  769.     POP    PSW
  770.     ANI    5FH    ;MAKE UPPER CASE
  771.     CPI    'Y'    ;WANT ERASED?
  772.     JNZ    CKDIS    ;QUIT IF NOT ERASE
  773. ;
  774. ;ERASE OLD FILE
  775. ;
  776.     LXI    D,FCB    ;POINT TO FCB
  777.     MVI    C,ERASE    ;GET BDOS FNC
  778.     CALL    BDOS    ;DO THE ERASE
  779.     RET        ;FROM "ERASFIL"
  780. ;
  781. ;---->    MAKEFIL: MAKES THE FILE TO BE RECEIVED
  782. ;
  783. MAKEFIL    LXI    D,FCB    ;POINT TO FCB
  784.     MVI    C,MAKE    ;GET BDOS FNC
  785.     CALL    BDOS    ;TO THE MAKE
  786.     INR    A    ;FF=BAD?
  787.     RNZ        ;OPEN OK
  788. ;DIRECTORY FULL - CAN'T MAKE FILE
  789.     CALL    ERXIT
  790.     DB    '++ERROR - CAN''T MAKE FILE',CR,LF
  791.     DB    '++DIRECTORY MUST BE FULL',CR,LF,'$'
  792. ;
  793. ;---->    OPENFIL: OPENS THE FILE TO BE SENT
  794. ;
  795. OPENFIL    LXI    D,FCB    ;POINT TO FILE
  796.     MVI    C,OPEN    ;GET FUNCTION
  797.     CALL    BDOS    ;OPEN IT
  798.     INR    A    ;OPEN OK?
  799.     JNZ    OPENOK    ;..YES
  800.     CALL    ERXIT    ;..NO, ABORT
  801.     DB    'CAN''T OPEN FILE$'
  802. ;
  803. OPENOK    CALL    ILPRT    ;PRINT:
  804.     DB    'FILE OPEN, EXTENT LENGTH: ',0
  805.     LDA    FCB+15    ;GET # SECTORS
  806.     CALL    HEXO    ;PRINT IN HEX
  807.     CALL    ILPRT    ;PRINT:
  808.     DB    'H',CR,LF,0
  809.     RET
  810. ;
  811. ;---->    CLOSFIL: CLOSES THE RECEIVED FILE
  812. ;
  813. CLOSFIL    LXI    D,FCB    ;POINT TO FILE
  814.     MVI    C,CLOSE    ;GET FUNCTION
  815.     CALL    BDOS    ;CLOSE IT
  816.     INR    A    ;CLOSE OK?
  817.     RNZ        ;..YES, RETURN
  818.     CALL    ERXIT    ;..NO, ABORT
  819.     DB    'CAN''T CLOSE FILE$'
  820. ;
  821. ;---->    RDSECT: READS A SECTOR
  822. ;
  823. ;FOR SPEED, THIS ROUTINE BUFFERS UP 16
  824. ;SECTORS AT A TIME.
  825. ;
  826. RDSECT    LDA    SECINBF    ;GET # SECT IN BUFF.
  827.     DCR    A    ;DECREMENT..
  828.     STA    SECINBF    ;..IT
  829.     JM    RDBLOCK    ;EXHAUSTED?  NEED MORE.
  830.     LHLD    SECPTR    ;GET POINTER
  831.     LXI    D,BASE+80H    ;TO DATA
  832.     CALL    MOVE128    ;MOVE TO BUFFER
  833.     SHLD    SECPTR    ;SAVE BUFFER POINTER
  834.     RET        ;FROM "READSEC"
  835. ;
  836. ;BUFFER IS EMPTY - READ IN ANOTHER BLOCK OF 16
  837. ;
  838. RDBLOCK    LDA    EOFLG    ;GET EOF FLAG
  839.     CPI    1    ;IS IT SET/
  840.     STC        ;TO SHOW EOF
  841.     RZ        ;GOT EOF
  842.     MVI    C,0    ;SECTORS IN BLOCK
  843.     LXI    D,DBUF    ;TO DISK BUFFER
  844. ;
  845. RDSECLP    PUSH    B
  846.     PUSH    D
  847.     MVI    C,STDMA    ;SET DMA..
  848.     CALL    BDOS    ;..ADDR
  849.     LXI    D,FCB
  850.     MVI    C,READ
  851.     CALL    BDOS
  852.     POP    D
  853.     POP    B
  854.     ORA    A    ;READ OK?
  855.     JZ    RDSECOK    ;YES
  856.     DCR    A    ;EOF?
  857.     JZ    REOF    ;GOT EOF
  858. ;
  859. ;READ ERROR
  860. ;
  861.     CALL    ERXIT
  862.     DB    '++FILE READ ERROR$'
  863. ;
  864. RDSECOK    LXI    H,80H    ;ADD LENGTH OF ONE SECTOR...
  865.     DAD    D    ;...TO NEXT BUFF
  866.     XCHG        ;BUFF TO DE
  867.     INR    C    ;MORE SECTORS?
  868.     MOV    A,C    ;GET COUNT
  869.     CPI    16    ;DONE?
  870.     JZ    RDBFULL    ;..YES, BUFF IS FULL
  871.     JMP    RDSECLP    ;READ MORE
  872. ;
  873. REOF    MVI    A,1
  874.     STA    EOFLG    ;SET EOF FLAG
  875.     MOV    A,C
  876. ;
  877. ;BUFFER IS FULL, OR GOT EOF
  878. ;
  879. RDBFULL    STA    SECINBF    ;STORE SECTOR COUNT
  880.     LXI    H,DBUF    ;INIT BUFFER..
  881.     SHLD    SECPTR    ;..POINTER
  882.     LXI    D,BASE+80H    ;RESET..
  883.     MVI    C,STDMA    ;..DMA..
  884.     CALL    BDOS    ;..ADDR
  885.     JMP    RDSECT    ;PASS SECT TO CALLER
  886. ;
  887. ;---->    WRSECT: WRITE A SECTOR
  888. ;
  889. ;WRITES THE SECTOR INTO A BUFFER.  WHEN 16
  890. ;HAVE BEEN WRITTEN, WRITES THE BLOCK TO DISK.
  891. ;
  892. ;ENTRY POINT "WRBLOCK" FLUSHES THE BUFFER AT EOF.
  893. ;
  894. WRSECT    LHLD    SECPTR    ;GET BUFF ADDR
  895.     XCHG        ;TO DE FOR MOVE
  896.     LXI    H,BASE+80H    ;FROM HERE
  897.     CALL    MOVE128    ;MOVE TO BUFFER
  898.     XCHG        ;SAVE NEXT..
  899.     SHLD    SECPTR    ;..BLOCK POINTER
  900.     LDA    SECINBF    ;BUMP THE..
  901.     INR    A    ;..SECTOR #..
  902.     STA    SECINBF    ;..IN THE BUFF
  903.     CPI    16    ;HAVE WE 16?
  904.     RNZ        ;NO, RETURN
  905. ;
  906. ;---->    WRBLOCK: WRITES A BLOCK TO DISK
  907. ;
  908. WRBLOCK    LDA    SECINBF    ;# SECT IN BUFFER
  909.     ORA    A    ;0 MEANS END OF FILE
  910.     RZ        ;NONE TO WRITE
  911.     MOV    C,A    ;SAVE COUNT
  912.     LXI    D,DBUF    ;POINT TO DISK BUFF
  913. ;
  914. DKWRLP    PUSH    H
  915.     PUSH    D
  916.     PUSH    B
  917.     MVI    C,STDMA    ;SET DMA
  918.     CALL    BDOS    ;TO BUFFER
  919.     LXI    D,FCB    ;THEN WRITE
  920.     MVI    C,WRITE    ;..THE..
  921.     CALL    BDOS    ;..BLOCK
  922.     POP    B
  923.     POP    D
  924.     POP    H
  925.     ORA    A
  926.     JNZ    WRERR    ;OOPS, ERROR
  927.     LXI    H,80H    ;LENGTH OF 1 SECT
  928.     DAD    D    ;HL= NEXT BUFF
  929.     XCHG        ;TO DE FOR SETDMA
  930.     DCR    C    ;MORE SECTORS?
  931.     JNZ    DKWRLP    ;..YES, LOOP
  932.     XRA    A    ;GET A ZERO
  933.     STA    SECINBF    ;RESET # OF SECTORS
  934.     LXI    H,DBUF    ;RESET BUFFER..
  935.     SHLD    SECPTR    ;..POINTER
  936. ;
  937. RSDMA    LXI    D,BASE+80H ;RESET..
  938.     MVI    C,STDMA    ;..DMA..
  939.     CALL    BDOS    ;..ADDR
  940.     RET
  941. ;
  942. WRERR    CALL    RSDMA    ;RESET DMA TO NORM.
  943.     CALL    ILPRT    ;PRINT:
  944.     DB    '++ERROR WRITING FILE',CR,LF,0
  945.     JMP    ABORT    ;EXIT
  946. ;
  947. ;---->    RECV: RECEIVE A CHARACTER
  948. ;
  949. ;TIMEOUT TIME IS IN B, IN SECONDS.  ENTRY VIA
  950. ;"RECVDG" DELETES GARBAGE CHARACTERS ON THE
  951. ;LINE.  FOR EXAMPLE, HAVING JUST SENT A SECTOR,
  952. ;CALLING RECVDG WILL DELETE ANY LINE-NOISE-INDUCED
  953. ;CHARACTERS "LONG" BEFORE THE ACK/NAK WOULD
  954. ;BE RECEIVED.
  955. ;
  956. RECVDG    EQU    $    ;RECEIVE W/GARBAGE DELETE
  957.     IN    MODDATP    ;GET A CHAR
  958.     IN    MODDATP    ;..TOTALLY PURGE UART
  959. ;
  960. RECV    PUSH    D    ;SAVE
  961. ;
  962.     IF    FASTCLK    ;4MHZ?
  963.     MOV    A,B    ;GET TIME REQUEST
  964.     ADD    A    ;DOUBLE IT
  965.     MOV    B,A    ;NEW TIME IN B
  966.     ENDIF
  967. ;
  968. MSEC    LXI    D,50000    ;1 SEC DCR COUNT
  969. ;
  970.     IF    NOT DCH
  971. MWTI    IN    MODCTLP    ;CHECK STATUS
  972.     ENDIF
  973. ;
  974.     IF    DCH
  975. MWTI    IN    MODCTL2    ;CHECK STATUS
  976.     ENDIF
  977. ;
  978.     ANI    MODRCVB    ;ISOLATE BIT
  979.     CPI    MODRCVR    ;READY?
  980.     JZ    MCHAR    ;GOT CHAR
  981.     DCR    E    ;COUNT..
  982.     JNZ    MWTI    ;..DOWN..
  983.     DCR    D    ;..FOR..
  984.     JNZ    MWTI    ;..TIMEOUT
  985.     DCR    B    ;MORE SECONDS?
  986.     JNZ    MSEC    ;YES, WAIT
  987. ;
  988. ;MODEM TIMED OUT RECEIVING
  989. ;
  990.     POP    D    ;RESTORE D,E
  991.     STC        ;CARRY SHOWS TIMEOUT
  992.     RET
  993. ;
  994. ;GOT CHAR FROM MODEM
  995. ;
  996. MCHAR    IN    MODDATP    ;READ THE CHAR
  997.     POP    D    ;RESTORE DE
  998. ;
  999. ;CALC CHECKSUM
  1000. ;
  1001.     PUSH    PSW    ;SAVE THE CHAR
  1002.     ADD    C    ;ADD TO CHECKSUM
  1003.     MOV    C,A    ;SAVE CHECKSUM
  1004. ;
  1005. ;CHECK IF MONITORING REC'D DATA
  1006. ;
  1007.     LDA    RSEEFLG    ;SEE RECEIVED..
  1008.     ORA    A    ;..DATA?
  1009.     JZ    MONIN    ;..YES
  1010. ;
  1011. ;CHECK IF "VIEWING" AND THIS IS A DATA CHAR
  1012. ;
  1013.     LDA    VSEEFLG    ;VIEWING..
  1014.     ORA    A    ;..DATA?
  1015.     JNZ    NOMONIN    ;..NO
  1016. ;
  1017. ;"VIEW" REQUESTED.  SHOW THE CHAR IT IS DATA
  1018. ;
  1019.     LDA    DATAFLG    ;GET DATA FLAG
  1020.     ORA    A    ;TEST IT
  1021.     JZ    NOMONIN    ;..OFF, NOT DATA
  1022. ;
  1023. MONIN    POP    PSW    ;..IS DATA,
  1024.     PUSH    PSW    ;GET IT,
  1025.     CALL    SHOW    ;..AND SHOW IT
  1026. ;
  1027. NOMONIN    POP    PSW    ;RESTORE CHAR
  1028.     ORA    A    ;CARRY OFF: NO ERROR
  1029.     RET        ;FROM "RECV"
  1030. ;
  1031. ;---->    SEND: SEND A CHARACTER TO THE MODEM
  1032. ;
  1033. SEND    PUSH    PSW    ;SAVE THE CHAR
  1034. ;
  1035. ;CHECK IF MONITORING SENT DATA
  1036. ;
  1037.     LDA    SSEEFLG    ;CHECK IF MONITORING..
  1038.     ORA    A    ;..SENT DATA
  1039.     JZ    MONOUT    ;..YES
  1040. ;
  1041. ;CHECK IF "VIEWING" THE FILE
  1042. ;
  1043.     LDA    VSEEFLG    ;GET VIEW FLAG
  1044.     ORA    A    ;TEST IT
  1045.     JNZ    NOMONOT    ;NO
  1046.     LDA    DATAFLG    ;IS THIS
  1047.     ORA    A    ;..DATA?
  1048.     JZ    NOMONOT    ;..NO.
  1049. ;
  1050. MONOUT    POP    PSW    ;GET THE CHAR
  1051.     PUSH    PSW    ;SAVE IT
  1052.     CALL    SHOW    ;SHOW IT
  1053. ;
  1054. NOMONOT    POP    PSW    ;RESTORE CHAR
  1055.     PUSH    PSW    ;SAVE IT
  1056.     ADD    C    ;CALC CKSUM
  1057.     MOV    C,A    ;SAVE CKSUM
  1058. ;
  1059.     IF    NOT DCH
  1060. SENDW    IN    MODCTLP    ;GET STATUS
  1061.     ENDIF
  1062. ;
  1063.     IF    DCH
  1064. SENDW    IN    MODCTL2    ;GET STATUS
  1065.     ENDIF
  1066. ;
  1067.     ANI    MODSNDB    ;ISOLATE READY BIT
  1068.     CPI    MODSNDR    ;READY?
  1069.     JNZ    SENDW    ;..NO, WAIT
  1070.     POP    PSW    ;GET CHAR
  1071.     OUT    MODDATP    ;OUTPUT IT
  1072.     RET        ;FROM "SEND"
  1073. ;
  1074. ;---->    WAITNAK: WAITS FOR INITIAL NAK
  1075. ;
  1076. ;TO ENSURE NO DATA IS SENT UNTIL THE RECEIVING
  1077. ;PROGRAM IS READY, THIS ROUTINE WAITS FOR THE
  1078. ;THE FIRST TIMEOUT-NAK FROM THE RECEIVER.
  1079. ;(E) CONTAINS THE # OF SECONDS TO WAIT.
  1080. ;
  1081. WAITNAK    LDA    VSEEFLG    ;VIEWING?
  1082.     ORA    A
  1083.     JZ    WAITNPR    ;PRINT MSG
  1084.     LDA    QFLG    ;QUIET..
  1085.     ORA    A    ;..MODE?
  1086.     JZ    WAITNLP    ;YES, SKIP MSG
  1087. ;
  1088. WAITNPR    CALL    ILPRT    ;PRINT:
  1089.     DB    'AWAITING INITIAL NAK',CR,LF,0
  1090. ;
  1091. WAITNLP    MVI    B,1    ;TIMEOUT DELAY
  1092.     CALL    RECV    ;DID WE GET..
  1093.     CPI    NAK    ;..A NAK?
  1094.     RZ        ;YES, SEND BLOCK
  1095.     DCR    E    ;80 TRIES?
  1096.     JZ    ABORT    ;YES, ABORT
  1097.     JMP    WAITNLP    ;NO, LOOP
  1098. ;
  1099. ;---->    INITADR: INIT'S CP/M BDOS ADDRESSES
  1100. ;
  1101. ;THIS ROUTINE FILLS IN THE ADDRESSES OF VARIOUS
  1102. ;JMP AND CALL INSTRUCTIONS, SO THAT CP/M BDOS
  1103. ;IS BYPASSED WHILE ACCESSING THE CONSOLE.  THIS
  1104. ;IS DONE TO ALLOW CHARACTERS SUCH AS CONTROL-C
  1105. ;AND CONTROL-S TO BE KEYED WHILE IN TERMINAL
  1106. ;MODE, WITHOUT CP/M INTERPRETING THEM.
  1107. ;
  1108. INITADR    LHLD    BASE+1    ;GET WARM BOOT ADDR
  1109.     LXI    D,3    ;LENGTH OF A 'JMP'
  1110.     DAD    D    ;TO CONSOLE STAT
  1111.     SHLD    VSTAT+1    ;MODIFY CALL
  1112.     DAD    D    ;TO CONSOLE IN
  1113.     SHLD    VKEYIN+1 ;MODIFY CALL
  1114.     DAD    D    ;TO CONSOLE OUT
  1115.     SHLD    VTYPE+1    ;MODIFY CALL
  1116.     RET
  1117. ;
  1118. ;---->    PROCOPT: PROCESS COMMAND OPTIONS
  1119. ; 
  1120. ;1) SAVES THE PRIMARY OPTION IN 'OPTION';
  1121. ;2) SCANS THE SUB-OPTION CHARACTERS, AND FOR
  1122. ;EACH FOUND, ZEROS THE APPROPRIATE ENTRY IN
  1123. ;THE OPTION TABLE.  FOR EXAMPLE, IF 'D' IS 
  1124. ;CODED (DISCONNECT) THEN THE 'D' STORED AT
  1125. ;'DISCFLG' IS SET TO 0 SO IT CAN BE TESTED
  1126. ;LATER.
  1127. ;
  1128. PROCOPT    LXI    D,FCB+1    ;TO PRIMARY OPT.
  1129.     LDAX    D    ;GET PRIMARY
  1130.     STA    OPTION    ;SAVE IT
  1131. ;
  1132. OPTLP    INX    D    ;TO SECONDARY OPTION
  1133.     LDAX    D    ;GET CHAR
  1134. ;
  1135. ;IF YOU MOD THIS PROGRAM FOR >7 OPTIONS,
  1136. ;YOU MUST CHANGE THE FOLLOWING, SINCE
  1137. ;THERE WON'T BE A ' ' AFTER THE OPTION
  1138. ;IF A BAUD RATE WAS SPECIFIED.
  1139. ;
  1140.     CPI    ' '    ;NO MORE OPT'NS?
  1141.     JZ    ENDOPT    ;..YES
  1142. ;SET THE APPROP. OPT: STORE 0 IN IT
  1143.     LXI    H,OPTBL    ;HL = ADDR OF 'OAQDSRV'
  1144.     MVI    B,OPTBE-OPTBL ;OPT TABLE LEN
  1145. ;
  1146. OPTCK    CMP    M    ;FOUND THE OPTION?
  1147.     JNZ    OPTNO    ;NO, DON'T SET IT
  1148.     MVI    M,0    ;SET THE OPTION
  1149.     JMP    OPTLP    ;GET NEXT OPTION
  1150. ;
  1151. OPTNO    INX    H    ;TO NEXT
  1152.     DCR    B    ;MORE?
  1153.     JNZ    OPTCK
  1154. ;OPTION NOT IN TABLE
  1155.     JMP    BADOPT    ;SHOW BAD SUB OPTION
  1156. ;
  1157. ;IF "VIEW" WAS ASKED FOR, SET QUIET FLAG
  1158. ;
  1159. ENDOPT    LDA    VSEEFLG    ;VIEW..
  1160.     ORA    A    ;..ASKED FOR?
  1161.     RNZ        ;..NO, RET FROM 'PROCOPT'
  1162.     STA    QFLG    ;YES, NO HDR/CKSUM PRT
  1163.     RET        ;FROM 'PROCOPT'
  1164. ;
  1165. ;DONE - CLOSE UP SHOP
  1166. ;
  1167. DONE    LDA    VSEEFLG    ;VIEWING?
  1168.     ORA    A
  1169.     JZ    DONETC    ;SHOW MSG
  1170.     LDA    QFLG    ;QUIET
  1171.     ORA    A    ;..MODE?
  1172.     JZ    DONECTE    ;YES, CK TERM/ECHO
  1173. ;
  1174. DONETC    CALL    ILPRT
  1175.     DB    CR,LF,'TRANSFER COMPLETE' 
  1176.     DB    CR,LF,0
  1177. ;
  1178. ;CHECK IF TERMINAL OR ECHO SUB COMMAND
  1179. ;WAS SPECIFIED
  1180. ;
  1181. DONECTE    LDA    TERMFLG    ;TERM?
  1182.     ORA    A
  1183.     JZ    TERM    ;..YES
  1184.     LDA    ECHOFLG    ;ECHO?
  1185.     ORA    A
  1186.     JZ    TRMECHO    ;..YES
  1187. ;
  1188. ;FALL INTO 'CKDIS'
  1189. ;
  1190. ;---->    CKDIS: CHECK IF DISCONNECT REQUESTED
  1191. ;
  1192. ;THIS ROUTINE IS JUMPED TO AT THE END OF
  1193. ;PROCESSING, AND DISCONNECTS THE PHONE IF
  1194. ;'D' WAS SPECIFIED AS A SUB-OPTION.
  1195. ;
  1196. CKDIS    LDA    DISCFLG    ;CHECK 'D' FLAG
  1197.     ORA    A    ;REQUESTED?
  1198. ;
  1199.     IF    PMMI OR DCH
  1200.     JNZ    NDIS    ;..NO, JUST EXIT
  1201.     ENDIF
  1202. ;
  1203.     IF    NOT PMMI AND NOT DCH
  1204.     JNZ    EXIT
  1205.     ENDIF
  1206. ;
  1207. ;AWAIT C/R TO DISC. SO WE DON'T LOSE THE PHONE
  1208. ;
  1209.     CALL    ILPRT
  1210.     DB    CR,LF,'PRESS RETURN TO DISCONNECT:',0
  1211.     CALL    KEYIN
  1212.     PUSH    PSW
  1213.     CALL    CRLF
  1214.     POP    PSW
  1215.     CPI    CR
  1216.     JNZ    CKDIS    ;ASK AGAIN
  1217. ;
  1218. ;---->    DISCONN: DISCONNECT THE PHONE
  1219. ;
  1220. DISCONN    EQU    $
  1221. ;
  1222.     IF    PMMI
  1223.     XRA    A    ;GET DISCONN VALUE
  1224.     OUT    MODCTLP    ;RESET ORIG/ANSW
  1225.     OUT    MODCTL2    ;TURN OFF DTR, DO BREAK
  1226.     ENDIF
  1227. ;
  1228.     IF    DCH
  1229.     XRA    A    ;GET DISCONNECT VALUE
  1230.     OUT    MODCTLP    ;DISCONNECT
  1231.     ENDIF
  1232. ;
  1233.     CALL    ILPRT    ;PRINT:
  1234.     DB    '++DISCONNECTED++',0
  1235.     JMP    EXIT
  1236. ;
  1237. ;NO DISCONNECT, TYPE MSG AS REMINDER THAT PHONE'S
  1238. ;OFF HOOK
  1239. ;
  1240.     IF    PMMI OR DCH
  1241. NDIS    LDA    QFLG    ;QUIET..
  1242.     ORA    A    ;..MODE?
  1243.     JZ    EXIT    ;..YES, NO MSG
  1244.     CALL    ILPRT
  1245.     DB    CR,LF,'++DON''T FORGET - THE MODEM IS '
  1246.     DB    'NOT DISCONNECTED++',CR,LF
  1247.     DB    'USE "MODEM D" TO DISCONNECT',CR,LF,0
  1248.     JMP    EXIT
  1249. ;
  1250.     ENDIF
  1251. ;
  1252. ;---->    INITMOD: INITIALIZES THE MODEM
  1253. ;
  1254. ;THIS ROUTINE IS USED TO INITIALIZE SERIAL
  1255. ;BOARDS, OR SETUP S-100 MODEM BOARDS.
  1256. ;JUST RETURNS IF NO INITIALIZATION REQUIRED.
  1257. ;
  1258. INITMOD:
  1259. ;
  1260.     IF    INITREQ  ;REQUIRE INIT?
  1261.     MVI    A,INITC1 ;GET 1ST INIT CHAR
  1262.     OUT    MODCTLP     ;OUTPUT IT
  1263.     NOP ! NOP! NOP     ;DELAY FOR USART
  1264.     NOP ! NOP
  1265.     MVI    A,INITC2 ;GET 2ND INIT CHAR
  1266.     OUT    MODCTLP     ;OUTPUT IT
  1267.     NOP ! NOP! NOP     ;DELAY FOR USART
  1268.     NOP ! NOP
  1269.     MVI    A,INITC3 ;GET 3RD INIT CHAR
  1270.     OUT    MODCTLP     ;OUTPUT IT
  1271.     NOP ! NOP! NOP     ;DELAY FOR USART
  1272.     NOP ! NOP
  1273.     MVI    A,INITC4 ;GET 4TH INIT CHAR
  1274.     OUT    MODCTLP     ;OUTPUT IT
  1275.     NOP ! NOP! NOP     ;DELAY FOR USART
  1276.     NOP ! NOP
  1277.     ENDIF
  1278. ;
  1279.     IF    PMMI
  1280.     CALL    GETBAUD    ;GET THE BAUD RATE
  1281.     OUT    BAUDRP    ;OUT BAUD RATE PORT
  1282.     ENDIF        ;PMMI
  1283. ;
  1284.     IF    DCH
  1285.     CALL    GETBAUD    ;GET BAUD RATE
  1286.     ENDIF        ;DCH
  1287. ;
  1288.     IF    PMMI
  1289. ;SET THE MOTOROLA MODEM CHIP BIT FOR >300 IF REQ'D
  1290. ;
  1291.     CPI    52    ;>300?
  1292.     MVI    A,5FH    ;VALUE FOR >300
  1293.     JC    GT300
  1294.     MVI    A,7FH    ;VALUE FOR <= 300
  1295. ;
  1296. GT300    OUT    MODCTL2    ;SET IT
  1297. ;
  1298. ;SET ORIG/ANSW IF REQUESTED
  1299. ;
  1300.     LDA    ORIGFLG    ;ORIGINATE..
  1301.     ORA    A    ;..MODE?
  1302.     MVI    A,ORIGMOD 
  1303.     JZ    OFFHOOK    ;..YES, DO IT
  1304.     LDA    ANSWFLG    ;ANSWER..
  1305.     ORA    A    ;..MODE?
  1306.     MVI    A,ANSWMOD
  1307.     RNZ        ;NEITHER ORIG NOR ANSW.
  1308.     ENDIF        ;PMMI
  1309. ;
  1310.     IF    DCH
  1311.     LDA    ANSWFLG        ;ANSWER..
  1312.     ORA    A
  1313.     MVI    B,ANSWMOD    ;SET ANSWER MODE
  1314.     JZ    INITM1
  1315.     LDA    ORIGFLG        ;GET ORIGINATE FLAG
  1316.     ORA    A
  1317.     MVI    B,ORIGMOD    ;SET ORIGINATE MODE
  1318.     JZ    INITM1
  1319.     LDA    HOLDD        ;NEITHER - GET LAST VALUE
  1320.     MOV    B,A        ;STORE IN B
  1321. ;
  1322. INITM1:    MOV    A,B        ;GET MODE
  1323.     STA    HOLDD        ;SAVE VALUE
  1324.     MOV    A,C        ;GET BAUD RATE INDICATOR
  1325.     ORA    A        ;ZEBO IF 110 BAUD
  1326.     MOV    A,B        ;GET MODE
  1327.     JZ    OFFHOOK        ;DO OFFHOOK
  1328.     ORI    1        ;SET 300 BAUD
  1329.     ENDIF            ;DCH
  1330. ;
  1331.     IF    PMMI OR DCH
  1332. ;
  1333. ;GO OFFHOOK IN REQUESTED (ORIG/ANSW) MODE
  1334. ;
  1335. OFFHOOK    LXI    H,4000    ;DELAY AMT
  1336. ;
  1337. OFFDLY    DCR    L
  1338.     JNZ    OFFDLY
  1339.     DCR    H
  1340.     JNZ    OFFDLY
  1341.     OUT    MODCTLP    ;GO OFF HOOK
  1342.     STA    CURRMOD    ;SAVE CURRENT MODE (NEEDED BY DIALMOD)
  1343.     RET
  1344.     ENDIF        ;PMMI OR DCH
  1345. ;
  1346.     IF    PMMI
  1347. ;---->    GETBAUD: GETS BAUD RATE FROM COMMAND
  1348. ;
  1349. ;THIS ROUTINE CHECKS IF A BAUD RATE HAS
  1350. ;BEEN ASKED FOR, (SUCH AS MODEM T.450),
  1351. ;AND IF SO, CALCULATES THE PMMI BAUD RATE
  1352. ;VALUE TO BE OUTPUT.  DEFAULTS TO 300.
  1353. ;
  1354. GETBAUD    LDA    FCB+9    ;GET 'FILETYPE'
  1355.     CPI    ' '    ;DEFAULT?
  1356.     MVI    A,52    ;300 BAUD VALUE
  1357.     RZ        ;NO BAUD RATE, USE 300
  1358. ;
  1359. ;GOT BAUD RATE - CONVERT TO PROPER TIMER VALUE
  1360. ;
  1361. ;FIRST, CONVERT THE NUMBER TO BINARY
  1362. ;
  1363.     CALL    CVBIN
  1364. ;
  1365. ;CALCULATE THE VALUE TO OUTPUT:
  1366. ;
  1367. ;    RATE = 250000/16/BAUD RATE
  1368. ;
  1369. ;    DIVIDE BY REPETITIVE SUBTRACTION
  1370. ;    ------
  1371. ;COMPLEMENT THE BAUD RATE
  1372. ;
  1373.     MOV    A,H    ;GET HI
  1374.     CMA        ;COMPLEMENT
  1375.     MOV    D,A    ;SAVE
  1376.     MOV    A,L    ;GET LO
  1377.     CMA        ;COMPLEMENT
  1378.     MOV    E,A    ;SAVE
  1379.     INX    D    ;DE=2'S COMPLEMENT
  1380. ;DIVIDE
  1381.     LXI    H,15625    ;250000/16 
  1382.     LXI    B,-1    ;INIT QUOTIENT
  1383. ;
  1384. DIVLP    INX    B    ;BUMP QUOTIENT
  1385.     DAD    D    ;'SUBTRACT'
  1386.     JC    DIVLP    ;LOOP 'TILL DONE
  1387. ;VALIDATE THE RESULT
  1388.     MOV    A,B    ;CAN'T HAVE >255
  1389.     ORA    A
  1390.     MOV    A,C    ;GET ACTUAL
  1391.     RZ        ;RET IF <256
  1392.     JMP    BADRATE    ;INVALID
  1393.     ENDIF        ;PMMI
  1394. ;
  1395.     IF    DCH
  1396. GETBAUD    LDA    FCB+9    ;GET FILETYPE
  1397.     CPI    ' '    ;DEFAULT?
  1398.     JNZ    GETBAU1    ;NO - DO BAUD RATE STUFF
  1399.     MVI    C,1    ;SET 300 BAUD
  1400.     MVI    B,17H    ;SET 1 STOP BIT
  1401.     JMP    GETBAU2
  1402. ;
  1403. ; CONVERT BAUD RATE TO BINARY
  1404. GETBAU1    CALL    CVBIN    ;CONVERT TO BINARY
  1405.     PUSH    H    ;SAVE BAUD RATE
  1406.     MVI    C,0    ;ANTICIPATE 110 BAUD
  1407.     MVI    B,1FH    ;SET 2 STOP BITS
  1408.     LXI    D,-110    ;GET CONSTANT
  1409.     DAD    D    ;SUBTRACT
  1410.     MOV    A,H
  1411.     ORA    L
  1412.     POP    H
  1413.     JZ    GETBAU2    ;110 BAUD
  1414.     MVI    B,17H    ;SET 1 STOP BIT
  1415.     INR    C
  1416.     LXI    D,-300    ;GET CONSTANT
  1417.     DAD    D
  1418.     MOV    A,H
  1419.     ORA    L
  1420.     JNZ    BADRATE    ;INVALID
  1421. ;
  1422. GETBAU2    MOV    A,B    ;GET SET UP
  1423.     OUT    MODCTL2    ;INITIALIZE MODEM FOR STOP BITS..
  1424.     RET        ;..DATA BITS, ETC.
  1425.     ENDIF        ;DCH
  1426. ;
  1427.     IF    PMMI OR DCH
  1428. ; ROUTINE TO CONVERT BAUD RATE TO BINARY
  1429. ;
  1430. CVBIN:    LXI    D,FCB+9    ;TO ASCII VALUE
  1431.     LXI    H,0    ;INIT BINARY RESULT
  1432. ;
  1433. DECLP    LDAX    D    ;GET ASCII DIGIT
  1434.     INX    D    ;TO NEXT DIGIT
  1435.     CPI    ' '    ;BLANK ONE?
  1436.     JZ    DECLP    ;..YES, SKIP IT
  1437.     CPI    '0'    ;VALIDATE IT
  1438.     JC    BADRATE    ;ERROR
  1439.     CPI    '9'+1    ;VALIDATE
  1440.     JNC    BADRATE    ;ERROR
  1441.     SUI    '0'    ;MAKE DIGIT BINARY
  1442. ;
  1443. ;MULTIPLY PREV VALUE BY 10
  1444. ;
  1445.     MOV    B,H    ;SET UP FOR
  1446.     MOV    C,L    ;MULTIPLY BY 10
  1447.     DAD    H    ;MULTIPLY BY 2
  1448.     DAD    H    ;X 2 = 4
  1449.     DAD    B    ;+ 1 = 5
  1450.     DAD    H    ;X 2 = 10
  1451.     ADD    L    ;ADD IN DIGIT
  1452.     MOV    L,A    ;SAVE BACK
  1453.     JNZ    DIGNC    ;NO CARRY?
  1454.     INR    H    ;ADD IN CARRY
  1455. ;CHECK IF DONE?
  1456. DIGNC    MOV    A,E    ;SEE IF PAST
  1457.     CPI    FCB+12    ;..LAST DIGIT
  1458.     JNZ    DECLP    ;NO, LOOP
  1459.     RET
  1460. ;
  1461. ;INVALID BAUD RATE
  1462. ;
  1463. BADRATE    CALL    ERXIT
  1464.     DB    '++INVALID BAUD RATE++$'
  1465.     ENDIF        ;PMMI OR DCH
  1466. ;
  1467. ;THE FOLLOWING PROVIDES A RETURN FROM INITMOD
  1468.     IF    NOT PMMI AND NOT DCH
  1469.     RET        ;**THIS MUST BE HERE**
  1470.     ENDIF        ;NOT PMMI AND NOT DCH
  1471. ;
  1472. ;---->    MOVEFCB: MOVES FCB(2) TO FCB
  1473. ;
  1474. ;I ATTEMPTED TO MAKE THE MODEM COMMAND 'NATURAL',
  1475. ;I.E. MODEM SEND FILENAME (MODEM S FN.FT) RATHER
  1476. ;THAT MODEM FILENAME SEND (MODEM FN.FT S) SO THIS
  1477. ;ROUTINE MOVES THE FILENAME FROM THE SECOND FCB
  1478. ;TO THE FIRST
  1479. ;
  1480. MOVEFCB    LXI    H,FCB+16 ;FROM
  1481.     LXI    D,FCB    ;TO
  1482.     MVI    B,16    ;LEN
  1483.     CALL    MOVE    ;DO THE MOVE
  1484.     XRA    A    ;GET 0
  1485.     STA    FCBSNO    ;ZERO SECTOR #
  1486.     STA    FCBEXT    ;..AND EXTENT
  1487.     RET
  1488. ;
  1489. ;---->    SHOW: SHOWS CHAR SENT/RECEIVED
  1490. ;
  1491. ;CR, LF, AND TAB ARE SHOWN.  ALL OTHER
  1492. ;NON-PRINTABLE CHARACTERS ARE SHOWN IN
  1493. ;HEX AS (XX)
  1494. ;
  1495. SHOW    CPI    LF    ;LF?
  1496.     JZ    CTYPE    ;..YES, TYPE IT
  1497.     CPI    CR    ;CR?
  1498.     JZ    CTYPE    ;..YES, TYPE IT
  1499.     CPI    09    ;TAB
  1500.     JZ    CTYPE    ;..YES, TYPE IT
  1501.     CPI    ' '    ;CTL-CHR?
  1502.     JC    SHOWHEX    ;YES, SHOW IN HEX
  1503.     CPI    7FH    ;DEL?
  1504.     JC    CTYPE    ;NO, TYPE THE CHAR
  1505. ;
  1506. SHOWHEX    PUSH    PSW    ;SAVE THE CHAR
  1507.     MVI    A,'('    ;TYPE..
  1508.     CALL    CTYPE    ;..'('
  1509.     POP    PSW    ;THEN..
  1510.     CALL    HEXO    ;..THE CHAR
  1511.     MVI    A,')'    ;THEN..
  1512.     JMP    CTYPE    ;..')' AND RETURN.
  1513. ;
  1514. ;---->    CTYPE: TYPES VIA CP/M SO TABS ARE EXPANDED
  1515. ;
  1516. CTYPE    PUSH    B    ;SAVE..
  1517.     PUSH    D    ;..ALL..
  1518.     PUSH    H    ;..REGS
  1519.     MOV    E,A    ;CHAR TO E
  1520.     MVI    C,WRCON    ;GET BDOS FNC
  1521.     CALL    BDOS    ;PRIN THE CHR
  1522.     POP    H    ;RESTORE..
  1523.     POP    D    ;..ALL..
  1524.     POP    B    ;..REGS
  1525.     RET        ;FROM "CTYPE"
  1526. ;
  1527. CRLF    MVI    A,CR
  1528.     CALL    TYPE
  1529.     MVI    A,LF
  1530. ;
  1531. ;---->    TYPE: TYPE VIA DIRECT CBIOS ACCESS
  1532. ;WE ASSUME CBIOS MAY DESTROY SOME REGISTERS,
  1533. ;SO SAVE THEM ALL.
  1534. ;
  1535. ;THIS ROUTINE BYPASSES CP/M'S CTL-S, CTL-C
  1536. ;TESTS.
  1537. ;
  1538. TYPE    PUSH    PSW    ;SAVE CHAR
  1539.     PUSH    B    ;AND OTHER REGISTERS
  1540.     PUSH    D
  1541.     PUSH    H
  1542.     MOV    C,A    ;FOR BIOS
  1543. VTYPE    CALL    $-$    ;MODIFIED AT INIT
  1544.     POP    H    ;RESTORE REGISTERS
  1545.     POP    D
  1546.     POP    B
  1547.     POP    PSW    ;..AND CHAR
  1548.     RET        ;FROM "TYPE"
  1549. ;
  1550. ;---->  STAT: KEYBOARD STATUS
  1551. ;
  1552. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1553. ;CBIOS CLOBBERS THEM.
  1554. ;
  1555. STAT    PUSH    B
  1556.     PUSH    D
  1557.     PUSH    H
  1558. VSTAT    CALL    $-$    ;ADDR SET AT INIT
  1559.     POP    H
  1560.     POP    D
  1561.     POP    B
  1562.     ORA    A    ;0 => NOT READY
  1563.     RET
  1564. ;
  1565. ;---->  KEYIN: KEYBOARD INPUT
  1566. ;
  1567. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1568. ;CBIOS CLOBBERS THEM.
  1569. ;
  1570. KEYIN    PUSH    B
  1571.     PUSH    D
  1572.     PUSH    H
  1573. VKEYIN    CALL    $-$    ;ADDR SET AT INIT
  1574.     POP    H
  1575.     POP    D
  1576.     POP    B
  1577.     ANI    7FH    ;STRIP PARITY IF THERE
  1578.     RET        ;FROM KEYIN
  1579. ;
  1580. ;---->  HEXO: HEX OUTPUT
  1581. ;
  1582. HEXO    PUSH    PSW    ;SAVE FOR RIGHT DIGIT
  1583.     RAR        ;RIGHT..
  1584.     RAR        ;..JUSTIFY..
  1585.     RAR        ;..LEFT..
  1586.     RAR        ;..DIGIT..
  1587.     CALL    NIBBL    ;PRINT LEFT DIGIT
  1588.     POP    PSW    ;RESTORE RIGHT
  1589. ;
  1590. NIBBL    ANI    0FH    ;ISOLATE DIGIT
  1591.     CPI    10    ;IS IS <10?
  1592.     JC    ISNUM    ;YES, NOT ALPHA
  1593.     ADI    7    ;ADD ALPHA BIAS
  1594. ;
  1595. ISNUM    ADI    '0'    ;MAKE PRINTABLE
  1596.     JMP    TYPE    ;..THEN TYPE IT
  1597. ;
  1598. ;---->    CKQUIT: QUIT/RETRY AFTER MULTIPLE ERRS.
  1599. ;
  1600. ;RETURNS W/ ZERO SET IF "RETRY" ASKED FOR
  1601. ;
  1602. CKQUIT    XRA    A    ;ZERO..
  1603.     STA    ERRCT    ;..ERROR COUNT
  1604.     CALL    ILPRT    ;PRINT:
  1605.     DB    'MULTIPLE ERRORS ENCOUNTERED.  '
  1606.     DB    'TYPE Q TO QUIT, R TO RETRY: ',0
  1607.     CALL    KEYIN    ;QUIT/RETRY
  1608.     PUSH    PSW
  1609.     CALL    TYPE
  1610.     CALL    CRLF
  1611.     POP    PSW
  1612.     ANI    5FH    ;MAKE UPPER CASE
  1613.     CPI    'R'    ;RETRY?
  1614.     RZ        ;'KEEP ON TRUCKIN'
  1615.     CPI    'Q'    ;QUIT?
  1616.     JNZ    CKQUIT    ;NO, ASK AGAIN
  1617.     ORA    A    ;SET NON-ZERO
  1618.     RET
  1619. ;
  1620. ;---->    ILPRT: INLINE PRINT OF MSG
  1621. ;
  1622. ;THE CALL TO ILPRT IS FOLLOWED BY A MESSAGE,
  1623. ;BINARY 0 AS THE END.  BINARY 1 MAY BE USED TO
  1624. ;PAUSE (MESSAGE 'PRESS RETURN TO CONTINUE')
  1625. ;
  1626. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  1627. ;
  1628. ILPLP    MOV    A,M    ;GET CHAR
  1629.     ORA    A    ;END OF MSG?
  1630.     JZ    ILPRET    ;..YES, RETURN
  1631.     CPI    1    ;PAUSE?
  1632.     JZ    ILPAUSE    ;..YES
  1633.     CALL    CTYPE    ;TYPE THE MSG
  1634. ;
  1635. ILPNEXT    INX    H    ;TO NEXT CHAR
  1636.     JMP    ILPLP    ;LOOP
  1637. ;
  1638. ;PAUSE WHILE TYPING HELP SO INFO DOESN'T
  1639. ;    SCROLL OFF OF VIDEO SCREENS
  1640. ;
  1641. ILPAUSE    CALL    ILPRT    ;PRINT:
  1642.     DB    CR,LF,'PRESS RETURN TO CONTINUE'
  1643.     DB    CR,LF,0
  1644.     CALL    KEYIN    ;GET ANY CHAR
  1645.     CPI    'C'-40H    ;REBOOT?
  1646.     JZ    EXIT    ;YES.
  1647.     JMP    ILPNEXT    ;LOOP
  1648. ;
  1649. ILPRET    XTHL        ;RESTORE HL
  1650.     RET        ;PAST MSG
  1651. ;
  1652. ;---->    PRTMSG: PRINTS MSG POINTED TO BY (DE)
  1653. ;
  1654. ;A '$' IS THE ENDING DELIMITER FOR THE PRINT.
  1655. ;NO REGISTERS SAVED.
  1656. ;
  1657. PRTMSG    MVI    C,PRINT    ;GET BDOS FNC
  1658.     JMP    BDOS    ;PRINT MESSAGE, RETURN
  1659. ;
  1660. ;---->    ERXIT: EXIT PRINTING MSG FOLLOWING CALL
  1661. ;
  1662. ERXIT    POP    D    ;GET MESSAGE
  1663.     CALL    PRTMSG    ;PRINT IT
  1664.     CALL    CKDIS    ;DISCONNECT?
  1665. ;
  1666. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  1667.     SPHL        ;RESTORE IT
  1668.     RET        ;--EXIT-- TO CP/M
  1669. ;
  1670. ;MOVE 128 CHARACTERS
  1671. ;
  1672. MOVE128    MVI    B,128    ;SET MOVE COUNT
  1673. ;
  1674. ;MOVE FROM (HL) TO (DE) LENGTH IN (B)
  1675. ;
  1676. MOVE    MOV    A,M    ;GET A CHAR
  1677.     STAX    D    ;STORE IT
  1678.     INX    H    ;TO NEXT "FROM"
  1679.     INX    D    ;TO NEXT "TO"
  1680.     DCR    B    ;MORE?
  1681.     JNZ    MOVE    ;..YES, LOOP
  1682.     RET        ;..NO, RETURN
  1683. ;    ----------------
  1684. ;
  1685. ;
  1686. ;---->    DIALMOD: DETECT PHONE # IN COMMAND LINE AND DIAL IT
  1687. ;
  1688. ;THIS ROUTINE (AND THE CALL TO IT) IS ENABLED ONLY WHEN 'DCH'
  1689. ;IS TRUE BECAUSE I DON'T KNOW HOW TO MAKE THE OTHER MODEM
  1690. ;BOARDS DIAL.  MOST OF THE PHONE NUMBER LOGIC SHOULD CROSS
  1691. ;OVER TO OTHER MODEM BOARDS IF SOMEBODY WILL GIVE IT A TRY.
  1692. ;
  1693. ;THE PHONE NUMBER IS THE LAST PARAMETER IN THE COMMAND LINE.
  1694. ;FOR EXAMPLE:    MODEM T 123-456-7890
  1695. ;        MODEM E 123-456-7890
  1696. ;        MODEM S ABCDEFGH.IJK 123-456-8790
  1697. ;        MODEM R ABCDEFGH.IJK 123-456-7890
  1698. ;IF NO PHONE NUMBER IS GIVEN, THIS ROUTINE RETURNS WITHOUT
  1699. ;DOING ANYTHING.  THE DIALER RECOGNIZES THE DIGITS 0-9 AND
  1700. ;ALSO AN ASTERISK (*), WHICH CAUSES A TWO SECOND DELAY.
  1701. ;THIS IS USEFUL FOR SUCH THINGS AS WAITING FOR THE SECOND
  1702. ;DIAL TONE IN A CENTREX SYSTEM.
  1703. ;THE POUND SIGN CHARACTER (#) MAY BE USED IN PLACE OF A PHONE
  1704. ;NUMBER TO RE-DIAL THE LAST-DIALED PHONE NUMBER.  THIS OF COURSE
  1705. ;WILL ONLY WORK IF NO OTHER PROGRAMS HAVE BEEN EXECUTED IN THE
  1706. ;INTERIM.
  1707. ;ALL OTHER CHARACTERS ARE IGNORED.  (THIS INCLUDES THE DASHES
  1708. ;IN THE ABOVE EXAMPLES, WHICH COULD HAVE BEEN OMITTED.)
  1709. ;THE LENGTH OF THE DIAL STRING MUST BE AT LEAST 7 CHARACTERS
  1710. ;TO BE RECOGNIZED, AND MAY CONSIST OF UP TO 20 CHARACTERS.
  1711. ;
  1712.     IF    FASTCLK
  1713. DIALTIM    EQU    -3390        ;SET DELAY LOOP LENGTH FOR DIALING
  1714.     ENDIF
  1715.     IF    NOT FASTCLK
  1716. DIALTIM    EQU    -1786
  1717.     ENDIF
  1718. ;
  1719.     IF    DCH
  1720. DIALMOD:LXI    H,BASE+80H    ;LOOK AT CP/M COMMAND TAIL
  1721.     MOV    B,M        ;GET BYTE COUNT
  1722.     INX    H        ;BUMP TO FIRST CHAR
  1723.     CALL    SKBLNK        ;SKIP LEADING BLANKS
  1724.     RC            ;NOTHING LEFT...QUIT
  1725.     CALL    SKARG        ;ALWAYS AT LEAST ONE ARG TO SKIP
  1726.     RC            ;NOTHING FOLLOWS...QUIT
  1727.     LDA    OPTION        ;LOOK AT MAIN OPTION TO SEE IF
  1728.     CPI    'T'        ; IT HAS A SECOND PARAMETER
  1729.     JZ    ONEARG        ;T HAS ONLY ONE
  1730.     CPI    'E'        ;SO DOES E
  1731.     JZ    ONEARG
  1732.     CALL    SKARG        ;MUST BE R OR S, SO SKIP FILENAME
  1733.     RC            ;QUIT IF NOTHING LEFT
  1734. ONEARG:    MOV    A,M        ;LOOK AT FIRST CHAR OF PHONE #
  1735.     CPI    '#'        ;REDIAL FLAG?
  1736.     JZ    REDIAL        ;IF SO, DON'T COPY NUMBER
  1737.     LXI    D,DIALBUF
  1738. CNLUP:    STAX    D        ;COPY PHONE NUMBER TO DIALBUF
  1739.     INX    D
  1740.     INX    H
  1741.     MOV    A,M
  1742.     DCR    B
  1743.     JNZ    CNLUP
  1744.     SUB    A        ;TAG END OF NUMBER WITH A NULL
  1745.     STAX    D
  1746. REDIAL:    CALL    ILPRT        ;SAY WE'RE DIALING
  1747.     DB    CR,LF,'DIALING - ',0
  1748.     LDA    CURRMOD        ;PICK UP MODEM COMMAND BYTE
  1749.     ANI    8DH        ;REMOVE CARRIER ENABLE
  1750.     OUT    MODCTLP
  1751.     MVI    B,40
  1752.     CALL    VARDLY        ;GIVE 2 SECOND DELAY FOR DIALTONE
  1753.     LXI    H,DIALBUF
  1754. DL:    MOV    A,M        ;PICK UP DIGIT
  1755.     ORA    A
  1756.     JZ    WAITANS        ;NULL MEANS FINISHED
  1757.     CALL    TYPE        ;ECHO DIGIT
  1758.     CPI    '*'
  1759.     MVI    B,40        ;IF STAR, DO 2 SECOND DELAY
  1760.     CZ    VARDLY
  1761.     INX    H        ;BUMP POINTER
  1762.     SUI    '0'        ;CONVERT DIGIT TO BINARY
  1763.     JNZ    NOTZ        ;CHANGE 0 TO 10
  1764.     MVI    A,10
  1765. NOTZ:    JC    DL        ;IGNORE NON-NUMERIC
  1766.     CPI    11
  1767.     JNC    DL
  1768. PULSE:    PUSH    PSW        ;SAVE PULSE COUNT
  1769.     LDA    CURRMOD
  1770.     ANI    7DH        ;DROP OFF-HOOK
  1771.     OUT    MODCTLP
  1772.     CALL    DELAY        ;FOR ONE HALF PULSE TIME
  1773.     ORI    80H
  1774.     OUT    MODCTLP        ;GO BACK OFF HOOK
  1775.     CALL    DELAY        ;FOR OTHER HALF PULSE TIME
  1776.     POP    PSW        ;GET BACK PULSE COUNT
  1777.     DCR    A        ;COUNT IT DOWN
  1778.     JNZ    PULSE        ;LOOP TILL DIGIT IS OUT
  1779.     MVI    B,10        ;DELAY 500MS BETWEEN DIGITS
  1780.     CALL    VARDLY
  1781.     JMP    DL        ;GO DO NEXT DIGIT
  1782. ;
  1783. VARDLY:    CALL    DELAY        ;DELAY (B) TIMES 50 MS.
  1784.     DCR    B
  1785.     JNZ    VARDLY
  1786.     RET
  1787. ;
  1788. DELAY:    PUSH    H        ;DELAY FOR 50 MILLISECONDS
  1789.     PUSH    D
  1790.     PUSH    PSW
  1791.     CALL    STAT        ;CHECK FOR CONTROL-D
  1792.     CNZ    KEYIN
  1793.     CPI    DISCCHR        ;TO ABORT DIALING
  1794.     JZ    DISCONN
  1795.     POP    PSW
  1796.     LXI    D,1        ;SET UP FOR DELAY LOOP
  1797.     LXI    H,DIALTIM
  1798. DLYLP:    XTHL            ;KILL LOTSA TIME
  1799.     XTHL
  1800.     DAD    D        ;SLOW WAY TO DO AN INX
  1801.     JNC    DLYLP
  1802.     POP    D
  1803.     POP    H        ;RESTORE REGS
  1804.     RET            ;DONE
  1805. ;
  1806. ; COME HERE AFTER DIALING TO WAIT FOR ANSWER
  1807. ;
  1808. WAITANS:CALL    CRLF        ;SHOW NUMBER FINISHED
  1809.     LXI    D,600        ;WE'LL WAIT 30 SECONDS FOR ANSWER
  1810.     LDA    CURRMOD
  1811.     MOV    B,A        ;SAVE CURRENT MODE
  1812.     ANI    4        ;CHECK ORIG/ANS BIT
  1813.     JNZ    CARR        ;IF ORIG, WAIT FOR ANSWERING CARRIER
  1814.     MOV    A,B        ;IF ANS, GIVE OUR CARRIER, THEN WAIT
  1815.     OUT    MODCTLP
  1816. CARR:    IN    MODCTL2        ;WAIT FOR CARRIER DETECT
  1817.     ANI    40H
  1818.     JNZ    GOTCARR
  1819.     CALL    DELAY
  1820.     DCX    D        ;COUNT DOWN DELAY
  1821.     MOV    A,D
  1822.     ORA    E
  1823.     JNZ    CARR
  1824.     CALL    ILPRT        ;SAY WE'RE GIVING UP
  1825.     DB    BEL,'NO ANSWER',CR,LF,0
  1826.     JMP    DISCONN        ;HANG UP
  1827. ;
  1828. GOTCARR:CALL    ILPRT        ;SAY WE GOT IT
  1829.     DB    BEL,'CONNECTION ESTABLISHED',CR,LF,0
  1830.     LDA    CURRMOD        ;RESTORE WHOLE MODE BYTE
  1831.     OUT    MODCTLP
  1832.     RET            ;ALL DONE
  1833. ;
  1834. SKBLNK:    MOV    A,M        ;SCAN PAST BLANKS IN COMMAND LINE
  1835.     CPI    ' '
  1836.     RNZ
  1837.     INX    H
  1838.     DCR    B
  1839.     JNZ    SKBLNK        ;CONTINUE SCAN TILL CHARS EXHAUSTED
  1840.     STC            ;CARRY SET SAYS END OF COMMAND
  1841.     RET
  1842. ;
  1843. SKARG:    MOV    A,M        ;SCAN PAST ONE ARGUMENT AND FOLLOWING BLANKS
  1844.     CPI    ' '
  1845.     JZ    SKBLNK        ;GOT BLANK...GO SKIP BLANKS
  1846.     INX    H
  1847.     DCR    B        ;SCAN TILL STRING GONE
  1848.     JNZ    SKARG
  1849.     STC            ;SET CARRY ON RETURN IF END OF STRING
  1850.     RET
  1851. ;
  1852.     ENDIF            ;(FOR DIALING LOGIC)
  1853. ;
  1854. ;
  1855. OPTION    DB    0    ;PRIMARY OPTION
  1856. ;
  1857. ;DATAFLG IS USED BY THE "V" SUBCOMMAND -
  1858. ;IT IS 0 WHEN A HEADER OR CKSUM IS BEING
  1859. ;SENT/RCD, AND 1 IF "VIEWABLE" DATA (THE
  1860. ;SECTOR ITSELF) IS
  1861. ;
  1862. DATAFLG    DB    0    ;AT HEADER, FIRST
  1863. ;
  1864. ;
  1865. ;SUB-OPTION TABLE.  IF AN OPTION IS IN EFFECT,
  1866. ;    THE CHARACTER IS SET TO BINARY 0
  1867. ;
  1868. OPTBL    EQU    $
  1869. ANSWFLG    DB    'A'    ;ANSWER MODE
  1870. DISCFLG    DB    'D'    ;DISCONNECT WHEN DONE
  1871. ECHOFLG    DB    'E'    ;TO ECHO AFTER XFER
  1872. ORIGFLG    DB    'O'    ;ORIGINATE MODE
  1873. QFLG    DB    'Q'    ;QUIET TRANSFER (NO MSGS)
  1874. RSEEFLG    DB    'R'    ;SEE WHAT'S RECEIVED
  1875. SSEEFLG    DB    'S'    ;SEE WHAT'S SENT
  1876. TERMFLG    DB    'T'    ;TO TERM AFTER XFER
  1877. VSEEFLG    DB    'V'    ;VIEW MESSAGES (NO HDR, ETC)
  1878. OPTBE    EQU    $    ;END OF OPTIONS
  1879. ;
  1880. RCVSNO    DB    0    ;SECT # RECEIVED
  1881. SECTNO    DB    0    ;CURRENT SECTOR NUMBER 
  1882. ERRCT    DB    0    ;ERROR COUNT
  1883. HOLDD    DB    86H    ;HOLD AREA - LAST DC HAYES CONT CHAR.
  1884. CURRMOD    DB    86H    ;CURRENT MODEM COMMAND BYTE
  1885. ;
  1886. ;FOLLOWING 3 USED BY DISK BUFFERING ROUTINES
  1887. EOFLG    DB    0    ;EOF FLAG (1=TRUE)
  1888. SECPTR    DW    DBUF
  1889. SECINBF    DB    0    ;# OF SECTORS IN BUFFER
  1890.     DS    60    ;STACK AREA
  1891. STACK    DS    2    ;STACK POINTER
  1892. ;
  1893. ;16 SECTOR DISK BUFFER (OVERLAYS HELP MSGS)
  1894. ;
  1895. DBUF    EQU    $    ;16 SECTOR DISK BUFFER
  1896. ;
  1897. ;INVALID COMMAND
  1898. ;
  1899. BADOPT    CALL    TYPE
  1900.     CALL    ILPRT    ;EXIT W/ERROR
  1901.     DB    ': INVALID OPTION ON MODEM '
  1902.     DB    'COMMAND - ',CR,LF
  1903.  DB 'PRESS RETURN FOR HELP, CTL-C IF NOT',CR,LF,1,0
  1904. ;
  1905. HELP    CALL    ILPRT
  1906.  DB 'Format for command is:',cr,lf,cr,lf
  1907.  DB 'MODEM ? FILENAME'
  1908.     IF    DCH
  1909.  DB ' PHONENUM'
  1910.     ENDIF
  1911.  DB CR,LF,CR,LF
  1912.  DB 'Where ? is a 1 character primary option,',cr,lf
  1913.  DB ' which may be followed by sub-options,',cr,lf
  1914.  DB ' and by ".xxx" to set baud rate to xxx.',CR,LF
  1915.  DB 'FILENAME is any valid CP/M unambiguous drive and filespec.',CR,LF
  1916.  DB ' It is used only for the "R" and "S" functions.',CR,LF
  1917.     IF    DCH
  1918.  DB 'PHONENUM is an optional parameter which if present',CR,LF
  1919.  DB ' is a telephone number to be automatically dialed.',CR,LF
  1920.  DB ' A "*" may be used to cause a 2 second pause in dialing.',CR,LF
  1921.  DB ' A "#" means to redial the last phone number attempted.',CR,LF
  1922.  DB ' All other characters are ignored.'
  1923.     ENDIF
  1924.  DB cr,lf,cr,lf,1
  1925.  DB 'Primary Options:',cr,lf
  1926.  DB '    S to send a file',cr,lf
  1927.  DB '    R to receive a file',cr,lf
  1928.  DB '    T to act as a terminal',cr,lf
  1929.  DB '    E to act as a computer (echo data)',cr,lf
  1930.  DB '    D to disconnect the phone'
  1931.  DB '    (S100 modems only)',cr,lf
  1932.  DB '    H to print this help file'
  1933.  DB cr,lf,cr,lf,1
  1934.  DB 'Secondary options:',cr,lf
  1935.  DB '    A answer mode',cr,lf
  1936.  DB '    O originate mode',cr,lf
  1937.  DB '    D disconnect after execution',cr,lf
  1938.  DB '    T go to terminal mode after file xfer',cr,lf
  1939.  DB '    E go to echo mode after file xfer',cr,lf
  1940.  DB '    Q quiet mode - no status msgs',cr,lf
  1941.  DB '    R show chars received',cr,lf
  1942.  DB '    S show chars sent',cr,lf
  1943.  DB '    V view file sent/received (no status)',cr,lf
  1944.  DB CR,LF,'FOR EXAMPLES, TYPE: MODEM X',cr,lf,0
  1945.     JMP    EXIT
  1946. ;
  1947. EXAM    CALL    ILPRT
  1948.  DB 'Send file, originate mode, 300 baud:',CR,LF
  1949.  DB '    MODEM SO fn.ft',cr,lf
  1950.  DB 'Send another file:',CR,LF
  1951.  DB '    MODEM S fn.ft',cr,lf
  1952.  DB 'Then send a third file at 450 baud and disconnect:'
  1953.  DB CR,LF,'    MODEM SD.450 fn.ft',cr,lf
  1954.  DB 'Act as a terminal, originate mode, at 110 baud:',cr,lf
  1955.  DB '    MODEM TO.110',CR,LF
  1956.  DB '    (Use ctl-D to disconnect)',cr,lf
  1957.  DB 'Receive file, answer mode, view it, 600 baud:',cr,lf
  1958.  DB '    MODEM RAV.600 fn.ft',cr,lf,0
  1959. JMP EXIT
  1960. ;
  1961. ;
  1962.     DS    128-($ AND 127)    ;FORCE NEXT SECTOR BOUNDARY
  1963. DIALBUF    EQU    $    ;STORAGE FOR NUMBER BEING DIALED
  1964. ;
  1965. ;
  1966. ; BDOS EQUATES (VERSION 2)
  1967. ;
  1968. RDCON    EQU    1
  1969. WRCON    EQU    2
  1970. PRINT    EQU    9
  1971. CONST    EQU    11    ;CONSOLE STAT
  1972. OPEN    EQU    15    ;0FFH=NOT FOUND
  1973. CLOSE    EQU    16    ;    "    "
  1974. SRCHF    EQU    17    ;    "    "
  1975. SRCHN    EQU    18    ;    "    "
  1976. ERASE    EQU    19    ;NO RET CODE
  1977. READ    EQU    20    ;0=OK, 1=EOF
  1978. WRITE    EQU    21    ;0=OK, 1=ERR, 2=?, 0FFH=NO DIR SPC
  1979. MAKE    EQU    22    ;0FFH=BAD
  1980. REN    EQU    23    ;0FFH=BAD
  1981. STDMA    EQU    26    ;SET DMA
  1982. BDOS    EQU    BASE+5
  1983. REIPL    EQU    BASE
  1984. FCB    EQU    BASE+5CH    ;SYSTEM FCB
  1985. FCBEXT    EQU    FCB+12        ;FILE EXTENT
  1986. FCBSNO    EQU    FCB+32        ;SECTOR #
  1987. FCB2    EQU    BASE+6CH    ;SECOND FCB
  1988.     END
  1989.