home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol017 / xmodem41.asm < prev   
Assembly Source File  |  1984-04-29  |  29KB  |  1,212 lines
  1. ;
  2. ;    XMODEM.ASM V4.1, by Keith Petersen, W8SDZ
  3. ;    Latest Revision: 2/17/81 Tim Nicholas
  4. ;
  5. ;    REMOTE CP/M - CP/M FILE TRANSFER PROGRAM
  6. ;
  7. ;Based on MODEM.ASM V2.0, by Ward Christensen.
  8. ;This program is intended for use on remote CP/M
  9. ;systems where it is important that the initialization
  10. ;of the modem not be changed, such as when using
  11. ;the PMMIBYE program. The baud rate and number of bits
  12. ;remains the same as whatever was set previously.
  13. ;There is no disconnect, terminal or echo option.
  14. ;
  15. ;NOTE: This file will assemble, without need for
  16. ;editing, to work with a PMMI MM-103 modem and 2 Mhz
  17. ;system clock.    See equates for options including
  18. ;other modems and 4 Mhz system clock frequency.
  19. ;
  20. ;Program updates/fixes (these are written in reverse
  21. ;order to minimize reading time to find latest update):
  22. ;
  23. ;
  24. ;02/17/81 Added test for "f2" tagged files in OPENOK
  25. ;      for MP/M version 1.1 compatiblity, which
  26. ;      doesn't allow Ctl-C or Ctl-S in "f1" tagged
  27. ;      files. (Tim Nicholas)
  28. ;
  29. ;02/16/81 Added hex to file size display. Now reports
  30. ;      size in both decimal and (xxxxH) hex. Thanks
  31. ;      to Ben Bronson for the idea. (Tim Nicholas)
  32. ;
  33. ;02/15/81 Added a software timer to the carrier test
  34. ;      added in SEND and RECV routines. This will
  35. ;      now abort only if carrier is lost for a 
  36. ;      period of 15 seconds. This is only essential
  37. ;      for those using external modems with certain
  38. ;      SIO's, but will provide the PMMI/DCH user
  39. ;      faster recovery in a lost carrier situation
  40. ;      as well. Approx 15 seconds plus 15 seconds
  41. ;      in BYE.COM, compared to 3 minutes at 300
  42. ;      baud with earlier revisions. Thanks to Ben
  43. ;      Bronson for his aid in developing this
  44. ;      revision. (Tim Nicholas)
  45. ;
  46. ;02/14/81 Corrected error in last update which read
  47. ;      the incorrect port for PMMI in the added
  48. ;      carrier test. (Tim Nicholas)
  49. ;    
  50. ;01/31/81 Added equates and code for a carrier test.
  51. ;      Test performed in modem I/O routines. This
  52. ;      is required since loss of carrier will go
  53. ;      undetected by BYE.COM, if the loss occurs
  54. ;      after a sucessful XMODEM signon, when using
  55. ;      an external modem and SIO. (Tim Nicholas)
  56. ;
  57. ;01/17/81 Re-wrote routine to calculate file size so
  58. ;         that it works correctly on v2.X systems with
  59. ;         extent folding (non-zero extent mask). (BRR)
  60. ;
  61. ;12/06/80 Re-wrote routine to calculate file size,
  62. ;      added decimal print of file size. (KBP)
  63. ;
  64. ;12/05/80 Corrected error in use of ext byte that pre-
  65. ;      vented files greater than one extent from 
  66. ;      being sent.     Ron Fowler
  67. ;
  68. ;12/03/80 Corrected file extent length display. Now
  69. ;      reports correct number of records for files
  70. ;      longer than one extent. Display is now
  71. ;      double precision (xxxxH). Also made some
  72. ;      cosmetic changes by re-arranging the equates.
  73. ;      By Tim Nicholas
  74. ;
  75. ;10/28/80 Cleaned up file. (KBP)
  76. ;
  77. ;10/23/80 Expanded conditional assembly of NOCOM routines
  78. ;      into NOCOMS, NOLBS, and NOCOMR equates, to allow
  79. ;      separate conditional assembly of tests for sending
  80. ;      .COM files, sending .??# files, and receiving .COM
  81. ;      files, respectively.    (Dave Hardy)
  82. ;
  83. ;10/15/80 Added traps for ambiguous file name or
  84. ;      none at all. (KBP)
  85. ;
  86. ;09/09/80 Added conditional assembly to prevent filetypes
  87. ;      '.COM' or '.??#' from being sent to distant end
  88. ;      and added conditional assembly of test for '.COM'
  89. ;      filetype on receive as well. See 'NOCOM' below.
  90. ;      Any filetype ending in '#' will not be sent by
  91. ;      this program if 'NOCOM' is set to TRUE.  J.SEYMOUR
  92. ;
  93. ;NOTE: If you add improvements or otherwise update
  94. ;this program, please modem a copy of the new file
  95. ;to "TECHNICAL CBBS" in Dearborn, Michigan - phone
  96. ;313-846-6127 (110, 300, 450 or 600 baud).  Use the
  97. ;filename XMODEM.NEW.    (KBP)
  98. ;
  99. FALSE    EQU    0
  100. TRUE    EQU    NOT FALSE
  101. ;
  102. ;-----------------------------------------------------
  103. ;     --- Conditional Assembly Options ---          ;
  104. ;------------------------------------------------------
  105. ;
  106. STDCPM    EQU    TRUE    ;TRUE, IS STANDARD CP/M
  107. ALTCPM    EQU    FALSE    ;TRUE, IS H8 OR TRS-80 CP/M
  108. ;
  109. PMMI    EQU    TRUE     ;TRUE, IS PMMI
  110. DCH    EQU    FALSE    ;TRUE, IS D.C. HAYES
  111. ;
  112. NOCOMS    EQU    FALSE    ;TRUE, NO .COM FILES SENT
  113. NOLBS    EQU    TRUE    ;TRUE, NO .??# FILES SENT
  114. NOCOMR    EQU    TRUE    ;TRUE, NO .COM FILES RECEIVED
  115. ;
  116. FASTCLK EQU    FALSE    ;PUT TRUE HERE FOR 4 MHZ CLOCK
  117. ;
  118. ;------------------------------------------------------
  119. ;         --- Modem Port Equates ---           ;
  120. ;------------------------------------------------------
  121. ;
  122.     IF    PMMI
  123. MODCTLP EQU    0C0H    ;PMMI VALUES
  124. MODSNDB EQU    1    ;BIT TO TEST FOR SEND
  125. MODSNDR EQU    1    ;VALUE WHEN READY
  126. MODRCVB EQU    2    ;BIT TO TEST FOR RECEIVE
  127. MODRCVR EQU    2    ;VALUE WHEN READY
  128. MODDCDB    EQU    4    ;CARRIER DETECT BIT
  129. MODDCDA    EQU    0    ;VALUE WHEN ACTIVE
  130. MODDATP EQU    0C1H    ;DATA PORT
  131. BAUDRP    EQU    0C2H    ;BAUD RATE OUTPUT/MODEM STATUS
  132. MODCTL2 EQU    0C3H    ;SECOND CTL PORT
  133.     ENDIF
  134. ;
  135.     IF    DCH
  136. MODCTLP EQU    82H    ;D. C. HAYES VALUES
  137. MODSNDB EQU    2    ;BIT TO TEST FOR SEND
  138. MODSNDR EQU    2    ;VALUE WHEN READY
  139. MODRCVB EQU    1    ;BIT TO TEST FOR RECEIVE
  140. MODRCVR EQU    1    ;VALUE WHEN READY
  141. MODDCDB    EQU    40H    ;CARRIER DETECT BIT
  142. MODDCDA    EQU    40H    ;VALUE WHEN ACTIVE
  143. MODDATP EQU    80H    ;DATA PORT
  144. MODCTL2 EQU    81H    ;SECOND CTL PORT
  145.     ENDIF
  146. ;
  147. ;---> NOTE: DCD (Carrier Detect) values above are for
  148. ;        the Micromodem 100. For DC-Hayes 80-103
  149. ;        the values are different.
  150. ;        MODDCDB  EQU  1  ;Carrier bit (CTS).
  151. ;        MODDCDA  EQU  1  ;Active value.
  152. ;
  153. ;
  154. ;
  155. ;If you are using an external modem (not S-100 plug-in)
  156. ;change these equates for your modem port requirements
  157. ;
  158.     IF    NOT PMMI AND NOT DCH
  159. MODCTLP EQU    35H    ;PUT YOUR MODEM STATUS PORT HERE
  160. MODSNDB EQU    01H    ;YOUR BIT TO TEST FOR SEND
  161. MODSNDR EQU    01H    ;YOUR VALUE WHEN READY
  162. MODRCVB EQU    02H    ;YOUR BIT TO TEST FOR RECEIVE
  163. MODRCVR EQU    02H    ;YOUR VALUE WHEN READY
  164. MODDCDB    EQU    1    ;CARRIER DETECT BIT
  165. MODDCDA    EQU    1    ;VALUE WHEN ACTIVE
  166. MODDATP EQU    34H    ;YOUR MODEM DATA PORT
  167. MODCTL2    EQU    36H    ;SECOND CONTROL/STATUS PORT.
  168.     ENDIF        ;END OF EXTERNAL MODEM EQUATES
  169. ;
  170. ;        --- End of Options ---
  171. ;------------------------------------------------------
  172. ;
  173. ;
  174. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS (10 STANDARD)
  175. ;
  176. ;Define ASCII characters used
  177. ;
  178. SOH    EQU    1    ;START OF HEADER
  179. EOT    EQU    4    ;END OF TRANSMISSION
  180. ACK    EQU    6    ;ACKNOWLEDGE
  181. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  182. CAN    EQU    18H    ;CONTROL-X FOR CANCEL
  183. LF    EQU    10    ;LINEFEED
  184. CR    EQU    13    ;CARRIAGE RETURN
  185. ; 
  186.     IF    STDCPM
  187. BASE    EQU    0    ;CP/M BASE ADDRESS
  188.     ENDIF
  189. ;
  190.     IF    ALTCPM
  191. BASE    EQU    4200H    ;ALTERNATE CP/M BASE ADDRESS
  192.     ENDIF
  193. ;
  194.     ORG    BASE+100H
  195. ;
  196. ;Init private stack
  197.     LXI    H,0    ;HL=0
  198.     DAD    SP    ;HL=STACK FROM CP/M
  199.     SHLD    STACK    ;..SAVE IT
  200.     LXI    SP,STACK ;SP=MY STACK
  201.     CALL    ILPRT    ;PRINT:
  202.     DB    CR,LF
  203.     DB    'XMODEM ver 4.1',CR,LF,0
  204. ;
  205. ;Get option
  206. ;
  207.     LDA    FCB+1    ;GET OPTION (S or R)
  208.     PUSH    PSW    ;SAVE OPTION
  209. ;
  210. ;Move the filename from FCB2 to FCB1
  211. ;
  212.     CALL    MOVEFCB
  213. ;
  214. ;Gobble up garbage chars from the line
  215. ;prior to receive or send
  216. ;
  217.     IN    MODDATP
  218.     IN    MODDATP
  219. ;
  220. ;Jump to appropriate function
  221. ;
  222.     POP    PSW    ;GET OPTION
  223. ;
  224.     CPI    'S'    ;SEND..
  225.     JZ    SENDFIL ;..A FILE?
  226. ;
  227.     CPI    'R'    ;RECEIVE..
  228.     JZ    RCVFIL    ;..A FILE?
  229. ;
  230. ;Invalid option
  231. ;
  232.     CALL    ERXIT    ;EXIT W/ERROR
  233.     DB    '++INVALID OPTION ON XMODEM '
  234.     DB    'COMMAND++',CR,LF
  235.     DB    'Must be S for SEND or R for '
  236.     DB    'RECEIVE',CR,LF,'$'
  237. ;
  238. * * * * * * * * * * * * * * * * * * * * *
  239. *                    *
  240. *    SENDFIL: SENDS A CP/M FILE    *
  241. *                    *
  242. * * * * * * * * * * * * * * * * * * * * *
  243. ;
  244. ;The CP/M file specified in the XMODEM command
  245. ;is transferred over the phone to another
  246. ;computer running MODEM with the "R" (receive)
  247. ;option.  The data is sent one sector at a
  248. ;time with headers and checksums, and re-
  249. ;transmission on errors.  
  250. ;
  251. SENDFIL CALL    TRAP    ;CHECK FOR NO NAME OR AMBIG. NAME
  252.     CALL    CNREC    ;COMPUTE # OF RECORDS.
  253.     CALL    OPENFIL ;OPEN THE FILE
  254.     MVI    E,80    ;WAIT 80 SEC..
  255.     CALL    WAITNAK ;..FOR INITIAL NAK
  256. ;
  257. SENDLP    CALL    RDSECT    ;READ A SECTOR
  258.     JC    SENDEOF ;SEND EOF IF DONE
  259.     CALL    INCRSNO ;BUMP SECTOR #
  260.     XRA    A    ;ZERO ERROR..
  261.     STA    ERRCT    ;..COUNT
  262. ;
  263. SENDRPT CALL    SENDHDR ;SEND A HEADER
  264.     CALL    SENDSEC ;SEND DATA SECTOR
  265.     CALL    SENDCKS ;SEND CKSUM
  266.     CALL    GETACK    ;GET THE ACK
  267.     JC    SENDRPT ;REPEAT IF NO ACK
  268.     JMP    SENDLP    ;LOOP UNTIL EOF
  269. ;
  270. ;File sent, send EOT's
  271. ;
  272. SENDEOF MVI    A,EOT    ;SEND..
  273.     CALL    SEND    ;..AN EOT
  274.     CALL    GETACK    ;GET THE ACK
  275.     JC    SENDEOF ;LOOP IF NO ACK
  276.     JMP    EXIT    ;ALL DONE
  277. ;
  278. * * * * * * * * * * * * * * * * * * * * *
  279. *                    *
  280. *    RCVFIL: RECEIVE A FILE        *
  281. *                    *
  282. * * * * * * * * * * * * * * * * * * * * *
  283. ;
  284. ;Receives a file in block format as sent
  285. ;by another person doing "MODEM S FN.FT".
  286. ;
  287. RCVFIL    CALL    TRAP    ;CHECK FOR NO NAME OR AMBIG. NAME
  288. ;
  289.     IF    NOCOMR
  290.     LXI    H,FCB+9 ;POINT TO FILETYPE
  291.     MVI    A,'C'    ;1ST LETTER
  292.     CMP    M    ;IS IT C ?
  293.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  294.     INX    H    ;GET 2ND LETTER
  295.     MVI    A,'O'    ;2ND LETTER
  296.     CMP    M    ;IS IT O ?
  297.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  298.     INX    H    ;GET 3RD LETTER
  299.     MVI    A,'M'    ;3RD LETTER
  300.     CMP    M    ;IS IT M ?
  301.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  302.     CALL    ERXIT    ;EXIT, PRINT ERROR MESSAGE
  303.     DB    '++CAN''T RECEIVE A .COM FILE++'
  304.     DB    CR,LF,CR,LF
  305.     DB    'Rename filetype ".OBJ" and try again'
  306.     DB    CR,LF,'$'
  307.     ENDIF
  308. ;
  309. CONTINU CALL    CHEKFIL ;SEE IF FILE EXISTS
  310.     CALL    MAKEFIL ;..THEN MAKE NEW
  311.     CALL    ILPRT    ;PRINT:
  312.     DB    'FILE OPEN - READY TO RECEIVE',CR,LF,0
  313. ;
  314. RCVLP    CALL    RCVSECT ;GET A SECTOR
  315.     JC    RCVEOT    ;GOT EOT
  316.     CALL    WRSECT    ;WRITE THE SECTOR
  317.     CALL    INCRSNO ;BUMP SECTOR #
  318.     CALL    SENDACK ;ACK THE SECTOR
  319.     JMP    RCVLP    ;LOOP UNTIL EOF
  320. ;
  321. ;Got EOT on sector - flush buffers, end
  322. ;
  323. RCVEOT    CALL    WRBLOCK ;WRITE THE LAST BLOCK
  324.     CALL    SENDACK ;ACK THE SECTOR
  325.     CALL    CLOSFIL ;CLOSE THE FILE
  326.     JMP    EXIT    ;ALL DONE
  327. ;
  328. * * * * * * * * * * * * * * * * * * * * *
  329. *                    *
  330. *        SUBROUTINES        *
  331. *                    *
  332. * * * * * * * * * * * * * * * * * * * * *
  333. ;
  334. ;---->    TRAP: Check for no file name or ambiguous name
  335. ;
  336. TRAP    LXI    H,FCB+1 ;POINT TO FILE NAME
  337.     MOV    A,M    ;GET FIRST CHAR OF FILE NAME
  338.     CPI    ' '    ;ANY THERE?
  339.     JNZ    ATRAP    ;YES, CHECK FOR AMBIGOUS FILE NAME
  340.     CALL    ERXIT    ;PRINT MSG, EXIT
  341.     DB    '++NO FILE NAME SPECIFIED++',CR,LF,'$'
  342. ;
  343. ATRAP    MVI    B,11    ;11 CHARS TO CHECK
  344. ;
  345. TRLOOP    MOV    A,M    ;GET CHAR FROM FCB
  346.     CPI    '?'    ;AMBIGUOUS?
  347.     JZ    TRERR    ;YES, EXIT WITH ERROR MSG
  348.     INX    H    ;POINT TO NEXT CHAR
  349.     DCR    B    ;ONE LESS TO GO
  350.     JNZ    TRLOOP    ;NOT DONE, CHECK SOME MORE
  351.     RET        ;NO AMBIGUOUS NAME, RETURN
  352. ;
  353. TRERR    CALL    ERXIT    ;PRINT MSG, EXIT
  354.     DB    '++CAN''T USE WILD CARD OPTIONS',CR,LF,'$'
  355. ;
  356. ;---->    RCVSECT: Receive a sector
  357. ;
  358. ;Returns with carry set if EOT received.
  359. ;
  360. RCVSECT XRA    A    ;GET 0
  361.     STA    ERRCT    ;INIT ERROR COUNT
  362. ;
  363. RCVRPT    MVI    B,10    ;10 SEC TIMEOUT
  364.     CALL    RECV    ;GET SOH/EOT
  365.     JC    RCVSTOT ;TIMEOUT
  366.     CPI    SOH    ;GET SOH?
  367.     JZ    RCVSOH    ;..YES
  368. ;
  369. ;Earlier versions of MODEM program send some nulls -
  370. ;ignore them
  371. ;
  372.     ORA    A    ;00 FROM SPEED CHECK?
  373.     JZ    RCVRPT    ;YES, IGNORE IT
  374.     CPI    EOT    ;END OF TRANSFER?
  375.     STC        ;RETURN WITH CARRY..
  376.     RZ        ;..SET IF EOT
  377. ;
  378. ;Didn't get SOH or EOT - 
  379. ;    -or-
  380. ;Did'nt get valid header - purge the line,
  381. ;then send NAK.
  382. ;
  383. RCVSERR MVI    B,1    ;WAIT FOR 1 SEC..
  384.     CALL    RECV    ;..WITH NO CHARS
  385.     JNC    RCVSERR ;LOOP UNTIL SENDER DONE
  386.     MVI    A,NAK    ;SEND..
  387.     CALL    SEND    ;..THE NAK
  388.     LDA    ERRCT    ;ABORT IF..
  389.     INR    A    ;..WE HAVE REACHED..
  390.     STA    ERRCT    ;..THE ERROR..
  391.     CPI    ERRLIM    ;..LIMIT?
  392.     JC    RCVRPT    ;..NO, TRY AGAIN
  393. ;
  394. ;10 errors in a row -
  395. ;
  396. RCVSABT CALL    CLOSFIL ;KEEP WHATEVER WE GOT
  397.     CALL    ERXIT
  398.     DB    '++UNABLE TO RECEIVE BLOCK '
  399.     DB    '- ABORTING++',CR,LF,'$'
  400. ;
  401. ;Timed out on receive
  402. ;
  403. RCVSTOT JMP    RCVSERR ;BUMP ERR CT, ETC.
  404. ;
  405. ;Got SOH - get block #, block # complemented
  406. ;
  407. RCVSOH    MVI    B,1    ;TIMEOUT = 1 SEC
  408.     CALL    RECV    ;GET SECTOR
  409.     JC    RCVSTOT ;GOT TIMEOUT
  410.     MOV    D,A    ;D=BLK #
  411.     MVI    B,1    ;TIMEOUT = 1 SEC
  412.     CALL    RECV    ;GET CMA'D SECT #
  413.     JC    RCVSTOT ;TIMEOUT
  414.     CMA        ;CALC COMPLEMENT
  415.     CMP    D    ;GOOD SECTOR #?
  416.     JZ    RCVDATA ;YES, GET DATA
  417. ;
  418. ;Got bad sector #
  419. ;
  420.     JMP    RCVSERR ;BUMP ERROR CT.
  421. ;
  422. RCVDATA MOV    A,D    ;GET SECTOR #
  423.     STA    RCVSNO    ;SAVE IT
  424.     MVI    C,0    ;INIT CKSUM
  425.     LXI    H,BASE+80H ;POINT TO BUFFER
  426. ;
  427. RCVCHR    MVI    B,1    ;1 SEC TIMEOUT
  428.     CALL    RECV    ;GET CHAR
  429.     JC    RCVSTOT ;TIMEOUT
  430.     MOV    M,A    ;STORE CHAR
  431.     INR    L    ;DONE?
  432.     JNZ    RCVCHR    ;NO, LOOP
  433. ;
  434. ;Verify checksum
  435. ;
  436.     MOV    D,C    ;SAVE CHECKSUM
  437.     MVI    B,1    ;TIMEOUT LEN.
  438.     CALL    RECV    ;GET CHECKSUM
  439.     JC    RCVSTOT ;TIMEOUT
  440.     CMP    D    ;CHECKSUM OK?
  441.     JNZ    RCVSERR ;NO, ERROR
  442. ;
  443. ;Got a sector, it's a duplicate if = previous,
  444. ;    or OK if = 1 + previous sector
  445. ;
  446.     LDA    RCVSNO    ;GET RECEIVED
  447.     MOV    B,A    ;SAVE IT
  448.     LDA    SECTNO    ;GET PREV
  449.     CMP    B    ;PREV REPEATED?
  450.     JZ    RECVACK ;ACK TO CATCH UP
  451.     INR    A    ;CALC NEXT SECTOR #
  452.     CMP    B    ;MATCH?
  453.     JNZ    ABORT    ;NO MATCH - STOP SENDER, EXIT
  454.     RET        ;CARRY OFF - NO ERRORS
  455. ;
  456. ;Previous sector repeated, due to the last ACK
  457. ;being garbaged.  ACK it so sender will catch up 
  458. ;
  459. RECVACK CALL    SENDACK ;SEND THE ACK,
  460.     JMP    RCVSECT ;GET NEXT BLOCK
  461. ;
  462. ;Send an ACK for the sector
  463. ;
  464. SENDACK MVI    A,ACK    ;GET ACK
  465.     CALL    SEND    ;..AND SEND IT
  466.     RET
  467. ;
  468. ;---->    SENDHDR: Send the sector header
  469. ;
  470. ;SEND: (SOH) (block #) (complemented block #)
  471. ;
  472. SENDHDR MVI    A,SOH    ;SEND..
  473.     CALL    SEND    ;..SOH,
  474.     LDA    SECTNO    ;THEN SEND..
  475.     CALL    SEND    ;..SECTOR #
  476.     LDA    SECTNO    ;THEN SECTOR #
  477.     CMA        ;..COMPLEMENTED..
  478.     CALL    SEND    ;..SECTOR #
  479.     RET        ;FROM SENDHDR
  480. ;
  481. ;---->    SENDSEC: Send the data sector
  482. ;
  483. SENDSEC MVI    C,0    ;INIT CKSUM
  484.     LXI    H,BASE+80H ;POINT TO BUFFER
  485. SENDC    MOV    A,M    ;GET A CHAR
  486.     CALL    SEND    ;SEND IT
  487.     INR    L    ;POINT TO NEXT CHAR
  488.     JNZ    SENDC    ;LOOP IF <100H
  489.     RET        ;FROM SENDSEC
  490. ;
  491. ;---->    SENDCKS: Send the checksum
  492. ;
  493. SENDCKS MOV    A,C    ;SEND THE..
  494.     CALL    SEND    ;..CHECKSUM
  495.     RET        ;FROM SENDCKS
  496. ;
  497. ;---->    GETACK: Get the ACK on the sector
  498. ;
  499. ;Returns with carry clear if ACK received.
  500. ;If an ACK is not received, the error count
  501. ;is incremented, and if less than "ERRLIM",
  502. ;carry is set and control returns.  If the
  503. ;error count is at "ERRLIM", the program
  504. ;aborts.
  505. ;
  506. GETACK    MVI    B,10    ;WAIT 10 SECONDS MAX
  507.     CALL    RECVDG    ;RECV W/GARBAGE COLLECT
  508.     JC    GETATOT ;TIMED OUT
  509.     CPI    ACK    ;OK? (CARRY OFF IF =)
  510.     RZ        ;YES, RET FROM GETACK
  511. ;
  512. ;Timeout or error on ACK - bump error count
  513. ;
  514. ACKERR    LDA    ERRCT    ;GET COUNT
  515.     INR    A    ;BUMP IT
  516.     STA    ERRCT    ;SAVE BACK
  517.     CPI    ERRLIM    ;AT LIMIT?
  518.     RC        ;NOT AT LIMIT
  519. ;
  520. ;Reached error limit
  521. ;
  522. CSABORT CALL    ERXIT
  523.     DB    '++CAN''T SEND SECTOR '
  524.     DB    '- ABORTING++',CR,LF,'$'
  525. ;
  526. ;Timeout getting ACK
  527. ;
  528. GETATOT JMP    ACKERR    ;NO MSG
  529. ; 
  530. ABORT    LXI    SP,STACK
  531. ;
  532. ABORTL    MVI    B,1    ;1 SEC. W/O CHARS.
  533.     CALL    RECV
  534.     JNC    ABORTL    ;LOOP UNTIL SENDER DONE
  535.     MVI    A,CAN    ;CONTROL X
  536.     CALL    SEND    ;STOP SENDING END
  537. ;
  538. ABORTW    MVI    B,1    ;1 SEC W/O CHARS.
  539.     CALL    RECV
  540.     JNC    ABORTW    ;LOOP UNTIL SENDER DONE
  541.     MVI    A,' '    ;GET A SPACE...
  542.     CALL    SEND    ;TO CLEAR OUT CONTROL X
  543.     CALL    ERXIT    ;EXIT WITH ABORT MSG
  544.     DB    'XMODEM PROGRAM CANCELLED',CR,LF,'$'
  545. ;
  546. ;---->    INCRSNO: Increment sector #
  547. ;
  548. INCRSNO LDA    SECTNO    ;INCR..
  549.     INR    A    ;..SECT..
  550.     STA    SECTNO    ;..NUMBER
  551.     RET
  552. ;
  553. ;---->    CHEKFIL: See if file exists
  554. ;
  555. ;If it exists, say use a different name.
  556. ;
  557. CHEKFIL LXI    D,FCB    ;POINT TO CTL BLOCK
  558.     MVI    C,SRCHF ;SEE IF IT..
  559.     CALL    BDOS    ;..EXISTS
  560.     INR    A    ;FOUND?
  561.     RZ        ;..NO, RETURN
  562.     CALL    ERXIT    ;EXIT, PRINT ERROR MESSAGE
  563.     DB    '++FILE EXISTS - USE A DIFFERENT NAME++'
  564.     DB    CR,LF,'$'
  565. ;
  566. ;---->    MAKEFIL: Makes the file to be received
  567. ;
  568. MAKEFIL    XRA    A    ;SET EXT & REC # TO 0
  569.     STA    FCBEXT
  570.     STA    FCBSNO
  571.     LXI    D,FCB    ;POINT TO FCB
  572.     MVI    C,MAKE    ;GET BDOS FNC
  573.     CALL    BDOS    ;TO THE MAKE
  574.     INR    A    ;FF=BAD?
  575.     RNZ        ;OPEN OK
  576. ;Directory full - can't make file
  577.     CALL    ERXIT
  578.     DB    '++ERROR - CAN''T MAKE FILE++',CR,LF
  579.     DB    'Directory must be full',CR,LF,'$'
  580. ;
  581. ;---->    CNREC: Computes record count, and saves it
  582. ;           until successful file OPEN.
  583. ;
  584. ;LOOK UP THE FCB IN THE DIRECTORY
  585. CNREC    MVI    A,'?'    ;MATCH ALL EXTENTS
  586.     STA    FCBEXT
  587.     MVI    A,0FFH
  588.     STA    MAXEXT    ;INIT MAX EXT NO.
  589.     MVI    C,SRCHF ;GET 'SEARCH FIRST' FNC
  590.     LXI    D,FCB
  591.     CALL    BDOS    ;READ FIRST
  592.     INR    A    ;WERE THERE ANY?
  593.     JNZ    SOME    ;GOT SOME
  594.     CALL    ERXIT
  595.     DB    '++FILE NOT FOUND++$'
  596. ;
  597. ;READ MORE DIRECTORY ENTRIES
  598. MOREDIR    MVI    C,SRCHN ;SEARCH NEXT
  599.     LXI    D,FCB
  600.     CALL    BDOS    ;READ DIR ENTRY
  601.     INR    A    ;CHECK FOR END (0FFH)
  602.     JNZ    SOME    ;NOT END OF DIR...PROCESS EXTENT
  603.     LDA    MAXEXT    ;HIT END...GET HIGHEST EXTENT NO. SEEN
  604.     MOV    L,A    ;WHICH GIVES EXTENT COUNT - 1
  605.     MVI    H,0
  606.     MOV    D,H
  607.     LDA    RCNT    ;GET RECORD COUNT OF MAX EXTENT SEEN
  608.     MOV    E,A    ;SAVE IT IN DE
  609.     DAD    H
  610.     DAD    H    ;MULTIPLY # OF EXTENTS - 1
  611.     DAD    H    ; TIMES 128
  612.     DAD    H
  613.     DAD    H
  614.     DAD    H
  615.     DAD    H
  616.     DAD    D    ;ADD IN SIZE OF LAST EXTENT
  617.     SHLD    RCNT    ;SAVE TOTAL RECORD COUNT
  618.     RET        ;AND EXIT
  619. ;
  620. ;POINT TO DIRECTORY ENTRY 
  621. SOME    DCR    A    ;UNDO PREV 'INR A'
  622.     ANI    3    ;MAKE MODULUS 4
  623.     ADD    A    ;MULTIPLY...
  624.     ADD    A    ;..BY 32 BECAUSE
  625.     ADD    A    ;..EACH DIRECTORY
  626.     ADD    A    ;..ENTRY IS 32
  627.     ADD    A    ;..BYTES LONG
  628.     LXI    H,BASE+80H ;POINT TO BUFFER
  629.     ADD    L    ;POINT TO ENTRY
  630.     ADI    15    ;OFFSET TO RECORD COUNT
  631.     MOV    L,A    ;HL NOW POINTS TO REC COUNT
  632.     MOV    B,M    ;GET RECORD COUNT
  633.     DCX    H
  634.     DCX    H    ;BACK DOWN TO EXTENT NUMBER
  635.     DCX    H
  636.     LDA    MAXEXT    ;COMPARE WITH CURRENT MAX.
  637.     ORA    A    ;IF NO MAX YET
  638.     JM    BIGGER    ;THEN SAVE RECORD COUNT ANYWAY
  639.     CMP    M
  640.     JNC    MOREDIR
  641. BIGGER:    MOV    A,B    ;SAVE NEW RECORD COUNT
  642.     STA    RCNT
  643.     MOV    A,M    ;SAVE NEW MAX. EXTENT NO.
  644.     STA    MAXEXT
  645.     JMP    MOREDIR    ;GO FIND MORE EXTENTS
  646. ;
  647. ;---->    OPENFIL: Opens the file to be sent
  648. ;
  649. OPENFIL    XRA    A    ;SET EXT & REC # TO 0 FOR PROPER OPEN
  650.     STA    FCBEXT
  651.     STA    FCBSNO
  652.     LXI    D,FCB    ;POINT TO FILE
  653.     MVI    C,OPEN    ;GET FUNCTION
  654.     CALL    BDOS    ;OPEN IT
  655.     INR    A    ;OPEN OK?
  656.     JNZ    OPENOK    ;..YES
  657.     CALL    ERXIT    ;..NO, ABORT
  658.     DB    '++OPEN ERROR++',CR,LF,'$'
  659. ;
  660. ;Check for distribution-protected file
  661. ;
  662. OPENOK    LDA    FCB+1    ;FIRST CHAR OF FILE NAME
  663.     ANI    80H    ;CHECK BIT 7
  664.     JNZ    OPENOT    ;If on, file can't be sent.
  665.     LDA    FCB+2    ;Also check "f2" for tag.
  666.     ANI    80H    ;Is it set?
  667.     JZ    OPENOK2    ;If not, ok to send file.
  668. ;
  669. OPENOT    CALL    ERXIT    ;EXIT W/MESSAGE
  670.     DB    '++THIS FILE IS NOT FOR DISTRIBUTION, SORRY++'
  671.     DB    CR,LF,'$'
  672. ;
  673. OPENOK2 EQU    $
  674. ;
  675.     IF    NOLBS OR NOCOMS ;CHECK FOR SEND RESTRICTIONS
  676.     LXI    H,FCB+11
  677.     MOV    A,M    ;CHECK FOR PROTECT ATTR
  678.     ANI    7FH    ;REMOVE CP/M 2.x ATTRS
  679.     ENDIF        ;NOLBS OR NOCOMS
  680. ;
  681.     IF    NOLBS    ;DON'T ALLOW '#' TO BE SENT.
  682.     CPI    '#'    ;CHK FOR '#' AS LAST FIRST
  683.     JZ    OPENOT    ;IF '#', CAN'T SEND, SHOW WHY
  684.     ENDIF        ;NOLBS
  685. ;
  686.     IF    NOCOMS    ;DON'T ALLOW .COM TO BE SENT
  687.     CPI    'M'    ;IF NOT, CHK FOR '.COM'
  688.     JNZ    OPENOK3 ;IF NOT, OK TO SEND
  689.     DCX    H
  690.     MOV    A,M    ;CHK NEXT CHAR
  691.     ANI    7FH    ;STRIP ATTRIBUTES
  692.     CPI    'O'    ; 'O'?
  693.     JNZ    OPENOK3 ;IF NOT, OK TO SEND
  694.     DCX    H
  695.     MOV    A,M    ;NOW CHK FIRST CHAR
  696.     ANI    7FH    ;STRIP ATTRIBUTES
  697.     CPI    'C'    ; 'C' AS IN '.COM'?
  698.     JNZ    OPENOK3 ;IF NOT, CONTINUE
  699.     CALL    ERXIT    ;EXIT W/MESSAGE
  700.     DB    '++CAN''T SEND A .COM FILE++'
  701.     DB    CR,LF,'$'
  702.     ENDIF        ;NOCOMS
  703. ;
  704. OPENOK3 CALL    ILPRT    ;PRINT:
  705.     DB    'FILE OPEN - SIZE: ',0
  706.     LHLD    RCNT    ; Get record count.
  707.     CALL    DECOUT    ;PRINT DECIMAL NUMBER OF SECTORS
  708.     CALL    ILPRT    ;Print:
  709.     DB    ' (',0
  710.     CALL    DHXOUT    ;Now print size in hex.
  711.     CALL    ILPRT    ;PRINT:
  712.     DB    'H) SECTORS',CR,LF,0
  713.     RET
  714. ;
  715. ;---->    CLOSFIL: Closes the received file
  716. ;
  717. CLOSFIL LXI    D,FCB    ;POINT TO FILE
  718.     MVI    C,CLOSE ;GET FUNCTION
  719.     CALL    BDOS    ;CLOSE IT
  720.     INR    A    ;CLOSE OK?
  721.     RNZ        ;..YES, RETURN
  722.     CALL    ERXIT    ;..NO, ABORT
  723.     DB    '++CAN''T CLOSE FILE++',CR,LF,'$'
  724. ;
  725. ;
  726. ;----> DECOUT: Decimal output routine
  727. ;
  728. DECOUT:    PUSH    B
  729.     PUSH    D
  730.     PUSH    H
  731.     LXI    B,-10
  732.     LXI    D,-1
  733. ;
  734. DECOU2:    DAD    B
  735.     INX    D
  736.     JC    DECOU2
  737.     LXI    B,10
  738.     DAD    B
  739.     XCHG
  740.     MOV    A,H
  741.     ORA    L
  742.     CNZ    DECOUT
  743.     MOV    A,E
  744.     ADI    '0'
  745.     CALL    CTYPE
  746.     POP    H
  747.     POP    D
  748.     POP    B
  749.     RET
  750. ;
  751. ; DHXOUT - double precision hex output routine.
  752. ;       Call with hex value in HL.
  753. ;
  754. DHXOUT    PUSH    H    ;Save H,L
  755.     PUSH    PSW    ;Save A
  756.     MOV    A,H    ;Get MS byte.
  757.     CALL    HEXO    ;Output hi order byte.
  758.     MOV    A,L    ;Get LS byte.
  759.     CALL    HEXO    ;Output lo order byte.
  760.     POP    PSW    ;Restore A
  761.     POP    H    ;Restore H,L
  762.     RET        ;Return to caller.
  763. ;
  764. ;
  765. ;---->    RDSECT: Reads a sector
  766. ;
  767. ;For speed, this routine buffers up 16
  768. ;sectors at a time.
  769. ;
  770. RDSECT    LDA    SECINBF ;GET # SECT IN BUFF.
  771.     DCR    A    ;DECREMENT..
  772.     STA    SECINBF ;..IT
  773.     JM    RDBLOCK ;EXHAUSTED?  NEED MORE.
  774.     LHLD    SECPTR    ;GET POINTER
  775.     LXI    D,BASE+80H ;TO DATA
  776.     CALL    MOVE128 ;MOVE TO BUFFER
  777.     SHLD    SECPTR    ;SAVE BUFFER POINTER
  778.     RET        ;FROM "READSEC"
  779. ;
  780. ;Buffer is empty - read in another block of 16
  781. ;
  782. RDBLOCK LDA    EOFLG    ;GED EOF FLAG
  783.     CPI    1    ;IS IT SET?
  784.     STC        ;TO SHOW EOF
  785.     RZ        ;GOT EOF
  786.     MVI    C,0    ;SECTORS IN BLOCK
  787.     LXI    D,DBUF    ;TO DISK BUFFER
  788. ;
  789. RDSECLP PUSH    B
  790.     PUSH    D
  791.     MVI    C,STDMA ;SET DMA..
  792.     CALL    BDOS    ;..ADDR
  793.     LXI    D,FCB
  794.     MVI    C,READ
  795.     CALL    BDOS
  796.     POP    D
  797.     POP    B
  798.     ORA    A    ;READ OK?
  799.     JZ    RDSECOK ;YES
  800.     DCR    A    ;EOF?
  801.     JZ    REOF    ;GOT EOF
  802. ;
  803. ;Read error
  804. ;
  805.     CALL    ERXIT
  806.     DB    '++FILE READ ERROR++',CR,LF,'$'
  807. ;
  808. RDSECOK LXI    H,80H    ;ADD LENGTH OF ONE SECTOR...
  809.     DAD    D    ;...TO NEXT BUFF
  810.     XCHG        ;BUFF TO DE
  811.     INR    C    ;MORE SECTORS?
  812.     MOV    A,C    ;GET COUNT
  813.     CPI    16    ;DONE?
  814.     JZ    RDBFULL ;..YES, BUFF IS FULL
  815.     JMP    RDSECLP ;READ MORE
  816. ;
  817. REOF    MVI    A,1
  818.     STA    EOFLG    ;SET EOF FLAG
  819.     MOV    A,C
  820. ;
  821. ;Buffer is full, or got EOF
  822. ;
  823. RDBFULL STA    SECINBF ;STORE SECTOR COUNT
  824.     LXI    H,DBUF    ;INIT BUFFER..
  825.     SHLD    SECPTR    ;..POINTER
  826.     LXI    D,BASE+80H ;RESET..
  827.     MVI    C,STDMA ;..DMA..
  828.     CALL    BDOS    ;..ADDR
  829.     JMP    RDSECT    ;PASS SECT TO CALLER
  830. ;
  831. ;---->    WRSECT: Write a sector
  832. ;
  833. ;Writes the sector into a buffer.  When 16
  834. ;have been written, writes the block to disk.
  835. ;
  836. ;Entry point "WRBLOCK" flushes the buffer at EOF.
  837. ;
  838. WRSECT    LHLD    SECPTR    ;GET BUFF ADDR
  839.     XCHG        ;TO DE FOR MOVE
  840.     LXI    H,BASE+80H    ;FROM HERE
  841.     CALL    MOVE128 ;MOVE TO BUFFER
  842.     XCHG        ;SAVE NEXT..
  843.     SHLD    SECPTR    ;..BLOCK POINTER
  844.     LDA    SECINBF ;BUMP THE..
  845.     INR    A    ;..SECTOR #..
  846.     STA    SECINBF ;..IN THE BUFF
  847.     CPI    16    ;HAVE WE 16?
  848.     RNZ        ;NO, RETURN
  849. ;
  850. ;---->    WRBLOCK: Writes a block to disk
  851. ;
  852. WRBLOCK LDA    SECINBF ;# SECT IN BUFFER
  853.     ORA    A    ;0 MEANS END OF FILE
  854.     RZ        ;NONE TO WRITE
  855.     MOV    C,A    ;SAVE COUNT
  856.     LXI    D,DBUF    ;POINT TO DISK BUFF
  857. ;
  858. DKWRLP    PUSH    H
  859.     PUSH    D
  860.     PUSH    B
  861.     MVI    C,STDMA ;SET DMA
  862.     CALL    BDOS    ;TO BUFFER
  863.     LXI    D,FCB    ;THEN WRITE
  864.     MVI    C,WRITE ;..THE..
  865.     CALL    BDOS    ;..BLOCK
  866.     POP    B
  867.     POP    D
  868.     POP    H
  869.     ORA    A
  870.     JNZ    WRERR    ;OOPS, ERROR
  871.     LXI    H,80H    ;LENGTH OF 1 SECT
  872.     DAD    D    ;HL= NEXT BUFF
  873.     XCHG        ;TO DE FOR SETDMA
  874.     DCR    C    ;MORE SECTORS?
  875.     JNZ    DKWRLP    ;..YES, LOOP
  876.     XRA    A    ;GET A ZERO
  877.     STA    SECINBF ;RESET # OF SECTORS
  878.     LXI    H,DBUF    ;RESET BUFFER..
  879.     SHLD    SECPTR    ;..POINTER
  880. ;
  881. RSDMA    LXI    D,BASE+80H ;RESET..
  882.     MVI    C,STDMA ;..DMA..
  883.     CALL    BDOS    ;..ADDR
  884.     RET
  885. ;
  886. WRERR    CALL    RSDMA    ;RESET DMA TO NORM.
  887.     MVI    C,CAN    ;CANCEL..
  888.     CALL    SEND    ;..SENDER
  889.     CALL    ERXIT    ;EXIT W/MSG:
  890.     DB    '++ERROR WRITING FILE++',CR,LF,'$'
  891. ;
  892. ;---->    RECV: Receive a character
  893. ;
  894. ;Timeout time is in B, in seconds.  Entry via
  895. ;"RECVDG" deletes garbage characters on the
  896. ;line.    For example, having just sent a sector,
  897. ;calling RECVDG will delete any line-noise-induced
  898. ;characters "long" before the ACK/NAK would
  899. ;be received.
  900. ;
  901. RECVDG    EQU    $    ;RECEIVE W/GARBAGE DELETE
  902.     IN    MODDATP ;GET A CHAR
  903.     IN    MODDATP ;..TOTALLY PURGE UART
  904. ;
  905. RECV    PUSH    D    ;SAVE
  906. ;
  907.     IF    FASTCLK ;4MHZ?
  908.     MOV    A,B    ;GET TIME REQUEST
  909.     ADD    A    ;DOUBLE IT
  910.     MOV    B,A    ;NEW TIME IN B
  911.     ENDIF
  912. ;
  913. MSEC    LXI    D,50000 ;1 SEC DCR COUNT
  914. ;
  915.     IF    NOT DCH
  916. MWTI    IN    MODCTLP ;CHECK STATUS
  917.     ENDIF
  918. ;
  919.     IF    DCH
  920. MWTI    IN    MODCTL2 ;CHECK STATUS
  921.     ENDIF
  922. ;
  923.     ANI    MODRCVB ;ISOLATE BIT
  924.     CPI    MODRCVR ;READY?
  925.     JZ    MCHAR    ;GOT CHAR
  926.     DCR    E    ;COUNT..
  927.     JNZ    MWTI    ;..DOWN..
  928.     DCR    D    ;..FOR..
  929.     JNZ    MWTI    ;..TIMEOUT
  930.     DCR    B    ;MORE SECONDS?
  931.     JNZ    MSEC    ;YES, WAIT
  932. ;
  933. ;Test for the presence of carrier - if none, go to 
  934. ;CARCK and continue testing for 15 seconds. If carrier
  935. ;returns, continue. If is doesn't return, exit.
  936. ;
  937.     IF    NOT DCH AND NOT PMMI
  938.     IN    MODCTL2    ;Read modem status.
  939.     ENDIF
  940. ;
  941.     IF    DCH
  942.     IN    MODCTLP    ;Read modem status.
  943.     ENDIF
  944. ;
  945.     IF    PMMI
  946.     IN    BAUDRP    ;Read modem status.
  947.     ENDIF
  948. ;
  949.     ANI    MODDCDB    ;Carrier detect mask.
  950.     CPI    MODDCDA    ;Is it still on?
  951.     CNZ    CARCK    ;If not, test for 15 seconds.
  952. ;
  953. ;Modem timed out receiving - but carrier still on.
  954. ;
  955.     POP    D    ;RESTORE D,E
  956.     STC        ;CARRY SHOWS TIMEOUT
  957.     RET
  958. ;
  959. ;Got character from modem
  960. ;
  961. MCHAR    IN    MODDATP ;READ THE CHAR
  962.     POP    D    ;RESTORE DE
  963. ;
  964. ;Calc checksum
  965. ;
  966.     PUSH    PSW    ;SAVE THE CHAR
  967.     ADD    C    ;ADD TO CHECKSUM
  968.     MOV    C,A    ;SAVE CHECKSUM
  969.     POP    PSW    ;RESTORE CHAR
  970.     ORA    A    ;CARRY OFF: NO ERROR
  971.     RET        ;FROM "RECV"
  972. ;
  973. ; CARCK - common 15 second carrier test for RECV and
  974. ; SEND. If carrier returns within 15 seconds, normal
  975. ; program execution continues. Else, it will abort
  976. ; to CP/M via EXIT.
  977. ;
  978. CARCK    MVI    E,150    ;Value for 15 second delay.
  979. CARCK1    CALL    DELAY    ;Kill .1 seconds.
  980.     ;
  981.     IF    NOT DCH AND NOT PMMI
  982.     IN    MODCTL2    ;Read modem status.
  983.     ENDIF
  984. ;
  985.     IF    DCH
  986.     IN    MODCTLP    ;Read modem status.
  987.     ENDIF
  988. ;
  989.     IF    PMMI
  990.     IN    BAUDRP    ;Read modem status.
  991.     ENDIF
  992. ;
  993.     ANI    MODDCDB    ;Carrier detect mask.
  994.     CPI    MODDCDA    ;Is it still on?
  995.     RZ        ;Return if carrier on.
  996.     DCR    E    ;Has 15 seconds expired?
  997.     JNZ    CARCK1    ;If not, continue testing.
  998.     JMP    EXIT    ;Else, abort to CP/M.
  999. ;
  1000. ; DELAY - 100 millisecond delay.
  1001. ;
  1002. DELAY    PUSH    B    ;Save B,C
  1003. ;
  1004.     IF    FASTCLK    ;If 4mhz clock.
  1005.     LXI    B,16667    ;Value for 100 ms delay.
  1006.     ENDIF
  1007. ;
  1008.     IF    NOT FASTCLK
  1009.     LXI    B,8334    ;Value for 100ms delay.
  1010.     ENDIF
  1011. ;
  1012. DELAY2    DCX    B    ;Update count.
  1013.     MOV    A,B    ;Get MS byte.
  1014.     ORA    C    ;Count = zero?
  1015.     JNZ    DELAY2    ;If not, continue.
  1016.     POP    B    ;Restore B,C
  1017.     RET        ;Return to CARCK1.
  1018. ;
  1019. ;
  1020. ;
  1021. ;---->    SEND: Send a character to the modem
  1022. ;
  1023. SEND    PUSH    PSW    ;SAVE THE CHAR
  1024.     ADD    C    ;CALC CKSUM
  1025.     MOV    C,A    ;SAVE CKSUM
  1026. ;
  1027.     IF    NOT DCH
  1028. SENDW    IN    MODCTLP ;GET STATUS
  1029.     ENDIF
  1030. ;
  1031.     IF    DCH
  1032. SENDW    IN    MODCTL2 ;GET STATUS
  1033.     ENDIF
  1034. ;
  1035.     ANI    MODSNDB ;ISOLATE READY BIT
  1036.     CPI    MODSNDR ;READY?
  1037.     JZ    SENDR    ;..Yes, go send.
  1038. ;
  1039. ;Xmit status not ready, so test for carrier before
  1040. ;looping - if lost, go to CARCK and give it up to 15
  1041. ;seconds to return. If it doesn't return abort via
  1042. ;EXIT.
  1043. ;
  1044.     PUSH    D    ;Save D,E
  1045. ;
  1046.     IF    NOT DCH AND NOT PMMI
  1047.     IN    MODCTL2    ;Read modem status.
  1048.     ENDIF
  1049. ;
  1050.     IF    DCH
  1051.     IN    MODCTLP    ;Read modem status.
  1052.     ENDIF
  1053. ;
  1054.     IF    PMMI
  1055.     IN    BAUDRP    ;Read modem status.
  1056.     ENDIF
  1057. ;
  1058.     ANI    MODDCDB    ;Carrier detect mask.
  1059.     CPI    MODDCDA    ;Is it still on?
  1060.     CNZ    CARCK    ;If not, continue testing it.
  1061.     POP    D    ;Restore D,E
  1062.     JMP    SENDW    ;Else, wait for xmit ready.
  1063. ;
  1064. ;Xmit status ready, carrier still on - send the data.
  1065. ;
  1066. SENDR    POP    PSW    ;GET CHAR
  1067.     OUT    MODDATP ;OUTPUT IT
  1068.     RET        ;FROM "SEND"
  1069. ;
  1070. ;---->    WAITNAK: Waits for initial NAK
  1071. ;
  1072. ;To ensure no data is sent until the receiving
  1073. ;program is ready, this routine waits for the
  1074. ;first timeout-NAK from the receiver.
  1075. ;(E) contains the # of seconds to wait.
  1076. ;
  1077. WAITNAK MVI    B,1    ;TIMEOUT DELAY
  1078.     CALL    RECV    ;DID WE GET..
  1079.     CPI    NAK    ;..A NAK?
  1080.     RZ        ;YES, SEND BLOCK
  1081.     DCR    E    ;80 TRIES?
  1082.     JZ    ABORT    ;YES, ABORT
  1083.     JMP    WAITNAK ;NO, LOOP
  1084. ;
  1085. ;---->    MOVEFCB: Moves FCB(2) to FCB
  1086. ;
  1087. ;In order to make the XMODEM command 'natural',
  1088. ;i.e. XMODEM SEND FILENAME (MODEM S FN.FT) rather
  1089. ;than XMODEM FILENAME SEND (MODEM FN.FT S), this
  1090. ;routine moves the filename from the second FCB
  1091. ;to the first.
  1092. ;
  1093. MOVEFCB LXI    H,FCB+16 ;FROM
  1094.     LXI    D,FCB    ;TO
  1095.     MVI    B,16    ;LEN
  1096.     CALL    MOVE    ;DO THE MOVE
  1097.     XRA    A    ;GET 0
  1098.     STA    FCBSNO    ;ZERO SECTOR #
  1099.     STA    FCBEXT    ;..AND EXTENT
  1100.     RET
  1101. ;
  1102. CTYPE    PUSH    B    ;SAVE..
  1103.     PUSH    D    ;..ALL..
  1104.     PUSH    H    ;..REGS
  1105.     MOV    E,A    ;CHAR TO E
  1106.     MVI    C,WRCON ;GET BDOS FNC
  1107.     CALL    BDOS    ;PRIN THE CHR
  1108.     POP    H    ;RESTORE..
  1109.     POP    D    ;..ALL..
  1110.     POP    B    ;..REGS
  1111.     RET        ;FROM "CTYPE"
  1112. ;
  1113. HEXO    PUSH    PSW    ;SAVE FOR RIGHT DIGIT
  1114.     RAR        ;RIGHT..
  1115.     RAR        ;..JUSTIFY..
  1116.     RAR        ;..LEFT..
  1117.     RAR        ;..DIGIT..
  1118.     CALL    NIBBL    ;PRINT LEFT DIGIT
  1119.     POP    PSW    ;RESTORE RIGHT
  1120. ;
  1121. NIBBL    ANI    0FH    ;ISOLATE DIGIT
  1122.     CPI    10    ;IS IT <10?
  1123.     JC    ISNUM    ;YES, NOT ALPHA
  1124.     ADI    7    ;ADD ALPHA BIAS
  1125. ;
  1126. ISNUM    ADI    '0'    ;MAKE PRINTABLE
  1127.     JMP    CTYPE    ;..THEN TYPE IT
  1128. ;
  1129. ;---->    ILPRT: Inline print of message
  1130. ;
  1131. ;The call to ILPRT is followed by a message,
  1132. ;binary 0 as the end.
  1133. ;
  1134. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  1135. ;
  1136. ILPLP    MOV    A,M    ;GET CHAR
  1137.     ORA    A    ;END OF MSG?
  1138.     JZ    ILPRET    ;..YES, RETURN
  1139.     CALL    CTYPE    ;TYPE THE MSG
  1140.     INX    H    ;TO NEXT CHAR
  1141.     JMP    ILPLP    ;LOOP
  1142. ;
  1143. ILPRET    XTHL        ;RESTORE HL
  1144.     RET        ;PAST MSG
  1145. ;
  1146. ;---->    ERXIT: Exit printing message following call
  1147. ;
  1148. ERXIT    POP    D    ;GET MESSAGE
  1149.     MVI    C,PRINT ;GET BDOS FNC
  1150.     CALL    BDOS    ;PRINT MESSAGE
  1151. ;
  1152. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  1153.     SPHL        ;RESTORE IT
  1154.     RET        ;--EXIT-- TO CP/M
  1155. ;
  1156. ;Move 128 characters
  1157. ;
  1158. MOVE128 MVI    B,128    ;SET MOVE COUNT
  1159. ;
  1160. ;Move from (HL) to (DE) length in (B)
  1161. ;
  1162. MOVE    MOV    A,M    ;GET A CHAR
  1163.     STAX    D    ;STORE IT
  1164.     INX    H    ;TO NEXT "FROM"
  1165.     INX    D    ;TO NEXT "TO"
  1166.     DCR    B    ;MORE?
  1167.     JNZ    MOVE    ;..YES, LOOP
  1168.     RET        ;..NO, RETURN
  1169. ;
  1170. ;Temporary storage area
  1171. ;
  1172. MAXEXT    DB    0    ;HIGHEST EXTENT NO. SEEN IN FILE SIZE CALC.
  1173. RCNT    DW    0    ;RECORD COUNT
  1174. RCVSNO    DB    0    ;SECT # RECEIVED
  1175. SECTNO    DB    0    ;CURRENT SECTOR NUMBER 
  1176. ERRCT    DB    0    ;ERROR COUNT
  1177. ;Following 3 used by disk buffering routines
  1178. EOFLG    DB    0    ;EOF FLAG (1=TRUE)
  1179. SECPTR    DW    DBUF
  1180. SECINBF DB    0    ;# OF SECTORS IN BUFFER
  1181.     DS    60    ;STACK AREA
  1182. STACK    DS    2    ;STACK POINTER
  1183. ;
  1184. ;16 sector disk buffer
  1185. ;
  1186. DBUF    EQU    $    ;16 SECTOR DISK BUFFER
  1187. ;
  1188. ;BDOS equates
  1189. ;
  1190. RDCON    EQU    1
  1191. WRCON    EQU    2
  1192. PRINT    EQU    9
  1193. CONST    EQU    11    ;CONSOLE STAT
  1194. OPEN    EQU    15    ;0FFH = NOT FOUND
  1195. CLOSE    EQU    16    ;    "       "
  1196. SRCHF    EQU    17    ;    "       "
  1197. SRCHN    EQU    18    ;    "       "
  1198. ERASE    EQU    19    ;NO RET CODE
  1199. READ    EQU    20    ;0=OK, 1=EOF
  1200. WRITE    EQU    21    ;0=OK, 1=ERR, 2=?, 0FFH=NO DIR SPC
  1201. MAKE    EQU    22    ;0FFH=BAD
  1202. REN    EQU    23    ;0FFH=BAD
  1203. STDMA    EQU    26    ;SET DMA
  1204. BDOS    EQU    BASE+5
  1205. FCB    EQU    BASE+5CH ;SYSTEM FCB
  1206. FCBEXT    EQU    FCB+12    ;FILE EXTENT
  1207. FCBSNO    EQU    FCB+32    ;SECTOR #
  1208. FCB2    EQU    BASE+6CH ;SECOND FCB
  1209. ;
  1210.     END
  1211.  
  1212.