home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol018 / file-ext.asm < prev    next >
Assembly Source File  |  1984-04-29  |  7KB  |  422 lines
  1. ; 
  2. ;                       FILE-EXT.ASM
  3. ;  
  4. ;  Originally  named  FILES.ASM,  and  from a  disassembly  by 
  5. ; "J.A.P"  of January 23,1980...FILE-EXT.ASM will display  the 
  6. ; selected disk's directory entries in the form:
  7. ; 
  8. ;          Filename.Typ   exs1s2rc <-----Group----->
  9. ;          =========================================
  10. ; 
  11. ;  The "hack-job" I did on this one was less than  ideal,  but 
  12. ; none the less, it get's the job done...the display format is 
  13. ; now  alot  cleaner,  and  it  does'nt  "warm  boot"  as  the 
  14. ; FILES.ASM version did...
  15. ; 
  16. ;  The  program will display the disk directory of the  logged 
  17. ; on  disk,  including all the Hexadecimal information on  the 
  18. ; groups.  If an illegal character is found in the filename or 
  19. ; filetype,  it  will  prompt  the operator as to  whether  to 
  20. ; delete the file (or not).  If the operator answers Y  (yes), 
  21. ; the  program will go on displaying more file information and 
  22. ; stopping  when  a bad filename or filetype  is  encountered. 
  23. ; When the display is all done,  the files that were  selected 
  24. ; for deletion will be removed from the directory.
  25. ; 
  26. ;  On  the  subject  of  "hack-job's"  of  software,  read  an 
  27. ; interesting  article  in  Psychology  Today  magazine,  "The 
  28. ; Hacker  Papers;  Computer  Addiction:  Reflection on  a  New 
  29. ; Obsession"...August 1980 issue, pages 62-69.
  30. ; 
  31. ;                               Best regards,
  32. ; 
  33. ;                               Kelly Smith, CP/M-NET (tm)
  34. ;                               805-527-9321 (Modem, 300 Baud)
  35. ;                               805-527-0518 (Verbal)
  36. ; 
  37.  
  38.     ORG    0100H
  39.  
  40. BDOS    EQU    05H
  41. TBUFF    EQU    80H
  42. ;
  43. CR    EQU    0DH    ;ASCII CARRIAGE RETURN
  44. LF    EQU    0AH    ;ASCII LINE FEED
  45. ;
  46. ;
  47. FILES:            ; 
  48.     LXI    H,0    ;
  49.     DAD    SP    ;
  50.     SHLD    OLDSTK    ;
  51.     LXI    SP,NEWSTK    ;
  52.     JMP    BEGIN    ;
  53. ;
  54. ;
  55. ;    SYSTEM SUBROUTINES
  56. ;
  57. ;    PRINT STRING FROM D&E REGS.
  58. ;
  59. PRINT:    MVI    C,9
  60.     CALL    BDOS
  61.     RET
  62. ;
  63. ;    TYPE A CHAR FROM (A)
  64. ;
  65. TYPE:        ; 
  66.     PUSH    B
  67.     PUSH    D
  68.     PUSH    H
  69.     MVI    C,2
  70.     MOV    E,A
  71.     CALL    BDOS    ;
  72.     POP    H
  73.     POP    D
  74.     POP    B
  75.     RET
  76. ;
  77. ;    SEARCH FOR A FILE
  78. ;
  79. SEARCH:        ; 
  80.     PUSH    B
  81.     PUSH    D
  82.     PUSH    H
  83.     MVI    C,11H
  84.     LXI    D,AFN    ;
  85.     CALL    BDOS    ;
  86.     STA    RESULT    ;
  87.     POP    H
  88.     POP    D
  89.     POP    B
  90.     RET
  91. ;
  92. ;    AMBIGUOUS FILENAME.TYP
  93. ;
  94. AFN:        ; 
  95.     DB    '?????????????'
  96. RESULT:        ; 
  97.     DB    0    ;STORAGE FOR RESULT OF BDOS CALL
  98. ;
  99. ;    FIND NEXT OCCURRENCE OF FILE
  100. ;
  101. NEXTFILE:        ; 
  102.     PUSH    B
  103.     PUSH    D
  104.     PUSH    H
  105.     MVI    C,12H
  106.     LXI    D,AFN    ;
  107.     CALL    BDOS    ;
  108.     STA    RESULT    ;
  109.     POP    H
  110.     POP    D
  111.     POP    B
  112.     RET
  113. ;
  114. ;    DELETE A FILE
  115. ;
  116. DELETE:        ; 
  117.     PUSH    B
  118.     PUSH    D
  119.     PUSH    H
  120.     MVI    C,13H
  121.     CALL    BDOS    ;
  122.     POP    H
  123.     POP    D
  124.     POP    B
  125.     RET
  126. ;
  127. ;    GET INPUT FROM CONSOLE
  128. ;
  129. CONIN:        ; 
  130.     PUSH    B
  131.     PUSH    D
  132.     PUSH    H
  133.     MVI    C,1
  134.     CALL    BDOS    ;
  135.     POP    H
  136.     POP    D
  137.     POP    B
  138.     RET
  139. ;
  140. ;    CONVERT A BYTE IN (A) TO TWO PRINTED CHARACTERS
  141. ;
  142. HEXASC:        ; 
  143.     CPI    0AH
  144.     JC    HEXA2    ;
  145.     ADI    '7'    ;
  146.     CALL    TYPE    ;
  147.     RET
  148. HEXA2:        ; 
  149.     ADI    '0'    ;
  150.     CALL    TYPE    ;
  151.     RET
  152. HEXCON:        ; 
  153.     PUSH    PSW
  154.     RAR
  155.     RAR
  156.     RAR
  157.     RAR
  158.     ANI    0FH
  159.     CALL    HEXASC    ;
  160.     POP    PSW
  161.     ANI    0FH
  162.     CALL    HEXASC    ;
  163.     RET
  164. ;
  165. ;    NEWLINE
  166. ;
  167. CRLF:        ; 
  168.     MVI    A,CR
  169.     CALL    TYPE    ;
  170.     MVI    A,LF
  171.     CALL    TYPE    ;
  172.     RET
  173. ;
  174. ;    PRINT A SPACE
  175. ;
  176. SPACE:        ; 
  177.     MVI    A,' '    ;
  178.     CALL    TYPE    ;
  179.     RET
  180. ;
  181. ;    MAIN WORK LOOP
  182. ;
  183. ;    THIS ROUTINE FINDS THE POSITION OF THE FILE
  184. ;    INFORMATION IN THE DIRECTORY DMA, PRINTS THE
  185. ;    DATA IF IT IS A CURRENT FILE, AND PROMPTS THE
  186. ;    OPERATOR FOR INSTRUCTIONS IF THE FILENAME HAS
  187. ;    ILLEGAL (NON-ASCII) DATA IN IT.
  188. ;
  189. WORKLOOP:        ; 
  190.     LDA    RESULT    ;RESULT HOLDS POSITION OF-
  191.     MOV    B,A    ; -THE DIRECTORY ENTRY IN THE DIR. DMA
  192.     ANI    3
  193.     RAL
  194.     RAL
  195.     RAL
  196.     RAL
  197.     RAL
  198.     ANI    0E0H
  199.     MOV    E,A
  200.     MVI    D,0
  201.     LXI    H,TBUFF    ;
  202.     DAD    D    ;HL NOW POINTS AT THE FILE INFO
  203.     MOV    A,M
  204.     CPI    0E5H    ;KILLED FILE?
  205.     RZ        ;YES
  206.     MOV    A,M
  207.     STA    ENTBYT    ;
  208.     PUSH    H
  209.     PUSH    H
  210.     MVI    B,8
  211.     INX    H
  212. WORK02:    MOV    A,M    ;PRINT FILE NAME
  213.     CALL    ILLCHK    ;
  214.     CALL    TYPE    ;
  215.     DCR    B
  216.     INX    H
  217.     JNZ    WORK02    ;
  218.     MVI    B,3
  219.     MVI    A,'.'
  220.     CALL    TYPE    ;PRINT NEXT THREE CHARACTERS AS ASCII
  221. WORK03:    MOV    A,M
  222.     CALL    ILLCHK    ;
  223.     CALL    TYPE    ;
  224.     DCR    B
  225.     INX    H
  226.     JNZ    WORK03    ;
  227.     CALL    TYPE
  228.     CALL    SPACE
  229.     MVI    B,3
  230.     POP    H    ;NOW DISPLAY ATTRIBUTES
  231.     LXI    D,9
  232.     DAD    D
  233. WORK03A:CALL    SPACE
  234.     MOV    A,M
  235.     RLC        ;TEST $SYS AND $R/O, AND RESERVED
  236.     MVI    A,'1'
  237.     JC    WORK03B
  238.     MVI    A,'0'
  239. WORK03B:CALL    TYPE
  240.     CALL    SPACE
  241.     DCR    B
  242.     INX    H
  243.     JNZ    WORK03A
  244.     MVI    B,20
  245. WORK04:    MOV    A,B
  246.     ANI    3
  247.     CZ    SPACE    ;
  248.     MOV    A,M
  249.     CALL    HEXCON    ;
  250.     INX    H
  251.     DCR    B
  252.     JNZ    WORK04    ;
  253.     CALL    CRLF    ;
  254.     POP    H
  255.     LDA    ENTBYT    ;
  256.     ORA    A
  257.     RZ
  258.     PUSH    H
  259.     LXI    H,DELMSG    ;
  260. WORK06:        ; 
  261.     MOV    A,M
  262.     ORA    A
  263.     JZ    WORK08    ;
  264.     CALL    TYPE    ;
  265.     INX    H
  266.     JMP    WORK06    ;
  267. DELMSG:        ; 
  268.     DB    'Delete this file ? ',0
  269. WORK08:        ; 
  270.     CALL    CONIN    ;
  271.     POP    H
  272.     ANI    5FH
  273.     CPI    'Y'    ;
  274.     PUSH    PSW
  275.     CALL    CRLF    ;KEEP IT NEAT
  276.     POP    PSW
  277.     RNZ
  278.     XCHG
  279.     LHLD    DELPTR    ;
  280.     MVI    B,10H
  281. WORK10:        ; 
  282.     LDAX    D
  283.     MOV    M,A
  284.     INX    H
  285.     INX    D
  286.     DCR    B
  287.     JNZ    WORK10    ;
  288.     SHLD    DELPTR    ;
  289.     RET
  290. ;
  291. ;    CHECK FOR NONASCII CHARACTER  <20H  OR  >60H
  292. ;
  293. ILLCHK:    PUSH    PSW
  294.     ANI    07FH    ;MASK FOR PROPRIETARY", "$SYS", "$R/W"
  295.     CPI    ' '    ;
  296.     JC    ILLEGL    ;
  297.     CPI    61H
  298.     JNC    ILLEGL    ;
  299.     POP    PSW
  300.     RET
  301. ILLEGL:    POP    PSW
  302.     PUSH    PSW
  303.     MVI    A,0FFH
  304.     STA    ENTBYT    ;
  305.     POP    PSW
  306.     RET
  307. ;
  308. ;
  309. ;
  310. MSG:    DB    'Filename.Typ R/OSysRes exs1s2rc'
  311.     DB    ' <--------------Group-------------->'
  312.     DB    CR,LF
  313.     DB    '==============================='
  314.     DB    '===================================='
  315.     DB    CR,LF,'$'
  316. ;
  317. ;
  318. ;
  319. ; ERROR MESSAGES
  320. ;
  321. ERROR1:    LXI    D,ERMSG1;SAY NO GO, AND BAIL OUT
  322.     CALL    PRINT
  323.     JMP    QUIT
  324.  
  325. ;
  326. ERMSG1:    DB    CR,LF,'Disk select should be " N:"$'
  327.  
  328. ;
  329. ERROR2:    LXI    D,ERMSG2;SAY NO GO, AND BAIL OUT
  330.     CALL    PRINT
  331.     JMP    QUIT
  332.  
  333. ERMSG2:    DB    CR,LF,'Bad delimeter, should be ":"$'
  334.  
  335. ;
  336. ERROR3:    LXI    D,ERMSG3;SAY NO GO, AND BAIL OUT
  337.     CALL    PRINT
  338.     JMP    QUIT
  339.  
  340. ERMSG3:    DB    CR,LF,'No drive specified$'
  341.  
  342. ;
  343. ERROR4:    LXI    D,ERMSG4;SAY NO GO, AND BAIL OUT
  344.     CALL    PRINT
  345.     JMP    QUIT
  346.  
  347. ERMSG4:    DB    CR,LF,'Only drives A to D allowed$'
  348.  
  349. ;
  350.  
  351. ;    PROGRAM BEGINS HERE
  352. ;
  353. BEGIN:
  354. ;
  355. ; CHECK FOR DRIVE SPECIFICATION
  356. ;
  357.     LDA    TBUFF    ;GET LENGTH OF COMMAND PARAMETERS
  358.     CPI    2    ; IF <2, NO PARAMETERS
  359.     JC    MAIN01    ; MUST BE PRESENT LOGGED-IN DRIVE
  360.     JZ    ERROR1    ;EXACTLY 2, IS ERROR
  361.     LHLD    TBUFF+2    ;AT LEAST 3 THEN...
  362.     MOV    A,H    ;NEXT CHARACTER SHOULD BE ":"
  363.     CPI    ':'
  364.     JNZ    ERROR2    ;ONLY ALLOW DRIVE SET
  365.     MOV    A,L    ;NEXT CHARACTER SHOULD BE DRIVE
  366.     CPI    'A'    ;AT A MINIMUM, "A"
  367.     JC    ERROR3
  368.     CPI    'E'    ;AT A MAXIMUM "D"
  369.     JNC    ERROR4
  370.     ANI    7    ;STRIP BITS, FOR 0 TO 3
  371.     DCR    A    ;BACK OFF FOR 0 TO 3
  372.     MOV    E,A    ;MAKE DISK NUMBER
  373.     MVI    D,0
  374.     MVI    C,14    ;BDOS SELECT DISK FUNCTION
  375.     CALL    BDOS
  376.  
  377. MAIN01:    LXI    D,MSG
  378.     CALL    PRINT
  379.         ; 
  380.     LXI    H,DELFIL    ;
  381.     SHLD    DELPTR    ;
  382.     CALL    SEARCH    ;
  383. MAIN02:        ; 
  384.     LDA    RESULT    ;
  385.     CPI    0FFH
  386.     JZ    MAIN04    ;
  387.     CALL    WORKLOOP    ;
  388.     CALL    NEXTFILE    ;
  389.     JMP    MAIN02    ;
  390. MAIN04:        ; 
  391.     LHLD    DELPTR    ;
  392.     LXI    D,DELFIL
  393.     MOV    A,L
  394.     CMP    E
  395.     JNZ    MAIN06    ;
  396.     MOV    A,H
  397.     CMP    D
  398.     JZ    QUIT    ;
  399. MAIN06:        ; 
  400.     LXI    D,-10H
  401.     DAD    D
  402.     SHLD    DELPTR    ;
  403.     XCHG
  404.     CALL    DELETE    ;
  405.     JMP    MAIN04    ;
  406. QUIT:        ; 
  407.     LHLD    OLDSTK    ;
  408.     SPHL
  409.     RET        ;
  410. ;
  411. ;    SOME STORAGE LOCATIONS
  412. ;
  413. OLDSTK:    DS    2    ;STORAGE FOR "OLD" STACK POINTER
  414.     DS    32
  415. NEWSTK    EQU    $    ;STORAGE FOR "NEW" STACK
  416. ENTBYT:    DS    1    ;
  417. DELPTR:    DS    16    ;
  418. DELFIL    EQU    $    ;FILE OF DELETEABLE FILE BUILDS HERE
  419. ;
  420. ;
  421.     END
  422.