home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol016 / aplmodem.asm < prev    next >
Assembly Source File  |  1984-04-29  |  36KB  |  1,613 lines
  1. ;
  2. ;    APMODEM.ASM V1.1
  3. ;    BY WARD CHRISTENSEN
  4. ;    Modified for the Apple ][
  5. ;    BY GORDON BANKS
  6. ;    1/1/81
  7. ;
  8. ;CP/M - CP/M FILE TRANSFER PROGRAM, AND
  9. ;TERMINAL PROGRAM.
  10. ;
  11. ;NOTE: THIS FILE WILL ASSEMBLE, WITHOUT NEED FOR
  12. ;EDITING, TO WORK WITH A D.C. HAYES MICROMODEM II.  
  13. ;IF YOU HAVE ANOTHER MODEM, YOU MUST CHANGE THE  
  14. ;EQUATES TO FALSE FOR MMII AND TRUE FOR YOUR MODEM.
  15. ;
  16. * * * * * * * * * * * * * * * * * * * * * * * * *
  17. *                        *
  18. *    THIS PROGRAM DOCUMENTED IN "MODEM.DOC"    *
  19. *                        *
  20. * * * * * * * * * * * * * * * * * * * * * * * * *
  21. ;
  22. ;PLEASE PASS ON MODS, BUGS, ETC, SO YOUR
  23. ;FIXES OR ENHANCEMENTS MAY BE SHARED BY ALL,
  24. ;         TO:
  25. ;    Gordon Banks
  26. ;    5715 S. Drexel #209
  27. ;    Chicago, IL 60637
  28. ;    (312) 324-6194
  29. ;
  30. ;    ----------
  31. ;
  32. ;    12/18/80
  33. ;ADAPTED FOR THE APPLE ][ COMPUTER RUNNING CP/M WITH
  34. ;THE Z-80 SOFTCARD BY CHANGING THE EQUATES FOR THE 
  35. ;VARIOUS APPLE MODEM CONFIGURATIONS AND CHANGING THE
  36. ;IN AND OUT STATEMENTS TO LDA AND STA. (GORDON BANKS)
  37. ;IT SUPPORTS THE FOLLOWING APPLE MODEM CONFIGURATIONS:
  38. ;    1)DC HAYS MICROMODEM II
  39. ;    2)EXTERNAL MODEM THROUGH ONE OF THE FOLLOWING:
  40. ;        a) CCS 7710 SERIAL INTERFACE
  41. ;        b) SSM SERIAL INTERFACE
  42. ;        c) APPLE COMMUNICATIONS INTERFACE
  43. ;        d) APPLE SERIAL INTERFACE
  44. ;
  45. ;DEFINE FALSE AND TRUE
  46. ;
  47. FALSE    EQU    0
  48. TRUE    EQU    NOT FALSE
  49. ;
  50. STDCPM    EQU    TRUE    ;TRUE, IS STANDARD CP/M
  51. ;
  52. BASE    EQU    0    ;CP/M BASE ADDRESS
  53. ;
  54. ;NOTE: IF DC HAYES THEN BAUD RATE DEFAULTS TO
  55. ;300 - 1 STOP BIT.  DO NOT CHANGE NEXT EQUATES
  56. ;
  57. ORIGMOD EQU    8EH    ;OFF HOOK, 110 BAUD, CAR. ON, ORIG.
  58. ANSWMOD    EQU    8AH    ;OFF HOOK, 110 BAUD, CAR. ON, ANSW.
  59. ;
  60. ;IF YOU ARE USING AN EXTERNAL MODEM 
  61. ;CHANGE THESE EQUATES FOR YOUR MODEM PORT REQUIREMENTS
  62. ;
  63. INITREQ    EQU    FALSE     ;TRUE, IF MODEM PORT INIT. REQ'D
  64. ;
  65. ;APPLE MODEM TYPES EQUATES
  66. MMII    EQU    TRUE    ;TRUE, IF USING D.C. HAYES MICROMODEM ][
  67. CCS    EQU    FALSE    ;TRUE, USING CCS 7710 SERIAL INTERFACE
  68. COMCARD    EQU    FALSE    ;TRUE, USING APPLE COMMUNICATIONS CARD
  69. SSM    EQU    FALSE    ;TRUE, USING SSM SERIAL INTERFACE
  70. ;
  71. ;the Apple serial card apparently has the same protocol for DATA 
  72. ;and STATUS as the communication card.
  73. ;N.B.-->I have not tested this program for the SSM or
  74. ;Apple serial interface, but according to documentation I have
  75. ;been able to obtain, they should work using these equates.
  76. ;
  77. INITC1    EQU    03    ;1ST INIT CHAR TO CTL PORT
  78. INITC2    EQU    17     ;2ND INIT CHAR TO CTL PORT
  79. ;
  80.     IF    CCS    ;CCS CARD
  81. MODCTLP    EQU    0E0A0H    ;STATUS PORT OF CCS ACIA         
  82. MODDATP    EQU    0E0A1H    ;DATA PORT OF CCS ACIA (MOT 6850)
  83.      ENDIF        ;CCS
  84. ;
  85.     IF    COMCARD    ;APPLE COMMUNCATIONS CARD
  86. MODCTLP    EQU    0E0AEH    ;STATUS
  87. MODDATP    EQU    0E0AFH    ;DATA
  88.     ENDIF        ;COMCARD
  89. ;
  90.     IF    MMII    ;DC HAYES MICROMODEM ][
  91. MODCTLP    EQU    0E0A6H    ;STATUS PORT
  92. MODCTL2    EQU    0E0A5H    ;2ND STATUS PORT
  93. MODDATP    EQU    0E0A7H    ;DATA PORT
  94.     ENDIF        ;MMII
  95. ;
  96.     IF    SSM    ;SSM INTERFACE
  97. MODCTLP    EQU    0E0A4H    ;STATUS
  98. MODDATP    EQU    0E0A5H    ;DATA
  99.     ENDIF        ;SSM
  100. ;
  101. MODSNDB    EQU    2    ;BIT TO TEST FOR SEND
  102. MODSNDR    EQU    2    ;VALUE WHEN READY
  103. MODRCVB    EQU    1    ;BIT TO TEST FOR RECEIVE
  104. MODRCVR    EQU    1    ;VALUE WHEN READY
  105. ;
  106. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS
  107. EXITCHR    EQU    'E'-40H ;CTL-E EXIT FROM T OR C
  108. DISCCHR    EQU    'D'-40H    ;CTL-D DISCONNECTS MODEM T/E
  109. ;
  110. FASTCLK    EQU    FALSE    ;TRUE FOR 4 MHZ CLOCK
  111. ;
  112. ;SOME TIME-SHARE COMPUTERS REQUIRE TERMINALS TO
  113. ;HAVE BIT 7 HIGH (MARKING), SO IN THE TERMINAL
  114. ;MODE WE FORCE IT TO HIGH IF THE FOLLOWING OPTION
  115. ;IS SELECTED:
  116. ;
  117. TIMESHR    EQU    FALSE    ;TRUE TO MAKE BIT 7 HIGH
  118. ; 
  119. ;DEFINE ASCII CHARACTERS USED
  120. ;
  121. SOH    EQU    1    ;START OF HEADER
  122. EOT    EQU    4    ;END OF TRANSMISSION
  123. ACK    EQU    6    ;ACKNOWLEDGE
  124. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  125. CAN    EQU    18H    ;CANCEL
  126. LF    EQU    10    ;LINEFEED
  127. CR    EQU    13    ;CARRIAGE RETURN
  128. ; 
  129.     ORG    BASE+100H
  130. ;
  131. ;INIT PRIVATE STACK
  132.     LXI    H,0    ;HL=0
  133.     DAD    SP    ;HL=STACK FROM CP/M
  134.     SHLD    STACK    ;..SAVE IT
  135.     LXI    SP,STACK ;SP=MY STACK
  136.     CALL    START    ;GO PRINT ID
  137.     DB    'APPLE ][ MODEM V1.1 as of '
  138.     DB    '1/1/81',CR,LF,'$'
  139. ; 
  140. START    POP    D    ;GET ID MESSAGE
  141.     MVI    C,PRINT
  142.     CALL    BDOS    ;PRINT ID MESSAGE
  143. ;
  144. ;INITIALIZE THE JMPS TO CP/M BIOS
  145. ;
  146.     CALL    INITADR
  147. ;
  148.     LDA    FCB+1    ;GET PRIMARY OPTION
  149.     CPI    'H'    ;MODEM H(ELP)?
  150.     JZ    HELP    ;..YES, GIVE HELP
  151.     CPI    'X'    ;MODEM X(AMPLES)?
  152.     JZ    EXAM    ;GIVE EXAMPLES
  153. ;
  154. ;SAVE PRIMARY OPTION, VALIDATE SECONDARY OPT.
  155. ;
  156.     CALL    PROCOPT
  157. ;
  158. ;INIT THE MODEM OR SERIAL PORT
  159. ;
  160.     CALL    INITMOD
  161. ;
  162. ;MOVE THE FILENAME FROM FCB 2 TO FCB 1
  163. ;
  164.     CALL    MOVEFCB
  165. ;
  166. ;GOBBLE UP GARBAGE CHARS FROM THE LINE
  167. ;PRIOR TO RECEIVE OR SEND
  168. ;
  169.     LDA    MODDATP
  170.     LDA    MODDATP
  171. ;
  172. ;JMP TO APPROPRIATE FUNCTION
  173. ;
  174.     LDA    OPTION    ;GET PRIMARY OPTION
  175. ;
  176.     CPI    'C'    ;(COMPAT W/EARLIER
  177.     JZ    TRMECHO    ;OPTION "COMPUTER")
  178. ;
  179.     CPI    'E'    ;TERMINAL IN ECHO
  180.     JZ    TRMECHO    ;..MODE?
  181. ;
  182.     CPI    'T'    ;TERMINAL..
  183.     JZ    TERM    ;..MODE?
  184. ;
  185.     CPI    'D'
  186.     JZ    DISCONN
  187. ;
  188.            CPI    'S'    ;SEND..
  189.     JZ    SENDFIL    ;..A FILE?
  190. ;
  191.     CPI    'R'    ;RECEIVE..
  192.     JZ    RCVFIL    ;..A FILE?
  193. ;
  194. ;INVALID OPTION
  195. ;
  196.     JMP    BADOPT
  197. ;
  198. * * * * * * * * * * * * * * * * * * * * *
  199. *                    *
  200. *    TERM: TERMINAL MODE        *
  201. *                    *
  202. * * * * * * * * * * * * * * * * * * * * *
  203. ;
  204. ;THIS PROGRAM SIMPLY SENDS KEYED CHARACTERS
  205. ;DOWN THE LINE, AND DISPLAYS CHARACTERS
  206. ;RECEIVED FROM THE LINE.  THIS MAKES IT
  207. ;SUITABLE FOR COMMUNICATION WITH TIME SHARING
  208. ;COMPUTERS, CBBS'S, OR ANOTHER PROGRAM
  209. ;RUNING "MODEM E" (ECHO MODE)
  210. ;
  211. ;TYPE THE "EXITCHR" (ORIGINALLY CTL-E) TO EXIT.
  212. ;OR THE "DISCCHR" (ORIGINALLY CTL-D) TO DISCONN.
  213. ;
  214. ;A FUTURE ENHANCEMENT WILL BE TO WRITE THE
  215. ;RECEIVED DATA IN MEMORY, AND ALLOW IT TO
  216. ;BE WRITTEN TO DISK
  217. ;
  218. TERM    CALL    STAT    ;LOCAL CHAR KEYED?
  219.     JZ    TERML    ;..NO, CHECK LINE
  220.     CALL    KEYIN    ;GET CHAR
  221.     CPI    EXITCHR    ;TIME TO END?
  222.     JZ    CKDIS    ;YES, CK DISCONN
  223.     CPI    DISCCHR    ;DISCONNECT REQUEST?
  224.     JZ    DISCONN    ;YES, DO IT
  225.     IF    TIMESHR
  226.     ORI    80H    ;FORCE BIT 7 TO HIGH
  227.     ENDIF        ;TIMESHR
  228.     STA    MODDATP    ;SEND THE CHAR
  229. ;
  230. ;SEE IF CHAR FROM LINE
  231. ;
  232. TERML    LDA    MODCTLP    ;READ STATUS
  233.     ANI    MODRCVB    ;ISOLATE BIT
  234.     CPI    MODRCVR    ;READY?
  235.     JNZ    TERM    ;..NO, LOOP
  236.     LDA    MODDATP    ;READ DATA
  237.     ANI    7FH    ;STRIP PARITY BIT
  238.     CALL    TYPE    ;TYPE IT
  239.     JMP    TERM    ;LOOP
  240. ;
  241. * * * * * * * * * * * * * * * * * * * * *
  242. *                    *
  243. *    TRMECHO: TERMINAL WITH ECHO    *
  244. *                    *
  245. * * * * * * * * * * * * * * * * * * * * *
  246. ;
  247. ;TERMINAL PROGRAM WITH ECHO - SEE NOTES
  248. ;UNDER "TERM" ABOVE
  249. ;
  250. ;C A U T I O N   DON'T RUN WITH BOTH COMPUTERS
  251. ;IN "ECHO" MODE - LINE ERRORS (OR ANY CHAR)
  252. ;WILL BE ECHOED BACK AND FORTH AD INFINITUM.
  253. ;
  254. TRMECHO    LDA    MODCTLP    ;GET STATUS
  255.     ANI    MODRCVB    ;ISOLATE READY BIT
  256.     CPI    MODRCVR    ;ARE WE READY?
  257.     JZ    LINECHR    ;YES, READ THE CHR
  258.     CALL    STAT    ;CHECK LOCAL KB
  259.     JZ    TRMECHO    ;..NO CHAR
  260.     CALL    KEYIN    ;GET LOCAL CHAR
  261.     CPI    EXITCHR    ;END?
  262.     JZ    CKDIS    ;YES, CK DISCONN, EXIT
  263.     CPI    DISCCHR    ;DISCONN?
  264.     JZ    DISCONN    ;..YES, DO IT.
  265.     STA    MODDATP    ;SEND CHAR
  266.     CALL    TYPE    ;ECHO IT LOCALLY
  267.     JMP    TRMECHO    ;..AND LOOP
  268. ;
  269. ;GOT CHAR FROM LINE
  270. ;
  271. LINECHR    LDA    MODDATP    ;GET CHAR
  272.     STA    MODDATP    ;ECHO IT
  273.     ANI    7FH    ;STRIP PARITY BIT
  274.     CALL    TYPE    ;TYPE IT
  275.     JMP    TRMECHO    ;LOOP
  276. ;
  277. * * * * * * * * * * * * * * * * * * * * *
  278. *                    *
  279. *    SENDFIL: SENDS A CP/M FILE    *
  280. *                    *
  281. * * * * * * * * * * * * * * * * * * * * *
  282. ;
  283. ;THE CP/M FILE SPECIFIED IN THE MODEM COMMAND
  284. ;IS TRANSFERRED OVER THE PHONE TO ANOTHER
  285. ;COMPUTER RUNNING MODEM WITH THE "R" (RECEIVE)
  286. ;OPTION.  THE DATA IS SENT ONE SECTOR AT A
  287. ;TIME WITH HEADERS AND CHECKSUMS, AND RE-
  288. ;TRANSMISSION ON ERRORS.  
  289. ;
  290. SENDFIL    CALL    OPENFIL    ;OPEN THE FILE
  291.     MVI    E,80    ;WAIT 80 SEC..
  292.     CALL    WAITNAK    ;..FOR INITIAL NAK
  293. ;
  294. SENDLP    CALL    RDSECT    ;READ A SECTOR
  295.     JC    SENDEOF    ;SEND EOF IF DONE
  296.     CALL    INCRSNO    ;BUMP SECTOR #
  297.     XRA    A    ;ZERO ERROR..
  298.     STA    ERRCT    ;..COUNT
  299. ;
  300. SENDRPT    CALL    SENDHDR    ;SEND A HEADER
  301.     CALL    SENDSEC    ;SEND DATA SECTOR
  302.     CALL    SENDCKS    ;SEND CKSUM
  303.     CALL    GETACK    ;GET THE ACK
  304.     JC    SENDRPT    ;REPEAT IF NO ACK
  305.     JMP    SENDLP    ;LOOP UNTIL EOF
  306. ;
  307. ;FILE SENT, SEND EOT'S
  308. ;
  309. SENDEOF    MVI    A,EOT    ;SEND..
  310.     CALL    SEND    ;..AN EOT
  311.     CALL    GETACK    ;GET THE ACK
  312.     JC    SENDEOF    ;LOOP IF NO ACK
  313.     JMP    DONE    ;ALL DONE
  314. ;
  315. * * * * * * * * * * * * * * * * * * * * *
  316. *                    *
  317. *    RCVFIL: RECEIVE A FILE        *
  318. *                    *
  319. * * * * * * * * * * * * * * * * * * * * *
  320. ;
  321. ;RECEIVES A FILE IN BLOCK FORMAT AS SENT
  322. ;BY ANOTHER PERSON DOING "MODEM S FN.FT".
  323. ;
  324. RCVFIL    CALL    ERASFIL    ;ERASE THE FILE
  325.     CALL    MAKEFIL    ;..THEN MAKE NEW
  326.     CALL    ILPRT    ;PRINT:
  327.     DB    'FILE OPEN, READY TO RECEIVE',CR,LF,0
  328. ;
  329. RCVLP    CALL    RCVSECT    ;GET A SECTOR
  330.     JC    RCVEOT    ;GOT EOT
  331.     CALL    WRSECT    ;WRITE THE SECTOR
  332.     CALL    INCRSNO    ;BUMP SECTOR #
  333.     CALL    SENDACK    ;ACK THE SECTOR
  334.     JMP    RCVLP    ;LOOP UNTIL EOF
  335. ;
  336. ;GOT EOT ON SECTOR - FLUSH BUFFERS, END
  337. ;
  338. RCVEOT    CALL    WRBLOCK    ;WRITE THE LAST BLOCK
  339.     CALL    SENDACK    ;ACK THE SECTOR
  340.     CALL    CLOSFIL    ;CLOSE THE FILE
  341.     JMP    DONE    ;ALL DONE
  342. ;
  343. * * * * * * * * * * * * * * * * * * * * *
  344. *                    *
  345. *        SUBROUTINES        *
  346. *                    *
  347. * * * * * * * * * * * * * * * * * * * * *
  348. ;
  349. ;
  350. ;---->    RCVSECT: RECEIVE A SECTOR
  351. ;
  352. ;RETURNS WITH CARRY SET IF EOT RECEIVED.
  353. ;
  354. RCVSECT    XRA    A    ;GET 0
  355.     STA    ERRCT    ;INIT ERROR COUNT
  356. ;
  357. RCVRPT    LDA    QFLG    ;QUIET?
  358.     ORA    A
  359.     JZ    RCVSQ    ;YES, NO STAT MSG.
  360.     CALL    ILPRT    ;PRINT:
  361.     DB    'AWAITING #',0
  362.     LDA    SECTNO    ;GET SECTOR #
  363.     INR    A    ;(REAL INR LATER)
  364.     CALL    HEXO    ;PRINT IN HEX
  365.     CALL    CRLF    ;..THEN CRLF
  366. ;
  367. RCVSQ    MVI    B,10    ;10 SEC TIMEOUT
  368.     CALL    RECV    ;GET SOH/EOT
  369.     JC    RCVSTOT    ;TIMEOUT
  370.     CPI    SOH    ;GET SOH?
  371.     JZ    RCVSOH    ;..YES
  372. ;
  373. ;EARLIER VERS. OF MODEM PROG SENT SOME NULLS -
  374. ;IGNORE THEM
  375. ;
  376.     ORA    A    ;00 FROM SPEED CHECK?
  377.     JZ    RCVSQ    ;YES, IGNORE IT
  378.     CPI    EOT    ;END OF TRANSFER?
  379.     STC        ;RETURN WITH CARRY..
  380.     RZ        ;..SET IF EOT
  381. ;
  382. ;DIDN'T GET SOH  OR EOT - 
  383. ;
  384.     MOV    B,A    ;SAVE CHAR
  385.     LDA    VSEEFLG    ;VIEWING..
  386.     ORA    A    ;..MODE?
  387.     JZ    RCVSEH    ;YES, PRT.MSG
  388.     LDA    QFLG    ;QUIET..
  389.     ORA    A    ;..MODE?
  390.     JZ    RCVSERR    ;YES, SKIP MSG
  391. RCVSEH    MOV    A,B    ;GET CHAR
  392.     CALL    HEXO    ;SHOW IN HEX
  393.     CALL    ILPRT    ;PRINT:
  394.     DB    'H RCD, NOT SOH',CR,LF,0
  395. ;
  396. ;DIDN'T GET VALID HEADER - PURGE THE LINE,
  397. ;THEN SEND NAK.
  398. ;
  399. RCVSERR    MVI    B,1    ;WAIT FOR 1 SEC..
  400.     CALL    RECV    ;..WITH NO CHARS
  401.     JNC    RCVSERR    ;LOOP UNTIL SENDER DONE
  402.     MVI    A,NAK    ;SEND..
  403.     CALL    SEND    ;..THE NAK
  404.     LDA    ERRCT    ;ABORT IF..
  405.     INR    A    ;..WE HAVE REACHED..
  406.     STA    ERRCT    ;..THE ERROR..
  407.     CPI    ERRLIM    ;..LIMIT?
  408.     JC    RCVRPT    ;..NO, TRY AGAIN
  409. ;
  410. ;10 ERRORS IN A ROW - 
  411. ;
  412.     LDA    VSEEFLG    ;VIEWING..
  413.     ORA    A    ;..FILE?
  414.     JZ    RCVCKQ    ;YES, ASK RETRY/QUIT
  415.     LDA    QFLG    ;QUIET..
  416.     ORA    A    ;..MODE?
  417.     JZ    RCVSABT    ;ABORT
  418. ;
  419. RCVCKQ    CALL    CKQUIT    ;RETRY/QUIT?
  420.     JZ    RCVSECT    ;TRY AGAIN
  421. ;
  422. RCVSABT    CALL    CLOSFIL    ;KEEP WHATEVER WE GOT
  423.     CALL    ERXIT
  424.     DB    '++UNABLE TO RECEIVE BLOCK'
  425.     DB    CR,LF,'++ABORTING++$'
  426. ;
  427. ;TIMEDOUT ON RECEIVE
  428. ;
  429. RCVSTOT    LDA    VSEEFLG    ;VIEWING..
  430.     ORA    A    ;..MODE?
  431.     JZ    RCVSPT    ;YES, PRT MSG
  432.     LDA    QFLG    ;QUIET..
  433.     ORA    A    ;..MODE?
  434.     JZ    RCVSERR    ;YES, NO MSG
  435. ;
  436. RCVSPT    CALL    ILPRT
  437.     DB    '++TIMEOUT++ ',0
  438. ;
  439. RCVPRN    LDA    ERRCT    ;PRINT ERROR..
  440.     CALL    HEXO    ;..COUNT
  441.     CALL    CRLF
  442.     JMP    RCVSERR    ;BUMP ERR CT, ETC.
  443. ;
  444. ;GOT SOH - GET BLOCK #, BLOCK # COMPLEMENTED
  445. ;
  446. RCVSOH    MVI    B,1    ;TIMEOUT = 1 SEC
  447.     CALL    RECV    ;GET SECTOR
  448.     JC    RCVSTOT    ;GOT TIMEOUT
  449.     MOV    D,A    ;D=BLK #
  450.     MVI    B,1    ;TIMEOUT = 1 SEC
  451.     CALL    RECV    ;GET CMA'D SECT #
  452.     JC    RCVSTOT    ;TIMEOUT
  453.     CMA        ;CALC COMPLEMENT
  454.     CMP    D    ;GOOD SECTOR #?
  455.     JZ    RCVDATA    ;YES, GET DATA
  456. ;
  457. ;GOT BAD SECTOR #
  458. ;
  459.     LDA    VSEEFLG    ;VIEWING..
  460.     ORA    A    ;..MODE?
  461.     JZ    RCVBSE    ;..YES, PRT MSG
  462.     LDA    QFLG    ;QUIET..
  463.     ORA    A    ;..MODE?
  464.     JZ    RCVSERR    ;..YES, NO MSG
  465. ;
  466. RCVBSE    CALL    ILPRT    ;PRINT:
  467.     DB    '++BAD SECTOR # IN HDR',CR,LF,0
  468.     JMP    RCVSERR    ;BUMP ERROR CT.
  469. ;
  470. RCVDATA    MOV    A,D    ;GET SECTOR #
  471.     STA    RCVSNO    ;SAVE IT
  472.     MVI    A,1    ;SHOW..
  473.     STA    DATAFLG    ;GETTING DATA
  474.     MVI    C,0    ;INIT CKSUM
  475.     LXI    H,BASE+80H    ;POINT TO BUFFER
  476. RCVCHR    MVI    B,1    ;1 SEC TIMEOUT
  477.     CALL    RECV    ;GET CHAR
  478.     JC    RCVSTOT    ;TIMEOUT
  479.     MOV    M,A    ;STORE CHAR
  480.     INR    L    ;DONE?
  481.     JNZ    RCVCHR    ;NO, LOOP
  482. ;
  483. ;VERIFY CHECKSUM
  484. ;
  485.     MOV    D,C    ;SAVE CHECKSUM
  486.     XRA    A    ;SHOW..
  487.     STA    DATAFLG    ;..END OF DATA
  488.     MVI    B,1    ;TIMEOUT LEN.
  489.     CALL    RECV    ;GET CHECKSUM
  490.     JC    RCVSTOT    ;TIMEOUT
  491.     CMP    D    ;CHECKSUM OK?
  492.     JNZ    RCVCERR    ;NO, ERROR
  493. ;
  494. ;GOT A SECTOR, IT'S A DUP IF = PREV,
  495. ;    OR OK IF = 1 + PREV SECTOR
  496. ;
  497.     LDA    RCVSNO    ;GET RECEIVED
  498.     MOV    B,A    ;SAVE IT
  499.     LDA    SECTNO    ;GET PREV
  500.     CMP    B    ;PREV REPEATED?
  501.     JZ    RECVACK    ;ACK TO CATCH UP
  502.     INR    A    ;CALC NEXT SECTOR #
  503.     CMP    B    ;MATCH?
  504.     JNZ    ABORT    ;NO MATCH - STOP SENDER, EXIT
  505.     RET        ;CARRY OFF - NO ERRORS
  506. ;
  507. ;GOT CKSUM
  508. ;
  509. RCVCERR    LDA    VSEEFLG    ;VIEWING..
  510.     ORA    A    ;..MODE?
  511.     JZ    RCVCPR    ;..YES, PRT MSG
  512.     LDA    QFLG    ;QUIET..
  513.     ORA    A    ;..MODE?
  514.     JZ    RCVSERR    ;YES, NO MSG
  515. ;
  516. RCVCPR    CALL    ILPRT
  517.     DB    '++CKSUM++ ',0
  518.     JMP    RCVPRN    ;PRINT ERROR #
  519. ;
  520. ;PREV SECT REPEATED, DUE TO THE LAST ACK
  521. ;BEING GARBAGED.  ACK IT SO SENDER WILL CATCH UP 
  522. ;
  523. RECVACK    CALL    SENDACK    ;SEND THE ACK,
  524.     JMP    RCVSECT    ;GET NEXT BLOCK
  525. ;
  526. ;SEND AN ACK FOR THE SECTOR
  527. ;
  528. SENDACK    MVI    A,ACK    ;GET ACK
  529.     CALL    SEND    ;..AND SEND IT
  530.     RET
  531. ;
  532. ;---->    SENDHDR: SEND THE SECTOR HEADER
  533. ;
  534. ;SEND: (SOH) (BLOCK #) (COMPLEMENTED BLOCK #)
  535. ;
  536. SENDHDR    LDA    QFLG    ;QUIET..
  537.     ORA    A    ;..MODE?
  538.     JZ    SENDHNM    ;YES, SKIP STATUS MSG.
  539.     CALL    ILPRT    ;PRINT:
  540.     DB    'SEND # ',0
  541.     LDA    SECTNO    ;PRINT..
  542.     CALL    HEXO    ;..SECT #
  543.     CALL    CRLF    ;..THEN CR/LF
  544. ;
  545. SENDHNM    MVI    A,SOH    ;SEND..
  546.     CALL    SEND    ;..SOH,
  547.     LDA    SECTNO    ;THEN SEND..
  548.     CALL    SEND    ;..SECTOR #
  549.     LDA    SECTNO    ;THEN SECTOR #
  550.     CMA        ;..COMPLEMENTED..
  551.     CALL    SEND    ;..SECTOR #
  552.     RET        ;FROM SENDHDR
  553. ;
  554. ;---->    SENDSEC: SEND THE DATA SECTOR
  555. ;
  556. ;WHILE SENDING THE SECTOR, THE "DATAFLG" IS SET
  557. ;SUCH THAT IF "V" (VIEW THE FILE) WAS REQUESTED,
  558. ;THE "SHOW" ROUTINE WILL PRINT THE DATA, BUT NOT
  559. ;THE HDR OR CKSUM, OR ANY NON-FATAL MSGS.
  560. ;
  561. SENDSEC    MVI    A,1    ;SHOW NOW AT DATA..
  562.     STA    DATAFLG    ;..FOR VIEW COMMAND
  563.     MVI    C,0    ;INIT CKSUM
  564.     LXI    H,BASE+80H    ;POINT TO BUFFER
  565. SENDC    MOV    A,M    ;GET A CHAR
  566.     CALL    SEND    ;SEND IT
  567.     INR    L    ;POINT TO NEXT CHAR
  568.     JNZ    SENDC    ;LOOP IF <100H
  569.     XRA    A    ;SHOW NOT INTO DATA..
  570.     STA    DATAFLG    ;..FOR VIEW COMMAND
  571.     RET        ;FROM SENDSEC
  572. ;
  573. ;---->    SENDCKS: SEND THE CHECKSUM
  574. ;
  575. SENDCKS    MOV    A,C    ;SEND THE..
  576.     CALL    SEND    ;..CHECKSUM
  577.     RET        ;FROM SENDCKS
  578. ;
  579. ;---->    GETACK: GET THE ACK ON THE SECTOR
  580. ;
  581. ;RETURNS WITH CARRY CLEAR IF ACK RECEIVED.
  582. ;IF AN ACK IS NOT RECEIVED, THE ERROR COUNT
  583. ;IS INCREMENTED, AND IF LESS THAN "ERRLIM",
  584. ;CARRY IS SET AND CONTROL RETURNS.  IF THE
  585. ;ERROR COUNT IS AT "ERRLIM", THE PROGRAM
  586. ;ABORTS IF IN "QUIET" MODE, OR ASKS THE
  587. ;USER FOR QUIT/RETRY IF NOT.
  588. ;
  589. GETACK    MVI    B,10    ;WAIT 10 SECONDS MAX
  590.     CALL    RECVDG    ;RECV W/GARBAGE COLLECT
  591.     JC    GETATOT    ;TIMED OUT
  592.     CPI    ACK    ;OK? (CARRY OFF IF =)
  593.     RZ        ;YES, RET FROM GETACK
  594.     MOV    B,A    ;SAVE CHAR
  595.     LDA    QFLG    ;QUIET..
  596.     ORA    A    ;..MODE?
  597.     JZ    ACKERR    ;..YES, NO MSG
  598.     MOV    A,B    ;GET CHAR
  599.     CALL    HEXO    ;PRINT IN HEX
  600.     CALL    ILPRT    ;PRINT:
  601.     DB    'H RCD, NOT ACK',CR,LF,0
  602. ;
  603. ;TIMEOUT OR ERROR ON ACK - BUMP ERROR COUNT
  604. ;
  605. ACKERR    LDA    ERRCT    ;GET COUNT
  606.     INR    A    ;BUMP IT
  607.     STA    ERRCT    ;SAVE BACK
  608.     CPI    ERRLIM    ;AT LIMIT?
  609.     RC        ;NOT AT LIMIT
  610. ;
  611. ;REACHED ERROR LIMIT
  612. ;
  613.     LDA    VSEEFLG    ;VIEWING..
  614.     ORA    A    ;..FILE?
  615.     JZ    GACKV    ;YES, ASK QUIT/RETRY
  616.     LDA    QFLG    ;QUIET..
  617.     ORA    A    ;..MODE?
  618.     JZ    CSABORT ;..YES, NO MSG
  619. ;
  620. GACKV    CALL    CKQUIT    ;SEE IF WANT TO QUIT
  621.     STC        ;TO SHOW NO ACK
  622.     RZ        ;KEEP ON TRYIN'
  623. ;
  624. CSABORT    CALL    ERXIT
  625.     DB    'CAN''T SEND SECTOR '
  626.     DB    '- ABORTING',CR,LF,'$'
  627. ;
  628. ;TIMEOUT GETTING ACK
  629. ;
  630. GETATOT    LDA    QFLG    ;QUIET..
  631.     ORA    A    ;..MODE?
  632.     JZ    ACKERR    ;YES, NO MSG
  633.     CALL    ILPRT    ;PRINT:
  634.     DB    'TIMEOUT ON ACK',CR,LF,0
  635.     JMP    ACKERR
  636. ; 
  637. ABORT    LXI    SP,STACK
  638. ;
  639. ABORTL    MVI    B,1    ;1 SEC. W/O CHARS.
  640.     CALL    RECV
  641.     JNC    ABORTL    ;LOOP UNTIL SENDER DONE
  642.     MVI    A,NAK    ;NEGATIVE ACK
  643.     CALL    SEND    ;TELL SENDING END
  644.     CALL    ILPRT    ;EXIT WITH ABORT MSG
  645.     DB    'MODEM PROGRAM CANCELLED',CR,LF,0
  646.     JMP    CKDIS    ;CHECK FOR DISCONN.
  647. ;
  648. ;---->    INCRSNO: INCREMENT SECTOR #
  649. ;
  650. INCRSNO    LDA    SECTNO    ;INCR..
  651.     INR    A    ;..SECT..
  652.     STA    SECTNO    ;..NUMBER
  653.     RET
  654. ;
  655. ;---->    ERASFIL: ERASE THE INCOMING FILE.
  656. ;
  657. ;IF IT EXISTS, ASK IF IT MAY BE ERASED.
  658. ;
  659. ERASFIL    LXI    D,FCB    ;POINT TO CTL BLOCK
  660.     MVI    C,SRCHF ;SEE IF IT..
  661.     CALL    BDOS    ;..EXISTS
  662.     INR    A    ;FOUND?
  663.     RZ        ;..NO, RETURN
  664.     CALL    ILPRT    ;PRINT:
  665.     DB    '++FILE EXISTS, TYPE Y TO ERASE: ',0
  666.     CALL    KEYIN    ;GET CHAR
  667.     PUSH    PSW
  668.     CALL    TYPE    ;ECHO
  669.     CALL    CRLF    ;BACK TO START OF LINE
  670.     POP    PSW
  671.     ANI    5FH    ;MAKE UPPER CASE
  672.     CPI    'Y'    ;WANT ERASED?
  673.     JNZ    CKDIS    ;QUIT IF NOT ERASE
  674. ;
  675. ;ERASE OLD FILE
  676. ;
  677.     LXI    D,FCB    ;POINT TO FCB
  678.     MVI    C,ERASE    ;GET BDOS FNC
  679.     CALL    BDOS    ;DO THE ERASE
  680.     RET        ;FROM "ERASFIL"
  681. ;
  682. ;---->    MAKEFIL: MAKES THE FILE TO BE RECEIVED
  683. ;
  684. MAKEFIL    LXI    D,FCB    ;POINT TO FCB
  685.     MVI    C,MAKE    ;GET BDOS FNC
  686.     CALL    BDOS    ;TO THE MAKE
  687.     INR    A    ;FF=BAD?
  688.     RNZ        ;OPEN OK
  689. ;DIRECTORY FULL - CAN'T MAKE FILE
  690.     CALL    ERXIT
  691.     DB    '++ERROR - CAN''T MAKE FILE',CR,LF
  692.     DB    '++DIRECTORY MUST BE FULL',CR,LF,'$'
  693. ;
  694. ;---->    OPENFIL: OPENS THE FILE TO BE SENT
  695. ;
  696. OPENFIL    LXI    D,FCB    ;POINT TO FILE
  697.     MVI    C,OPEN    ;GET FUNCTION
  698.     CALL    BDOS    ;OPEN IT
  699.     INR    A    ;OPEN OK?
  700.     JNZ    OPENOK    ;..YES
  701.     CALL    ERXIT    ;..NO, ABORT
  702.     DB    'CAN''T OPEN FILE$'
  703. ;
  704. OPENOK    CALL    ILPRT    ;PRINT:
  705.     DB    'FILE OPEN, EXTENT LENGTH: ',0
  706.     LDA    FCB+15    ;GET # SECTORS
  707.     CALL    HEXO    ;PRINT IN HEX
  708.     CALL    ILPRT    ;PRINT:
  709.     DB    'H',CR,LF,0
  710.     RET
  711. ;
  712. ;---->    CLOSFIL: CLOSES THE RECEIVED FILE
  713. ;
  714. CLOSFIL    LXI    D,FCB    ;POINT TO FILE
  715.     MVI    C,CLOSE    ;GET FUNCTION
  716.     CALL    BDOS    ;CLOSE IT
  717.     INR    A    ;CLOSE OK?
  718.     RNZ        ;..YES, RETURN
  719.     CALL    ERXIT    ;..NO, ABORT
  720.     DB    'CAN''T CLOSE FILE$'
  721. ;
  722. ;---->    RDSECT: READS A SECTOR
  723. ;
  724. ;FOR SPEED, THIS ROUTINE BUFFERS UP 16
  725. ;SECTORS AT A TIME.
  726. ;
  727. RDSECT    LDA    SECINBF    ;GET # SECT IN BUFF.
  728.     DCR    A    ;DECREMENT..
  729.     STA    SECINBF    ;..IT
  730.     JM    RDBLOCK    ;EXHAUSTED?  NEED MORE.
  731.     LHLD    SECPTR    ;GET POINTER
  732.     LXI    D,BASE+80H    ;TO DATA
  733.     CALL    MOVE128    ;MOVE TO BUFFER
  734.     SHLD    SECPTR    ;SAVE BUFFER POINTER
  735.     RET        ;FROM "READSEC"
  736. ;
  737. ;BUFFER IS EMPTY - READ IN ANOTHER BLOCK OF 16
  738. ;
  739. RDBLOCK    LDA    EOFLG    ;GET EOF FLAG
  740.     CPI    1    ;IS IT SET/
  741.     STC        ;TO SHOW EOF
  742.     RZ        ;GOT EOF
  743.     MVI    C,0    ;SECTORS IN BLOCK
  744.     LXI    D,DBUF    ;TO DISK BUFFER
  745. ;
  746. RDSECLP    PUSH    B
  747.     PUSH    D
  748.     MVI    C,STDMA    ;SET DMA..
  749.     CALL    BDOS    ;..ADDR
  750.     LXI    D,FCB
  751.     MVI    C,READ
  752.     CALL    BDOS
  753.     POP    D
  754.     POP    B
  755.     ORA    A    ;READ OK?
  756.     JZ    RDSECOK    ;YES
  757.     DCR    A    ;EOF?
  758.     JZ    REOF    ;GOT EOF
  759. ;
  760. ;READ ERROR
  761. ;
  762.     CALL    ERXIT
  763.     DB    '++FILE READ ERROR$'
  764. ;
  765. RDSECOK    LXI    H,80H    ;ADD LENGTH OF ONE SECTOR...
  766.     DAD    D    ;...TO NEXT BUFF
  767.     XCHG        ;BUFF TO DE
  768.     INR    C    ;MORE SECTORS?
  769.     MOV    A,C    ;GET COUNT
  770.     CPI    16    ;DONE?
  771.     JZ    RDBFULL    ;..YES, BUFF IS FULL
  772.     JMP    RDSECLP    ;READ MORE
  773. ;
  774. REOF    MVI    A,1
  775.     STA    EOFLG    ;SET EOF FLAG
  776.     MOV    A,C
  777. ;
  778. ;BUFFER IS FULL, OR GOT EOF
  779. ;
  780. RDBFULL    STA    SECINBF    ;STORE SECTOR COUNT
  781.     LXI    H,DBUF    ;INIT BUFFER..
  782.     SHLD    SECPTR    ;..POINTER
  783.     LXI    D,BASE+80H    ;RESET..
  784.     MVI    C,STDMA    ;..DMA..
  785.     CALL    BDOS    ;..ADDR
  786.     JMP    RDSECT    ;PASS SECT TO CALLER
  787. ;
  788. ;---->    WRSECT: WRITE A SECTOR
  789. ;
  790. ;WRITES THE SECTOR INTO A BUFFER.  WHEN 16
  791. ;HAVE BEEN WRITTEN, WRITES THE BLOCK TO DISK.
  792. ;
  793. ;ENTRY POINT "WRBLOCK" FLUSHES THE BUFFER AT EOF.
  794. ;
  795. WRSECT    LHLD    SECPTR    ;GET BUFF ADDR
  796.     XCHG        ;TO DE FOR MOVE
  797.     LXI    H,BASE+80H    ;FROM HERE
  798.     CALL    MOVE128    ;MOVE TO BUFFER
  799.     XCHG        ;SAVE NEXT..
  800.     SHLD    SECPTR    ;..BLOCK POINTER
  801.     LDA    SECINBF    ;BUMP THE..
  802.     INR    A    ;..SECTOR #..
  803.     STA    SECINBF    ;..IN THE BUFF
  804.     CPI    16    ;HAVE WE 16?
  805.     RNZ        ;NO, RETURN
  806. ;
  807. ;---->    WRBLOCK: WRITES A BLOCK TO DISK
  808. ;
  809. WRBLOCK    LDA    SECINBF    ;# SECT IN BUFFER
  810.     ORA    A    ;0 MEANS END OF FILE
  811.     RZ        ;NONE TO WRITE
  812.     MOV    C,A    ;SAVE COUNT
  813.     LXI    D,DBUF    ;POINT TO DISK BUFF
  814. ;
  815. DKWRLP    PUSH    H
  816.     PUSH    D
  817.     PUSH    B
  818.     MVI    C,STDMA    ;SET DMA
  819.     CALL    BDOS    ;TO BUFFER
  820.     LXI    D,FCB    ;THEN WRITE
  821.     MVI    C,WRITE    ;..THE..
  822.     CALL    BDOS    ;..BLOCK
  823.     POP    B
  824.     POP    D
  825.     POP    H
  826.     ORA    A
  827.     JNZ    WRERR    ;OOPS, ERROR
  828.     LXI    H,80H    ;LENGTH OF 1 SECT
  829.     DAD    D    ;HL= NEXT BUFF
  830.     XCHG        ;TO DE FOR SETDMA
  831.     DCR    C    ;MORE SECTORS?
  832.     JNZ    DKWRLP    ;..YES, LOOP
  833.     XRA    A    ;GET A ZERO
  834.     STA    SECINBF    ;RESET # OF SECTORS
  835.     LXI    H,DBUF    ;RESET BUFFER..
  836.     SHLD    SECPTR    ;..POINTER
  837. ;
  838. RSDMA    LXI    D,BASE+80H ;RESET..
  839.     MVI    C,STDMA    ;..DMA..
  840.     CALL    BDOS    ;..ADDR
  841.     RET
  842. ;
  843. WRERR    CALL    RSDMA    ;RESET DMA TO NORM.
  844.     CALL    ILPRT    ;PRINT:
  845.     DB    '++ERROR WRITING FILE',CR,LF,0
  846.     JMP    ABORT    ;EXIT
  847. ;
  848. ;---->    RECV: RECEIVE A CHARACTER
  849. ;
  850. ;TIMEOUT TIME IS IN B, IN SECONDS.  ENTRY VIA
  851. ;"RECVDG" DELETES GARBAGE CHARACTERS ON THE
  852. ;LINE.  FOR EXAMPLE, HAVING JUST SENT A SECTOR,
  853. ;CALLING RECVDG WILL DELETE ANY LINE-NOISE-INDUCED
  854. ;CHARACTERS "LONG" BEFORE THE ACK/NAK WOULD
  855. ;BE RECEIVED.
  856. ;
  857. RECVDG    EQU    $    ;RECEIVE W/GARBAGE DELETE
  858.     LDA    MODDATP    ;GET A CHAR
  859.     LDA    MODDATP    ;..TOTALLY PURGE UART
  860. ;
  861. RECV    PUSH    D    ;SAVE
  862. ;
  863.     IF    FASTCLK    ;4MHZ?
  864.     MOV    A,B    ;GET TIME REQUEST
  865.     ADD    A    ;DOUBLE IT
  866.     MOV    B,A    ;NEW TIME IN B
  867.     ENDIF
  868. ;
  869. MSEC    LXI    D,50000    ;1 SEC DCR COUNT
  870. MWTI    LDA    MODCTLP    ;CHECK STATUS
  871.     ANI    MODRCVB    ;ISOLATE BIT
  872.     CPI    MODRCVR    ;READY?
  873.     JZ    MCHAR    ;GOT CHAR
  874.     DCR    E    ;COUNT..
  875.     JNZ    MWTI    ;..DOWN..
  876.     DCR    D    ;..FOR..
  877.     JNZ    MWTI    ;..TIMEOUT
  878.     DCR    B    ;MORE SECONDS?
  879.     JNZ    MSEC    ;YES, WAIT
  880. ;
  881. ;MODEM TIMED OUT RECEIVING
  882. ;
  883.     POP    D    ;RESTORE D,E
  884.     STC        ;CARRY SHOWS TIMEOUT
  885.     RET
  886. ;
  887. ;GOT CHAR FROM MODEM
  888. ;
  889. MCHAR    LDA    MODDATP    ;READ THE CHAR
  890.     POP    D    ;RESTORE DE
  891. ;
  892. ;CALC CHECKSUM
  893. ;
  894.     PUSH    PSW    ;SAVE THE CHAR
  895.     ADD    C    ;ADD TO CHECKSUM
  896.     MOV    C,A    ;SAVE CHECKSUM
  897. ;
  898. ;CHECK IF MONITORING REC'D DATA
  899. ;
  900.     LDA    RSEEFLG    ;SEE RECEIVED..
  901.     ORA    A    ;..DATA?
  902.     JZ    MONIN    ;..YES
  903. ;
  904. ;CHECK IF "VIEWING" AND THIS IS A DATA CHAR
  905. ;
  906.     LDA    VSEEFLG    ;VIEWING..
  907.     ORA    A    ;..DATA?
  908.     JNZ    NOMONIN    ;..NO
  909. ;
  910. ;"VIEW" REQUESTED.  SHOW THE CHAR IT IS DATA
  911. ;
  912.     LDA    DATAFLG    ;GET DATA FLAG
  913.     ORA    A    ;TEST IT
  914.     JZ    NOMONIN    ;..OFF, NOT DATA
  915. ;
  916. MONIN    POP    PSW    ;..IS DATA,
  917.     PUSH    PSW    ;GET IT,
  918.     CALL    SHOW    ;..AND SHOW IT
  919. ;
  920. NOMONIN    POP    PSW    ;RESTORE CHAR
  921.     ORA    A    ;CARRY OFF: NO ERROR
  922.     RET        ;FROM "RECV"
  923. ;
  924. ;---->    SEND: SEND A CHARACTER TO THE MODEM
  925. ;
  926. SEND    PUSH    PSW    ;SAVE THE CHAR
  927. ;
  928. ;CHECK IF MONITORING SENT DATA
  929. ;
  930.     LDA    SSEEFLG    ;CHECK IF MONITORING..
  931.     ORA    A    ;..SENT DATA
  932.     JZ    MONOUT    ;..YES
  933. ;
  934. ;CHECK IF "VIEWING" THE FILE
  935. ;
  936.     LDA    VSEEFLG    ;GET VIEW FLAG
  937.     ORA    A    ;TEST IT
  938.     JNZ    NOMONOT    ;NO
  939.     LDA    DATAFLG    ;IS THIS
  940.     ORA    A    ;..DATA?
  941.     JZ    NOMONOT    ;..NO.
  942. ;
  943. MONOUT    POP    PSW    ;GET THE CHAR
  944.     PUSH    PSW    ;SAVE IT
  945.     CALL    SHOW    ;SHOW IT
  946. ;
  947. NOMONOT    POP    PSW    ;RESTORE CHAR
  948.     PUSH    PSW    ;SAVE IT
  949.     ADD    C    ;CALC CKSUM
  950.     MOV    C,A    ;SAVE CKSUM
  951. SENDW    LDA    MODCTLP    ;GET STATUS
  952.     ANI    MODSNDB    ;ISOLATE READY BIT
  953.     CPI    MODSNDR    ;READY?
  954.     JNZ    SENDW    ;..NO, WAIT
  955.     POP    PSW    ;GET CHAR
  956.     STA    MODDATP    ;OUTPUT IT
  957.     RET        ;FROM "SEND"
  958. ;
  959. ;---->    WAITNAK: WAITS FOR INITIAL NAK
  960. ;
  961. ;TO ENSURE NO DATA IS SENT UNTIL THE RECEIVING
  962. ;PROGRAM IS READY, THIS ROUTINE WAITS FOR THE
  963. ;THE FIRST TIMEOUT-NAK FROM THE RECEIVER.
  964. ;(E) CONTAINS THE # OF SECONDS TO WAIT.
  965. ;
  966. WAITNAK    LDA    VSEEFLG    ;VIEWING?
  967.     ORA    A
  968.     JZ    WAITNPR    ;PRINT MSG
  969.     LDA    QFLG    ;QUIET..
  970.     ORA    A    ;..MODE?
  971.     JZ    WAITNLP    ;YES, SKIP MSG
  972. ;
  973. WAITNPR    CALL    ILPRT    ;PRINT:
  974.     DB    'AWAITING INITIAL NAK',CR,LF,0
  975. ;
  976. WAITNLP    MVI    B,1    ;TIMEOUT DELAY
  977.     CALL    RECV    ;DID WE GET..
  978.     CPI    NAK    ;..A NAK?
  979.     RZ        ;YES, SEND BLOCK
  980.     DCR    E    ;80 TRIES?
  981.     JZ    ABORT    ;YES, ABORT
  982.     JMP    WAITNLP    ;NO, LOOP
  983. ;
  984. ;---->    INITADR: INIT'S CP/M BDOS ADDRESSES
  985. ;
  986. ;THIS ROUTINE FILLS IN THE ADDRESSES OF VARIOUS
  987. ;JMP AND CALL INSTRUCTIONS, SO THAT CP/M BDOS
  988. ;IS BYPASSED WHILE ACCESSING THE CONSOLE.  THIS
  989. ;IS DONE TO ALLOW CHARACTERS SUCH AS CONTROL-C
  990. ;AND CONTROL-S TO BE KEYED WHILE IN TERMINAL
  991. ;MODE, WITHOUT CP/M INTERPRETING THEM.
  992. ;
  993. INITADR    LHLD    BASE+1    ;GET WARM BOOT ADDR
  994.     LXI    D,3    ;LENGTH OF A 'JMP'
  995.     DAD    D    ;TO CONSOLE STAT
  996.     SHLD    VSTAT+1    ;MODIFY CALL
  997.     DAD    D    ;TO CONSOLE IN
  998.     SHLD    VKEYIN+1 ;MODIFY CALL
  999.     DAD    D    ;TO CONSOLE OUT
  1000.     SHLD    VTYPE+1    ;MODIFY CALL
  1001.     RET
  1002. ;
  1003. ;---->    PROCOPT: PROCESS COMMAND OPTIONS
  1004. ; 
  1005. ;1) SAVES THE PRIMARY OPTION IN 'OPTION';
  1006. ;2) SCANS THE SUB-OPTION CHARACTERS, AND FOR
  1007. ;EACH FOUND, ZEROS THE APPROPRIATE ENTRY IN
  1008. ;THE OPTION TABLE.  FOR EXAMPLE, IF 'D' IS 
  1009. ;CODED (DISCONNECT) THEN THE 'D' STORED AT
  1010. ;'DISCFLG' IS SET TO 0 SO IT CAN BE TESTED
  1011. ;LATER.
  1012. ;
  1013. PROCOPT    LXI    D,FCB+1    ;TO PRIMARY OPT.
  1014.     LDAX    D    ;GET PRIMARY
  1015.     STA    OPTION    ;SAVE IT
  1016. ;
  1017. OPTLP    INX    D    ;TO SECONDARY OPTION
  1018.     LDAX    D    ;GET CHAR
  1019. ;
  1020. ;IF YOU MOD THIS PROGRAM FOR >7 OPTIONS,
  1021. ;YOU MUST CHANGE THE FOLLOWING, SINCE
  1022. ;THERE WON'T BE A ' ' AFTER THE OPTION
  1023. ;IF A BAUD RATE WAS SPECIFIED.
  1024. ;
  1025.     CPI    ' '    ;NO MORE OPT'NS?
  1026.     JZ    ENDOPT    ;..YES
  1027. ;SET THE APPROP. OPT: STORE 0 IN IT
  1028.     LXI    H,OPTBL    ;HL = ADDR OF 'OAQDSRV'
  1029.     MVI    B,OPTBE-OPTBL ;OPT TABLE LEN
  1030. ;
  1031. OPTCK    CMP    M    ;FOUND THE OPTION?
  1032.     JNZ    OPTNO    ;NO, DON'T SET IT
  1033.     MVI    M,0    ;SET THE OPTION
  1034.     JMP    OPTLP    ;GET NEXT OPTION
  1035. ;
  1036. OPTNO    INX    H    ;TO NEXT
  1037.     DCR    B    ;MORE?
  1038.     JNZ    OPTCK
  1039. ;OPTION NOT IN TABLE
  1040.     JMP    BADOPT    ;SHOW BAD SUB OPTION
  1041. ;
  1042. ;IF "VIEW" WAS ASKED FOR, SET QUIET FLAG
  1043. ;
  1044. ENDOPT    LDA    VSEEFLG    ;VIEW..
  1045.     ORA    A    ;..ASKED FOR?
  1046.     RNZ        ;..NO, RET FROM 'PROCOPT'
  1047.     STA    QFLG    ;YES, NO HDR/CKSUM PRT
  1048.     RET        ;FROM 'PROCOPT'
  1049. ;
  1050. ;DONE - CLOSE UP SHOP
  1051. ;
  1052. DONE    LDA    VSEEFLG    ;VIEWING?
  1053.     ORA    A
  1054.     JZ    DONETC    ;SHOW MSG
  1055.     LDA    QFLG    ;QUIET
  1056.     ORA    A    ;..MODE?
  1057.     JZ    DONECTE    ;YES, CK TERM/ECHO
  1058. ;
  1059. DONETC    CALL    ILPRT
  1060.     DB    CR,LF,'TRANSFER COMPLETE' 
  1061.     DB    CR,LF,0
  1062. ;
  1063. ;CHECK IF TERMINAL OR ECHO SUB COMMAND
  1064. ;WAS SPECIFIED
  1065. ;
  1066. DONECTE    LDA    TERMFLG    ;TERM?
  1067.     ORA    A
  1068.     JZ    TERM    ;..YES
  1069.     LDA    ECHOFLG    ;ECHO?
  1070.     ORA    A
  1071.     JZ    TRMECHO    ;..YES
  1072. ;
  1073. ;FALL INTO 'CKDIS'
  1074. ;
  1075. ;---->    CKDIS: CHECK IF DISCONNECT REQUESTED
  1076. ;
  1077. ;THIS ROUTINE IS JUMPED TO AT THE END OF
  1078. ;PROCESSING, AND DISCONNECTS THE PHONE IF
  1079. ;'D' WAS SPECIFIED AS A SUB-OPTION.
  1080. ;
  1081. CKDIS    LDA    DISCFLG    ;CHECK 'D' FLAG
  1082.     ORA    A    ;REQUESTED?
  1083. ;
  1084.     IF    MMII
  1085.     JNZ    NDIS    ;..NO, JUST EXIT
  1086.     ENDIF
  1087. ;
  1088.     IF    NOT MMII
  1089.     JNZ    EXIT
  1090.     ENDIF
  1091. ;
  1092. ;AWAIT C/R TO DISC. SO WE DON'T LOSE THE PHONE
  1093. ;
  1094.     CALL    ILPRT
  1095.     DB    CR,LF,'PRESS RETURN TO DISCONNECT:',0
  1096.     CALL    KEYIN
  1097.     PUSH    PSW
  1098.     CALL    CRLF
  1099.     POP    PSW
  1100.     CPI    CR
  1101.     JNZ    CKDIS    ;ASK AGAIN
  1102. ;
  1103. ;---->    DISCONN: DISCONNECT THE PHONE
  1104. ;
  1105. DISCONN    EQU    $
  1106. ;
  1107.     IF    MMII
  1108.     XRA    A    ;GET DISCONNECT VALUE
  1109.     STA    MODCTL2    ;DISCONNECT
  1110.     ENDIF
  1111. ;
  1112.     CALL    ILPRT    ;PRINT:
  1113.     DB    '++DISCONNECTED++',0
  1114.     JMP    EXIT
  1115. ;
  1116. ;NO DISCONNECT, TYPE MSG AS REMINDER THAT PHONE'S
  1117. ;OFF HOOK
  1118. ;
  1119.     IF    MMII
  1120. NDIS    LDA    QFLG    ;QUIET..
  1121.     ORA    A    ;..MODE?
  1122.     JZ    EXIT    ;..YES, NO MSG
  1123.     CALL    ILPRT
  1124.     DB    CR,LF,'++DON''T FORGET - THE MODEM IS '
  1125.     DB    'NOT DISCONNECTED++',CR,LF
  1126.     DB    'USE "MODEM D" TO DISCONNECT',CR,LF,0
  1127.     JMP    EXIT
  1128. ;
  1129.     ENDIF
  1130. ;
  1131. ;---->    INITMOD: INITIALIZES THE MODEM
  1132. ;
  1133. ;THIS ROUTINE IS USED TO INITIALIZE SERIAL
  1134. ;BOARDS, OR SETUP S-100 MODEM BOARDS.
  1135. ;JUST RETURNS IF NO INITIALIZATION REQUIRED.
  1136. ;
  1137. INITMOD:
  1138. ;
  1139.     IF    INITREQ  ;REQUIRE INIT?
  1140.     MVI    A,INITC1 ;GET 1ST INIT CHAR
  1141.     STA    MODCTLP     ;OUTPUT IT
  1142.     NOP ! NOP! NOP     ;DELAY FOR USART
  1143.     NOP ! NOP
  1144.     MVI    A,INITC2 ;GET 2ND INIT CHAR
  1145.     STA    MODCTLP     ;OUTPUT IT
  1146.     NOP ! NOP! NOP     ;DELAY FOR USART
  1147.     NOP ! NOP
  1148.     ENDIF
  1149. ;
  1150.     IF    MMII
  1151.     CALL    GETBAUD    ;GET BAUD RATE
  1152.     LDA    ANSWFLG        ;ANSWER..
  1153.     ORA    A
  1154.     MVI    B,ANSWMOD    ;SET ANSWER MODE
  1155.     JZ    INITM1
  1156.     LDA    ORIGFLG        ;GET ORIGINATE FLAG
  1157.     ORA    A
  1158.     MVI    B,ORIGMOD    ;SET ORIGINATE MODE
  1159.     JZ    INITM1
  1160.     LDA    HOLDD        ;NEITHER - GET LAST VALUE
  1161.     MOV    B,A        ;STORE IN B
  1162. ;
  1163. INITM1:    MOV    A,B        ;GET MODE
  1164.     STA    HOLDD        ;SAVE VALUE
  1165.     MOV    A,C        ;GET BAUD RATE INDICATOR
  1166.     ORA    A        ;ZEBO IF 110 BAUD
  1167.     MOV    A,B        ;GET MODE
  1168.     JZ    OFFHOOK        ;DO OFFHOOK
  1169.     ORI    1        ;SET 300 BAUD
  1170. ;GO OFFHOOK IN REQUESTED (ORIG/ANSW) MODE
  1171. ;
  1172. OFFHOOK    LXI    H,4000    ;DELAY AMT
  1173. ;
  1174. OFFDLY    DCR    L
  1175.     JNZ    OFFDLY
  1176.     DCR    H
  1177.     JNZ    OFFDLY
  1178.     STA    MODCTL2    ;GO OFF HOOK
  1179.     RET
  1180.     ENDIF        ;MMII
  1181. ;
  1182.     IF    MMII
  1183. GETBAUD    LDA    FCB+9    ;GET FILETYPE
  1184.     CPI    ' '    ;DEFAULT?
  1185.     JNZ    GETBAU1    ;NO - DO BAUD RATE STUFF
  1186.     MVI    C,1    ;SET 300 BAUD
  1187.     MVI    B,15H    ;SET 1 STOP BIT
  1188.     JMP    GETBAU2
  1189. ;
  1190. ; CONVERT BAUD RATE TO BINARY
  1191. GETBAU1    CALL    CVBIN    ;CONVERT TO BINARY
  1192.     PUSH    H    ;SAVE BAUD RATE
  1193.     MVI    C,0    ;ANTICIPATE 110 BAUD
  1194.     MVI    B,15H    ;SET 2 STOP BITS
  1195.     LXI    D,-110    ;GET CONSTANT
  1196.     DAD    D    ;SUBTRACT
  1197.     MOV    A,H
  1198.     ORA    L
  1199.     POP    H
  1200.     JZ    GETBAU2    ;110 BAUD
  1201.     MVI    B,15H    ;SET 1 STOP BIT
  1202.     INR    C
  1203.     LXI    D,-300    ;GET CONSTANT
  1204.     DAD    D
  1205.     MOV    A,H
  1206.     ORA    L
  1207.     JNZ    BADRATE    ;INVALID
  1208. ;
  1209. GETBAU2    MOV    A,B    ;GET SET UP
  1210.     STA    MODCTLP    ;INITIALIZE MODEM FOR STOP BITS..
  1211.     RET        ;..DATA BITS, ETC.
  1212.     ENDIF        ;DCH
  1213. ;
  1214.     IF COMCARD    ;APPLE COMMUNCATIONS CARD
  1215. GETBAUD    LDA    FCB+9    ;GET FILETYPE
  1216.     CPI    ' '    ;DEFAULT?
  1217.     JNZ    GETBAU1 ;NO - DO BAUD RATE STUFF
  1218.     MVI    B,11H    ;300 BAUD STATUS CODE
  1219.     JMP    GETBAU2
  1220. ;  CONVERT BAUD RATE TO BINARY
  1221. GETBAU1    CALL    CVBIN    ;CONVERT TO BINARY
  1222.     PUSH    H    ;SAVE BAUD RATE
  1223.     MVI    B,52H    ;ANTICIPATE 110 BAUD
  1224.     LXI    D,-110    ;GET CONSTANT
  1225.     DAD    D    ;SUBTRACT
  1226.     MOV    A,H    
  1227.     ORA    L
  1228.     POP    H
  1229.     JZ    GETBAU2    ;110 BAUD
  1230.     MVI    B,11H    ;300 BAUD STATUS CODE
  1231.     INR    C
  1232.     LXI    D,-300    ;GET CONSTANT
  1233.     DAD    D
  1234.     MOV    A,H
  1235.     ORA    L
  1236.     JNZ    BADRATE    ;INVALID RATE (300 OR 110 ONLY)
  1237. GETBAU2    MOV    A,B    ;GET SET UP
  1238.     STA    MODCTLP    ;STORE TO STATUS PORT
  1239.     RET
  1240.     ENDIF    ;COMCARD
  1241. ;
  1242.     IF    COMCARD OR MMII
  1243. ; ROUTINE TO CONVERT BAUD RATE TO BINARY
  1244. ;
  1245. CVBIN:    LXI    D,FCB+9    ;TO ASCII VALUE
  1246.     LXI    H,0    ;INIT BINARY RESULT
  1247. ;
  1248. DECLP    LDAX    D    ;GET ASCII DIGIT
  1249.     INX    D    ;TO NEXT DIGIT
  1250.     CPI    ' '    ;BLANK ONE?
  1251.     JZ    DECLP    ;..YES, SKIP IT
  1252.     CPI    '0'    ;VALIDATE IT
  1253.     JC    BADRATE    ;ERROR
  1254.     CPI    '9'+1    ;VALIDATE
  1255.     JNC    BADRATE    ;ERROR
  1256.     SUI    '0'    ;MAKE DIGIT BINARY
  1257. ;
  1258. ;MULTIPLY PREV VALUE BY 10
  1259. ;
  1260.     MOV    B,H    ;SET UP FOR
  1261.     MOV    C,L    ;MULTIPLY BY 10
  1262.     DAD    H    ;MULTIPLY BY 2
  1263.     DAD    H    ;X 2 = 4
  1264.     DAD    B    ;+ 1 = 5
  1265.     DAD    H    ;X 2 = 10
  1266.     ADD    L    ;ADD IN DIGIT
  1267.     MOV    L,A    ;SAVE BACK
  1268.     JNZ    DIGNC    ;NO CARRY?
  1269.     INR    H    ;ADD IN CARRY
  1270. ;CHECK IF DONE?
  1271. DIGNC    MOV    A,E    ;SEE IF PAST
  1272.     CPI    FCB+12    ;..LAST DIGIT
  1273.     JNZ    DECLP    ;NO, LOOP
  1274.     RET
  1275. ;
  1276. ;INVALID BAUD RATE
  1277. ;
  1278. BADRATE    CALL    ERXIT
  1279.     DB    '++INVALID BAUD RATE++$'
  1280.     ENDIF        ;PMMI OR DCH
  1281. ;
  1282. ;THE FOLLOWING PROVIDES A RETURN FROM INITMOD
  1283.     IF    NOT MMII AND NOT COMCARD
  1284.     RET        ;**THIS MUST BE HERE**
  1285.     ENDIF        ;NOT PMMI AND NOT DCH
  1286. ;
  1287. ;---->    MOVEFCB: MOVES FCB(2) TO FCB
  1288. ;
  1289. ;I ATTEMPTED TO MAKE THE MODEM COMMAND 'NATURAL',
  1290. ;I.E. MODEM SEND FILENAME (MODEM S FN.FT) RATHER
  1291. ;THAT MODEM FILENAME SEND (MODEM FN.FT S) SO THIS
  1292. ;ROUTINE MOVES THE FILENAME FROM THE SECOND FCB
  1293. ;TO THE FIRST
  1294. ;
  1295. MOVEFCB    LXI    H,FCB+16 ;FROM
  1296.     LXI    D,FCB    ;TO
  1297.     MVI    B,16    ;LEN
  1298.     CALL    MOVE    ;DO THE MOVE
  1299.     XRA    A    ;GET 0
  1300.     STA    FCBSNO    ;ZERO SECTOR #
  1301.     STA    FCBEXT    ;..AND EXTENT
  1302.     RET
  1303. ;
  1304. ;---->    SHOW: SHOWS CHAR SENT/RECEIVED
  1305. ;
  1306. ;CR, LF, AND TAB ARE SHOWN.  ALL OTHER
  1307. ;NON-PRINTABLE CHARACTERS ARE SHOWN IN
  1308. ;HEX AS (XX)
  1309. ;
  1310. SHOW    CPI    LF    ;LF?
  1311.     JZ    CTYPE    ;..YES, TYPE IT
  1312.     CPI    CR    ;CR?
  1313.     JZ    CTYPE    ;..YES, TYPE IT
  1314.     CPI    09    ;TAB
  1315.     JZ    CTYPE    ;..YES, TYPE IT
  1316.     CPI    ' '    ;CTL-CHR?
  1317.     JC    SHOWHEX    ;YES, SHOW IN HEX
  1318.     CPI    7FH    ;DEL?
  1319.     JC    CTYPE    ;NO, TYPE THE CHAR
  1320. ;
  1321. SHOWHEX    PUSH    PSW    ;SAVE THE CHAR
  1322.     MVI    A,'('    ;TYPE..
  1323.     CALL    CTYPE    ;..'('
  1324.     POP    PSW    ;THEN..
  1325.     CALL    HEXO    ;..THE CHAR
  1326.     MVI    A,')'    ;THEN..
  1327.     JMP    CTYPE    ;..')' AND RETURN.
  1328. ;
  1329. ;---->    CTYPE: TYPES VIA CP/M SO TABS ARE EXPANDED
  1330. ;
  1331. CTYPE    PUSH    B    ;SAVE..
  1332.     PUSH    D    ;..ALL..
  1333.     PUSH    H    ;..REGS
  1334.     MOV    E,A    ;CHAR TO E
  1335.     MVI    C,WRCON    ;GET BDOS FNC
  1336.     CALL    BDOS    ;PRIN THE CHR
  1337.     POP    H    ;RESTORE..
  1338.     POP    D    ;..ALL..
  1339.     POP    B    ;..REGS
  1340.     RET        ;FROM "CTYPE"
  1341. ;
  1342. CRLF    MVI    A,CR
  1343.     CALL    TYPE
  1344.     MVI    A,LF
  1345. ;
  1346. ;---->    TYPE: TYPE VIA DIRECT CBIOS ACCESS
  1347. ;WE ASSUME CBIOS MAY DESTROY SOME REGISTERS,
  1348. ;SO SAVE THEM ALL.
  1349. ;
  1350. ;THIS ROUTINE BYPASSES CP/M'S CTL-S, CTL-C
  1351. ;TESTS.
  1352. ;
  1353. TYPE    PUSH    PSW    ;SAVE CHAR
  1354.     PUSH    B    ;AND OTHER REGISTERS
  1355.     PUSH    D
  1356.     PUSH    H
  1357.     MOV    C,A    ;FOR BIOS
  1358. VTYPE    CALL    $-$    ;MODIFIED AT INIT
  1359.     POP    H    ;RESTORE REGISTERS
  1360.     POP    D
  1361.     POP    B
  1362.     POP    PSW    ;..AND CHAR
  1363.     RET        ;FROM "TYPE"
  1364. ;
  1365. ;---->  STAT: KEYBOARD STATUS
  1366. ;
  1367. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1368. ;CBIOS CLOBBERS THEM.
  1369. ;
  1370. STAT    PUSH    B
  1371.     PUSH    D
  1372.     PUSH    H
  1373. VSTAT    CALL    $-$    ;ADDR SET AT INIT
  1374.     POP    H
  1375.     POP    D
  1376.     POP    B
  1377.     ORA    A    ;0 => NOT READY
  1378.     RET
  1379. ;
  1380. ;---->  KEYIN: KEYBOARD INPUT
  1381. ;
  1382. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1383. ;CBIOS CLOBBERS THEM.
  1384. ;
  1385. KEYIN    PUSH    B
  1386.     PUSH    D
  1387.     PUSH    H
  1388. VKEYIN    CALL    $-$    ;ADDR SET AT INIT
  1389.     POP    H
  1390.     POP    D
  1391.     POP    B
  1392.     ANI    7FH    ;STRIP PARITY IF THERE
  1393.     RET        ;FROM KEYIN
  1394. ;
  1395. ;---->  HEXO: HEX OUTPUT
  1396. ;
  1397. HEXO    PUSH    PSW    ;SAVE FOR RIGHT DIGIT
  1398.     RAR        ;RIGHT..
  1399.     RAR        ;..JUSTIFY..
  1400.     RAR        ;..LEFT..
  1401.     RAR        ;..DIGIT..
  1402.     CALL    NIBBL    ;PRINT LEFT DIGIT
  1403.     POP    PSW    ;RESTORE RIGHT
  1404. ;
  1405. NIBBL    ANI    0FH    ;ISOLATE DIGIT
  1406.     CPI    10    ;IS IS <10?
  1407.     JC    ISNUM    ;YES, NOT ALPHA
  1408.     ADI    7    ;ADD ALPHA BIAS
  1409. ;
  1410. ISNUM    ADI    '0'    ;MAKE PRINTABLE
  1411.     JMP    TYPE    ;..THEN TYPE IT
  1412. ;
  1413. ;---->    CKQUIT: QUIT/RETRY AFTER MULTIPLE ERRS.
  1414. ;
  1415. ;RETURNS W/ ZERO SET IF "RETRY" ASKED FOR
  1416. ;
  1417. CKQUIT    XRA    A    ;ZERO..
  1418.     STA    ERRCT    ;..ERROR COUNT
  1419.     CALL    ILPRT    ;PRINT:
  1420.     DB    'MULTIPLE ERRORS ENCOUNTERED.  '
  1421.     DB    'TYPE Q TO QUIT, R TO RETRY: ',0
  1422.     CALL    KEYIN    ;QUIT/RETRY
  1423.     PUSH    PSW
  1424.     CALL    TYPE
  1425.     CALL    CRLF
  1426.     POP    PSW
  1427.     ANI    5FH    ;MAKE UPPER CASE
  1428.     CPI    'R'    ;RETRY?
  1429.     RZ        ;'KEEP ON TRUCKIN'
  1430.     CPI    'Q'    ;QUIT?
  1431.     JNZ    CKQUIT    ;NO, ASK AGAIN
  1432.     ORA    A    ;SET NON-ZERO
  1433.     RET
  1434. ;
  1435. ;---->    ILPRT: INLINE PRINT OF MSG
  1436. ;
  1437. ;THE CALL TO ILPRT IS FOLLOWED BY A MESSAGE,
  1438. ;BINARY 0 AS THE END.  BINARY 1 MAY BE USED TO
  1439. ;PAUSE (MESSAGE 'PRESS RETURN TO CONTINUE')
  1440. ;
  1441. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  1442. ;
  1443. ILPLP    MOV    A,M    ;GET CHAR
  1444.     ORA    A    ;END OF MSG?
  1445.     JZ    ILPRET    ;..YES, RETURN
  1446.     CPI    1    ;PAUSE?
  1447.     JZ    ILPAUSE    ;..YES
  1448.     CALL    CTYPE    ;TYPE THE MSG
  1449. ;
  1450. ILPNEXT    INX    H    ;TO NEXT CHAR
  1451.     JMP    ILPLP    ;LOOP
  1452. ;
  1453. ;PAUSE WHILE TYPING HELP SO INFO DOESN'T
  1454. ;    SCROLL OFF OF VIDEO SCREENS
  1455. ;
  1456. ILPAUSE    CALL    ILPRT    ;PRINT:
  1457.     DB    CR,LF,'PRESS RETURN TO CONTINUE'
  1458.     DB    CR,LF,0
  1459.     CALL    KEYIN    ;GET ANY CHAR
  1460.     CPI    'C'-40H    ;REBOOT?
  1461.     JZ    EXIT    ;YES.
  1462.     JMP    ILPNEXT    ;LOOP
  1463. ;
  1464. ILPRET    XTHL        ;RESTORE HL
  1465.     RET        ;PAST MSG
  1466. ;
  1467. ;---->    PRTMSG: PRINTS MSG POINTED TO BY (DE)
  1468. ;
  1469. ;A '$' IS THE ENDING DELIMITER FOR THE PRINT.
  1470. ;NO REGISTERS SAVED.
  1471. ;
  1472. PRTMSG    MVI    C,PRINT    ;GET BDOS FNC
  1473.     JMP    BDOS    ;PRINT MESSAGE, RETURN
  1474. ;
  1475. ;---->    ERXIT: EXIT PRINTING MSG FOLLOWING CALL
  1476. ;
  1477. ERXIT    POP    D    ;GET MESSAGE
  1478.     CALL    PRTMSG    ;PRINT IT
  1479.     CALL    CKDIS    ;DISCONNECT?
  1480. ;
  1481. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  1482.     SPHL        ;RESTORE IT
  1483.     RET        ;--EXIT-- TO CP/M
  1484. ;
  1485. ;MOVE 128 CHARACTERS
  1486. ;
  1487. MOVE128    MVI    B,128    ;SET MOVE COUNT
  1488. ;
  1489. ;MOVE FROM (HL) TO (DE) LENGTH IN (B)
  1490. ;
  1491. MOVE    MOV    A,M    ;GET A CHAR
  1492.     STAX    D    ;STORE IT
  1493.     INX    H    ;TO NEXT "FROM"
  1494.     INX    D    ;TO NEXT "TO"
  1495.     DCR    B    ;MORE?
  1496.     JNZ    MOVE    ;..YES, LOOP
  1497.     RET        ;..NO, RETURN
  1498. ;    ----------------
  1499. OPTION    DB    0    ;PRIMARY OPTION
  1500. ;
  1501. ;DATAFLG IS USED BY THE "V" SUBCOMMAND -
  1502. ;IT IS 0 WHEN A HEADER OR CKSUM IS BEING
  1503. ;SENT/RCD, AND 1 IF "VIEWABLE" DATA (THE
  1504. ;SECTOR ITSELF) IS
  1505. ;
  1506. DATAFLG    DB    0    ;AT HEADER, FIRST
  1507. ;
  1508. ;
  1509. ;SUB-OPTION TABLE.  IF AN OPTION IS IN EFFECT,
  1510. ;    THE CHARACTER IS SET TO BINARY 0
  1511. ;
  1512. OPTBL    EQU    $
  1513. ANSWFLG    DB    'A'    ;ANSWER MODE
  1514. DISCFLG    DB    'D'    ;DISCONNECT WHEN DONE
  1515. ECHOFLG    DB    'E'    ;TO ECHO AFTER XFER
  1516. ORIGFLG    DB    'O'    ;ORIGINATE MODE
  1517. QFLG    DB    'Q'    ;QUIET TRANSFER (NO MSGS)
  1518. RSEEFLG    DB    'R'    ;SEE WHAT'S RECEIVED
  1519. SSEEFLG    DB    'S'    ;SEE WHAT'S SENT
  1520. TERMFLG    DB    'T'    ;TO TERM AFTER XFER
  1521. VSEEFLG    DB    'V'    ;VIEW MESSAGES (NO HDR, ETC)
  1522. OPTBE    EQU    $    ;END OF OPTIONS
  1523. ;
  1524. RCVSNO    DB    0    ;SECT # RECEIVED
  1525. SECTNO    DB    0    ;CURRENT SECTOR NUMBER 
  1526. ERRCT    DB    0    ;ERROR COUNT
  1527. HOLDD    DB    8EH    ;HOLD AREA - LAST DC HAYES CONT CHAR.
  1528. ;FOLLOWING 3 USED BY DISK BUFFERING ROUTINES
  1529. EOFLG    DB    0    ;EOF FLAG (1=TRUE)
  1530. SECPTR    DW    DBUF
  1531. SECINBF    DB    0    ;# OF SECTORS IN BUFFER
  1532.     DS    60    ;STACK AREA
  1533. STACK    DS    2    ;STACK POINTER
  1534. ;
  1535. ;16 SECTOR DISK BUFFER (OVERLAYS HELP MSGS)
  1536. ;
  1537. DBUF    EQU    $    ;16 SECTOR DISK BUFFER
  1538. ;
  1539. ;INVALID COMMAND
  1540. ;
  1541. BADOPT    CALL    TYPE
  1542.     CALL    ILPRT    ;EXIT W/ERROR
  1543.     DB    ': INVALID OPTION ON MODEM '
  1544.     DB    'COMMAND - ',CR,LF
  1545.  DB 'PRESS RETURN FOR HELP, CTL-C IF NOT',CR,LF,1,0
  1546. ;
  1547. HELP    CALL    ILPRT
  1548.  DB 'Format for command is:',cr,lf,cr,lf
  1549.  DB 'MODEM # FILENAME',CR,LF,CR,LF
  1550.  DB 'Where # is a 1 character primary option,',cr,lf
  1551.  DB ' which may be followed by sub-options,',cr,lf
  1552.  DB ' and by ".xxx" to set baud rate to xxx'
  1553.  DB cr,lf,cr,lf,1
  1554.  DB 'Primary Options:',cr,lf
  1555.  DB '    S to send a file',cr,lf
  1556.  DB '    R to receive a file',cr,lf
  1557.  DB '    T to act as a terminal',cr,lf
  1558.  DB '    E to act as a computer (echo data)',cr,lf
  1559.  DB '    D to disconnect the phone'
  1560.  DB '    (Micromodem ][ only)',cr,lf
  1561.  DB '    H to print this help file'
  1562.  DB cr,lf,cr,lf,1
  1563.  DB 'Secondary options:',cr,lf
  1564.  DB '    A answer mode',cr,lf
  1565.  DB '    O originate mode',cr,lf
  1566.  DB '    D disconnect after execution',cr,lf
  1567.  DB '    T go to terminal mode after file xfer',cr,lf
  1568.  DB '    E go to echo mode after file xfer',cr,lf
  1569.  DB '    Q quiet mode - no status msgs',cr,lf
  1570.  DB '    R show chars received',cr,lf
  1571.  DB '    S show chars sent',cr,lf
  1572.  DB '    V view file sent/received (no status)',cr,lf
  1573.  DB CR,LF,'FOR EXAMPLES, TYPE: MODEM X',cr,lf,0
  1574.     JMP    EXIT
  1575. ;
  1576. EXAM    CALL    ILPRT
  1577.  DB 'Send file, originate mode, 300 baud:',CR,LF
  1578.  DB '    MODEM SO fn.ft',cr,lf
  1579.  DB 'Send another file:',CR,LF
  1580.  DB '    MODEM S fn.ft',cr,lf
  1581.  DB 'Then send a third file at 110 baud and disconnect:'
  1582.  DB CR,LF,'    MODEM SD.110 fn.ft',cr,lf
  1583.  DB 'Act as a terminal, originate mode, at 110 baud:',cr,lf
  1584.  DB '    MODEM TO.110',CR,LF
  1585.  DB '    (Use ctl-D to disconnect)',cr,lf
  1586.  DB 'Receive file, answer mode, view it, 600 baud:',cr,lf
  1587.  DB '    MODEM RAV.110 fn.ft',cr,lf,0
  1588. JMP EXIT
  1589. ;
  1590. ; BDOS EQUATES (VERSION 2)
  1591. ;
  1592. RDCON    EQU    1
  1593. WRCON    EQU    2
  1594. PRINT    EQU    9
  1595. CONST    EQU    11    ;CONSOLE STAT
  1596. OPEN    EQU    15    ;0FFH=NOT FOUND
  1597. CLOSE    EQU    16    ;    "    "
  1598. SRCHF    EQU    17    ;    "    "
  1599. SRCHN    EQU    18    ;    "    "
  1600. ERASE    EQU    19    ;NO RET CODE
  1601. READ    EQU    20    ;0=OK, 1=EOF
  1602. WRITE    EQU    21    ;0=OK, 1=ERR, 2=?, 0FFH=NO DIR SPC
  1603. MAKE    EQU    22    ;0FFH=BAD
  1604. REN    EQU    23    ;0FFH=BAD
  1605. STDMA    EQU    26    ;SET DMA
  1606. BDOS    EQU    BASE+5
  1607. REIPL    EQU    BASE
  1608. FCB    EQU    BASE+5CH    ;SYSTEM FCB
  1609. FCBEXT    EQU    FCB+12        ;FILE EXTENT
  1610. FCBSNO    EQU    FCB+32        ;SECTOR #
  1611. FCB2    EQU    BASE+6CH    ;SECOND FCB
  1612.     END
  1613.