home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol009 / mdir8-17.asm < prev    next >
Assembly Source File  |  1984-04-29  |  10KB  |  464 lines
  1. ;            MDIR.ASM
  2. ;             revised 8/17/80
  3. ;
  4. ;       CP/M-2 MASTER DISK DIRECTORY PROGRAM
  5. ;            by Jeff Hammersley, MD.
  6. ;
  7. ; PRINTS A COMPLETE DISK DIRECTORY INCLUDING ALL USERS,
  8. ; SORTED ALPHABETICALLY AND PRINTED 4 WIDE.
  9. ;
  10. ; Based on 'FMAP' as originally written by Ward Christensen
  11. ; and its subsequent evolution to 'SDIR' by Keith Petersen.
  12. ;
  13. ;---------------------------------------------------------------;
  14. ;                                ;
  15. ; Commands:                            ;
  16. ;                                ;
  17. ; MDIR      returns all files on the default disk under any user.    ;
  18. ;                                ;
  19. ; Note: optional drive name may be specified.            ;
  20. ;                                ;
  21. ;                                ;
  22. ; MDIR FILENAME.FILETYPE    searches for all files that match    ;
  23. ;        in all user areas.                ;
  24. ;                                ;
  25. ; MDIR S???.*  returns all 4 character files with any extention    ;
  26. ;        in any user areas.                ;
  27. ;                                ;
  28. ;_______________________________________________________________;
  29. ; 
  30. ;07/02/80 FIXED TO ALLOW MORE THAN 256 NAMES IN DIRECTORY,
  31. ;      PRINT DRIVE NAME, AND ALLOW SPECIFYING DRIVE.
  32. ;      BY KEITH PETERSEN, W8SDZ.
  33. ;
  34. ;07/30/80 FIXED TO ELIMINATE CRASH WHEN NO NAMES ARE IN
  35. ;      DIRECTORY. REPLACED DECIMAL OUTPUT ROUTINE WITH
  36. ;      SIMPLER ONE WHICH IS SMALLER AND ALLOWS USE OF
  37. ;      ONE LESS LEADING SPACE SO DISPLAY CAN BE PRINTED
  38. ;      ON A 72-CHARACTER PRINTER. (KBP)
  39. ;
  40. ;08/17/80 CORRECTED MISSING INR A IN SEARCH FIRST ROUTINE,
  41. ;      WHICH CAUSED DUPLICATE LISTING OF THIRD DIRECTORY
  42. ;      ENTRY. (KBP)
  43. ;
  44. BASE    SET    0
  45. ;
  46. ALTCPM    EQU    0    ;PUT 1 HERE FOR H8 OR TRS-80 CP/M
  47. ;
  48.     IF    ALTCPM
  49. BASE    SET    4200H
  50.     ENDIF
  51. ;
  52. NAMES    EQU    256    ;MAX NUMBER OF NAMES IN DIRECTORY
  53. ;
  54. FCB    EQU    BASE+5CH ;SYSTEM FCB
  55. NPL    EQU    4    ;NUMBER OF NAMES PER LINE
  56. CR    EQU    0DH    ;CARRIAGE RETURN
  57. LF    EQU    0AH    ;LINE FEED
  58. DELIM    EQU    ':'    ;FENCE (DELIMITER) CHARACTER
  59. ;
  60.     ORG    BASE+100H
  61. ;
  62.     JMP    START    ;JUMP AROUND I.D.
  63.     DB    'MDIR.COM 8/17/80 '
  64. ;
  65. ;SAVE THE STACK
  66. START    LXI    H,0
  67.     DAD    SP    ;H=STACK
  68.     SHLD    STACK    ;SAVE IT
  69.     LXI    SP,STACK ;GET NEW STACK
  70.     LDA    FCB
  71.     ORA    A    ;ANY DRIVE SPECIFIED?
  72.     JZ    FSPEC2
  73.     DCR    A    ;CORRECT DISK NUMBER FOR CP/M
  74.     PUSH    PSW    ;SAVE REQUESTED DISK NUMBER
  75.     MVI    C,CURDSK ;FIND OUT WHERE WE'RE LOGGED
  76.     CALL    BDOS
  77.     STA    CDSK    ;SAVE IT FOR LATER
  78.     POP    PSW    ;GET REQUESTED DISK NR.
  79.     MOV    E,A    ;TO E FOR CP/M
  80.     MVI    C,SELDSK ;SELECT DISK REQUESTED
  81.     CALL    BDOS
  82. ;
  83. FSPEC2    MVI    C,CURDSK ;FIND OUT WHERE WE'RE LOGGED
  84.     CALL    BDOS
  85.     ADI    'A'    ;MAKE PRINTABLE
  86.     STA    DRNAME
  87. ;PRINT HEADER
  88.     CALL    FSPEC3
  89.     DB    CR,LF
  90.     DB    '.. MASTER DIRECTORY - DRIVE '
  91. DRNAME    DB    'X:'
  92.     DB    CR,LF,CR,LF,'$'
  93. ;
  94. FSPEC3    POP    D
  95.     MVI    C,PRINT
  96.     CALL    BDOS
  97.     LXI    H,FCB+1
  98.     MOV    A,M    ;GET 1ST CHAR. OF NAME REQUEST
  99.     STA    SAVFCB    ;SAVE FOR LATER
  100. ;
  101. ;MAKE DR FIELD OF FCB '?' TO FORCE RETURN OF ALL USER ENTRIES
  102.     DCX    H    ;POINT TO DR FIELD
  103.     MVI    M,'?'    ;STORE '?' IN FCB
  104. ;
  105. ;RETURN ALL DIRECTORY ENTRIES
  106.     MVI    C,FSRCHF ;GET 'SEARCH FIRST' FNC
  107.     LXI    D,FCB
  108.     CALL    BDOS    ;READ FIRST
  109.     INR    A    ;COMPENSATE FOR LATER DCR
  110.     JMP    SOME    ;GOT SOME (BECAUSE OF ? IN DR FIELD)
  111. ;
  112. ;READ MORE DIRECTORY ENTRIES
  113. MOREDIR    MVI    C,FSRCHN ;SEARCH NEXT
  114.     LXI    D,FCB
  115.     CALL    BDOS    ;READ DIR ENTRY
  116.     INR    A    ;CHECK FOR END (0FFH)
  117.     JZ    SPRINT    ;NO MORE - SORT & PRINT
  118. ;POINT TO DIRECTORY ENTRY 
  119. SOME    DCR    A    ;UNDO PREV 'INR A'
  120.     ANI    3    ;MAKE MODULUS 4
  121.     ADD    A    ;MULTIPLY...
  122.     ADD    A    ;..BY 32 BECAUSE
  123.     ADD    A    ;..EACH DIRECTORY
  124.     ADD    A    ;..ENTRY IS 32
  125.     ADD    A    ;..BYTES LONG
  126.     LXI    H,BASE+80H ;POINT TO BUFFER
  127.     ADD    L    ;POINT TO ENTRY
  128.     MOV    L,A    ;SAVE (CAN'T CARRY TO H)
  129. ;MOVE ENTRY TO TABLE
  130.     MOV    A,M    ;GET DR FIELD
  131.     CPI    0E5H    ;IS IT AN ERASED FILE ?
  132.     JZ    MOREDIR    ;YES, IGNORE AND GET ANOTHER
  133.     MOV    D,H    ;ENTRY TO DE
  134.     MOV    E,L
  135.     MVI    A,12    ;GET OFFSET TO EXTENT BYTE
  136.     ADD    L    ;ADD TO GET CORRECT POINTER
  137.     MOV    L,A
  138.     MOV    A,M    ;GET EXTENT BYTE
  139.     ORA    A    ;IS EXTENT OTHER THAN ZERO ?
  140.     JNZ    MOREDIR    ;IGNORE ALL EXTENTS BEYOND THE FIRST
  141.     LHLD    NEXTT    ;NEXT TABLE ENTRY TO HL
  142.     MVI    B,12    ;ENTRY LENGTH
  143. ;
  144. TMOVE    LDAX    D    ;GET ENTRY CHAR
  145.     ANI    7FH    ;REMOVE ATTRIBUTES
  146.     MOV    M,A    ;STORE IN TABLE
  147.     INX    D
  148.     INX    H
  149.     DCR    B    ;MORE?
  150.     JNZ    TMOVE
  151.     SHLD    NEXTT    ;SAVE UPDATED TABLE ADDR
  152.     LHLD    COUNT    ;GET PREV COUNT
  153.     INX    H    ;ADD ONE
  154.     SHLD    COUNT    ;RESAVE COUNT
  155.     JMP    MOREDIR
  156. ;
  157. ;SORT AND PRINT
  158. SPRINT    LHLD    COUNT    ;GET COUNT
  159.     MOV    A,H
  160.     ORA    L    ;CHECK FOR ZERO COUNT
  161.     JZ    NFEXIT    ;NOTHING IN DIRECTORY, EXIT
  162.     SHLD    OCOUNT    ;SAVE FOR ORDER TABLE COUNT
  163.     SHLD    SCOUNT    ;SAVE FOR SORT COUNT
  164.     LXI    H,ORDER
  165.     LXI    D,TABLE
  166.     LXI    B,12    ;ENTRY LENGTH
  167. ;
  168. BLDORD    MOV    M,E    ;SAVE LO ORD ADDR
  169.     INX    H
  170.     MOV    M,D    ;SAVE HI ORD ADDR
  171.     INX    H
  172.     XCHG        ;TABLE ADDR TO HL
  173.     DAD    B    ;POINT TO NEXT ENTRY
  174.     XCHG        ;NEXT ENTRY TO DE
  175.     PUSH    H
  176.     LHLD    OCOUNT    ;GET COUNT
  177.     DCX    H    ;ONE LESS
  178.     SHLD    OCOUNT    ;SAVE NEW COUNT
  179.     MOV    A,L
  180.     ORA    H    ;MORE?
  181.     POP    H
  182.     JNZ    BLDORD    ;..YES
  183.     LHLD    COUNT    ;GET COUNT
  184.     DCX    H
  185.     MOV    A,L
  186.     ORA    H    ;ONLY 1 ENTRY?
  187.     JZ    DONE    ;..YES, SO SKIP SORT
  188. ;
  189. SORT    XRA    A    ;GET A ZERO
  190.     STA    SWITCH    ;SHOW NONE SWITCHED
  191.     LHLD    SCOUNT    ;GET COUNT
  192.     DCX    H    ;USE 1 LESS
  193.     SHLD    TEMP    ;SAVE # TO COMPARE
  194.     SHLD    SCOUNT    ;SAVE HIGHEST ENTRY
  195.     MOV    A,L
  196.     ORA    H
  197.     JZ    DONE    ;EXIT IF NO MORE
  198.     LXI    H,ORDER ;POINT TO ORDER TABLE
  199. ;
  200. SORTLP    CALL    COMPR    ;COMPARE 2 ENTRIES
  201.     CM    SWAP    ;SWAP IF NOT IN ORDER
  202.     INX    H    ;BUMP ORDER
  203.     INX    H    ;..TABLE POINTER
  204.     PUSH    H
  205.     LHLD    TEMP    ;GET COUNT
  206.     DCX    H    ;ONE LESS
  207.     SHLD    TEMP    ;SAVE COUNT
  208.     MOV    A,L
  209.     ORA    H    ;DONE?
  210.     POP    H
  211.     JNZ    SORTLP    ;CONTINUE
  212. ;ONE PASS OF SORT DONE
  213.     LDA    SWITCH    ;ANY SWAPS DONE?
  214.     ORA    A
  215.     JNZ    SORT
  216. ;
  217. ;SORT IS ALL DONE - PRINT ENTRIES
  218. DONE    LXI    H,ORDER
  219.     SHLD    NEXTT
  220. ;
  221. ;PRINT AN ENTRY
  222.     MVI    C,NPL    ;NR. OF NAMES PER LINE
  223. ;
  224. ENTRY:    PUSH    B
  225.     MVI    C,CONST    ;CK STATUS OF KBD
  226.     CALL    BDOS    ;ANY KEY PRESSED?
  227.     POP    B
  228.     ORA    A
  229.     JNZ    ABORT    ;YES, ABORT
  230.     LHLD    NEXTT    ;GET ORDER TABLE POINTER
  231.     MOV    E,M    ;GET LO ADDR
  232.     INX    H
  233.     MOV    D,M    ;GET HI ADDR
  234.     INX    H
  235.     SHLD    NEXTT    ;SAVE UPDATED TABLE POINTER
  236.     XCHG        ;TABLE ENTRY TO HL
  237.     LDA    SAVFCB    ;GET SAVED 1ST CHAR. OF FCB
  238.     CPI    ' '    ;WAS NAME SPECIFIED?
  239.     JNZ    MATCH    ;YES, GO SEE IF PRESENT
  240. ;PRINT USER #
  241. PTONE    MOV    A,M    ;GET USER NUMBER
  242.     CPI    32    ;IS IT VALID ? (IE.< 32)
  243.     JNC    NULL    ; NO, IGNORE IT
  244.     ORA    A    ;IS IT USER 0 ?
  245.     JNZ    PTONE2    ;NO, SKIP NEXT ROUTINE
  246.     CALL    SPACE2    ;USER 0, FILL WITH SPACES
  247.     JMP    PTONE3    ;SKIP DECOUT PRINT
  248. ;
  249. PTONE2    PUSH    H
  250.     MVI    H,0
  251.     MOV    L,A    ;NUMBER TO L FOR DECOUT
  252.     CPI    10    ;LESS THAN 10?
  253.     CC    SPACE    ;YES, ADD ONE SPACE
  254.     CALL    DECOUT    ;PRINT USER NUMBER
  255.     POP    H
  256. ;
  257. PTONE3    CALL    SPACE    ;MAKE IT LOOK NICE
  258.     INX    H    ;POINT TO NAME
  259.     MVI    B,8    ;FILE NAME LENGTH
  260.     CALL    TYPEIT    ;TYPE FILENAME
  261.     CALL    PERIOD    ;PERIOD AFTER FN
  262.     MVI    B,3    ;GET THE FILETYPE
  263.     CALL    TYPEIT
  264.     DCR    C    ;ONE LESS ON THIS LINE
  265.     PUSH    PSW
  266.     CNZ    FENCE    ;NO CR-LF NEEDED, DO FENCE
  267.     POP    PSW
  268.     CZ    CRLF    ;CR-LF NEEDED
  269. ;SEE IF MORE ENTRIES
  270. NULL    PUSH    H
  271.     LHLD    COUNT
  272.     DCX    H
  273.     SHLD    COUNT
  274.     MOV    A,L
  275.     ORA    H
  276.     POP    H
  277.     JNZ    ENTRY    ;YES, MORE
  278.     JMP    EXIT
  279. ;
  280. MATCH    PUSH    D    ;SAVE DE
  281.     PUSH    H    ;SAVE HL
  282.     LXI    D,FCB    ;GET FCB REQUEST
  283.     INX    H    ;MOVE TO FN.FT
  284.     INX    D    ;
  285.     MVI    B,11    ;GET NUMBER OF CHARACTERS TO COMPARE
  286. ;
  287. MAT1    LDAX    D    ;GET CHARACTER
  288.     CPI    '*'    ;IS FILENAME OR FILETYPE AMBIGUOUS ?
  289.     JZ    WHCH    ; YES, DETERMINE WHICH ONE
  290.     CPI    '?'    ;IS IT A AMBIGUOUS CHARACTER ?
  291.     JZ    AMBC    ; YES
  292.     CMP    M    ;COMPARE TO MEMORY
  293.     JNZ    NOMATCH    ;MATCH FAILURE
  294. ;
  295. AMBC    INX    D
  296.     INX    H    ;GET NEW CHARACTERS
  297.     DCR    B    ;ARE WE DONE ?
  298.     JNZ    MAT1    ;NO, COMPARE NEXT
  299. ;
  300. FTYP    POP    H
  301.     POP    D    ;RESTORE REGISTERS
  302.     JMP    PTONE    ;GO PRINT ONE
  303. ;
  304. WHCH    MOV    A,B    ;GET B
  305.     CPI    3    ;IS IT STILL THE FILENAME ?
  306.     JC    FTYP    ; NO, IT IS ANY TYPE SO WE ARE DONE.
  307.     MVI    B,3    ;YES, LOAD UP TO FILETYPE
  308.     JMP    MAT1    ;RETURN FOR MORE
  309. ;
  310. NOMATCH    POP    H
  311.     POP    D    ;RESTORE REGISTERS
  312.     JMP    NULL    ;GET NEW FILENAME TO TRY
  313. ;
  314. PERIOD    MVI    A,'.'
  315.     JMP    TYPE
  316. ;
  317. FENCE    CALL    SPACE2
  318.     MVI    A,DELIM    ;FENCE CHARACTER
  319.     JMP    TYPE
  320. ;
  321. SPACE3    CALL    SPACE
  322. ;
  323. SPACE2    CALL    SPACE
  324. ;
  325. SPACE    MVI    A,' '
  326. ;
  327. ;TYPE CHAR IN A
  328. TYPE    PUSH    B
  329.     PUSH    D
  330.     PUSH    H
  331.     MOV    E,A
  332.     MVI    C,WRCHR
  333.     CALL    BDOS
  334.     POP    H
  335.     POP     D
  336.     POP    B
  337.     RET
  338. ;
  339. TYPEIT    MOV    A,M
  340.     CALL    TYPE
  341.     INX    H
  342.     DCR    B
  343.     JNZ    TYPEIT
  344.     RET
  345. ;
  346. CRLF    MVI    A,CR    ;CARRIAGE RETURN
  347.     CALL    TYPE
  348.     MVI    A,LF    ;LINE FEED
  349.     CALL    TYPE
  350.     MVI    C,NPL    ;NUMBER OF NAMES PER LINE
  351.     RET
  352. ;
  353. ;DECIMAL OUTPUT ROUTINE
  354. ;
  355. DECOUT:    PUSH    B
  356.     PUSH    D
  357.     PUSH    H
  358.     LXI    B,-10
  359.     LXI    D,-1
  360. ;
  361. DECOU2:    DAD    B
  362.     INX    D
  363.     JC    DECOU2
  364.     LXI    B,10
  365.     DAD    B
  366.     XCHG
  367.     MOV    A,H
  368.     ORA    L
  369.     CNZ    DECOUT
  370.     MOV    A,E
  371.     ADI    '0'
  372.     CALL    TYPE
  373.     POP    H
  374.     POP    D
  375.     POP    B
  376.     RET
  377. ;
  378. ;COMPARE ROUTINE FOR SORT
  379. COMPR    PUSH    H    ;SAVE TABLE ADDR
  380.     MOV    E,M    ;LOAD LO
  381.     INX    H
  382.     MOV    D,M    ;LOAD HI
  383.     INX    H
  384.     MOV    C,M
  385.     INX    H
  386.     MOV    B,M
  387. ;BC, DE NOW POINT TO ENTRIES TO BE COMPARED
  388.     XCHG
  389. CMPLP    LDAX    B
  390.     CMP    M
  391.     INX    H
  392.     INX    B
  393.     JZ    CMPLP
  394.     POP    H
  395.     RET        ;COND CODE TELLS ALL
  396. ;
  397. ;SWAP ENTRIES IN THE ORDER TABLE
  398. SWAP    MVI    A,1
  399.     STA    SWITCH    ;SHOW A SWAP WAS MADE
  400.     MOV    C,M
  401.     INX    H
  402.     PUSH    H    ;SAVE TABLE ADDR+1
  403.     MOV    B,M
  404.     INX    H
  405.     MOV    E,M
  406.     MOV    M,C
  407.     INX    H
  408.     MOV    D,M
  409.     MOV    M,B
  410.     POP    H
  411.     MOV    M,D
  412.     DCX    H    ;BACK POINTER TO CORRECT LOC'N
  413.     MOV    M,E
  414.     RET
  415. ;
  416. NFEXIT    CALL    ERXIT
  417.     DB    '++NO FILES ON THIS DISK',CR,LF,'$'
  418. ;
  419. ;ERROR EXIT
  420. ERXIT    POP    D    ;GET MSG
  421.     MVI    C,PRINT
  422.     JMP    CALLB    ;PRINT MSG, EXIT
  423. ;
  424. ;ABORT - READ CHAR ENTERED
  425. ABORT    MVI    C,RDCHR    ;DELETE THE CHAR
  426. CALLB    CALL    BDOS
  427. ;
  428. ;FALL INTO EXIT
  429. ;EXIT - ALL DONE, RESTORE DISK LOG IN AND STACK
  430. EXIT    LDA    CDSK    ;GET ORIGINAL DISK NR.
  431.     MOV    E,A    ;TO E FOR CP/M
  432.     MVI    C,SELDSK ;RESTORE LOG-IN TO IT
  433.     CALL    BDOS
  434.     LHLD    STACK    ;GET OLD STACK
  435.     SPHL        ;MOVE TO STACK
  436.     RET        ;..AND RETURN
  437. ;
  438. NEXTT    DW    TABLE    ;NEXT TABLE ENTRY
  439. COUNT    DW    0    ;ENTRY COUNT
  440. SWITCH    DB    0    ;SWAP SWITCH FOR SORT
  441. SAVFCB    DS    1    ;SAVED 1ST CHAR. OF FCB
  442. CDSK    DS    1    ;CURRENTLY LOGGED DISK NUMBER
  443. OCOUNT    DS    2    ;# NAMES TO PUT IN ORDER TABLE
  444. SCOUNT    DS    2    ;# TO SORT
  445. TEMP    DS    2    ;SAVE DIR ENTRY
  446. ORDER    DS    NAMES*2    ;ORDER TABLE (TWO BYTES PER NAME)
  447.     DS    60    ;STACK AREA
  448. STACK    DS    2    ;SAVE OLD STACK HERE
  449. TABLE    EQU    $    ;READ ENTRIES IN HERE
  450. ;
  451. ; BDOS EQUATES
  452. ;
  453. RDCHR    EQU    1    ;READ CHAR FROM CONSOLE
  454. WRCHR    EQU    2    ;WRITE CHR TO CONSOLE
  455. PRINT    EQU    9    ;PRINT CONSOLE BUFF
  456. CONST    EQU    11    ;CHECK CONS STAT
  457. SELDSK    EQU    14    ;SELECT DISK DRIVE
  458. FSRCHF    EQU    17    ;   "    "
  459. FSRCHN    EQU    18    ;   "    "
  460. CURDSK    EQU    25    ;CHECK CURRENT DISK 0=A: 1=B:, ETC.
  461. BDOS    EQU    BASE+5
  462. ;
  463.     END
  464.