home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol018 / 3812dump.asm < prev    next >
Assembly Source File  |  1984-04-29  |  21KB  |  833 lines
  1. ; 
  2. ; 
  3. ; 
  4. ;                     3812DUMP.ASM  Ver.1.0
  5. ; 
  6. ;                             as of
  7. ; 
  8. ;                        August 25, 1980
  9. ; 
  10. ;  This  program is a disk dump and edit  utility,  originally 
  11. ; written  by S.  J.  Singer for CP/M 1.4 single density  (IBM 
  12. ; 3741 compatible) diskettes (ref.  CP/M User's Group,  Volume 
  13. ; 24.1),  and  modified for usage with the iCOM FD3812  Double 
  14. ; Density  Disk Controller (IBM System  34  compatible).  Note 
  15. ; also,  that  this  utility is unique to Lifeboat  Associates 
  16. ; implementation  of  CP/M Version 1.4,  and as such  may  not 
  17. ; display  Group Allocations or Sector Interlace properly  for 
  18. ; other   implementations  of  CP/M  1.4  on  double   density 
  19. ; diskette.
  20. ; 
  21. ; 
  22. ;                         Operation
  23. ; 
  24. ;   The program  may  be executed either by type 3812DUMP<cr>, 
  25. ; or  3812DUMP  followed  by  a  or  track  number  and sector 
  26. ; number,  or  group  allocation  vector  number,   or   group 
  27. ; allocation "map", followed by carriage return.
  28. ;  
  29. ;  If  3812DUMP alone is typed,  the program will display  the 
  30. ; sign-on  message,  and then prompt for keyboard input with a 
  31. ; "*"  character.  Operation  in this mode is similar  to  the 
  32. ; Digital Research utilities PIP,  DDT, or SID except that you 
  33. ; will  be operating directly on disk data rather than  memory 
  34. ; data.  After  the  "*" prompt,  you may select  one  of  the 
  35. ; following operations:
  36. ; 
  37. ; 
  38. ; 
  39. ; 1.0 To dump selected tracks and sectors;
  40. ; 
  41. ;      *TRACK 3 SECTOR 7<cr>
  42. ;      *TRACK 5 SECTOR 3-9<cr>
  43. ;      *TRACK 6<cr> (Dump all 52 sectors of track 6)
  44. ;      *TRACK 0<cr> (Dump all 26 sectors of track 0)
  45. ; 
  46. ; 2.0 To dump the group allocations by track and sector;
  47. ; 
  48. ;      *GROUP 0<cr> (Dump the group allocation for the directory)
  49. ; 
  50. ; 3.0 To dump the group alloaction "bit" map
  51. ; 
  52. ;      *MAP<cr>
  53. ; 
  54. ; 4.0 To verify (read all tracks, all sectors for errors)
  55. ; 
  56. ;      *VERIFY<cr>
  57. ; 
  58. ; 
  59. ;  Note,  that the words VERIFY, MAP, GROUP, TRACK, and SECTOR 
  60. ; may be abreviated as shown in the following examples:
  61. ; 
  62. ;      *G 4<cr>
  63. ; 
  64. ;      or,
  65. ; 
  66. ;      *T 7 S 3-4<cr>
  67. ; 
  68. ;      or,
  69. ; 
  70. ;      *S 2-9 T 14<cr>
  71. ; 
  72. ;      or,
  73. ; 
  74. ;      *M<cr>
  75. ; 
  76. ;      or,
  77. ; 
  78. ;      *V<cr>
  79. ; 
  80. ; 
  81. ;  Also, the format is quite free. Spaces are usually ignored, 
  82. ; and  ae only required after the words TRACK and SECTOR (or T 
  83. ; and S).  In addition,  all the commands may be specified  at 
  84. ; the  CP/M  command level after the disk "A>" or  "B>"  etc., 
  85. ; prompt as shown in the following example:
  86. ; 
  87. ;      A>3812DUMP T 0 S 26<cr>
  88. ; 
  89. ;
  90. ;  A  limited  disk editing feature is also included to  allow 
  91. ; "hot patching" of the selected diskette.  Any single  sector 
  92. ; on a diskette may be modified (edited), by requesting a dump 
  93. ; of  the  track  and sector followed by the  word  EDIT.  For 
  94. ; example:
  95. ; 
  96. ;      A>3812DUMP T 1 S 3 EDIT<cr>
  97. ; 
  98. ;  The  requested  sector  on  the  specified  track  will  be 
  99. ; displayed,  followed by the edit prompt "Edit -".  Enter the 
  100. ; "address" of the byte within that sector to be modified, and 
  101. ; the  program  will  respond by  typing  back  the  "address" 
  102. ; entered  and the present content of that address.  To change 
  103. ; the contents of that address,  enter a two digit hexadecimal 
  104. ; value followed by a carriage return.  The program will  then 
  105. ; display the next sequential address and its content. To stop 
  106. ; enetering data,  type a "." followed by carriage return, and 
  107. ; the  program  will  redisplay  the the  sector  showing  the 
  108. ; modifications.  Note  also,  that  typeing only  a  carriage 
  109. ; return  omits  any modification of the  currently  displayed 
  110. ; address,  and merely advances to the next address.  At  this 
  111. ; point,  you  have  not actually modified the sector  on  the 
  112. ; diskette,   only   the  "memory  image"...when  editing   is 
  113. ; completed,  you  may  write the "memory image" back  to  the 
  114. ; sector by typeing WRITE<cr>.  Additionally, you can stop the 
  115. ; editing  of  the sector by typeing STOP<cr>,  and  terminate 
  116. ; without writing the diskette.
  117. ; 
  118. ;  All edit entries must be made in hexadecimal (entering non-
  119. ; hexadecimal  characters  will result in an  error  message), 
  120. ; with the permissable range of 0000 to 007F (larger address's 
  121. ; will  give an error message).  Note,  that for the  Lifeboat 
  122. ; Associates implementation of CP/M Version 1.4, that track 00 
  123. ; is 26 sectors of 128 bytes each,  and all other tracks  will 
  124. ; be  52  sectors of 128 bytes (in reality 26 sectors  of  256 
  125. ; bytes).
  126. ; 
  127. ;  An  additional  feature of the program,  is the ability  to 
  128. ; VERIFY  (read all tracks and sectors for errors) a  diskette 
  129. ; as shown in the following example:
  130. ; 
  131. ;      A>3812DUMP B:VERIFY<cr>
  132. ; 
  133. ;      or,
  134. ; 
  135. ;      A>3812DUMP V<cr>
  136. ; 
  137. ;      or,
  138. ; 
  139. ;      *V<cr>
  140. ; 
  141. ; 
  142. ;  Finally,  as with other CP/M utiliies,  the display may  be 
  143. ; started  and  stopped while scrolling with Control-S  (as  a 
  144. ; "toggle"),  and  Control-C will return you to the "*" prompt 
  145. ; (if already at the "*" prompt, you will return to CP/M).
  146. ; 
  147. ; 
  148. ;                          Notes
  149. ; 
  150. ;  The  program  must  be assembled  with  Digital  Research's 
  151. ; macro-assembler MAC, and a macro library file DDMACRO.LIB.
  152. ; 
  153. ;  This  program  is  PUBLIC DOMAIN,   and  as  such  is  for 
  154. ; distribution to all users whether public or private.
  155. ; 
  156. ; 
  157. ;                               Best regards,
  158. ;                               
  159. ;                               Kelly Smith, CP/M-NET (tm)
  160. ;                               805-527-9321 (Modem, 300 Baud)
  161. ;                               805-527-0518 (Verbal)
  162. ;
  163. ;
  164. ;
  165. ;
  166. $+PRINT
  167.  
  168.     MACLIB    DDMACRO        ;INCLUDE DOUBLE DENSITY MACRO LIBRARY
  169.  
  170.     ORG    100H        ;SET PROG START
  171.  
  172.     LXI    H,0
  173.     DAD    SP        ;GET STACK POINTER
  174.     SHLD    OLDSTK
  175.     LXI    SP,NEWSTK    ;SET UP NEW STACK
  176.     DISKIO    ?DRIVE        ;GET CURRENTLY LOGGED DRIVE NO
  177.     STA    NEWDRV        ;ALSO SAVE IN NEW DRIVE NO
  178.     LDA    81H        ;CONSOLE INPUT ALREADY HERE ?
  179.     ORA    A
  180.     JZ    SIGNON        ;BUFFER EMPTY, INPUT FROM CONSOLE
  181.     LDA    80H        ;GET NO OF CHAR INPUT
  182.     ORI    80H        ;ADD 128
  183.     MOV    L,A        ;TO L
  184.     XRA    A        ;ZERO
  185.     MOV    H,A        ;HL CONTAINS ADDR OF END OF BUFFER
  186. ZBFF:    INR    L
  187.     JZ    START        ;REMAINDER OF BUFFER ZEROED
  188.     MOV    M,A
  189.     JMP    ZBFF        ;LOOP
  190. SIGNON:    PRINT    <CR,LF,'Disk Dump Utility for iCom FD3812, Ver.1.0',CR,LF>
  191. NEWIN:    PRINT    <CR,LF,'*'>
  192.     MVI    A,0FFH        ;SET SWITCH TO RETURN HERE AGAIN
  193.     STA    INFLAG
  194.     LXI    SP,NEWSTK    ;RESET STACK POINTER
  195.     XRA    A
  196.     STA    VALFLG        ;RESET VALIDATION ERROR FLAG
  197.     LXI    H,0
  198.     SHLD    LINE        ;SET LINE COUNT TO ZERO
  199.     FILL    80H,0FFH    ;ZERO INPUT BUFFER
  200.     INPUT    80H        ;READ FILE NAME
  201. ;
  202. ;  SELECT DISK DRIVE AND SET UP FILE CONTROL BLOCK
  203. ;
  204. START:    FILL    FCB,FCB+32    ;ZERO FILE CONTROL BLOCK
  205.     MATCH    82H,'A:'    ;DRIVE A
  206.     JZ    ADISK
  207.     MATCH    82H,'B:'    ;DRIVE B
  208.     JZ    BDISK
  209.     JMP    GETNAM        ;NO DRIVE SPECIFIED
  210. ADISK:    XRA    A
  211.     STA    NEWDRV        ;SELECT DRIVE A
  212.     JMP    DOWN
  213. BDISK:    MVI    A,1
  214.     STA    NEWDRV        ;SELECT DRIVE B
  215. DOWN:    MOVE    82H,80H,40H    ;SHIFT BUFFER DOWN TWO BYTES
  216. ;
  217. ;  SEARCH FOR DIRECT READ OF TRACK AND SECTOR OR VALIDATE
  218. ;
  219. GETNAM:    INSTR    82H,40H,'VERIFY'
  220.     JC    VERIFY        ;VERIFY DISK
  221.     INSTR    82H,40H,'V'
  222.     JC    VERIFY        ;VERIFY DISK
  223.     INSTR    82H,40H,'GROUP'
  224.     JC    GROUP        ;DISPLAY CPM 8 SECTOR GROUP
  225.     INSTR    82H,40H,'G '    ;SEARCH FOR 'G'
  226.     JC    GROUP        ;DISPLAY GROUP
  227.     INSTR    82H,40H,'MAP'    ;ALLOCATION MAP
  228.     JC    MAP        ;DISPLAY GROUP ALLOCATION MAP
  229.     INSTR    82H,40H,'M'    ;ALLOCATION MAP
  230.     JC    MAP        ;DISPLAY GROUP ALLOCATION MAP
  231.     INSTR    82H,40H,'TRACK'    ;SEARCH FOR TRACK
  232.     JC    TRK1
  233.     INSTR    82H,40H,'T '    ;SEARCH FOR 'T'
  234.     JNC    FILNAM        ;NO TRACK GO TO READ FILE
  235. TRK1:    SCAN            ;FIND AND CONVERT NUMBER
  236.     DECIN
  237.     JC    INERR        ;INPUT ERROR ON CARRY
  238.     STA    TRACK        ;SAVE TRACK NO
  239.     INSTR    82H,40H,'SECTOR'    ;SEARCH FOR SECTOR
  240.     JC    SEC1
  241.     INSTR    82H,40H,'S '    ;TRY 'S'
  242.     JNC    WHLTRK        ;DUMP ENTIRE TRACK
  243. SEC1:    SCAN    
  244.     DECIN
  245.     JC    INERR        ;INPUT ERROR ON CARRY
  246.     STA    BSEC        ;BEGINNING SECTOR
  247.     STA    ESEC        ;SAVE IN END SECTOR ALSO
  248.     XCHG            ;SET BUFFER POINTER FOR SCAN
  249.     SHLD    IPOINT        ;SAVE BUFFER POINTER FOR EDIT
  250.     INSTR    ,40H,'-'    ;SEARCH FOR '-'
  251.     JNC    EDIT        ;CHECK FOR EDITION OF SECTOR
  252.     SCAN
  253.     DECIN            ;SCAN AND CONVERT ANOTHER NO
  254.     JC    INERR        ;ERROR IF CARRY SET
  255.     STA    ESEC        ;SAVE IN END SECTOR
  256.     LXI    H,BSEC        ;POINTS TO BSEC
  257.     CMP    M        ;COMPARE BEGIN AND END
  258.     JP    DOREAD        ;OK IF END>=BEGIN
  259.     MOV    B,A        ;OTHERWISE
  260.     MOV    A,M        ;SWITCH THEM
  261.     STA    ESEC
  262.     MOV    M,B
  263. DOREAD:    CALL    RDISK0        ;READ DIRECT
  264.     JMP    ENDFIL        ;BACK FOR MORE INPUT
  265. EDIT:    LHLD    IPOINT        ;RESET BUFFER POINTER
  266.     INSTR    ,40H,'EDIT'    ;CHECK EDIT FUNCTION
  267.     JNC    DOREAD        ;GO TO DISPLAY SECTOR
  268.     CALL    RDISK0        ;DISPLAY SECTOR
  269. EDIT1:    PRINT    <CR,LF,'Edit - '>
  270.     FILL    INBUF,INBUF+9
  271.     INPUT    INBUF,6        ;INPUT MAXIMUM 6 CHAR
  272.     INSTR    INBUF,8,'WRITE'    ;WRITE EDITED SECTOR ON DISK?
  273.     JC    WRTDSK        ;WRITE BUFFER BACK ON DISK
  274.     INSTR    INBUF,8,'STOP'    ;STOP EDITING WITHOUT WRITING?
  275.     JC    ENDFIL        ;EXIT
  276.     HEXIN    INBUF+2        ;CONV ASCII TO HEX
  277.     JNC    CKLIM        ;IF NO ERROR, CHECK ADDR
  278.     LDAX    D        ;GET ASCII CHAR
  279.     CPI    '.'        ;CHECK FOR EXIT CHAR
  280.     JZ    EDIT3        ;BACK FOR MORE EDITING
  281.     JMP    ADERR        ;ADDRESS ERROR
  282. CKLIM:    LXI    D,0080H        ;CHECK ADDR LIMIT
  283.     CPHL
  284.     JP    ADERR        ;ADDRESS ERROR
  285.     SHLD    IPOINT        ;SAVE ADDRESS
  286.     PRINT    CRLF,$
  287. PTX:    HEXOUT    IPOINT+1
  288.     HEXOUT    IPOINT        ;ECHO THE ADDRESS
  289.     PRINT    SPACE,$
  290.     LHLD    IPOINT        ;ECHO PRESENT CONTENTS
  291.     LXI    D,0080H
  292.     DAD    D        ;COMPUTE MEMORY ADDR
  293.     MOV    A,M        ;GET BYTE FROM MEMORY
  294.     HEXOUT
  295.     PRINT    SPACE,$
  296.     FILL    INBUF,INBUF+5    ;ZERO INPUT BUFFER
  297.     INPUT    INBUF,4        ;INPUT 4 CHAR MAX
  298.     HEXIN    INBUF+2        ;CONVERT
  299.     JNC    EDIT2        ;HEX CHAR
  300.     LDAX    D        ;GET ASCII CHAR
  301.     CPI    '.'        ;PERIOD ENDS INPUT
  302.     JZ    EDIT3        ;BACK FOR MORE EDITING
  303.     JMP    HEXERR        ;ERROR NOT HEX CHAR
  304. EDIT2:    LDA    INBUF+1        ;LOAD NO OF CHAR TYPED
  305.     ORA    A
  306.     JZ    EDITX        ;NO REPLACEMENT IF JUST CR
  307.     MOV    A,L        ;CONVERTED CHAR BACK TO A
  308.     LHLD    IPOINT        ;LOAD MEMORY BUFFER POINTER
  309.     LXI    D,0080H        ;OFFSET
  310.     DAD    D        ;CALC MEMORY ADDR
  311.     MOV    M,A        ;STORE NEW INPUT TO MEMORY
  312. EDITX:    PRINT    CRLF,$
  313.     LDA    IPOINT        ;LEAST SIGNIFICANT HALF OF ADDR
  314.     INR    A        ;INCR BY ONE
  315.     ANI    7FH        ;COUNT MOD 128
  316.     STA    IPOINT
  317.     JMP    PTX        ;INPUT MORE DATA
  318. EDIT3:    LXI    H,0
  319.     SHLD    LINE        ;RESET LINE NO TO ZERO
  320.     CALL    PRTSEC        ;PRINT BUFFER WITH HEADING
  321.     JMP    EDIT1        ;BACK FOR ADDITIONAL EDITING
  322. WRTDSK:    CALLBIOS DWRITE        ;WRITE BUFFER BACK ON DISK
  323.     JMP ENDFIL        ;EXIT
  324. ;
  325. ;  READ TRACK AND SECTOR DIRECT
  326. ;
  327. RDISK0:    CALL    FIXB
  328. RDISK:    SETSEC    BSEC        ;SET SECTOR
  329.     JC    BADSEC        ;WRONG SECTOR NO
  330. TRK2:    SETTRK    TRACK        ;SET TRACK
  331.     JC    BADTRK        ;WRONG TRACK NO
  332.     LDA    NEWDRV
  333.     MOV    E,A
  334.     DISKIO    LOGIN            ;SELECT NEW DEIVE IF SPECIFIED
  335.     CALLBIOS DREAD        ;READ TRACK AND SECTOR
  336. ;
  337. ;  PRINT DRIVE, TRACK AND SECTOR HEADING
  338. ;
  339. PRTSEC:    LDA    NEWDRV        ;NEW DRIVE NO
  340.     ORA    A
  341.     JNZ    PRNB        ;PRINT DRIVE B
  342.     PRINT    <CR,LF,'               Drive A -'>
  343. PRNTRK:    PRINT    ' Track '
  344.     LXI    H,0
  345.     LDA    TRACK
  346.     MOV    L,A
  347.     DECOUT
  348.     PRINT    '  Sector '
  349.     LXI    H,0
  350.     LDA    BSEC
  351.     MOV    L,A
  352.     DECOUT
  353.     PRINT    CRLF,$
  354.     CALL    PRTBUF        ;PRINT IT
  355.     LXI    H,BSEC        ;ADDR OF SECTOR NUMBER
  356.     LDA    ESEC        ;END SECTOR NUMBER
  357.     CMP    M        ;COMPARE THEM
  358.     RZ            ;EXIT IF THEY ARE EQUAL
  359.     INR    M        ;INCR BSEC
  360.     JMP    RDISK
  361. PRNB:    PRINT    <CR,LF,'               Drive B -'>
  362.     JMP    PRNTRK        ;PRINT TRACK AND SECTOR
  363. ;
  364. ;  DUMP ENTIRE TRACK IF NO SECTOR INPUT
  365. ;
  366. WHLTRK:    MVI    A,1        ;BEGIN SECTOR
  367.     STA    BSEC
  368.     LDA    TRACK        ;GET TRACK NUMBER
  369.     ORA    A
  370.     JNZ    ESEC52        ;IF NOT TRACK 00, DO 52 SECTORS
  371.     MVI    A,26        ;IT'S TRACK 00, DO 26 SECTORS
  372.     JMP    ESECEND
  373. ESEC52:    MVI    A,52        ;NOT TRACK 00, DO 52 SECTORS
  374. ESECEND:STA    ESEC
  375.     CALL    RDISK0        ;TO READ DISK
  376.     JMP    ENDFIL        ;BACK FOR MORE INPUT
  377. ;
  378. ;  FILL IN FCB FOR NAMED FILE
  379. ;
  380. FILNAM:    FILFCB    FCB,82H    ;FILL IN FCB NAME FROM INPUT BUFFER
  381.     JC    NAMERR        ;ERROR IN FILE NAME
  382.     MATCH    FCB+9,'COM'    ;TEST FOR COM FILE
  383.     JNZ    SELDR
  384.     LXI    H,100H    
  385.     SHLD    LINE        ;SET LINE NO. TO 100
  386. SELDR:    LDA    NEWDRV        ;SELECT NEW DRIVE
  387.     MOV    E,A
  388.     DISKIO    LOGIN
  389.     DISKIO    OPEN,FCB    ;0PEN FILE
  390.     CPI    255        ;CHECK FILE PRESENT
  391.     JZ    OPNERR        ;EXIT IF ERROR
  392. RDFILE:    DISKIO    READ,FCB    ;READ A BLOCK
  393.     ORA    A        ;ZERO INDICATES SUCESSFUL READ
  394.     JNZ    ENDFIL        ;1 INDICATES EOF
  395.     CALL    PRTBUF        ;DO PRINT SUBROUTINE
  396.     JMP    RDFILE        ;BACK FOR NEXT BLOCK
  397. ENDFIL:    LDA    INFLAG        ;SEE WHERE TO GO
  398.     ORA    A
  399.     JZ    MONITOR
  400.     JMP    NEWIN
  401. ;
  402. ;
  403. ;  PRTBUF - PRINT BUFFER IN HEX AND ASCII
  404. ;
  405. PRTBUF:    MVI    B,8        ;8 LINES
  406.     LXI    H,80H        ;INITIAL BUFFER POINTER
  407.     SHLD    IPOINT        ;STORAGE FOR POINTER
  408. BPRN:    LHLD    IPOINT        ;LOAD POINTER
  409.     MVI    C,16        ;CHAR PER LINE
  410.     LDA    LINE+1        ;LINE NUMBER
  411.     SAVE    B,H
  412.     HEXOUT
  413.     LDA    LINE        ;SECOND TWO DIGITS
  414.     HEXOUT
  415.     PRINT    '  '
  416.     RESTORE    H,B
  417. PLOOP:    MOV    A,M        ;GET A BYTE
  418.     SAVE    B,H
  419.     HEXOUT
  420.     PRINT    SPACE,$
  421.     RESTORE    H,B
  422.     INX    H        ;INCR MEMORY POINTER
  423.     MOV    A,C
  424.     CPI    9        ;CHECK 8 CHAR
  425.     JNZ    DECC        ;SKIP IF NOT
  426.     SAVE    B,H
  427.     PRINT    SPACE,$
  428.     RESTORE    H,B
  429. DECC:    DCR    C        ;DECR CHAR COUNT
  430.     JNZ    PLOOP        ;PRINT SOME MORE
  431.     SAVE    B
  432.     PRINT    SPACE,$
  433.     RESTORE    B
  434.     LHLD    IPOINT        ;RESET POINTER FOR ASCII
  435.     MVI    C,10H        ;RESET CHAR COUNT
  436. PLOOP1:    MOV    A,M        ;GET A BYTE
  437.     ANI    7FH        ;MASK OFF HIGH BIT
  438.     CPI    7FH        ;DELETE CODE
  439.     JZ    PERIOD        ;PRINT PERIOD FOR DELETE
  440.     CPI    20H        ;TEST FOR CONTROL CHAR
  441.     JP    SKIPX        ;SKIP SUBSTITUTION
  442. PERIOD:    MVI    A,2EH        ;ASCII PERIOD
  443. SKIPX:    SAVE    B,H
  444.     CHAROUT            ;PRINT IT SAVE REGS
  445.     RESTORE    H,B
  446.     INX    H        ;INCR MEMORY POINTER
  447.     MOV    A,C
  448.     CPI    9        ;CHECK 8 CHAR
  449.     JNZ    DECC2
  450.     SAVE    B,H
  451.     PRINT    SPACE,$
  452.     RESTORE    H,B
  453. DECC2:    DCR    C        ;DECR CHAR COUNT
  454.     JNZ    PLOOP1        ;PRINT SOME MORE
  455.     SAVE    B
  456.     PRINT    CRLF,$        ;CARRIAGE RETURN
  457.     CALL    PRNCON        ;PRINT CONTROL?
  458.     POP    B
  459.     INDEX    LINE,16        ;INCR LINE NO BY 16
  460.     DCR    B        ;DECR    LINE COUNT
  461.     RZ            ;RETURN IF LINE COUNT ZERO
  462.     INDEX    IPOINT,16    ;INCR POINTER BY 16
  463.     JMP    BPRN        ;LOOP BACK
  464. ;
  465. ;    THIS SECTIONS VERIFIES A DISK FOR BAD SECTORS
  466. ;
  467. VERIFY:    MVI    A,1        ;START WITH SECTOR 1
  468.     STA    SNUM
  469.     XRA    A        ;START WITH TRACK 0
  470.     STA    TNUM
  471.     LDA    NEWDRV        ;SELECT NEW DRIVE
  472.     MOV    E,A
  473.     DISKIO    LOGIN
  474. RS0:    SETTRK    TNUM
  475.     JC    BADTRK
  476. RS1:    SETSEC    SNUM
  477.     JC    BADSEC
  478.     CALLBIOS DREAD
  479.     ORA    A
  480.     CNZ    VALERR        ;ERROR IF NOT ZERO
  481.     CALL    PRNCON        ;ESCAPE ON CONTROL C
  482.     LDA    SNUM        ;SECTOR NO
  483.     ADI    5        ;INCR BY 5
  484.     STA    SNUM        ;STORE IT BACK
  485.     PUSH    PSW        ;SAVE BIASED SECTOR NUMBER
  486.     LDA    TRACK        ;GET TRACK NUMBER
  487.     ORA    A
  488.     JNZ    RS2        ;IF NOT TRACK 00, MAKE MOD 52
  489.     POP    PSW
  490.     SBI    27        ;IT'S TRACK 00, MAKE MOD 26
  491.     JMP    RS3
  492. RS2:    POP    PSW        ;GET BIASED SECTOR NUMBER
  493.     SBI    53        ;CALC SECTOR MOD 52
  494. RS3:    JM    RS1        ;SECTOR OK IF MINUS
  495.     INR    A        ;SECTOR MOD 26 OR 52
  496.     STA    SNUM        ;STORE IT BACK
  497.     CPI    1        ;ARE WE BACK TO ONE YET
  498.     JNZ    RS1        ;READ SOME MORE
  499.     LDA    TNUM        ;TRACK NUMBER
  500.     INR    A        ;INCR BY ONE
  501.     CPI    77        ;CHECK LIMIT
  502.     JZ    VALOUT        ;TO EXIT
  503.     STA    TNUM        ;STORE BACK TRACK NO
  504.     JMP    RS0        ;BACK TO READ ROUTINE
  505. VALOUT:    LDA    VALFLG        ;CHECK ERROR FLAG
  506.     ORA    A
  507.     JNZ    ENDFIL
  508.     PRINT    <CR,LF,'Succesfully Verified'>
  509.     LDA    NEWDRV
  510.     ORA    A
  511.     JNZ    VAL2
  512.     PRINT    ' Drive A'
  513.     JMP    ENDFIL
  514. VAL2:    PRINT    ' Drive B'
  515.     JMP    ENDFIL
  516. VALERR:    PRINT    <CR,LF,'Error, Track '>
  517.     LDA    TNUM
  518.     LXI    H,0
  519.     MOV    L,A
  520.     DECOUT
  521.     PRINT    ' Sector '
  522.     LXI    H,0
  523.     LDA    SNUM
  524.     MOV    L,A
  525.     DECOUT
  526.     PRINT    CRLF,$
  527.     MVI    A,-1
  528.     STA    VALFLG        ;SET ERROR FLAG
  529.     RET
  530. ;
  531. ;  PRINT CONTROL AND ESCAPE
  532. ;
  533. PRNCON:    MVI    C,11
  534.     CALL    5
  535.     ANI    1
  536.     RZ            ;RETURN
  537.     CHARIN            ;READ CONSOLE
  538.     CPI    3        ;TEST FOR CONTROL C
  539.     JZ    ENDFIL        ;EXIT IF CONTROL C
  540.     RET
  541. ;
  542. ;    THIS SECTION DISPLAYS A CPM GROUP OF 8 SECTORS
  543. ;
  544. GROUP:    SCAN            ;GET THE GROUP NO
  545.     DECIN            ;CONVERT TO BINARY
  546.     JC    INERR        ;INPUT ERROR IF CARRY SET
  547.     STA    G        ;SAVE GROUP NO
  548.     ADI    13        ;CHECK LEGAL RANGE
  549.     JC    BADGRP
  550.     XRA    A
  551.     STA    S        ;SET SECTOR COUNT TO 0
  552.     CALL    FIXB        ;RESTORE DRIVE B IF SELECTED
  553. GRP1:    CALL    GRPTS        ;CONVERT TO TRACK AND SECTOR
  554.     CALL    RDISK        ;PRINT THE SECTOR
  555.     LDA    S        ;CHECK SECTOR COUNT
  556.     INR    A
  557.     STA    S        ;INCR S BY 1
  558.     CPI    16        ;CHECK LIMIT
  559.     JNZ    GRP1        ;PRINT ANOTHER SECTOR
  560.     JMP    ENDFIL        ;BACK FOR MORE INPUT
  561. ;
  562. ;   GRPTS  CONVERT CPM GROUP AND SECTOR NUMBER TO TRK AND SEC
  563. ;
  564. GRPTS:    MVI    H,0        ;ZERO H
  565.     LDA    G        ;GROUP NO
  566.     MOV    L,A        ;TO L
  567.     MOV    D,H        ;ZERO    D
  568.     DAD    H
  569.     DAD    H
  570.     DAD    H
  571.     DAD    H        ;SHIFT LEFT 4
  572.     LDA    S        ;GET SECTOR NO
  573.     MOV    E,A        ;TO DE
  574.     DAD    D        ;HL HAS G*16+S
  575.     LDA    TRACK        ;GET TRACK NUMBER, DO SECTOR NUMBER AS REQUIRED
  576.     ORA    A
  577.     LXI    D,-26        ;26 SECTORS, DIVISOR
  578.     JZ    SDGRP        ;IF TRACK 00, DO SINGLE DENSITY GROUP
  579.     LXI    D,-52        ;52 SECTORS, DIVISOR
  580. SDGRP:    MVI    A,1        ;CONTAINS DIVIDEND
  581. DIV:    DAD    D        ;SUB 52
  582.     INR    A
  583.     JC    DIV        ;LOOP TILL MINUS
  584.     PUSH    PSW        ;SAVE TRACK NUMBER
  585.     LDA    TRACK        ;GET TRACK NUMBER, INDEX AS REQUIRED
  586.     ORA    A
  587.     LXI    D,SDTABLE+26    ;INDEX INTO SINGLE DENSITY TABLE
  588.     JZ    SDDIV
  589.     LXI    D,DDTABLE+52    ;INDEX INTO DOUBLE DENSITY TABLE
  590. SDDIV:    POP    PSW        ;RECOVER TRACK NUMBER
  591.     DAD    D
  592.     STA    TRACK        ;STORE TRACK NO
  593.     MOV    A,M        ;GET SECTOR NO
  594.     STA    BSEC        ;SAVE IN BEGINNING SECTOR
  595.     STA    ESEC        ;SAVE IN END SECTOR TOO
  596.     RET
  597. $+PRINT
  598. ;
  599. ;    THIS ROUTINE DISPLAYS THE DISK SECTOR ALLOCATION MAP
  600. ;
  601. MAP:    LDA    NEWDRV
  602.     MOV    E,A
  603.     DISKIO    LOGIN        ;LOG IN SELECTED DRIVE
  604.     DISKIO    ?ALLOC        ;GET POINTER TO ALLOCATION MAP
  605.     MOV    H,B
  606.     MOV    L,A        ;TO HL
  607.     SHLD    IPOINT        ;SAVE MAP POINTER
  608.     LXI    H,0        ;ZERO HL
  609.     SHLD    G        ;ZERO COUNT OF UNUSED GROUPS
  610.     PRINT    <CR,LF,LF,'             Group Allocation Map, Drive -'>
  611.     LDA    NEWDRV        ;LOGGED DRIVE
  612.     ORA    A
  613.     JNZ    DRB        ;DRIVE B
  614.     PRINT    <' A',CR,LF,LF>
  615.     JMP    MAP1
  616. DRB:    PRINT    <' B',CR,LF,LF>
  617. MAP1:    LHLD    IPOINT        ;POINTER TO DISK ALLOCATION MAP
  618.     MVI    D,8        ;NO OF LINES
  619. MAP2:    MVI    C,4        ;WORDS PER LINE
  620. MAPX:    SAVE
  621.     PRINT    '            '
  622.     RESTORE
  623. MAP3:    MVI    B,8        ;BITS PER WORD
  624.     MOV    A,M        ;GET A BYTE FROM ALLOC MAP
  625. MAP4:    RAL            ;SHIFT LEFT THRU CARRY
  626.     SAVE    B,D,H,PSW
  627.     JC    MAP5        ;PRINT A ONE
  628.     PRINT    '0'        ;PRINT A ZERO
  629.     LDA    G        ;UNUSED GROUPS
  630.     INR    A        ;ADD 1
  631.     STA    G        ;STORE IT BACK
  632.     JMP    MAP6
  633. MAP5:    PRINT    '1'        ;PRINT A ONE
  634. MAP6:    RESTORE    PSW,H,D,B
  635.     SAVE    PSW        ;SAVE BIT MAP BYTE
  636.     MOV    A,B        ;BIT COUNT
  637.     CPI    7
  638.     JNZ    MAPY
  639.     MOV    A,C        ;WORD COUNT
  640.     CPI    2
  641.     JNZ    MAPY
  642.     MOV    A,D        ;LINE COUNT
  643.     CPI    1
  644.     JNZ    MAPY
  645.     RESTORE    PSW
  646.     JMP    MAP7        ;TO PRINT UNUSED GROUPS
  647. MAPY:    RESTORE    PSW
  648.     DCR    B        ;DCR BIT COUNT
  649.     JNZ    MAP4        ;PRINT MORE BITS
  650.     DCR    C        ;DECR WORD COUNT
  651.     INX    H        ;INCR ALLOC MAP POINTER
  652.     JNZ    MAP3
  653.     SAVE
  654.     PRINT    CRLF,$
  655.     RESTORE
  656.     DCR    D        ;DECR LINE COUNT
  657.     JMP    MAP2
  658. MAP7:    PRINT    <CR,LF,LF,'          '>
  659.     DECOUT    G        ;PRINT NO OF UNUSED SECTORS
  660.     PRINT    <' Groups remaining on disk, out of 486',CR,LF>
  661.     JMP    ENDFIL        ;EXIT
  662. ;
  663. ;
  664. ;    THIS ROUTINE RESTORES DRIVE B
  665. ;
  666. FIXB:    LDA    NEWDRV        ;CHECK DRIVE NO
  667.     ORA    A
  668.     RZ            ;RETURN IF DRIVE A
  669.     LDA    NEWDRV        ;SELECT DRIVE B
  670.     MOV    E,A
  671.     DISKIO    LOGIN
  672.     XRA    A
  673.     STA    TNUM        ;SELECT TRACK ZERO
  674.     INR    A        ;SELECT SECTOR 1
  675.     STA    SNUM
  676.     SETSEC    SNUM
  677.     SETTRK    TNUM
  678.     CALLBIOS DHOME        ;HOME DRIVES
  679.     CALLBIOS DREAD        ;READ TRACK ZERO DIRECT
  680.     RET
  681. ;
  682. ;  ERROR AND EXIT ROUTINES
  683. ;
  684. ;
  685. INERR:    PRINT    <CR,LF,'Input Error'>
  686.     JMP    ENDFIL
  687. ;
  688. BADSEC:    PRINT    <CR,LF,'Incorrect Sector Number'>
  689.     JMP    ENDFIL
  690. ;
  691. BADTRK:    PRINT    <CR,LF,'Incorrect Track Number'>
  692.     JMP    ENDFIL
  693. ;
  694. BADGRP:    PRINT    <CR,LF,'Incorrect Group Number, greater than 485'>
  695.     JMP    ENDFIL
  696. ;
  697. OPNERR:    LDA    NEWDRV        ;CURRENT DRIVE NO
  698.     ORA    A
  699.     JNZ    OPNER1
  700.     PRINT    <CR,LF,'No file by that name on Drive A'>
  701.     JMP    ENDFIL
  702. OPNER1:    PRINT    <CR,LF,'No file by that name on Drive B'>
  703.     JMP    ENDFIL
  704. ;
  705. RDERR:    PRINT    <CR,LF,'Disk Read Error'>
  706.     JMP    MONITOR
  707. NAMERR:    PRINT    <CR,LF,'Error in File Name'>
  708.     JMP    ENDFIL
  709. ;
  710. ADERR:    PRINT    <CR,LF,LF,'Address Error'>
  711.     JMP    EDIT1        ;ADDRESS ERROR ON EDIT
  712. ;
  713. HEXERR:    PRINT    <CR,LF,'  Error, enter Hexadecimal Values Only',CR,LF>
  714.     JMP    PTX
  715. ;
  716. MONITOR: PRINT    CRLF,$
  717.     LDA    DRVNO        ;RESTORE LOGGED DRIVE NO
  718.     MOV    E,A
  719.     DISKIO    LOGIN
  720.     LHLD    OLDSTK
  721.     SPHL            ;RESET OLD STACK POINTER
  722.     RET
  723. ;
  724. ;
  725. ;   DATA ALLOCATIONS
  726. ;
  727. FCB    EQU    5CH        ;FILE CONTROL BLOCK
  728. SPACE:    DB    ' $'        ;ASCII SPACE
  729. CRLF:    DB    0DH,0AH,24H    ;ASCII CR LF
  730. I:    DW    0        ;PSEUDO INDEX REGISTER
  731. LINE:    DW    0        ;LINE NUMBER FOR LISTING
  732. IPOINT:    DW    00        ;VARIABLE BUFFER POINTER
  733. INBUF:    DS    10        ;USED AS CONSOLE INPUT BUFFER
  734. LASTIN:    DB    0        ;LAST CONSOLE INPUT CHAR
  735. INFLAG:    DB    0        ;FLAG, RET FOR MORE CONSOLE INPUT
  736. DRVNO:    DB    0        ;STORAGE FOR ORIGINALLY LOGGED DRIVE
  737. NEWDRV:    DB    0        ;STORAGE FOR NEW DRIVE NO
  738. TRACK:    DB    0        ;SELECTED TRACK
  739. BSEC:    DB    0        ;SELECTED BEGINNING SECTOR
  740. ESEC:    DB    0        ;SELECTED ENDING SECTOR
  741. TNUM:    DB    0        ;TRACK NO FOR VALIDATE
  742. SNUM:    DB    0        ;SECTOR NO FOR VALIDATE
  743. VALFLG:    DB    0        ;VALIDATION ERROR FLAG
  744. G:    DB    0        ;CPM GROUP NO
  745. S:    DB    0        ;SECTOR NO WITHIN GROUP G
  746. COUNT:    DB    0        ;COUNT OF DIRECTORY ENTRIES
  747. OLDSTK:    DW    0        ;STORAGE FOR OLD STACK POINTER
  748. ENDSTK:    DS    24        ;STORAGE FOR NEW STACK
  749. NEWSTK:    DW    0        ;NEW STACK
  750. INB:    DW    0        ;STORES POINTER TO INPUT BUFFER AREA
  751. OUTB:    DW    0        ;STORES POINTER TO DIRECTORY BUFFER AREA
  752. SDTABLE:DB    01        ;DOUBLE DENSITY SECTOR LOOK UP TABLE
  753.     DB    07
  754.     DB    13
  755.     DB    19
  756.     DB    25
  757.     DB    05
  758.     DB    11
  759.     DB    17
  760.     DB    23
  761.     DB    03
  762.     DB    09
  763.     DB    15
  764.     DB    21
  765.     DB    02
  766.     DB    08
  767.     DB    14
  768.     DB    20
  769.     DB    26
  770.     DB    06
  771.     DB    12
  772.     DB    18
  773.     DB    24
  774.     DB    04
  775.     DB    10
  776.     DB    16
  777.     DB    22
  778. DDTABLE:DB    01        ;DOUBLE DENSITY SECTOR LOOK UP TABLE
  779.     DB    02
  780.     DB    19
  781.     DB    20
  782.     DB    37
  783.     DB    38
  784.     DB    03
  785.     DB    04
  786.     DB    21
  787.     DB    22
  788.     DB    39
  789.     DB    40
  790.     DB    05
  791.     DB    06
  792.     DB    23
  793.     DB    24
  794.     DB    41
  795.     DB    42
  796.     DB    07
  797.     DB    08
  798.     DB    25
  799.     DB    26
  800.     DB    43
  801.     DB    44
  802.     DB    09
  803.     DB    10
  804.     DB    27
  805.     DB    28
  806.     DB    45
  807.     DB    46
  808.     DB    11
  809.     DB    12
  810.     DB    29
  811.     DB    30
  812.     DB    47
  813.     DB    48
  814.     DB    13
  815.     DB    14
  816.     DB    31
  817.     DB    32
  818.     DB    49
  819.     DB    50
  820.     DB    15
  821.     DB    16
  822.     DB    33
  823.     DB    34
  824.     DB    51
  825.     DB    52
  826.     DB    17
  827.     DB    18
  828.     DB    35
  829.     DB    36
  830. PDIR    DW    0        ;POINTER TABLE TO DIRECTORY (64 ENTRIES MAX)
  831. DIRBUF:    EQU    PDIR+130    ;START OF AREA USED TO STORE AND SORT DIRECTORY
  832.     END
  833.