home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol048 / xmodem46.asm < prev   
Assembly Source File  |  1984-04-29  |  40KB  |  1,581 lines
  1. ;
  2. ;    XMODEM.ASM V4.6, by Keith Petersen, W8SDZ
  3. ;           (revised 10/19/81)
  4. ;
  5. ;    REMOTE CP/M - CP/M FILE TRANSFER PROGRAM
  6. ;
  7. ;Based on MODEM.ASM V2.0, by Ward Christensen.
  8. ;This program is intended for use on remote CP/M
  9. ;systems where it is important that the initialization
  10. ;of the modem not be changed, such as when using
  11. ;the PMMIBYE program. The baud rate and number of bits
  12. ;remains the same as whatever was set previously.
  13. ;There is no disconnect, terminal or echo option.
  14. ;
  15. ;Updates/fixes (in reverse order to minimize reading time):
  16. ;
  17. ;10/19/81 Corrected numerous 'IN MODCTL2' errors for the DC
  18. ;      Hayes modem.  Added DC Hayes detection of framing
  19. ;      errors, overrun errors, and parity errors (if
  20. ;      parity is used) for the receive file routine.
  21. ;      (Bill Aten)
  22. ;
  23. ;10/12/81 Added code to implement Cyclic Redundancy
  24. ;      Checking for both receiving and sending files.
  25. ;      The CRC can only be specified by the operator
  26. ;      on the receive file option as a secondary
  27. ;      option of 'C' (XMODEM RC FN.FT).  When CRC is
  28. ;      in effect, an initial 'C' instead of a NAK will
  29. ;      be sent to the sender to start things off.
  30. ;      The 'C' will be the signal to the sender
  31. ;      (hopefully a version of MODEM that implements
  32. ;      this CRC convention) that CRC is in effect.
  33. ;      CRC will then take the place of the checksum
  34. ;      checking for data validity.  The CRC should
  35. ;      make file transfers as far as data integrity is
  36. ;      concerned better than 99.99% error free.  The
  37. ;      crc macro, CRC120, was used to implement CRC
  38. ;      in this program and its equivalent version of
  39. ;      MODEM.  Acknowledgements and thanks to Paul
  40. ;      Hansknecht who designed and wrote CRC120.
  41. ;
  42. ;07/01/81 REDID H8/H89 EQUATES TESTED PROGRAM USING BOTH
  43. ;      SYSTEMS AND CHANGED VER TO 4.4    (AL OLANDER)
  44. ;
  45. ;06/28/81 INSTALL H8/H89 EQUATES AND CHANGE EXTERNAL
  46. ;      MODEM EQUATES TO "EXTMOD". (L. SHIPINSKI)
  47. ;
  48. ;05/30/81 Added IF PMMI/ENDIF to RCVERR routine to eliminate
  49. ;      'undefined symbol' error when set for DCH modem.
  50. ;      (Dave Hardy)
  51. ;
  52. ;05/07/81 Changed signon revision number.
  53. ;      Cleaned up file. (KBP)
  54. ;
  55. ;05/01/81 Added detection of framing errors, overrun
  56. ;      errors, and parity errors (if parity is used)
  57. ;      for the receive file routine.  This feature
  58. ;      is only active for the PMMI modem, since I
  59. ;      do not know what the modem status bits are
  60. ;      for IDS and D.C. Hayes modems.  If there
  61. ;      is one of the above errors, the line will
  62. ;      be purged for that block and a NAK will be
  63. ;      sent to the sender for that block.  This was
  64. ;      added to help catch those transmission errors
  65. ;      that are not always caught by the checksum.
  66. ;      This error checking is in addition to the
  67. ;      checksum routine. (John Mahr)
  68. ;
  69. ;02/17/81 Added test for "f2" tagged files in OPENOK
  70. ;      for MP/M version 1.1 compatiblity, which
  71. ;      doesn't allow Ctl-C or Ctl-S in "f1" tagged
  72. ;      files. (Tim Nicholas)
  73. ;
  74. ;02/16/81 Added hex to file size display. Now reports
  75. ;      size in both decimal and (xxxxH) hex. Thanks
  76. ;      to Ben Bronson for the idea. (Tim Nicholas)
  77. ;
  78. ;02/15/81 Added a software timer to the carrier test
  79. ;      added in SEND and RECV routines. This will
  80. ;      now abort only if carrier is lost for a 
  81. ;      period of 15 seconds. This is only essential
  82. ;      for those using external modems with certain
  83. ;      SIO's, but will provide the PMMI/DCH user
  84. ;      faster recovery in a lost carrier situation
  85. ;      as well. Approx 15 seconds plus 15 seconds
  86. ;      in BYE.COM, compared to 3 minutes at 300
  87. ;      baud with earlier revisions. Thanks to Ben
  88. ;      Bronson for his aid in developing this
  89. ;      revision. (Tim Nicholas)
  90. ;
  91. ;02/14/81 Corrected error in last update which read
  92. ;      the incorrect port for PMMI in the added
  93. ;      carrier test. (Tim Nicholas)
  94. ;    
  95. ;01/31/81 Added equates and code for a carrier test.
  96. ;      Test performed in modem I/O routines. This
  97. ;      is required since loss of carrier will go
  98. ;      undetected by BYE.COM, if the loss occurs
  99. ;      after a sucessful XMODEM signon, when using
  100. ;      an external modem and SIO. (Tim Nicholas)
  101. ;
  102. ;01/17/81 Re-wrote routine to calculate file size so
  103. ;         that it works correctly on v2.X systems with
  104. ;         extent folding (non-zero extent mask). (BRR)
  105. ;
  106. ;12/06/80 Re-wrote routine to calculate file size,
  107. ;      added decimal print of file size. (KBP)
  108. ;
  109. ;12/05/80 Corrected error in use of ext byte that pre-
  110. ;      vented files greater than one extent from 
  111. ;      being sent.     Ron Fowler
  112. ;
  113. ;12/03/80 Corrected file extent length display. Now
  114. ;      reports correct number of records for files
  115. ;      longer than one extent. Display is now
  116. ;      double precision (xxxxH). Also made some
  117. ;      cosmetic changes by re-arranging the equates.
  118. ;      By Tim Nicholas
  119. ;
  120. ;10/28/80 Cleaned up file. (KBP)
  121. ;
  122. ;10/23/80 Expanded conditional assembly of NOCOM routines
  123. ;      into NOCOMS, NOLBS, and NOCOMR equates, to allow
  124. ;      separate conditional assembly of tests for sending
  125. ;      .COM files, sending .??# files, and receiving .COM
  126. ;      files, respectively.    (Dave Hardy)
  127. ;
  128. ;10/15/80 Added traps for ambiguous file name or
  129. ;      none at all. (KBP)
  130. ;
  131. ;09/09/80 Added conditional assembly to prevent filetypes
  132. ;      '.COM' or '.??#' from being sent to distant end
  133. ;      and added conditional assembly of test for '.COM'
  134. ;      filetype on receive as well. See 'NOCOM' below.
  135. ;      Any filetype ending in '#' will not be sent by
  136. ;      this program if 'NOCOM' is set to TRUE.  J.SEYMOUR
  137. ;
  138. ;NOTE: If you add improvements or otherwise update
  139. ;this program, please modem a copy of the new file
  140. ;to "TECHNICAL CBBS" in Dearborn, Michigan - phone
  141. ;313-846-6127 (110, 300, 450 or 600 baud).  Use the
  142. ;filename XMODEM.NEW.    (KBP)
  143. ;
  144. FALSE    EQU    0
  145. TRUE    EQU    NOT FALSE
  146. ;
  147. ;-----------------------------------------------------
  148. ;     --- Conditional Assembly Options ---          ;
  149. ;------------------------------------------------------
  150. ;
  151. STDCPM    EQU    TRUE    ;TRUE, IS STANDARD CP/M
  152. ALTCPM    EQU    FALSE    ;TRUE, IS TRS-80 OR H8 W/O 0-ORG
  153. ;
  154. PMMI    EQU    FALSE     ;TRUE, IS PMMI
  155. DCH    EQU    TRUE    ;TRUE, IS D.C. HAYES
  156. H8    EQU    FALSE    ;TRUE, IS H8/H89 W/INS8250 MODEM CHIP
  157. EXTMOD    EQU    FALSE    ;TRUE, IS NONE OF THE ABOVE!
  158. ;
  159. NOCOMS    EQU    TRUE    ;TRUE, NO .COM FILES SENT
  160. NOLBS    EQU    TRUE    ;TRUE, NO .??# FILES SENT
  161. NOCOMR    EQU    TRUE    ;TRUE, NO .COM FILES RECEIVED
  162. ;
  163. FASTCLK EQU    TRUE    ;PUT TRUE HERE FOR 4 MHZ CLOCK
  164. ;
  165. FRNTPNL    EQU    FALSE    ;TO DISPLAY STATUS ON FRONT PANEL
  166. PANEL    EQU    0FFH    ;DEFAULT ADDRESS OF FRONT PANEL
  167. ;
  168. ;------------------------------------------------------
  169. ;         --- Modem Port Equates ---           ;
  170. ;------------------------------------------------------
  171. ;
  172.     IF    PMMI
  173. MODCTLP EQU    0C0H    ;PMMI VALUES(base port addr)
  174. MODSNDB EQU    1    ;BIT TO TEST FOR SEND
  175. MODSNDR EQU    1    ;VALUE WHEN READY
  176. MODRCVB EQU    2    ;BIT TO TEST FOR RECEIVE
  177. MODRCVR EQU    2    ;VALUE WHEN READY
  178. MODDCDB    EQU    4    ;CARRIER DETECT BIT
  179. MODDCDA    EQU    0    ;VALUE WHEN ACTIVE
  180. MODPARE    EQU    08H    ;VALUE FOR PARITY ERROR
  181. MODOVRE    EQU    10H    ;VALUE FOR OVERRUN ERROR
  182. MODFRME    EQU    20H    ;VALUE FOR FRAMING ERROR
  183. MODDATP EQU    MODCTLP+1;DATA PORT
  184. BAUDRP    EQU    MODCTLP+2;BAUD RATE OUTPUT/MODEM STATUS
  185. MODCTL2 EQU    MODCTLP+3;SECOND CTL PORT
  186.     ENDIF
  187. ;
  188.     IF    H8
  189. MODCTLP    EQU    0DDH    ;H8/H89 VALUES (LSR-LINE STATUS REG.)
  190. MODSNDB    EQU    20H    ;TEST FOR SEND (LSR-THRE)
  191. MODSNDR    EQU    20H    ;VALUE WHEN READY
  192. MODRCVB    EQU    01H    ;TEST FOR RECIEVE (LSR-DR)
  193. MODRCVR    EQU    01H    ;VALUE WHEN READY
  194. MODDCDB    EQU    20H    ;CARRIER DETECT BIT (MSR-CTS)
  195. MODDCDA    EQU    20H    ;VALUE WHEN ACTIVE
  196. MODPARE    EQU    04H    ;VALUE FOR PARITY ERROR (LSR-PE)
  197. MODOVRE    EQU    02H    ;VALUE FOR OVERRUN ERROR (LSR-OR)
  198. MODFRME    EQU    08H    ;VALUE FOR FRAMING ERROE (LSR-FE)
  199. MODDATP    EQU    0D8H    ;DATA PORT, SEND OR RECIEVE
  200. BAUDRP    EQU    0DDH    ;BAUD RATE PORT (DALB IN LCR MUST=1)
  201. MODCTL2    EQU    0DEH    ;MODEM STATUS REGISTER (MSR)
  202. MODCTL1    EQU    0DBH    ;LINE CONTROL REGISTER (LCR)
  203.     ENDIF
  204. ;
  205.     IF    DCH
  206. MODCTLP EQU    82H    ;D. C. HAYES VALUES
  207. MODSNDB EQU    2    ;BIT TO TEST FOR SEND
  208. MODSNDR EQU    2    ;VALUE WHEN READY
  209. MODRCVB EQU    1    ;BIT TO TEST FOR RECEIVE
  210. MODRCVR EQU    1    ;VALUE WHEN READY
  211. MODDCDB    EQU    40H    ;CARRIER DETECT BIT
  212. MODDCDA    EQU    40H    ;VALUE WHEN ACTIVE
  213. MODPARE    EQU    04H    ;VALUE FOR PARITY ERROR
  214. MODOVRE    EQU    10H    ;VALUE FOR OVERRUN ERROR
  215. MODFRME    EQU    08H    ;VALUE FOR FRAMING ERROR
  216. MODDATP EQU    80H    ;DATA PORT
  217. MODCTL2 EQU    81H    ;SECOND CTL PORT
  218.     ENDIF
  219. ;
  220. ;---> NOTE: DCD (Carrier Detect) values above are for
  221. ;        the Micromodem 100. For DC-Hayes 80-103
  222. ;        the values are different.
  223. ;        MODDCDB  EQU  1  ;Carrier bit (CTS).
  224. ;        MODDCDA  EQU  1  ;Active value.
  225. ;
  226. ;
  227. ;
  228. ;If you are using an external modem (not S-100 plug-in)
  229. ;change these equates for your modem port requirements
  230. ;
  231.     IF    EXTMOD
  232. MODCTLP EQU    35H    ;PUT YOUR MODEM STATUS PORT HERE
  233. MODSNDB EQU    01H    ;YOUR BIT TO TEST FOR SEND
  234. MODSNDR EQU    01H    ;YOUR VALUE WHEN READY
  235. MODRCVB EQU    02H    ;YOUR BIT TO TEST FOR RECEIVE
  236. MODRCVR EQU    02H    ;YOUR VALUE WHEN READY
  237. MODDCDB    EQU    1    ;CARRIER DETECT BIT
  238. MODDCDA    EQU    1    ;VALUE WHEN ACTIVE
  239. MODDATP EQU    34H    ;YOUR MODEM DATA PORT
  240. MODCTL2    EQU    36H    ;SECOND CONTROL/STATUS PORT.
  241.     ENDIF        ;END OF EXTERNAL MODEM EQUATES
  242. ;
  243. ;        --- End of Options ---
  244. ;------------------------------------------------------
  245. ;
  246. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS (10 STANDARD)
  247. ;
  248. ;Define ASCII characters used
  249. ;
  250. SOH    EQU    1    ;START OF HEADER
  251. EOT    EQU    4    ;END OF TRANSMISSION
  252. ACK    EQU    6    ;ACKNOWLEDGE
  253. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  254. CRC    EQU    'C'    ;CRC REQUEST CHARACTER
  255. CAN    EQU    18H    ;CONTROL-X FOR CANCEL
  256. LF    EQU    10    ;LINEFEED
  257. CR    EQU    13    ;CARRIAGE RETURN
  258. ; 
  259.     IF    STDCPM
  260. BASE    EQU    0    ;CP/M BASE ADDRESS
  261.     ENDIF
  262. ;
  263.     IF    ALTCPM
  264. BASE    EQU    4200H    ;ALTERNATE CP/M BASE ADDRESS
  265.     ENDIF
  266. ;
  267.     ORG    BASE+100H
  268. ;
  269. ;Init private stack
  270.     LXI    H,0    ;HL=0
  271.     DAD    SP    ;HL=STACK FROM CP/M
  272.     SHLD    STACK    ;..SAVE IT
  273.     LXI    SP,STACK ;SP=MY STACK
  274.     CALL    ILPRT    ;PRINT:
  275.     DB    CR,LF
  276.     DB    'XMODEM ver 4.6',CR,LF,0
  277. ;
  278. ;GET OPTION
  279. ;
  280.     LDA    FCB+2    ;SECONDARY OPTION?
  281.     CPI    'C'    ;CRC CHECKING REQUESTED?
  282.     JNZ    CHKOPTN    ;NO, GO CHECK PRIMARY
  283.     LDA    FCB+1    ;GET PRIMARY OPTION
  284.     CPI    'R'    ;CRC VALID ONLY FOR RECEIVE
  285.     JNZ    OPTNERR    ;PRT MSG, ABORT
  286.     XRA    A    ;ZERO ACCUM
  287.     STA    CRCFLG    ;TURN ON CRC FLAG
  288. ;
  289. CHKOPTN    LDA    FCB+1    ;GET OPTION (S or R)
  290.     PUSH    PSW    ;SAVE OPTION
  291. ;
  292. ;Move the filename from FCB2 to FCB1
  293. ;
  294.     CALL    MOVEFCB
  295. ;
  296. ;Gobble up garbage chars from the line
  297. ;prior to receive or send
  298. ;
  299.     IN    MODDATP
  300.     IN    MODDATP
  301. ;
  302. ;Jump to appropriate function
  303. ;
  304.     POP    PSW    ;GET OPTION
  305. ;
  306.     CPI    'S'    ;SEND..
  307.     JZ    SENDFIL ;..A FILE?
  308. ;
  309.     CPI    'R'    ;RECEIVE..
  310.     JZ    RCVFIL    ;..A FILE?
  311. ;
  312. ;Invalid option
  313. ;
  314. OPTNERR    CALL    ERXIT    ;EXIT W/ERROR
  315.     DB    '++INVALID OPTION ON XMODEM '
  316.     DB    'COMMAND++',CR,LF
  317.     DB    'Must be S for SEND; or R or RC '
  318.     DB    'for RECEIVE',CR,LF,'$'
  319. ;
  320. * * * * * * * * * * * * * * * * * * * * *
  321. *                    *
  322. *    SENDFIL: SENDS A CP/M FILE    *
  323. *                    *
  324. * * * * * * * * * * * * * * * * * * * * *
  325. ;
  326. ;The CP/M file specified in the XMODEM command
  327. ;is transferred over the phone to another
  328. ;computer running MODEM with the "R" (receive)
  329. ;option.  The data is sent one sector at a
  330. ;time with headers and checksums, and re-
  331. ;transmission on errors.  
  332. ;
  333. SENDFIL CALL    TRAP    ;CHECK FOR NO NAME OR AMBIG. NAME
  334.     CALL    CNREC    ;COMPUTE # OF RECORDS.
  335.     CALL    OPENFIL ;OPEN THE FILE
  336.     MVI    E,80    ;WAIT 80 SEC..
  337.     CALL    WAITNAK ;..FOR INITIAL NAK
  338. ;
  339. SENDLP    CALL    RDSECT    ;READ A SECTOR
  340.     JC    SENDEOF ;SEND EOF IF DONE
  341.     CALL    INCRSNO ;BUMP SECTOR #
  342.     XRA    A    ;ZERO ERROR..
  343.     STA    ERRCT    ;..COUNT
  344. ;
  345. SENDRPT CALL    SENDHDR ;SEND A HEADER
  346.     CALL    SENDSEC ;SEND DATA SECTOR
  347.     LDA    CRCFLG    ;GET CRC FLAG
  348.     ORA    A    ;CRC IN EFFECT?
  349.     CZ    SENDCRC    ;YES, SEND CRC
  350.     CNZ    SENDCKS ;NO, SEND CKSUM
  351.     CALL    GETACK    ;GET THE ACK
  352.     JC    SENDRPT ;REPEAT IF NO ACK
  353.     JMP    SENDLP    ;LOOP UNTIL EOF
  354. ;
  355. ;File sent, send EOT's
  356. ;
  357. SENDEOF MVI    A,EOT    ;SEND..
  358.     CALL    SEND    ;..AN EOT
  359.     CALL    GETACK    ;GET THE ACK
  360.     JC    SENDEOF ;LOOP IF NO ACK
  361.     JMP    EXIT    ;ALL DONE
  362. ;
  363. * * * * * * * * * * * * * * * * * * * * *
  364. *                    *
  365. *    RCVFIL: RECEIVE A FILE        *
  366. *                    *
  367. * * * * * * * * * * * * * * * * * * * * *
  368. ;
  369. ;Receives a file in block format as sent
  370. ;by another person doing "MODEM S FN.FT".
  371. ;Can be invoked by 'XMODEM R FN.FT' or
  372. ;by 'XMODEM RC FN.FT' if CRC is to be used.
  373. ;
  374. RCVFIL    CALL    TRAP    ;CHECK FOR NO NAME OR AMBIG. NAME
  375. ;
  376.     IF    NOCOMR
  377.     LXI    H,FCB+9 ;POINT TO FILETYPE
  378.     MVI    A,'C'    ;1ST LETTER
  379.     CMP    M    ;IS IT C ?
  380.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  381.     INX    H    ;GET 2ND LETTER
  382.     MVI    A,'O'    ;2ND LETTER
  383.     CMP    M    ;IS IT O ?
  384.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  385.     INX    H    ;GET 3RD LETTER
  386.     MVI    A,'M'    ;3RD LETTER
  387.     CMP    M    ;IS IT M ?
  388.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  389.     CALL    ERXIT    ;EXIT, PRINT ERROR MESSAGE
  390.     DB    '++CAN''T RECEIVE A .COM FILE++'
  391.     DB    CR,LF,CR,LF
  392.     DB    'Rename filetype ".OBJ" and try again'
  393.     DB    CR,LF,'$'
  394.     ENDIF
  395. ;
  396. CONTINU CALL    CHEKFIL ;SEE IF FILE EXISTS
  397.     CALL    MAKEFIL ;..THEN MAKE NEW
  398.     CALL    ILPRT    ;PRINT:
  399.     DB    'FILE OPEN - READY TO RECEIVE',CR,LF,0
  400. ;
  401. RCVLP    CALL    RCVSECT ;GET A SECTOR
  402.     JC    RCVEOT    ;GOT EOT
  403.     CALL    WRSECT    ;WRITE THE SECTOR
  404.     CALL    INCRSNO ;BUMP SECTOR #
  405.     CALL    SENDACK ;ACK THE SECTOR
  406.     JMP    RCVLP    ;LOOP UNTIL EOF
  407. ;
  408. ;Got EOT on sector - flush buffers, end
  409. ;
  410. RCVEOT    CALL    WRBLOCK ;WRITE THE LAST BLOCK
  411.     CALL    SENDACK ;ACK THE SECTOR
  412.     CALL    CLOSFIL ;CLOSE THE FILE
  413.     JMP    EXIT    ;ALL DONE
  414. ;
  415. * * * * * * * * * * * * * * * * * * * * *
  416. *                    *
  417. *        SUBROUTINES        *
  418. *                    *
  419. * * * * * * * * * * * * * * * * * * * * *
  420. ;
  421. ;---->    TRAP: Check for no file name or ambiguous name
  422. ;
  423. TRAP    LXI    H,FCB+1 ;POINT TO FILE NAME
  424.     MOV    A,M    ;GET FIRST CHAR OF FILE NAME
  425.     CPI    ' '    ;ANY THERE?
  426.     JNZ    ATRAP    ;YES, CHECK FOR AMBIGOUS FILE NAME
  427.     CALL    ERXIT    ;PRINT MSG, EXIT
  428.     DB    '++NO FILE NAME SPECIFIED++',CR,LF,'$'
  429. ;
  430. ATRAP    MVI    B,11    ;11 CHARS TO CHECK
  431. ;
  432. TRLOOP    MOV    A,M    ;GET CHAR FROM FCB
  433.     CPI    '?'    ;AMBIGUOUS?
  434.     JZ    TRERR    ;YES, EXIT WITH ERROR MSG
  435.     INX    H    ;POINT TO NEXT CHAR
  436.     DCR    B    ;ONE LESS TO GO
  437.     JNZ    TRLOOP    ;NOT DONE, CHECK SOME MORE
  438.     RET        ;NO AMBIGUOUS NAME, RETURN
  439. ;
  440. TRERR    CALL    ERXIT    ;PRINT MSG, EXIT
  441.     DB    '++CAN''T USE WILD CARD OPTIONS++',CR,LF,'$'
  442. ;
  443. ;---->    RCVSECT: Receive a sector
  444. ;
  445. ;Returns with carry set if EOT received.
  446. ;
  447. RCVSECT XRA    A    ;GET 0
  448.     STA    ERRCT    ;INIT ERROR COUNT
  449. ;
  450. RCVRPT:
  451.     IF    PMMI OR H8 OR DCH
  452.     XRA    A    ;GET 0
  453.     STA    ERRCDE    ;CLEAR RECEIVE ERROR CODE
  454.     ENDIF
  455. ;
  456.     MVI    B,10    ;10 SEC TIMEOUT
  457.     CALL    RECV    ;GET SOH/EOT
  458.     JC    RCVSTOT ;TIMEOUT
  459. ;
  460.     IF    PMMI OR H8 OR DCH
  461.     CALL    RCVERR    ;TRANS ERROR?
  462.     JC    RCVSERR    ;CARRY SET IF ERROR
  463.     ENDIF
  464. ;
  465.     CPI    SOH    ;GET SOH?
  466.     JZ    RCVSOH    ;..YES
  467. ;
  468. ;Earlier versions of MODEM program send some nulls -
  469. ;ignore them
  470. ;
  471.     ORA    A    ;00 FROM SPEED CHECK?
  472.     JZ    RCVRPT    ;YES, IGNORE IT
  473.     CPI    EOT    ;END OF TRANSFER?
  474.     STC        ;RETURN WITH CARRY..
  475.     RZ        ;..SET IF EOT
  476. ;
  477. ;Didn't get SOH or EOT - 
  478. ;    -or-
  479. ;Didn't get valid header - purge the line,
  480. ;then send NAK.
  481. ;
  482. RCVSERR MVI    B,1    ;WAIT FOR 1 SEC..
  483.     CALL    RECV    ;..WITH NO CHARS
  484.     JNC    RCVSERR ;LOOP UNTIL SENDER DONE
  485.     LDA    CRCFLG    ;GET CRC FLAG
  486.     ORA    A    ;CRC IN EFFECT?
  487.     MVI    A,NAK    ;PUT NAK IN ACCUM
  488.     JNZ    RCVSER2    ;NO, SEND THE NAK
  489.     LDA    FIRSTIME;GET FIRST TIME SWITCH
  490.     ORA    A    ;HAS FIRST SOH BEEN RECEIVED?
  491.     MVI    A,NAK    ;PUT NAK IN ACCUM
  492.     JZ    RCVSER2    ;YES, THEN SEND NAK
  493.     MVI    A,CRC    ;TELL SENDER CRC IS IN EFFECT
  494. ;
  495. RCVSER2    CALL    SEND    ;..THE NAK or CRC request
  496.     LDA    ERRCT    ;ABORT IF..
  497.     INR    A    ;..WE HAVE REACHED..
  498.     STA    ERRCT    ;..THE ERROR..
  499.     CPI    ERRLIM    ;..LIMIT?
  500.     JC    RCVRPT    ;..NO, TRY AGAIN
  501. ;
  502. ;10 errors in a row -
  503. ;
  504. RCVSABT CALL    CLOSFIL ;KEEP WHATEVER WE GOT
  505.     CALL    ERXIT
  506.     DB    '++UNABLE TO RECEIVE BLOCK '
  507.     DB    '- ABORTING++',CR,LF,'$'
  508. ;
  509. ;Timed out on receive
  510. ;
  511. RCVSTOT JMP    RCVSERR ;BUMP ERR CT, ETC.
  512. ;
  513. ;---->RCVERR: Checks to see if framing error, overrun, or
  514. ;        parity error occurred.
  515. ;    1. Error code (ERRCDE) was set in recv routine
  516. ;    2. ERRCDE=0 for no errors, ERRCDE<>0 for errors
  517. ;    3. If there has been an error, this routine sets
  518. ;        the carry bit on.
  519. ;
  520.     IF    PMMI OR H8 OR DCH
  521. RCVERR    PUSH    PSW    ;SAVE CHAR TRANSMITTED
  522.     LDA    ERRCDE    ;GET RECEIVE ERR CODE
  523.     ANA    A    ;IS IT ZERO?
  524.     JZ    RCVERR2    ;YES, NO ERROR
  525.     POP    PSW    ;RESTORE CHAR TRANSMITTED
  526.     STC        ;SET CARRY ON FOR ERROR
  527.     RET
  528. ;
  529. RCVERR2    POP    PSW    ;RESTORE CHAR TRANSMITTED
  530.     ORA    A    ;CLEAR CARRY BIT
  531.     RET
  532.     ENDIF
  533. ;
  534. ;Got SOH - get block #, block # complemented
  535. ;
  536. RCVSOH    XRA    A    ;ZERO ACCUM
  537.     STA    FIRSTIME;INDICATE FIRST SOH RECV'D
  538.     MVI    B,1    ;TIMEOUT = 1 SEC
  539.     CALL    RECV    ;GET SECTOR
  540.     JC    RCVSTOT ;GOT TIMEOUT
  541. ;
  542.     IF    PMMI OR H8 OR DCH
  543.     CALL    RCVERR    ;TRANS ERROR?
  544.     JC    RCVSERR    ;CARRY SET IF ERROR
  545.     ENDIF
  546. ;
  547.     MOV    D,A    ;D=BLK #
  548.     MVI    B,1    ;TIMEOUT = 1 SEC
  549.     CALL    RECV    ;GET CMA'D SECT #
  550.     JC    RCVSTOT ;TIMEOUT
  551. ;
  552.     IF    PMMI OR H8 OR DCH
  553.     CALL    RCVERR    ;TRANS ERROR?
  554.     JC    RCVSERR    ;CARRY SET IF ERROR
  555.     ENDIF
  556. ;
  557.     CMA        ;CALC COMPLEMENT
  558.     CMP    D    ;GOOD SECTOR #?
  559.     JZ    RCVDATA ;YES, GET DATA
  560. ;
  561. ;Got bad sector #
  562. ;
  563.     JMP    RCVSERR ;BUMP ERROR CT.
  564. ;
  565. RCVDATA MOV    A,D    ;GET SECTOR #
  566.     STA    RCVSNO    ;SAVE IT
  567.     MVI    C,0    ;INIT CKSUM
  568.     CALL    CLRCRC    ;CLEAR CRC COUNTER
  569.     LXI    H,BASE+80H ;POINT TO BUFFER
  570. ;
  571. RCVCHR    MVI    B,1    ;1 SEC TIMEOUT
  572.     CALL    RECV    ;GET CHAR
  573.     JC    RCVSTOT ;TIMEOUT
  574. ;
  575.     IF    PMMI OR H8 OR DCH
  576.     CALL    RCVERR    ;TRANS ERROR?
  577.     JC    RCVSERR    ;CARRY SET IF ERROR
  578.     ENDIF
  579. ;
  580.     MOV    M,A    ;STORE CHAR
  581.     INR    L    ;DONE?
  582.     JNZ    RCVCHR    ;NO, LOOP
  583.     LDA     CRCFLG    ;GET CRC FLAG
  584.     ORA    A    ;CRC IN EFFECT?
  585.     JZ    RCVCRC    ;YES, TO RECEIVE CRC
  586. ;
  587. ;Verify checksum
  588. ;
  589.     MOV    D,C    ;SAVE CHECKSUM
  590.     MVI    B,1    ;TIMEOUT LEN.
  591.     CALL    RECV    ;GET CHECKSUM
  592.     JC    RCVSTOT ;TIMEOUT
  593. ;
  594.     IF    PMMI OR H8 OR DCH
  595.     CALL    RCVERR    ;TRANS ERROR?
  596.     JC    RCVSERR    ;CARRY SET IF ERROR
  597.     ENDIF
  598. ;
  599.     CMP    D    ;CHECKSUM OK?
  600.     JNZ    RCVSERR ;NO, ERROR
  601. ;
  602. ;Got a sector, it's a duplicate if = previous,
  603. ;    or OK if = 1 + previous sector
  604. ;
  605. CHKSNUM    LDA    RCVSNO    ;GET RECEIVED
  606.     MOV    B,A    ;SAVE IT
  607.     LDA    SECTNO    ;GET PREV
  608.     CMP    B    ;PREV REPEATED?
  609.     JZ    RECVACK ;ACK TO CATCH UP
  610.     INR    A    ;CALC NEXT SECTOR #
  611.     CMP    B    ;MATCH?
  612.     JNZ    ABORT    ;NO MATCH - STOP SENDER, EXIT
  613.     RET        ;CARRY OFF - NO ERRORS
  614. ;
  615. ;---->    RCVCRC:    Receive the cyclic redundancy check
  616. ;        characters (2 bytes), and see if the crc
  617. ;        received matches the one calculated.
  618. ;        If they match, get next sector, else
  619. ;        send a NAK requesting the sector be
  620. ;        resent.
  621. ;
  622. RCVCRC    MVI    E,2    ;NUMBER OF BYTES TO RECEIVE
  623. ;
  624. RCVCRC2    MVI    B,1    ;1 SEC TIMEOUT
  625.     CALL    RECV    ;GET CRC BYTE
  626.     JC    RCVSTOT    ;TIMEOUT
  627. ;
  628.     IF    PMMI OR H8 OR DCH
  629.     CALL    RCVERR    ;TRANSMISSION ERROR?
  630.     JC    RCVSERR    ;YES, IF CARRY IS ON
  631.     ENDIF
  632. ;
  633.     DCR    E    ;DECREMENT NUM OF BYTES
  634.     JNZ    RCVCRC2    ;GET BOTH BYTES
  635.     CALL    CHKCRC    ;CHECK RCVD CRC AGAINST CALC'D CRC
  636.     ORA    A    ;IS CRC OKAY?
  637.     JZ    CHKSNUM    ;YES, GO CHECK SECTOR NUMBERS
  638.     JMP    RCVSERR    ;GO CHECK ERROR LIMIT AND SEND NAK
  639. ;
  640. ;Previous sector repeated, due to the last ACK
  641. ;being garbaged.  ACK it so sender will catch up 
  642. ;
  643. RECVACK CALL    SENDACK ;SEND THE ACK,
  644.     JMP    RCVSECT ;GET NEXT BLOCK
  645. ;
  646. ;Send an ACK for the sector
  647. ;
  648. SENDACK MVI    A,ACK    ;GET ACK
  649.     CALL    SEND    ;..AND SEND IT
  650.     RET
  651. ;
  652. ;---->    SENDHDR: Send the sector header
  653. ;
  654. ;SEND: (SOH) (block #) (complemented block #)
  655. ;
  656. SENDHDR MVI    A,SOH    ;SEND..
  657.     CALL    SEND    ;..SOH,
  658.     LDA    SECTNO    ;THEN SEND..
  659.     CALL    SEND    ;..SECTOR #
  660.     LDA    SECTNO    ;THEN SECTOR #
  661.     CMA        ;..COMPLEMENTED..
  662.     CALL    SEND    ;..SECTOR #
  663.     RET        ;FROM SENDHDR
  664. ;
  665. ;---->    SENDSEC: Send the data sector
  666. ;
  667. SENDSEC MVI    C,0    ;INIT CKSUM
  668.     CALL    CLRCRC    ;CLEAR THE CRC COUNTER
  669.     LXI    H,BASE+80H ;POINT TO BUFFER
  670. ;
  671. SENDC    MOV    A,M    ;GET A CHAR
  672.     CALL    SEND    ;SEND IT
  673.     INR    L    ;POINT TO NEXT CHAR
  674.     JNZ    SENDC    ;LOOP IF <100H
  675.     RET        ;FROM SENDSEC
  676. ;
  677. ;---->    SENDCKS: Send the checksum
  678. ;
  679. SENDCKS MOV    A,C    ;SEND THE..
  680.     CALL    SEND    ;..CHECKSUM
  681.     RET        ;FROM SENDCKS
  682. ;
  683. ;---->    SENDCRC: Send the two Cyclic Redundancy
  684. ;         Check characters.  Call FINCRC
  685. ;         to calc the CRC which will be in
  686. ;         d,e regs upon return.
  687. ;
  688. SENDCRC    CALL    FINCRC    ;CALC THE CRC FOR THIS SECTOR
  689.     MOV    A,D    ;PUT FIRST CRC BYTE IN ACCUM
  690.     CALL    SEND    ;SEND IT
  691.     MOV    A,E    ;PUT SECOND CRC BYTE IN ACCUM
  692.     CALL    SEND    ;SEND IT
  693.     XRA    A    ;SET ZERO RETURN CODE
  694.     RET
  695. ;
  696. ;---->    GETACK: Get the ACK on the sector
  697. ;
  698. ;Returns with carry clear if ACK received.
  699. ;If an ACK is not received, the error count
  700. ;is incremented, and if less than "ERRLIM",
  701. ;carry is set and control returns.  If the
  702. ;error count is at "ERRLIM", the program
  703. ;aborts.
  704. ;
  705. GETACK    MVI    B,10    ;WAIT 10 SECONDS MAX
  706.     CALL    RECVDG    ;RECV W/GARBAGE COLLECT
  707.     JC    GETATOT ;TIMED OUT
  708.     CPI    ACK    ;OK? (CARRY OFF IF =)
  709.     RZ        ;YES, RET FROM GETACK
  710. ;
  711. ;Timeout or error on ACK - bump error count
  712. ;
  713. ACKERR    LDA    ERRCT    ;GET COUNT
  714.     INR    A    ;BUMP IT
  715.     STA    ERRCT    ;SAVE BACK
  716.     CPI    ERRLIM    ;AT LIMIT?
  717.     RC        ;NOT AT LIMIT
  718. ;
  719. ;Reached error limit
  720. ;
  721. CSABORT CALL    ERXIT
  722.     DB    '++CAN''T SEND SECTOR '
  723.     DB    '- ABORTING++',CR,LF,'$'
  724. ;
  725. ;Timeout getting ACK
  726. ;
  727. GETATOT JMP    ACKERR    ;NO MSG
  728. ; 
  729. ABORT    LXI    SP,STACK
  730. ;
  731. ABORTL    MVI    B,1    ;1 SEC. W/O CHARS.
  732.     CALL    RECV
  733.     JNC    ABORTL    ;LOOP UNTIL SENDER DONE
  734.     MVI    A,CAN    ;CONTROL X
  735.     CALL    SEND    ;STOP SENDING END
  736. ;
  737. ABORTW    MVI    B,1    ;1 SEC W/O CHARS.
  738.     CALL    RECV
  739.     JNC    ABORTW    ;LOOP UNTIL SENDER DONE
  740.     MVI    A,' '    ;GET A SPACE...
  741.     CALL    SEND    ;TO CLEAR OUT CONTROL X
  742.     CALL    ERXIT    ;EXIT WITH ABORT MSG
  743.     DB    'XMODEM PROGRAM CANCELLED',CR,LF,'$'
  744. ;
  745. ;---->    INCRSNO: Increment sector #
  746. ;
  747. INCRSNO LDA    SECTNO    ;INCR..
  748.     INR    A    ;..SECT..
  749.     STA    SECTNO    ;..NUMBER
  750.     RET
  751. ;
  752. ;---->    CHEKFIL: See if file exists
  753. ;
  754. ;If it exists, say use a different name.
  755. ;
  756. CHEKFIL LXI    D,FCB    ;POINT TO CTL BLOCK
  757.     MVI    C,SRCHF ;SEE IF IT..
  758.     CALL    BDOS    ;..EXISTS
  759.     INR    A    ;FOUND?
  760.     RZ        ;..NO, RETURN
  761.     CALL    ERXIT    ;EXIT, PRINT ERROR MESSAGE
  762.     DB    '++FILE EXISTS - USE A DIFFERENT NAME++'
  763.     DB    CR,LF,'$'
  764. ;
  765. ;---->    MAKEFIL: Makes the file to be received
  766. ;
  767. MAKEFIL    XRA    A    ;SET EXT & REC # TO 0
  768.     STA    FCBEXT
  769.     STA    FCBSNO
  770.     LXI    D,FCB    ;POINT TO FCB
  771.     MVI    C,MAKE    ;GET BDOS FNC
  772.     CALL    BDOS    ;TO THE MAKE
  773.     INR    A    ;FF=BAD?
  774.     RNZ        ;OPEN OK
  775. ;Directory full - can't make file
  776.     CALL    ERXIT
  777.     DB    '++ERROR - CAN''T MAKE FILE++',CR,LF
  778.     DB    'Directory must be full',CR,LF,'$'
  779. ;
  780. ;---->    CNREC: Computes record count, and saves it
  781. ;           until successful file OPEN.
  782. ;
  783. ;LOOK UP THE FCB IN THE DIRECTORY
  784. CNREC    MVI    A,'?'    ;MATCH ALL EXTENTS
  785.     STA    FCBEXT
  786.     MVI    A,0FFH
  787.     STA    MAXEXT    ;INIT MAX EXT NO.
  788.     MVI    C,SRCHF ;GET 'SEARCH FIRST' FNC
  789.     LXI    D,FCB
  790.     CALL    BDOS    ;READ FIRST
  791.     INR    A    ;WERE THERE ANY?
  792.     JNZ    SOME    ;GOT SOME
  793.     CALL    ERXIT
  794.     DB    '++FILE NOT FOUND++$'
  795. ;
  796. ;READ MORE DIRECTORY ENTRIES
  797. MOREDIR    MVI    C,SRCHN ;SEARCH NEXT
  798.     LXI    D,FCB
  799.     CALL    BDOS    ;READ DIR ENTRY
  800.     INR    A    ;CHECK FOR END (0FFH)
  801.     JNZ    SOME    ;NOT END OF DIR...PROCESS EXTENT
  802.     LDA    MAXEXT    ;HIT END...GET HIGHEST EXTENT NO. SEEN
  803.     MOV    L,A    ;WHICH GIVES EXTENT COUNT - 1
  804.     MVI    H,0
  805.     MOV    D,H
  806.     LDA    RCNT    ;GET RECORD COUNT OF MAX EXTENT SEEN
  807.     MOV    E,A    ;SAVE IT IN DE
  808.     DAD    H
  809.     DAD    H    ;MULTIPLY # OF EXTENTS - 1
  810.     DAD    H    ; TIMES 128
  811.     DAD    H
  812.     DAD    H
  813.     DAD    H
  814.     DAD    H
  815.     DAD    D    ;ADD IN SIZE OF LAST EXTENT
  816.     SHLD    RCNT    ;SAVE TOTAL RECORD COUNT
  817.     RET        ;AND EXIT
  818. ;
  819. ;POINT TO DIRECTORY ENTRY 
  820. SOME    DCR    A    ;UNDO PREV 'INR A'
  821.     ANI    3    ;MAKE MODULUS 4
  822.     ADD    A    ;MULTIPLY...
  823.     ADD    A    ;..BY 32 BECAUSE
  824.     ADD    A    ;..EACH DIRECTORY
  825.     ADD    A    ;..ENTRY IS 32
  826.     ADD    A    ;..BYTES LONG
  827.     LXI    H,BASE+80H ;POINT TO BUFFER
  828.     ADD    L    ;POINT TO ENTRY
  829.     ADI    15    ;OFFSET TO RECORD COUNT
  830.     MOV    L,A    ;HL NOW POINTS TO REC COUNT
  831.     MOV    B,M    ;GET RECORD COUNT
  832.     DCX    H
  833.     DCX    H    ;BACK DOWN TO EXTENT NUMBER
  834.     DCX    H
  835.     LDA    MAXEXT    ;COMPARE WITH CURRENT MAX.
  836.     ORA    A    ;IF NO MAX YET
  837.     JM    BIGGER    ;THEN SAVE RECORD COUNT ANYWAY
  838.     CMP    M
  839.     JNC    MOREDIR
  840. ;
  841. BIGGER:    MOV    A,B    ;SAVE NEW RECORD COUNT
  842.     STA    RCNT
  843.     MOV    A,M    ;SAVE NEW MAX. EXTENT NO.
  844.     STA    MAXEXT
  845.     JMP    MOREDIR    ;GO FIND MORE EXTENTS
  846. ;
  847. ;---->    OPENFIL: Opens the file to be sent
  848. ;
  849. OPENFIL    XRA    A    ;SET EXT & REC # TO 0 FOR PROPER OPEN
  850.     STA    FCBEXT
  851.     STA    FCBSNO
  852.     LXI    D,FCB    ;POINT TO FILE
  853.     MVI    C,OPEN    ;GET FUNCTION
  854.     CALL    BDOS    ;OPEN IT
  855.     INR    A    ;OPEN OK?
  856.     JNZ    OPENOK    ;..YES
  857.     CALL    ERXIT    ;..NO, ABORT
  858.     DB    '++OPEN ERROR++',CR,LF,'$'
  859. ;
  860. ;Check for distribution-protected file
  861. ;
  862. OPENOK    LDA    FCB+1    ;FIRST CHAR OF FILE NAME
  863.     ANI    80H    ;CHECK BIT 7
  864.     JNZ    OPENOT    ;If on, file can't be sent.
  865.     LDA    FCB+2    ;Also check "f2" for tag.
  866.     ANI    80H    ;Is it set?
  867.     JZ    OPENOK2    ;If not, ok to send file.
  868. ;
  869. OPENOT    CALL    ERXIT    ;EXIT W/MESSAGE
  870.     DB    '++THIS FILE IS NOT FOR DISTRIBUTION, SORRY++'
  871.     DB    CR,LF,'$'
  872. ;
  873. OPENOK2 EQU    $
  874. ;
  875.     IF    NOLBS OR NOCOMS ;CHECK FOR SEND RESTRICTIONS
  876.     LXI    H,FCB+11
  877.     MOV    A,M    ;CHECK FOR PROTECT ATTR
  878.     ANI    7FH    ;REMOVE CP/M 2.x ATTRS
  879.     ENDIF        ;NOLBS OR NOCOMS
  880. ;
  881.     IF    NOLBS    ;DON'T ALLOW '#' TO BE SENT.
  882.     CPI    '#'    ;CHK FOR '#' AS LAST FIRST
  883.     JZ    OPENOT    ;IF '#', CAN'T SEND, SHOW WHY
  884.     ENDIF        ;NOLBS
  885. ;
  886.     IF    NOCOMS    ;DON'T ALLOW .COM TO BE SENT
  887.     CPI    'M'    ;IF NOT, CHK FOR '.COM'
  888.     JNZ    OPENOK3 ;IF NOT, OK TO SEND
  889.     DCX    H
  890.     MOV    A,M    ;CHK NEXT CHAR
  891.     ANI    7FH    ;STRIP ATTRIBUTES
  892.     CPI    'O'    ; 'O'?
  893.     JNZ    OPENOK3 ;IF NOT, OK TO SEND
  894.     DCX    H
  895.     MOV    A,M    ;NOW CHK FIRST CHAR
  896.     ANI    7FH    ;STRIP ATTRIBUTES
  897.     CPI    'C'    ; 'C' AS IN '.COM'?
  898.     JNZ    OPENOK3 ;IF NOT, CONTINUE
  899.     CALL    ERXIT    ;EXIT W/MESSAGE
  900.     DB    '++CAN''T SEND A .COM FILE++'
  901.     DB    CR,LF,'$'
  902.     ENDIF        ;NOCOMS
  903. ;
  904. OPENOK3 CALL    ILPRT    ;PRINT:
  905.     DB    'FILE OPEN - SIZE: ',0
  906.     LHLD    RCNT    ; Get record count.
  907.     CALL    DECOUT    ;PRINT DECIMAL NUMBER OF SECTORS
  908.     CALL    ILPRT    ;Print:
  909.     DB    ' (',0
  910.     CALL    DHXOUT    ;Now print size in hex.
  911.     CALL    ILPRT    ;PRINT:
  912.     DB    'H) SECTORS',CR,LF,0
  913.     RET
  914. ;
  915. ;---->    CLOSFIL: Closes the received file
  916. ;
  917. CLOSFIL LXI    D,FCB    ;POINT TO FILE
  918.     MVI    C,CLOSE ;GET FUNCTION
  919.     CALL    BDOS    ;CLOSE IT
  920.     INR    A    ;CLOSE OK?
  921.     RNZ        ;..YES, RETURN
  922.     CALL    ERXIT    ;..NO, ABORT
  923.     DB    '++CAN''T CLOSE FILE++',CR,LF,'$'
  924. ;
  925. ;
  926. ;----> DECOUT: Decimal output routine
  927. ;
  928. DECOUT:    PUSH    B
  929.     PUSH    D
  930.     PUSH    H
  931.     LXI    B,-10
  932.     LXI    D,-1
  933. ;
  934. DECOU2:    DAD    B
  935.     INX    D
  936.     JC    DECOU2
  937.     LXI    B,10
  938.     DAD    B
  939.     XCHG
  940.     MOV    A,H
  941.     ORA    L
  942.     CNZ    DECOUT
  943.     MOV    A,E
  944.     ADI    '0'
  945.     CALL    CTYPE
  946.     POP    H
  947.     POP    D
  948.     POP    B
  949.     RET
  950. ;
  951. ;---->    DHXOUT: - double precision hex output routine.
  952. ;    Call with hex value in HL.
  953. ;
  954. DHXOUT    PUSH    H    ;Save H,L
  955.     PUSH    PSW    ;Save A
  956.     MOV    A,H    ;Get MS byte.
  957.     CALL    HEXO    ;Output hi order byte.
  958.     MOV    A,L    ;Get LS byte.
  959.     CALL    HEXO    ;Output lo order byte.
  960.     POP    PSW    ;Restore A
  961.     POP    H    ;Restore H,L
  962.     RET        ;Return to caller.
  963. ;
  964. ;
  965. ;---->    RDSECT: Reads a sector
  966. ;
  967. ;For speed, this routine buffers up 16
  968. ;sectors at a time.
  969. ;
  970. RDSECT    LDA    SECINBF ;GET # SECT IN BUFF.
  971.     DCR    A    ;DECREMENT..
  972.     STA    SECINBF ;..IT
  973.     JM    RDBLOCK ;EXHAUSTED?  NEED MORE.
  974.     LHLD    SECPTR    ;GET POINTER
  975.     LXI    D,BASE+80H ;TO DATA
  976.     CALL    MOVE128 ;MOVE TO BUFFER
  977.     SHLD    SECPTR    ;SAVE BUFFER POINTER
  978.     RET        ;FROM "READSEC"
  979. ;
  980. ;Buffer is empty - read in another block of 16
  981. ;
  982. RDBLOCK LDA    EOFLG    ;GED EOF FLAG
  983.     CPI    1    ;IS IT SET?
  984.     STC        ;TO SHOW EOF
  985.     RZ        ;GOT EOF
  986.     MVI    C,0    ;SECTORS IN BLOCK
  987.     LXI    D,DBUF    ;TO DISK BUFFER
  988. ;
  989. RDSECLP PUSH    B
  990.     PUSH    D
  991.     MVI    C,STDMA ;SET DMA..
  992.     CALL    BDOS    ;..ADDR
  993.     LXI    D,FCB
  994.     MVI    C,READ
  995.     CALL    BDOS
  996.     POP    D
  997.     POP    B
  998.     ORA    A    ;READ OK?
  999.     JZ    RDSECOK ;YES
  1000.     DCR    A    ;EOF?
  1001.     JZ    REOF    ;GOT EOF
  1002. ;
  1003. ;Read error
  1004. ;
  1005.     CALL    ERXIT
  1006.     DB    '++FILE READ ERROR++',CR,LF,'$'
  1007. ;
  1008. RDSECOK LXI    H,80H    ;ADD LENGTH OF ONE SECTOR...
  1009.     DAD    D    ;...TO NEXT BUFF
  1010.     XCHG        ;BUFF TO DE
  1011.     INR    C    ;MORE SECTORS?
  1012.     MOV    A,C    ;GET COUNT
  1013.     CPI    16    ;DONE?
  1014.     JZ    RDBFULL ;..YES, BUFF IS FULL
  1015.     JMP    RDSECLP ;READ MORE
  1016. ;
  1017. REOF    MVI    A,1
  1018.     STA    EOFLG    ;SET EOF FLAG
  1019.     MOV    A,C
  1020. ;
  1021. ;Buffer is full, or got EOF
  1022. ;
  1023. RDBFULL STA    SECINBF ;STORE SECTOR COUNT
  1024.     LXI    H,DBUF    ;INIT BUFFER..
  1025.     SHLD    SECPTR    ;..POINTER
  1026.     LXI    D,BASE+80H ;RESET..
  1027.     MVI    C,STDMA ;..DMA..
  1028.     CALL    BDOS    ;..ADDR
  1029.     JMP    RDSECT    ;PASS SECT TO CALLER
  1030. ;
  1031. ;---->    WRSECT: Write a sector
  1032. ;
  1033. ;Writes the sector into a buffer.  When 16
  1034. ;have been written, writes the block to disk.
  1035. ;
  1036. ;Entry point "WRBLOCK" flushes the buffer at EOF.
  1037. ;
  1038. WRSECT    LHLD    SECPTR    ;GET BUFF ADDR
  1039.     XCHG        ;TO DE FOR MOVE
  1040.     LXI    H,BASE+80H    ;FROM HERE
  1041.     CALL    MOVE128 ;MOVE TO BUFFER
  1042.     XCHG        ;SAVE NEXT..
  1043.     SHLD    SECPTR    ;..BLOCK POINTER
  1044.     LDA    SECINBF ;BUMP THE..
  1045.     INR    A    ;..SECTOR #..
  1046.     STA    SECINBF ;..IN THE BUFF
  1047.     CPI    16    ;HAVE WE 16?
  1048.     RNZ        ;NO, RETURN
  1049. ;
  1050. ;---->    WRBLOCK: Writes a block to disk
  1051. ;
  1052. WRBLOCK LDA    SECINBF ;# SECT IN BUFFER
  1053.     ORA    A    ;0 MEANS END OF FILE
  1054.     RZ        ;NONE TO WRITE
  1055.     MOV    C,A    ;SAVE COUNT
  1056.     LXI    D,DBUF    ;POINT TO DISK BUFF
  1057. ;
  1058. DKWRLP    PUSH    H
  1059.     PUSH    D
  1060.     PUSH    B
  1061.     MVI    C,STDMA ;SET DMA
  1062.     CALL    BDOS    ;TO BUFFER
  1063.     LXI    D,FCB    ;THEN WRITE
  1064.     MVI    C,WRITE ;..THE..
  1065.     CALL    BDOS    ;..BLOCK
  1066.     POP    B
  1067.     POP    D
  1068.     POP    H
  1069.     ORA    A
  1070.     JNZ    WRERR    ;OOPS, ERROR
  1071.     LXI    H,80H    ;LENGTH OF 1 SECT
  1072.     DAD    D    ;HL= NEXT BUFF
  1073.     XCHG        ;TO DE FOR SETDMA
  1074.     DCR    C    ;MORE SECTORS?
  1075.     JNZ    DKWRLP    ;..YES, LOOP
  1076.     XRA    A    ;GET A ZERO
  1077.     STA    SECINBF ;RESET # OF SECTORS
  1078.     LXI    H,DBUF    ;RESET BUFFER..
  1079.     SHLD    SECPTR    ;..POINTER
  1080. ;
  1081. RSDMA    LXI    D,BASE+80H ;RESET..
  1082.     MVI    C,STDMA ;..DMA..
  1083.     CALL    BDOS    ;..ADDR
  1084.     RET
  1085. ;
  1086. WRERR    CALL    RSDMA    ;RESET DMA TO NORM.
  1087.     MVI    C,CAN    ;CANCEL..
  1088.     CALL    SEND    ;..SENDER
  1089.     CALL    ERXIT    ;EXIT W/MSG:
  1090.     DB    '++ERROR WRITING FILE++',CR,LF,'$'
  1091. ;
  1092. ;---->    RECV: Receive a character
  1093. ;
  1094. ;Timeout time is in B, in seconds.  Entry via
  1095. ;"RECVDG" deletes garbage characters on the
  1096. ;line.    For example, having just sent a sector,
  1097. ;calling RECVDG will delete any line-noise-induced
  1098. ;characters "long" before the ACK/NAK would
  1099. ;be received.
  1100. ;
  1101. RECVDG    EQU    $    ;RECEIVE W/GARBAGE DELETE
  1102.     IN    MODDATP ;GET A CHAR
  1103.     IN    MODDATP ;..TOTALLY PURGE UART
  1104. ;
  1105. RECV    PUSH    D    ;SAVE
  1106. ;
  1107.     IF    FASTCLK ;4MHZ?
  1108.     MOV    A,B    ;GET TIME REQUEST
  1109.     ADD    A    ;DOUBLE IT
  1110.     MOV    B,A    ;NEW TIME IN B
  1111.     ENDIF
  1112. ;
  1113. MSEC    LXI    D,50000 ;1 SEC DCR COUNT
  1114. ;
  1115.     IF    NOT DCH
  1116. MWTI    IN    MODCTLP ;CHECK STATUS
  1117.     ENDIF
  1118. ;
  1119.     IF    DCH
  1120. MWTI    IN    MODCTL2 ;CHECK STATUS
  1121.     ENDIF
  1122. ;
  1123.     IF    PMMI AND FRNTPNL
  1124.     OUT    PANEL    ;DISPLAY STATUS ON PANEL LIGHTS
  1125.     ENDIF
  1126. ;
  1127.     ANI    MODRCVB ;ISOLATE BIT
  1128.     CPI    MODRCVR ;READY?
  1129.     JZ    MCHAR    ;GOT CHAR
  1130.     DCR    E    ;COUNT..
  1131.     JNZ    MWTI    ;..DOWN..
  1132.     DCR    D    ;..FOR..
  1133.     JNZ    MWTI    ;..TIMEOUT
  1134.     DCR    B    ;MORE SECONDS?
  1135.     JNZ    MSEC    ;YES, WAIT
  1136. ;
  1137. ;Test for the presence of carrier - if none, go to 
  1138. ;CARCK and continue testing for 15 seconds. If carrier
  1139. ;returns, continue. If is doesn't return, exit.
  1140. ;
  1141.     IF    EXTMOD OR H8 OR DCH
  1142.     IN    MODCTL2    ;READ MODEM STATUS
  1143.     ENDIF
  1144. ;
  1145.     IF    PMMI
  1146.     IN    BAUDRP    ;READ MODEM STATUS
  1147.     ENDIF
  1148. ;
  1149.     IF    PMMI AND FRNTPNL
  1150.     OUT    PANEL    ;DISPLAY STATUS ON PANEL LIGHTS
  1151.     ENDIF
  1152. ;
  1153.     ANI    MODDCDB    ;CARRIER DETECT MASK
  1154.     CPI    MODDCDA    ;IS IT STILL ON?
  1155.     CNZ    CARCK    ;IF NOT, TEST FOR 15 SECONDS
  1156. ;
  1157. ;Modem timed out receiving - but carrier still on.
  1158. ;
  1159.     POP    D    ;RESTORE D,E
  1160.     STC        ;CARRY SHOWS TIMEOUT
  1161.     RET
  1162. ;
  1163. ;Got character from modem
  1164. ;
  1165. MCHAR:
  1166.     IF    PMMI OR H8 OR DCH
  1167. ;Check to see if there was a framing error,
  1168. ;overrun, or parity error.
  1169. ;
  1170.     IF    PMMI OR H8
  1171.     IN    MODCTLP    ;GET MODEM STATUS
  1172.     ENDIF
  1173. ;
  1174.     IF    DCH
  1175.     IN    MODCTL2    ;GET MODEM STATUS
  1176.     ENDIF
  1177. ;
  1178.     MOV    D,A    ;SAVE STATUS
  1179.     ANI    MODFRME    ;FRAMING ERROR?
  1180.     CPI    MODFRME
  1181.     JNZ    MCHAR2    ;NO, CHECK FOR OVERRUN
  1182.     LDA    ERRCDE    ;GET RECV ERR CODE
  1183.     ORI    MODFRME    ;TURN ON RECV ERR CODE
  1184.     STA    ERRCDE    ;PUT IT BACK
  1185. ;
  1186. MCHAR2:    MOV    A,D    ;RESTORE MODEM STATUS
  1187.     ANI    MODOVRE    ;OVERRUN?
  1188.     CPI    MODOVRE
  1189.     JNZ    MCHAR3    ;NO, CHECK FOR PARITY ERROR
  1190.     LDA    ERRCDE
  1191.     ORI    MODOVRE    ;TURN ON RECV ERR CODE
  1192.     STA    ERRCDE
  1193. ;
  1194. MCHAR3:    MOV    A,D    ;RESTORE MODEM STATUS
  1195.     ANI    MODPARE    ;PARITY ERROR?
  1196.     CPI    MODPARE
  1197.     JNZ    MCHAR4    ;NO, GET DATA CHAR
  1198.     LDA    ERRCDE
  1199.     ORI    MODPARE
  1200.     STA    ERRCDE
  1201. ;
  1202. MCHAR4:
  1203.     ENDIF        ;PMMI OR H8 OR DCH
  1204. ;
  1205. ;Get data char
  1206. ;
  1207.     IN    MODDATP ;READ THE CHAR
  1208.     POP    D    ;RESTORE DE
  1209. ;
  1210. ;Calc checksum and CRC
  1211. ;
  1212.     PUSH    PSW    ;SAVE THE CHAR
  1213.     CALL    UPDCRC    ;CALC CRC
  1214.     ADD    C    ;ADD TO CHECKSUM
  1215.     MOV    C,A    ;SAVE CHECKSUM
  1216.     POP    PSW    ;RESTORE CHAR
  1217.     ORA    A    ;CARRY OFF: NO ERROR
  1218.     RET        ;FROM "RECV"
  1219. ;
  1220. ;CARCK - common 15 second carrier test for RECV and
  1221. ;SEND. If carrier returns within 15 seconds, normal
  1222. ;program execution continues. Else, it will abort
  1223. ;to CP/M via EXIT.
  1224. ;
  1225. CARCK    MVI    E,150    ;VALUE FOR 15 SECOND DELAY
  1226. ;
  1227. CARCK1    CALL    DELAY    ;KILL .1 SECONDS
  1228. ;
  1229.     IF    EXTMOD OR H8 OR DCH
  1230.     IN    MODCTL2    ;READ MODEM STATUS
  1231.     ENDIF
  1232. ;
  1233.     IF    PMMI
  1234.     IN    BAUDRP    ;READ MODEM STATUS
  1235.     ENDIF
  1236. ;
  1237.     IF    PMMI AND FRNTPNL
  1238.     OUT    PANEL    ;DISPLAY STATUS
  1239.     ENDIF
  1240. ;
  1241.     ANI    MODDCDB    ;CARRIER DETECT MASK
  1242.     CPI    MODDCDA    ;IS IT STILL ON?
  1243.     RZ        ;RETURN IF CARRIER ON
  1244.     DCR    E    ;HAS 15 SECONDS EXPIRED?
  1245.     JNZ    CARCK1    ;IF NOT, CONTINUE TESTING
  1246.     JMP    EXIT    ;ELSE, ABORT TO CP/M.
  1247. ;
  1248. ;DELAY - 100 millisecond delay.
  1249. ;
  1250. DELAY    PUSH    B    ;SAVE B,C
  1251. ;
  1252.     IF    FASTCLK    ;IF 4MHZ CLOCK
  1253.     LXI    B,16667    ;VALUE FOR 100MS DELAY
  1254.     ENDIF
  1255. ;
  1256.     IF    NOT FASTCLK
  1257.     LXI    B,8334    ;VALUE FOR 100MS DELAY
  1258.     ENDIF
  1259. ;
  1260. DELAY2    DCX    B    ;UPDATE COUNT
  1261.     MOV    A,B    ;GET MS BYTE
  1262.     ORA    C    ;COUNT = ZERO?
  1263.     JNZ    DELAY2    ;IF NOT, CONTINUE
  1264.     POP    B    ;RESTORE B,C
  1265.     RET        ;RETURN TO CARCK1.
  1266. ;
  1267. ;---->    SEND: Send a character to the modem
  1268. ;
  1269. SEND    PUSH    PSW    ;SAVE THE CHARACTER
  1270.     CALL    UPDCRC    ;calc the crc
  1271.     ADD    C    ;CALC CKSUM
  1272.     MOV    C,A    ;SAVE CKSUM
  1273. ;
  1274.     IF    NOT DCH
  1275. SENDW    IN    MODCTLP ;GET STATUS
  1276.     ENDIF
  1277. ;
  1278.     IF    DCH
  1279. SENDW    IN    MODCTL2 ;GET STATUS
  1280.     ENDIF
  1281. ;
  1282.     IF    PMMI AND FRNTPNL
  1283.     OUT    PANEL    ;DISPLAY STATUS
  1284.     ENDIF
  1285. ;
  1286.     ANI    MODSNDB ;ISOLATE READY BIT
  1287.     CPI    MODSNDR ;READY?
  1288.     JZ    SENDR    ;..YES, GO SEND
  1289. ;
  1290. ;Xmit status not ready, so test for carrier before
  1291. ;looping - if lost, go to CARCK and give it up to 15
  1292. ;seconds to return. If it doesn't return abort via
  1293. ;EXIT.
  1294. ;
  1295.     PUSH    D    ;Save D,E
  1296. ;
  1297.     IF    EXTMOD OR H8 OR DCH
  1298.     IN    MODCTL2    ;READ MODEM STATUS
  1299.     ENDIF
  1300. ;
  1301.     IF    PMMI
  1302.     IN    BAUDRP    ;READ MODEM STATUS
  1303.     ENDIF
  1304. ;
  1305.     IF    PMMI AND FRNTPNL
  1306.     OUT    PANEL    ;DISPLAY STATUS
  1307.     ENDIF
  1308. ;
  1309.     ANI    MODDCDB    ;CARRIER DETECT MASK
  1310.     CPI    MODDCDA    ;IS IT STILL ON?
  1311.     CNZ    CARCK    ;IF NOT, CONTINUE TESTING IT
  1312.     POP    D    ;RESTORE D,E
  1313.     JMP    SENDW    ;ELSE, WAIT FOR XMIT READY.
  1314. ;
  1315. ;Xmit status ready, carrier still on - send the data.
  1316. ;
  1317. SENDR    POP    PSW    ;GET CHAR
  1318.     OUT    MODDATP ;OUTPUT IT
  1319.     RET        ;FROM "SEND"
  1320. ;
  1321. ;---->    WAITNAK: Waits for initial NAK
  1322. ;
  1323. ;To ensure no data is sent until the receiving
  1324. ;program is ready, this routine waits for the
  1325. ;first timeout-NAK or the letter 'C' for CRC
  1326. ;from the receiver.  If CRC is in effect, then
  1327. ;Cyclic Redundancy Checks are used instead of
  1328. ;checksums.
  1329. ;(E) contains the # of seconds to wait.
  1330. ;
  1331. WAITNAK MVI    B,1    ;TIMEOUT DELAY
  1332.     CALL    RECV    ;DID WE GET..
  1333.     CPI    NAK    ;..A NAK?
  1334.     RZ        ;YES, SEND BLOCK
  1335.     CPI    CRC    ;CRC INDICATED?
  1336.     JZ    WAITCRC    ;YES, GO PUT CRC IN EFFECT
  1337.     DCR    E    ;80 TRIES?
  1338.     JZ    ABORT    ;YES, ABORT
  1339.     JMP    WAITNAK ;NO, LOOP
  1340. ;
  1341. ;----> WAITCRC: Turn on CRC Flag
  1342. ;
  1343. WAITCRC    XRA    A    ;ZERO ACCUM
  1344.     STA    CRCFLG    ;TURN ON CRC OPT
  1345.     RET
  1346. ;
  1347. ;---->    MOVEFCB: Moves FCB(2) to FCB
  1348. ;
  1349. ;In order to make the XMODEM command 'natural',
  1350. ;i.e. XMODEM SEND FILENAME (MODEM S FN.FT) rather
  1351. ;than XMODEM FILENAME SEND (MODEM FN.FT S), this
  1352. ;routine moves the filename from the second FCB
  1353. ;to the first.
  1354. ;
  1355. MOVEFCB LXI    H,FCB+16 ;FROM
  1356.     LXI    D,FCB    ;TO
  1357.     MVI    B,16    ;LEN
  1358.     CALL    MOVE    ;DO THE MOVE
  1359.     XRA    A    ;GET 0
  1360.     STA    FCBSNO    ;ZERO SECTOR #
  1361.     STA    FCBEXT    ;..AND EXTENT
  1362.     RET
  1363. ;
  1364. CTYPE    PUSH    B    ;SAVE..
  1365.     PUSH    D    ;..ALL..
  1366.     PUSH    H    ;..REGS
  1367.     MOV    E,A    ;CHAR TO E
  1368.     MVI    C,WRCON ;GET BDOS FNC
  1369.     CALL    BDOS    ;PRIN THE CHR
  1370.     POP    H    ;RESTORE..
  1371.     POP    D    ;..ALL..
  1372.     POP    B    ;..REGS
  1373.     RET        ;FROM "CTYPE"
  1374. ;
  1375. HEXO    PUSH    PSW    ;SAVE FOR RIGHT DIGIT
  1376.     RAR        ;RIGHT..
  1377.     RAR        ;..JUSTIFY..
  1378.     RAR        ;..LEFT..
  1379.     RAR        ;..DIGIT..
  1380.     CALL    NIBBL    ;PRINT LEFT DIGIT
  1381.     POP    PSW    ;RESTORE RIGHT
  1382. ;
  1383. NIBBL    ANI    0FH    ;ISOLATE DIGIT
  1384.     CPI    10    ;IS IT <10?
  1385.     JC    ISNUM    ;YES, NOT ALPHA
  1386.     ADI    7    ;ADD ALPHA BIAS
  1387. ;
  1388. ISNUM    ADI    '0'    ;MAKE PRINTABLE
  1389.     JMP    CTYPE    ;..THEN TYPE IT
  1390. ;
  1391. ;---->    ILPRT: Inline print of message
  1392. ;
  1393. ;The call to ILPRT is followed by a message,
  1394. ;binary 0 as the end.
  1395. ;
  1396. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  1397. ;
  1398. ILPLP    MOV    A,M    ;GET CHAR
  1399.     ORA    A    ;END OF MSG?
  1400.     JZ    ILPRET    ;..YES, RETURN
  1401.     CALL    CTYPE    ;TYPE THE MSG
  1402.     INX    H    ;TO NEXT CHAR
  1403.     JMP    ILPLP    ;LOOP
  1404. ;
  1405. ILPRET    XTHL        ;RESTORE HL
  1406.     RET        ;PAST MSG
  1407. ;
  1408. ;---->    ERXIT: Exit printing message following call
  1409. ;
  1410. ERXIT    POP    D    ;GET MESSAGE
  1411.     MVI    C,PRINT ;GET BDOS FNC
  1412.     CALL    BDOS    ;PRINT MESSAGE
  1413. ;
  1414. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  1415.     SPHL        ;RESTORE IT
  1416.     RET        ;--EXIT-- TO CP/M
  1417. ;
  1418. ;Move 128 characters
  1419. ;
  1420. MOVE128 MVI    B,128    ;SET MOVE COUNT
  1421. ;
  1422. ;Move from (HL) to (DE) length in (B)
  1423. ;
  1424. MOVE    MOV    A,M    ;GET A CHAR
  1425.     STAX    D    ;STORE IT
  1426.     INX    H    ;TO NEXT "FROM"
  1427.     INX    D    ;TO NEXT "TO"
  1428.     DCR    B    ;MORE?
  1429.     JNZ    MOVE    ;..YES, LOOP
  1430.     RET        ;..NO, RETURN
  1431. ;
  1432. ;************************************************************************
  1433. ;* CRCSUBS (Cyclic Redundancy Code Subroutines) version 1.20        *
  1434. ;* 8080 Mnemonics                            *
  1435. ;*                                    *
  1436. ;*         These subroutines will compute and check a true 16-bit        *
  1437. ;*    Cyclic Redundancy Code for a message of arbitrary length.    *
  1438. ;*                                    *
  1439. ;*    The  use  of this scheme will guarantee detection of all    *
  1440. ;*    single and double bit errors, all  errors  with  an  odd    *
  1441. ;*    number  of  error bits, all burst errors of length 16 or    *
  1442. ;*    less, 99.9969% of all 17-bit error bursts, and  99.9984%    *
  1443. ;*    of  all  possible  longer  error bursts.  (Ref: Computer    *
  1444. ;*    Networks, Andrew S.  Tanenbaum, Prentiss-Hall, 1981)        *
  1445. ;*                                    *
  1446. ;*                                    *
  1447. ;*    There are four entry points, which are used as follows:        *
  1448. ;*                                    *
  1449. ;*    CLRCRC - A call to this entry resets the CRC accumulator.    *
  1450. ;*         It must be called at the start of each message.    *
  1451. ;*                                    *
  1452. ;*         Entry Parameters: None.                *
  1453. ;*                                    *
  1454. ;*         Exit Conditions:  CRC accumulator cleared.        *
  1455. ;*                   All registers preserved.        *
  1456. ;*                                    *
  1457. ;*                                    *
  1458. ;*    UPDCRC - A call to this entry updates the CRC accumulator.    *
  1459. ;*         It must be called once for each byte in the        *
  1460. ;*         message for which the CRC is being calculated.        *
  1461. ;*                                    *
  1462. ;*         Entry Parameters: (A) = a byte to be included        *
  1463. ;*                     in the CRC calculation.    *
  1464. ;*                                    *
  1465. ;*         Exit Conditions:  CRC accumulator updated.        *
  1466. ;*                   All registers preserved.        *
  1467. ;*                                    *
  1468. ;*                                    *
  1469. ;*    FINCRC - A call to this entry finishes the CRC calculation    *
  1470. ;*         for a message which is to be TRANSMITTED. It must    *
  1471. ;*         be called after the last byte of the message has    *
  1472. ;*         been passed thru UPDCRC. It returns the calculated    *
  1473. ;*         CRC bytes, which must be transmitted as the final    *
  1474. ;*         two bytes of the message (first D, then E).        *
  1475. ;*                                    *
  1476. ;*         Entry Parameters: None.                *
  1477. ;*                                    *
  1478. ;*         Exit Conditions:  (DE) = calculated CRC bytes.        *
  1479. ;*                   All other registers preserved.    *
  1480. ;*                                    *
  1481. ;*                                    *
  1482. ;*    CHKCRC - A call to this routine checks the CRC bytes of        *
  1483. ;*         a RECEIVED message and returns a code to indicate    *
  1484. ;*         whether the message was received correctly. It must    *
  1485. ;*         be called after the message AND the two CRC bytes    *
  1486. ;*         have been received AND passed thru UPDCRC.        *
  1487. ;*                                    *
  1488. ;*         Entry Parameters: None.                *
  1489. ;*                                    *
  1490. ;*         Exit Conditions:  (A) =  0 if message ok.        *
  1491. ;*                   (A) = -1 if message garbled.        *
  1492. ;*                   All other registers preserved.    *
  1493. ;*                                    *
  1494. ;************************************************************************
  1495. ;*                                    *
  1496. ;*    Designed & coded by Paul Hansknecht, June 13, 1981        *
  1497. ;*                                    *
  1498. ;*                                    *
  1499. ;*    Copyright (c) 1981, Carpenter Associates            *
  1500. ;*                Box 451                    *
  1501. ;*                Bloomfield Hills, MI 48013            *
  1502. ;*                313/855-3074                *
  1503. ;*                                    *
  1504. ;*    This program may be freely reproduced for non-profit use.    *
  1505. ;*                                    *
  1506. ;************************************************************************
  1507. ;
  1508. ;    ENTRY    CLRCRC,UPDCRC,FINCRC,CHKCRC
  1509. ;
  1510. CLRCRC:    EQU    $        ; Reset CRC Accumulator for a new message.
  1511.     PUSH    H
  1512.     LXI    H,0
  1513.     SHLD    CRCVAL
  1514.     POP    H
  1515.     RET
  1516. ;
  1517. UPDCRC:    EQU    $        ; Update CRC Accumulator using byte in (A).
  1518.     PUSH    PSW
  1519.     PUSH    B
  1520.     PUSH    H
  1521.     MVI    B,8
  1522.     MOV    C,A
  1523.     LHLD    CRCVAL
  1524. UPDLOOP:MOV    A,C
  1525.     RLC
  1526.     MOV    C,A
  1527.     MOV    A,L
  1528.     RAL
  1529.     MOV    L,A
  1530.     MOV    A,H
  1531.     RAL
  1532.     MOV    H,A
  1533.     JNC    SKIPIT
  1534.     MOV    A,H        ; The generator is X^16 + X^12 + X^5 + 1
  1535.     XRI    10H        ; as recommended by CCITT.
  1536.     MOV    H,A        ; An alternate generator which is often
  1537.     MOV    A,L        ; used in synchronous transmission protocols
  1538.     XRI    21H        ; is X^16 + X^15 + X^2 + 1. This may be
  1539.     MOV    L,A        ; used by substituting XOR 80H for XOR 10H
  1540. SKIPIT:    DCR    B        ; and XOR 05H for XOR 21H in the adjacent code.
  1541.     JNZ    UPDLOOP
  1542.     SHLD    CRCVAL
  1543.     POP    H
  1544.     POP    B
  1545.     POP    PSW
  1546.     RET
  1547. ;
  1548. FINCRC:    EQU    $        ; Finish CRC calc for outbound message.
  1549.     PUSH    PSW
  1550.     XRA    A
  1551.     CALL    UPDCRC
  1552.     CALL    UPDCRC
  1553.     PUSH    H
  1554.     LHLD    CRCVAL
  1555.     MOV    D,H
  1556.     MOV    E,L
  1557.     POP    H
  1558.     POP    PSW
  1559.     RET
  1560. ;
  1561. CHKCRC:    EQU    $        ; Check CRC bytes of received message.
  1562.     PUSH    H
  1563.     LHLD    CRCVAL
  1564.     MOV    A,H
  1565.     ORA    L
  1566.     POP    H
  1567.     RZ
  1568.     MVI    A,0FFh
  1569.     RET
  1570. ;
  1571. ;
  1572. CRCVAL    DW    0
  1573. ;
  1574. ;
  1575. ;
  1576. ;Temporary storage area
  1577. ;
  1578. MAXEXT    DB    0    ;HIGHEST EXTENT NO. SEEN IN FILE SIZE CALC.
  1579. RCNT    DW    0    ;RECORD COUNT
  1580. RCVSNO    DB    0    ;SECT # RECEIVED
  1581. SECTNO    DB    0    ;CURRENT SECTO