home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol040 / pauswait.asm < prev    next >
Assembly Source File  |  1984-04-29  |  8KB  |  211 lines
  1. ;
  2. ;      PAUSE/WAIT.ASM Version 1.0 as of April 19, 1981
  3. ; 
  4. ;             by: Kelly Smith, CP/M-Net "SYSOP"
  5. ; 
  6. ;  This  program  is intended for usage with  SUBMIT.COM  as 
  7. ; either a 'PAUSE' (contine SUBMIT file when any key  struck 
  8. ; on  your  keyboard)  function,  or as a  'WAIT'  (continue 
  9. ; SUBMIT  file when any key struck on your keyboard  OR  the 
  10. ; programmable delay (up to 90 seconds) times out) function.
  11. ; 
  12. ;  PAUSEWAIT.ASM is handy,  if you need time to do something 
  13. ; between  functions in your SUBMIT file (i.e,  run  to  the 
  14. ; 'frig'  for another beer and don't want to miss  anything, 
  15. ; etc.).  This  program was NOT inspired by any direct  need
  16. ; for  it,  as much as in RETALIATION to SuperSoft selling a 
  17. ; CP/M  utilities  diskette ("...that no programmer  can  be 
  18. ; without")  that  includes PUBLIC DOMAIN software  programs 
  19. ; like XDIR, SORT, (looks like Ward's SORT-V12 to me), PRINT 
  20. ; (probably   from  CPMUG  by  Tony  Gold),   PG   (MLIST42) 
  21. ; etc.,etc...really  'ticks-me-off' when I see  stuff  being 
  22. ; sold to the people thats FREE...so much for my ranting and 
  23. ; raving.  PAUSWAIT.ASM  is intended to go one step  further 
  24. ; with SuperSoft's PAUSE utility.  Not to hack SuperSoft too 
  25. ; much,  the  DIAGNOSTICS  II software package is  excellent 
  26. ; (although  they still don't understand how the  PSW  works 
  27. ; for  various 'flavors' of 8080/8085/Z80 CPU's in their CPU 
  28. ; test)...Gee, and I said I wasn't going to hack them...
  29. ; 
  30. ;  PAUSWAIT.ASM  may be assembled for 'PAUSE' by setting the 
  31. ; equate 'pause' to TRUE (as supplied here) or assembled  as 
  32. ; 'WAIT', by setting the equate 'pause' to FALSE.
  33. ; 
  34. ;  Additional  conditional  assemblies  may  be  set-up,  by 
  35. ; various  TRUE/FALSE configurations for 'upper'  (uppercase 
  36. ; only  terminals),   'stdcpm'  (standard  CP/M),   'altcpm' 
  37. ; (alternate CP/M),  'mpmprl' (MP/M program relocatable), or 
  38. ; 'fastclk' (4 Mhz CPU system clock).
  39. ; 
  40. ;  When  assembled  as  'PAUSE',  just enter PAUSE  in  your 
  41. ; SUBMIT  file...then when it's running,  strike any key  on 
  42. ; your keyboard to continue.  When assembled as 'WAIT', just 
  43. ; enter  WAIT  1 (for 10 seconds delay) up to  WAIT  9  (you 
  44. ; guessed  it,  90 seconds delay) in your SUBMIT file,  then 
  45. ; wait  out the programmed delay or strike any key  on  your 
  46. ; keyboard  to  continue.  If 'WAIT' does not have  a  value 
  47. ; specified  (or you followed it with something  weird),  it 
  48. ; defaults to a 90 second delay time...
  49. ;
  50. ;
  51. ;
  52. true    equ    -1    ; define true
  53. false    equ    not true; define false
  54. ;
  55. pause    equ    true    ; true, if "pause" assembly
  56.             ; false, if "wait" assembly
  57. upper    equ    false    ; true if uppercase only terminal
  58. stdcpm    equ    true    ; true if regular CP/M (base address 0000h)
  59. altcpm    equ    false    ; true if alternate CP/M (base address 4200h)
  60. mpmprl    equ    false    ; true if MP/M program relocatable format
  61. fastclk    equ    false    ; true if 4 mhz system clock
  62. ;
  63.     if    stdcpm    ; if standard CP/M...
  64. base    equ    0000h    ; bsae for standard CP/M system
  65.     endif        ; end if...
  66. ;
  67.     if    altcpm    ; if alternate CP/M...
  68. base    equ    4200h    ; base for H8 or TRS-80 CP/M system
  69.     endif        ; end if...
  70. ;
  71. bdos    equ    base+5    ; CP/M BDOS entry address for function call
  72. tfcb    equ    base+5ch; transient file control block base address
  73. ;
  74. rdcon    equ    1    ; read console character
  75. wrcbuf    equ    9    ; write buffer contents to console
  76. const    equ    11    ; console (data available) status
  77. ;
  78. lf    equ    00ah    ; (^j) line feed
  79. cr    equ    00dh    ; (^m) carriage return
  80. bel    equ    007h    ; (^g) bell - human attention required
  81.  
  82.     if    mpmprl    ; if MP/M program relocatable...
  83.     org    base
  84.     endif        ; end if...
  85. ;
  86.     if    not mpmprl    ; if not MP/M program relocatable...
  87.     org    base+100h
  88.     endif        ; end if...
  89.  
  90.     if    pause    ; if "pause"
  91. start:    lxi    h,0    ; save "old" CP/M stack pointer
  92.     dad    sp
  93.     shld    oldstk
  94.     lxi    sp,stack; make "new" stack pointer
  95.     lxi    d,msg1    ; display "Pausing, for any keyboard entry to continue"
  96.     mvi    c,wrcbuf; write console buffer function
  97.     call    bdos    ; let CP/M do the work...
  98. pausek:    mvi    c,const    ; get console status function
  99.     call    bdos    ; let CP/M do the work...
  100.     rrc        ; any key struck?
  101.     jnc    pausek    ; pause until any key struck, to exit
  102.     mvi    c,rdcon    ; read console character function
  103.     call    bdos
  104.     lhld    oldstk    ; get "old" CP/M stack pointer
  105.     sphl        ; and restore for...
  106.     ret        ; return to CP/M
  107.     endif        ; end if "pause"
  108. ;
  109.     if    pause and upper    ; if uppercase only terminal...
  110. MSG1:    DB    BEL,'PAUSING, FOR ANY KEYBOARD ENTRY TO CONTINUE: $'
  111.     endif        ; end if...
  112. ;
  113.     if    pause and not upper    ; if not uppercase only terminal...
  114. msg1:    db    bel,'Pausing, for any keyboard entry to continue: $'
  115.     endif        ; end if...
  116.  
  117.     if    not pause    ; if not "pause" assembly
  118. start:    lxi    h,0    ; save "old" CP/M stack pointer
  119.     dad    sp
  120.     shld    oldstk
  121.     lxi    sp,stack; make "new" stack pointer
  122.     lxi    d,msg1    ; display "Waiting for any keyboard entry, or timeout"
  123.     mvi    c,wrcbuf; write console buffer function
  124.     call    bdos    ; let CP/M do the work...
  125.     lda    tfcb+1    ; get number of ten second delays required
  126.     sui    '0'    ; make hex value from ASCII value
  127.     cpi    1    ; < 10 seconds requested?
  128.     jc    timebad    ; if so, bad time requested
  129.     cpi    9    ; > 90 seconds requested?
  130.     jz    timeok    ; if = 90 seconds, that's o.k.
  131.     jc    timeok    ; if not, time is o.k.
  132. timebad:lxi    d,msg2    ; display "Bad entry equals 90 seconds "
  133.     mvi    c,wrcbuf; write console buffer function
  134.     call    bdos    ; let CP/M do the work...
  135.     mvi    a,9    ; force 90 second delay on this dummy...
  136. timeok:    sta    cnt    ; save number of ten second delays
  137. next:    call    delay    ; do ten second delay
  138.     lda    cnt    ; de-bump number of 10 second delays to left to do
  139.     dcr    a
  140.     sta    cnt    ; and save for next time...
  141.     push    psw    ; save temporarily...
  142.     lxi    d,msg3    ; display "bel" and ". "
  143.     mvi    c,wrcbuf; write console buffer function
  144.     call    bdos    ; let CP/M do the work...
  145.     pop    psw    ; get flags, check for all timed out
  146.     jnz    next    ; if not timed out, do next 10 second delay
  147.     jmp    exitold    ; exit, on CP/M's "old" stack pointer
  148.     endif        ; end if...
  149. ;
  150.     if    not pause and fastclk    ; 4 mhz system clock
  151. delay:    mvi    a,44    ; 10 seconds, with 4 Mhz system clock
  152.     endif        ; end if...
  153. ; 
  154.     if    not pause and not fastclk
  155. delay:    mvi    a,22    ; 10 seconds, with 2 Mhz system clock
  156.     endif        ; end if...
  157. ; 
  158.     if    not pause    ; if not "pause" assembly...
  159. delay1:    lxi    h,0
  160.     lxi    d,33    ; loop delay value (fine tuned)...
  161. waitcnt:dad    d    ; wait between bell rings
  162.     push    psw    ; exile all registers
  163.     push    b
  164.     push    d
  165.     push    h
  166.     mvi    c,const    ; get console status function
  167.     call    bdos    ; let CP/M do the work...
  168.     rrc        ; any key struck?
  169.     jc    exit    ; exit via CP/M "old" stack pointer, if any key entry
  170.     pop    h    ; get all registers back from exile
  171.     pop    d
  172.     pop    b
  173.     pop    psw
  174.     jnc    waitcnt    ; minor delay loop done?
  175.     dcr    a    ; major delay loop done?
  176.     jnz    delay1    ; no, loop
  177.     ret        ; return from "delay", no keyboard entry yet
  178. exit:    mvi    c,rdcon    ; read console character function
  179.     call    bdos
  180. exitold:lhld    oldstk    ; get "old" CP/M stack pointer
  181.     sphl        ; and restore for...
  182.     ret        ; return to CP/M
  183.     endif        ; end if "not pause"
  184. ; 
  185.     if    not pause and upper    ; if uppercase only terminal...
  186. MSG1:    DB    'WAITING FOR ANY KEYBOARD ENTRY, OR TIMEOUT: $'
  187. ;
  188. MSG2:    DB    CR,LF,'BAD ENTRY (MUST BE 1 TO 9) EQUALS 90 SECONDS! $'
  189.     endif        ; end if...
  190. ;
  191.     if    not pause and not upper    ; if not uppercase only terminal...
  192. msg1:    db    'Waiting for any keyboard entry, or timeout: $'
  193. msg2:    db    cr,lf,'Bad entry (must be 1 to 9) equals 90 seconds! $'
  194.     endif        ; end if...
  195. ;
  196.     if    not pause    ; if not "pause" assembly...
  197. msg3:    db    bel,'. $'
  198. ;
  199. cnt:    ds    1    ; 10 second increments storage counter
  200.     endif        ; end if "not pause"
  201.  
  202. oldstk:    ds    2    ; storage for "old" CP/M stack pointer
  203.     ds    32    ; storage for 16 level stack
  204. stack    equ    $    ; storage for "new" stack pointer
  205. ;
  206.     if    mpmprl
  207.     db    0    ; force allocation of storage space
  208.     endif
  209. ; 
  210.     end    start
  211.